mime-def.el

   1 ;;; mime-def.el --- definition module about MIME
   2
   3 ;; Copyright (C) 1995,1996,1997,1998,1999 Free Software Foundation, Inc.
   4 ;; Copyright (C) 1999 Electrotechnical Laboratory, JAPAN.
   5 ;; Licensed to the Free Software Foundation.
   6
   7 ;; Author: MORIOKA Tomohiko <tomo@m17n.org>
   8 ;; Keywords: definition, MIME, multimedia, mail, news
   9
  10 ;; This file is part of FLIM (Faithful Library about Internet Message).
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (require 'poe)
  30 (require 'poem)
  31 (require 'pcustom)
  32 (require 'mcharset)
  33 (require 'alist)
  34
  35 (eval-when-compile (require 'cl))       ; list*
  36
  37 (eval-and-compile
  38   (defconst mime-library-product ["FLIM" (1 13 2) "Kasanui"]
  39     "Product name, version number and code name of MIME-library package.")
  40   )
  41
  42 (defmacro mime-product-name (product)
  43   `(aref ,product 0))
  44
  45 (defmacro mime-product-version (product)
  46   `(aref ,product 1))
  47
  48 (defmacro mime-product-code-name (product)
  49   `(aref ,product 2))
  50
  51 (defconst mime-library-version
  52   (eval-when-compile
  53     (concat (mime-product-name mime-library-product) " "
  54             (mapconcat #'number-to-string
  55                        (mime-product-version mime-library-product) ".")
  56             " - \"" (mime-product-code-name mime-library-product) "\"")))
  57
  58
  59 ;;; @ variables
  60 ;;;
  61
  62 (require 'custom)
  63
  64 (defgroup mime '((default-mime-charset custom-variable))
  65   "Emacs MIME Interfaces"
  66   :group 'news
  67   :group 'mail)
  68
  69 (defcustom mime-uuencode-encoding-name-list '("x-uue" "x-uuencode")
  70   "*List of encoding names for uuencode format."
  71   :group 'mime
  72   :type '(repeat string))
  73
  74
  75 ;;; @ required functions
  76 ;;;
  77
  78 (defsubst regexp-* (regexp)
  79   (concat regexp "*"))
  80
  81 (defsubst regexp-or (&rest args)
  82   (concat "\\(" (mapconcat (function identity) args "\\|") "\\)"))
  83
  84
  85 ;;; @ about STD 11
  86 ;;;
  87
  88 (eval-and-compile
  89   (defconst std11-quoted-pair-regexp "\\\\.")
  90   (defconst std11-non-qtext-char-list '(?\" ?\\ ?\r ?\n))
  91   (defconst std11-qtext-regexp
  92     (eval-when-compile
  93       (concat "[^" std11-non-qtext-char-list "]"))))
  94 (defconst std11-quoted-string-regexp
  95   (eval-when-compile
  96     (concat "\""
  97             (regexp-*
  98              (regexp-or std11-qtext-regexp std11-quoted-pair-regexp))
  99             "\"")))
 100
 101
 102 ;;; @ about MIME
 103 ;;;
 104
 105 (eval-and-compile
 106   (defconst mime-tspecial-char-list
 107     '(?\] ?\[ ?\( ?\) ?< ?> ?@ ?, ?\; ?: ?\\ ?\" ?/ ?? ?=)))
 108 (defconst mime-token-regexp
 109   (eval-when-compile
 110     (concat "[^" mime-tspecial-char-list "\000-\040]+")))
 111 (defconst mime-charset-regexp mime-token-regexp)
 112
 113 (defconst mime-media-type/subtype-regexp
 114   (concat mime-token-regexp "/" mime-token-regexp))
 115
 116
 117 ;;; @@ base64 / B
 118 ;;;
 119
 120 (defconst base64-token-regexp "[A-Za-z0-9+/]")
 121 (defconst base64-token-padding-regexp "[A-Za-z0-9+/=]")
 122
 123 (defconst B-encoded-text-regexp
 124   (concat "\\(\\("
 125           base64-token-regexp
 126           base64-token-regexp
 127           base64-token-regexp
 128           base64-token-regexp
 129           "\\)*"
 130           base64-token-regexp
 131           base64-token-regexp
 132           base64-token-padding-regexp
 133           base64-token-padding-regexp
 134           "\\)"))
 135
 136 ;; (defconst eword-B-encoding-and-encoded-text-regexp
 137 ;;   (concat "\\(B\\)\\?" eword-B-encoded-text-regexp))
 138
 139
 140 ;;; @@ Quoted-Printable / Q
 141 ;;;
 142
 143 (defconst quoted-printable-hex-chars "0123456789ABCDEF")
 144
 145 (defconst quoted-printable-octet-regexp
 146   (concat "=[" quoted-printable-hex-chars
 147           "][" quoted-printable-hex-chars "]"))
 148
 149 (defconst Q-encoded-text-regexp
 150   (concat "\\([^=?]\\|" quoted-printable-octet-regexp "\\)+"))
 151
 152 ;; (defconst eword-Q-encoding-and-encoded-text-regexp
 153 ;;   (concat "\\(Q\\)\\?" eword-Q-encoded-text-regexp))
 154
 155
 156 ;;; @ Content-Type
 157 ;;;
 158
 159 (defsubst make-mime-content-type (type subtype &optional parameters)
 160   (list* (cons 'type type)
 161          (cons 'subtype subtype)
 162          (nreverse parameters))
 163   )
 164
 165 (defsubst mime-content-type-primary-type (content-type)
 166   "Return primary-type of CONTENT-TYPE."
 167   (cdr (car content-type)))
 168
 169 (defsubst mime-content-type-subtype (content-type)
 170   "Return primary-type of CONTENT-TYPE."
 171   (cdr (cadr content-type)))
 172
 173 (defsubst mime-content-type-parameters (content-type)
 174   "Return primary-type of CONTENT-TYPE."
 175   (cddr content-type))
 176
 177 (defsubst mime-content-type-parameter (content-type parameter)
 178   "Return PARAMETER value of CONTENT-TYPE."
 179   (cdr (assoc parameter (mime-content-type-parameters content-type))))
 180
 181
 182 (defsubst mime-type/subtype-string (type &optional subtype)
 183   "Return type/subtype string from TYPE and SUBTYPE."
 184   (if type
 185       (if subtype
 186           (format "%s/%s" type subtype)
 187         (format "%s" type))))
 188
 189
 190 ;;; @ Content-Disposition
 191 ;;;
 192
 193 (defsubst mime-content-disposition-type (content-disposition)
 194   "Return disposition-type of CONTENT-DISPOSITION."
 195   (cdr (car content-disposition)))
 196
 197 (defsubst mime-content-disposition-parameters (content-disposition)
 198   "Return disposition-parameters of CONTENT-DISPOSITION."
 199   (cdr content-disposition))
 200
 201 (defsubst mime-content-disposition-parameter (content-disposition parameter)
 202   "Return PARAMETER value of CONTENT-DISPOSITION."
 203   (cdr (assoc parameter (cdr content-disposition))))
 204
 205 (defsubst mime-content-disposition-filename (content-disposition)
 206   "Return filename of CONTENT-DISPOSITION."
 207   (mime-content-disposition-parameter content-disposition "filename"))
 208
 209
 210 ;;; @ MIME entity
 211 ;;;
 212
 213 (require 'luna)
 214
 215 (autoload 'mime-entity-content-type "mime")
 216 (autoload 'mime-parse-multipart "mime-parse")
 217 (autoload 'mime-parse-encapsulated "mime-parse")
 218 (autoload 'mime-entity-content "mime")
 219
 220 (luna-define-class mime-entity ()
 221                    (location
 222                     content-type children parent
 223                     node-id
 224                     content-disposition encoding
 225                     ;; for other fields
 226                     original-header parsed-header))
 227
 228 (defalias 'mime-entity-representation-type-internal 'luna-class-name)
 229 (defalias 'mime-entity-set-representation-type-internal 'luna-set-class-name)
 230
 231 (luna-define-internal-accessors 'mime-entity)
 232
 233 (luna-define-method mime-entity-fetch-field ((entity mime-entity)
 234                                              field-name)
 235   (or (symbolp field-name)
 236       (setq field-name (intern (capitalize (capitalize field-name)))))
 237   (cdr (assq field-name
 238              (mime-entity-original-header-internal entity))))
 239
 240 (luna-define-method mime-entity-children ((entity mime-entity))
 241   (let* ((content-type (mime-entity-content-type entity))
 242          (primary-type (mime-content-type-primary-type content-type)))
 243     (cond ((eq primary-type 'multipart)
 244            (mime-parse-multipart entity)
 245            )
 246           ((and (eq primary-type 'message)
 247                 (memq (mime-content-type-subtype content-type)
 248                       '(rfc822 news external-body)
 249                       ))
 250            (mime-parse-encapsulated entity)
 251            ))
 252     ))
 253
 254 (luna-define-method mime-insert-text-content ((entity mime-entity))
 255   (insert
 256    (decode-mime-charset-string (mime-entity-content entity)
 257                                (or (mime-content-type-parameter
 258                                     (mime-entity-content-type entity)
 259                                     "charset")
 260                                    default-mime-charset)
 261                                'CRLF)
 262    ))
 263
 264
 265 ;;; @ for mm-backend
 266 ;;;
 267
 268 (defmacro mm-expand-class-name (type)
 269   `(intern (format "mime-%s-entity" ,type)))
 270
 271 (defmacro mm-define-backend (type &optional parents)
 272   `(luna-define-class ,(mm-expand-class-name type)
 273                       ,(nconc (mapcar (lambda (parent)
 274                                         (mm-expand-class-name parent)
 275                                         )
 276                                       parents)
 277                               '(mime-entity))))
 278
 279 (defmacro mm-define-method (name args &rest body)
 280   (or (eq name 'initialize-instance)
 281       (setq name (intern (format "mime-%s" name))))
 282   (let ((spec (car args)))
 283     (setq args
 284           (cons (list (car spec)
 285                       (mm-expand-class-name (nth 1 spec)))
 286                 (cdr args)))
 287     `(luna-define-method ,name ,args ,@body)
 288     ))
 289
 290 (put 'mm-define-method 'lisp-indent-function 'defun)
 291
 292 (def-edebug-spec mm-define-method
 293   (&define name ((arg symbolp)
 294                  [&rest arg]
 295                  [&optional ["&optional" arg &rest arg]]
 296                  &optional ["&rest" arg]
 297                  )
 298            def-body))
 299
 300
 301 ;;; @ message structure
 302 ;;;
 303
 304 (defvar mime-message-structure nil
 305   "Information about structure of message.
 306 Please use reference function `mime-entity-SLOT' to get value of SLOT.
 307
 308 Following is a list of slots of the structure:
 309
 310 node-id                 node-id (list of integers)
 311 content-type            content-type (content-type)
 312 content-disposition     content-disposition (content-disposition)
 313 encoding                Content-Transfer-Encoding (string or nil)
 314 children                entities included in this entity (list of entity)
 315
 316 If an entity includes other entities in its body, such as multipart or
 317 message/rfc822, `mime-entity' structures of them are included in
 318 `children', so the `mime-entity' structure become a tree.")
 319
 320 (make-variable-buffer-local 'mime-message-structure)
 321
 322 (make-obsolete-variable 'mime-message-structure "should not use it.")
 323
 324
 325 ;;; @ for mel-backend
 326 ;;;
 327
 328 (defvar mel-service-list nil)
 329
 330 (defmacro mel-define-service (name &optional args &rest rest)
 331   "Define NAME as a service for Content-Transfer-Encodings.
 332 If ARGS is specified, NAME is defined as a generic function for the
 333 service."
 334   `(progn
 335      (add-to-list 'mel-service-list ',name)
 336      (defvar ,(intern (format "%s-obarray" name)) (make-vector 7 0))
 337      ,@(if args
 338            `((defun ,name ,args
 339                ,@rest
 340                (funcall (mel-find-function ',name ,(car (last args)))
 341                         ,@(luna-arglist-to-arguments (butlast args)))
 342                )))
 343      ))
 344
 345 (put 'mel-define-service 'lisp-indent-function 'defun)
 346
 347
 348 (defvar mel-encoding-module-alist nil)
 349
 350 (defsubst mel-find-function-from-obarray (ob-array encoding)
 351   (let* ((f (intern-soft encoding ob-array)))
 352     (or f
 353         (let ((rest (cdr (assoc encoding mel-encoding-module-alist))))
 354           (while (and rest
 355                       (progn
 356                         (require (car rest))
 357                         (null (setq f (intern-soft encoding ob-array)))
 358                         ))
 359             (setq rest (cdr rest))
 360             )
 361           f))))
 362
 363 (defsubst mel-copy-method (service src-backend dst-backend)
 364   (let* ((oa (symbol-value (intern (format "%s-obarray" service))))
 365          (f (mel-find-function-from-obarray oa src-backend))
 366          sym)
 367     (when f
 368       (setq sym (intern dst-backend oa))
 369       (or (fboundp sym)
 370           (fset sym (symbol-function f))
 371           ))))
 372
 373 (defsubst mel-copy-backend (src-backend dst-backend)
 374   (let ((services mel-service-list))
 375     (while services
 376       (mel-copy-method (car services) src-backend dst-backend)
 377       (setq services (cdr services)))))
 378
 379 (defmacro mel-define-backend (type &optional parents)
 380   "Define TYPE as a mel-backend.
 381 If PARENTS is specified, TYPE inherits PARENTS.
 382 Each parent must be backend name (string)."
 383   (cons 'progn
 384         (mapcar (lambda (parent)
 385                   `(mel-copy-backend ,parent ,type)
 386                   )
 387                 parents)))
 388
 389 (defmacro mel-define-method (name args &rest body)
 390   "Define NAME as a method function of (nth 1 (car (last ARGS))) backend.
 391 ARGS is like an argument list of lambda, but (car (last ARGS)) must be
 392 specialized parameter.  (car (car (last ARGS))) is name of variable
 393 and (nth 1 (car (last ARGS))) is name of backend (encoding)."
 394   (let* ((specializer (car (last args)))
 395          (class (nth 1 specializer)))
 396     `(progn
 397        (mel-define-service ,name)
 398        (fset (intern ,class ,(intern (format "%s-obarray" name)))
 399              (lambda ,(butlast args)
 400                ,@body)))))
 401
 402 (put 'mel-define-method 'lisp-indent-function 'defun)
 403
 404 (defmacro mel-define-method-function (spec function)
 405   "Set SPEC's function definition to FUNCTION.
 406 First element of SPEC is service.
 407 Rest of ARGS is like an argument list of lambda, but (car (last ARGS))
 408 must be specialized parameter.  (car (car (last ARGS))) is name of
 409 variable and (nth 1 (car (last ARGS))) is name of backend (encoding)."
 410   (let* ((name (car spec))
 411          (args (cdr spec))
 412          (specializer (car (last args)))
 413          (class (nth 1 specializer)))
 414     `(let (sym)
 415        (mel-define-service ,name)
 416        (setq sym (intern ,class ,(intern (format "%s-obarray" name))))
 417        (or (fboundp sym)
 418            (fset sym (symbol-function ,function))))))
 419
 420 (defmacro mel-define-function (function spec)
 421   (let* ((name (car spec))
 422          (args (cdr spec))
 423          (specializer (car (last args)))
 424          (class (nth 1 specializer)))
 425     `(progn
 426        (define-function ,function
 427          (intern ,class ,(intern (format "%s-obarray" name))))
 428        )))
 429
 430 (defvar base64-dl-module
 431   (if (and (fboundp 'base64-encode-string)
 432            (subrp (symbol-function 'base64-encode-string)))
 433       nil
 434     (if (fboundp 'dynamic-link)
 435         (let ((path (expand-file-name "base64.so" exec-directory)))
 436           (and (file-exists-p path)
 437                path)
 438           ))))
 439
 440
 441 ;;; @ end
 442 ;;;
 443
 444 (provide 'mime-def)
 445
 446 ;;; mime-def.el ends here