git.chise.org Git - elisp/gnus.git-/blob - lisp/deuglify.el

   1 ;;; deuglify.el --- deuglify broken Outlook (Express) articles
   2
   3 ;; Copyright (C) 2002 Free Software Foundation, Inc.
   4 ;; Copyright (C) 2001,2002 Raymond Scholz
   5
   6 ;; Author: Raymond Scholz <rscholz@zonix.de>
   7 ;;         Thomas Steffen (unwrapping algorithm,
   8 ;;                         based on an idea of Stefan Monnier)
   9 ;; Keywords: mail, news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This file enables Gnus to repair broken citations produced by
  31 ;; common user agents like MS Outlook (Express).  It may repair
  32 ;; articles of other user agents too.
  33 ;;
  34 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  35
  36 ;;
  37 ;; Outlook sometimes wraps cited lines before sending a message as
  38 ;; seen in this example:
  39 ;;
  40 ;; Example #1
  41 ;; ----------
  42 ;;
  43 ;; John Doe wrote:
  44 ;;
  45 ;; > This sentence no verb.  This sentence no verb.  This sentence
  46 ;; no
  47 ;; > verb.  This sentence no verb.  This sentence no verb.  This
  48 ;; > sentence no verb.
  49 ;;
  50 ;; The function `gnus-outlook-unwrap-lines' tries to recognize those
  51 ;; erroneously wrapped lines and will unwrap them.  I.e. putting the
  52 ;; wrapped parts ("no" in this example) back where they belong (at the
  53 ;; end of the cited line above).
  54 ;;
  55 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  56 ;;
  57 ;; Note that some people not only use broken user agents but also
  58 ;; practice a bad citation style by omitting blank lines between the
  59 ;; cited text and their own text.
  60 ;:
  61 ;; Example #2
  62 ;; ----------
  63 ;;
  64 ;; John Doe wrote:
  65 ;;
  66 ;; > This sentence no verb.  This sentence no verb.  This sentence no
  67 ;; You forgot in all your sentences.
  68 ;; > verb.  This sentence no verb.  This sentence no verb.  This
  69 ;; > sentence no verb.
  70 ;;
  71 ;; Unwrapping "You forgot in all your sentences." would be illegal as
  72 ;; this part wasn't intended to be cited text.
  73 ;; `gnus-outlook-unwrap-lines' will only unwrap lines if the resulting
  74 ;; citation line will be of a certain maximum length.  You can control
  75 ;; this by adjusting `gnus-outlook-deuglify-unwrap-max'.  Also
  76 ;; unwrapping will only be done if the line above the (possibly)
  77 ;; wrapped line has a minimum length of `gnus-outlook-deuglify-unwrap-min'.
  78 ;;
  79 ;; Furthermore no unwrapping will be undertaken if the last character
  80 ;; is one of the chars specified in
  81 ;; `gnus-outlook-deuglify-unwrap-stop-chars'.  Setting this to ".?!"
  82 ;; inhibits unwrapping if the cited line ends with a full stop,
  83 ;; question mark or exclamation mark.  Note that this variable
  84 ;; defaults to `nil', triggering a few false positives but generally
  85 ;; giving you better results.
  86 ;;
  87 ;; Unwrapping works on every level of citation.  Thus you will be able
  88 ;; repair broken citations of broken user agents citing broken
  89 ;; citations of broken user agents citing broken citations...
  90 ;;
  91 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  92 ;;
  93 ;; Citations are commonly introduced with an attribution line
  94 ;; indicating who wrote the cited text.  Outlook adds superfluous
  95 ;; information that can be found in the header of the message to this
  96 ;; line and often wraps it.
  97 ;;
  98 ;; If that weren't enough, lots of people write their own text above
  99 ;; the cited text and cite the complete original article below.
 100 ;;
 101 ;; Example #3
 102 ;; ----------
 103 ;;
 104 ;; Hey, John.  There's no in all your sentences!
 105 ;;
 106 ;; John Doe <john.doe@some.domain> wrote in message
 107 ;; news:a87usw8$dklsssa$2@some.news.server...
 108 ;; > This sentence no verb.  This sentence no verb.  This sentence
 109 ;; no
 110 ;; > verb.  This sentence no verb.  This sentence no verb.  This
 111 ;; > sentence no verb.
 112 ;; >
 113 ;; > Bye, John
 114 ;;
 115 ;; Repairing the attribution line will be done by function
 116 ;; `gnus-outlook-repair-attribution' which calls other function that
 117 ;; try to recognize and repair broken attribution lines.  See variable
 118 ;; `gnus-outlook-deuglify-attrib-cut-regexp' for stuff that should be
 119 ;; cut off from the beginning of an attribution line and variable
 120 ;; `gnus-outlook-deuglify-attrib-verb-regexp' for the verbs that are
 121 ;; required to be found in an attribution line.  These function return
 122 ;; the point where the repaired attribution line starts.
 123 ;;
 124 ;; Rearranging the article so that the cited text appears above the
 125 ;; new text will be done by function
 126 ;; `gnus-outlook-rearrange-citation'.  This function calls
 127 ;; `gnus-outlook-repair-attribution' to find and repair an attribution
 128 ;; line.
 129 ;;
 130 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 131 ;;
 132 ;; Well, and that's what the message will look like after applying
 133 ;; deuglification:
 134 ;;
 135 ;; Example #3 (deuglified)
 136 ;; -----------------------
 137 ;;
 138 ;; John Doe <john.doe@some.domain> wrote:
 139 ;;
 140 ;; > This sentence no verb.  This sentence no verb.  This sentence no
 141 ;; > verb.  This sentence no verb.  This sentence no verb.  This
 142 ;; > sentence no verb.
 143 ;; >
 144 ;; > Bye, John
 145 ;;
 146 ;; Hey, John.  There's no in all your sentences!
 147 ;;
 148 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 149 ;;
 150 ;; Usage
 151 ;; -----
 152 ;;
 153 ;; Press `W k' in the Summary Buffer.
 154 ;;
 155 ;; Non recommended usage :-)
 156 ;; ---------------------
 157 ;;
 158 ;; To automatically invoke deuglification on every article you read,
 159 ;; put something like that in your .gnus:
 160 ;;
 161 ;; (add-hook 'gnus-article-decode-hook 'gnus-outlook-unwrap-lines)
 162 ;;
 163 ;; or _one_ of the following lines:
 164 ;;
 165 ;; ;; repair broken attribution lines
 166 ;; (add-hook 'gnus-article-decode-hook 'gnus-outlook-repair-attribution)
 167 ;;
 168 ;; ;; repair broken attribution lines and citations
 169 ;; (add-hook 'gnus-article-decode-hook 'gnus-outlook-rearrange-citation)
 170 ;;
 171 ;; Note that there always may be some false positives, so I suggest
 172 ;; using the manual invocation.  After deuglification you may want to
 173 ;; refill the whole article using `W w'.
 174 ;;
 175 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 176 ;;
 177 ;; Limitations
 178 ;; -----------
 179 ;;
 180 ;; As I said before there may (or will) be a few false positives on
 181 ;; unwrapping cited lines with `gnus-outlook-unwrap-lines'.
 182 ;;
 183 ;; `gnus-outlook-repair-attribution' will only fix the first
 184 ;; attribution line found in the article.  Furthermore it fixed to
 185 ;; certain kinds of attributions.  And there may be horribly many
 186 ;; false positives, vanishing lines and so on -- so don't trust your
 187 ;; eyes.  Again I recommend manual invocation.
 188 ;;
 189 ;; `gnus-outlook-rearrange-citation' carries all the limitations of
 190 ;; `gnus-outlook-repair-attribution'.
 191 ;;
 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 193 ;;
 194 ;; See ChangeLog for other changes.
 195 ;;
 196 ;; Revision 1.5  2002/01/27 14:39:17  rscholz
 197 ;; * New variable `gnus-outlook-deuglify-no-wrap-chars' to inhibit
 198 ;;   unwrapping if one these chars is first in the possibly wrapped line.
 199 ;; * Improved rearranging of the article.
 200 ;; * New function `gnus-outlook-repair-attribution-block' for repairing
 201 ;;   those big "Original Message (following some headers)" attributions.
 202 ;;
 203 ;; Revision 1.4  2002/01/03 14:05:00  rscholz
 204 ;; Renamed `gnus-outlook-deuglify-article' to
 205 ;; `gnus-article-outlook-deuglify-article'.
 206 ;; Made it easier to deuglify the article while being in Gnus' Article
 207 ;; Edit Mode. (suggested by Phil Nitschke)
 208 ;;
 209 ;;
 210 ;; Revision 1.3  2002/01/02 23:35:54  rscholz
 211 ;; Fix a bug that caused succeeding long attribution lines to be
 212 ;; unwrapped.  Minor doc fixes and regular expression tuning.
 213 ;;
 214 ;; Revision 1.2  2001/12/30 20:14:34  rscholz
 215 ;; Clean up source.
 216 ;;
 217 ;; Revision 1.1  2001/12/30 20:13:32  rscholz
 218 ;; Initial revision
 219 ;;
 220 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 221
 222 ;;; Code:
 223
 224 (require 'gnus-art)
 225 (require 'gnus-sum)
 226
 227 (defconst gnus-outlook-deuglify-version "1.5 Gnus version"
 228   "Version of gnus-outlook-deuglify.")
 229
 230 ;;; User Customizable Variables:
 231
 232 (defgroup gnus-outlook-deuglify nil
 233   "Deuglify articles generated by broken user agents like MS
 234 Outlook (Express).")
 235
 236 ;;;###autoload
 237 (defcustom gnus-outlook-deuglify-unwrap-min 45
 238   "Minimum length of the cited line above the (possibly) wrapped line."
 239   :type 'number
 240   :group 'gnus-outlook-deuglify)
 241
 242 ;;;###autoload
 243 (defcustom gnus-outlook-deuglify-unwrap-max 95
 244   "Maximum length of the cited line after unwrapping."
 245   :type 'number
 246   :group 'gnus-outlook-deuglify)
 247
 248 (defcustom gnus-outlook-deuglify-cite-marks ">|#%"
 249   "Characters that indicate cited lines."
 250   :type 'string
 251   :group 'gnus-outlook-deuglify)
 252
 253 (defcustom gnus-outlook-deuglify-unwrap-stop-chars nil ;; ".?!" or nil
 254   "Characters that inhibit unwrapping if they are the last one on the
 255 cited line above the possible wrapped line."
 256   :type 'string
 257   :group 'gnus-outlook-deuglify)
 258
 259 (defcustom gnus-outlook-deuglify-no-wrap-chars "`"
 260   "Characters that inhibit unwrapping if they are the first one in the
 261 possibly wrapped line."
 262   :type 'string
 263   :group 'gnus-outlook-deuglify)
 264
 265 (defcustom  gnus-outlook-deuglify-attrib-cut-regexp
 266   "\\(On \\|Am \\)?\\(Mon\\|Tue\\|Wed\\|Thu\\|Fri\\|Sat\\|Sun\\),[^,]+, "
 267   "Regular expression matching the beginning of an attribution line
 268 that should be cut off."
 269   :type 'string
 270   :group 'gnus-outlook-deuglify)
 271
 272 (defcustom gnus-outlook-deuglify-attrib-verb-regexp
 273   "wrote\\|writes\\|says\\|schrieb\\|schreibt\\|meinte\\|skrev\\|a écrit\\|schreef"
 274   "Regular expression matching the verb used in an attribution line."
 275   :type 'string
 276   :group 'gnus-outlook-deuglify)
 277
 278 (defcustom  gnus-outlook-deuglify-attrib-end-regexp
 279   ": *\\|\\.\\.\\."
 280   "Regular expression matching the end of an attribution line."
 281   :type 'string
 282   :group 'gnus-outlook-deuglify)
 283
 284
 285 ;; Functions
 286
 287 ;; TODO: don't kill MIME parts
 288 ;;;###autoload
 289 (defun gnus-outlook-unwrap-lines ()
 290   "Unwrap lines that appear to be wrapped citation lines.  You can
 291 control what lines will be unwrapped by frobbing
 292 `gnus-outlook-deuglify-unwrap-min' and
 293 `gnus-outlook-deuglify-unwrap-max', indicating the miminum and maximum
 294 length of an unwrapped citation line."
 295   (interactive)
 296   (save-excursion
 297     (let ((case-fold-search nil)
 298           (inhibit-read-only t)
 299           (cite-marks gnus-outlook-deuglify-cite-marks)
 300           (no-wrap gnus-outlook-deuglify-no-wrap-chars)
 301           (stop-chars gnus-outlook-deuglify-unwrap-stop-chars))
 302       (gnus-with-article-buffer
 303         (article-goto-body)
 304         (while (re-search-forward
 305                 (concat
 306                  "^\\([ \t" cite-marks "]*\\)"
 307                  "\\([" cite-marks "].*[^\n " stop-chars "]\\)[ \t]?\n"
 308                  "\\1\\([^\n " cite-marks no-wrap "]+.*\\)$")
 309               nil t)
 310           (let ((len12 (- (match-end 2) (match-beginning 1)))
 311               (len3 (- (match-end 3) (match-beginning 3))))
 312             (if (and (> len12 gnus-outlook-deuglify-unwrap-min)
 313                      (< (+ len12 len3) gnus-outlook-deuglify-unwrap-max))
 314                 (progn
 315                   (replace-match "\\1\\2 \\3")
 316                   (goto-char (match-beginning 0))))))))))
 317
 318 ;; TODO: respect signatures, don't kill MIME parts
 319 (defun gnus-outlook-rearrange-article (from-where)
 320   "Put the text from `from-where' to the end of buffer at the top of
 321 the article buffer."
 322   (save-excursion
 323     (let ((inhibit-read-only t)
 324           (cite-marks gnus-outlook-deuglify-cite-marks))
 325       (gnus-with-article-buffer
 326         (unless (search-forward-regexp
 327                    (concat "^[ \t]*[^" cite-marks "\n]") nil t)
 328           (kill-region from-where (point-max))
 329           (article-goto-body)
 330           (yank)
 331           (insert "\n"))))))
 332
 333 ;; John Doe <john.doe@some.domain> wrote in message
 334 ;; news:a87usw8$dklsssa$2@some.news.server...
 335
 336 (defun gnus-outlook-repair-attribution-outlook ()
 337   "Repair a broken attribution line (Outlook)."
 338   (save-excursion
 339     (let ((case-fold-search nil)
 340           (inhibit-read-only t)
 341           (cite-marks gnus-outlook-deuglify-cite-marks))
 342       (gnus-with-article-buffer
 343         (article-goto-body)
 344         (if (re-search-forward
 345              (concat "^\\([^" cite-marks "].+\\)"
 346                      "\\(" gnus-outlook-deuglify-attrib-verb-regexp "\\)"
 347                      "\\(.*\n?[^\n" cite-marks "].*\\)?"
 348                      "\\(" gnus-outlook-deuglify-attrib-end-regexp "\\)$")
 349              nil t)
 350             (progn
 351               (replace-match "\\1\\2\\4")
 352               (match-beginning 0)))))))
 353
 354
 355 ;; ----- Original Message -----
 356 ;; From: "John Doe" <john.doe@some.domain>
 357 ;; To: "Doe Foundation" <info@doefnd.org>
 358 ;; Sent: Monday, November 19, 2001 12:13 PM
 359 ;; Subject: More Doenuts
 360
 361 (defun gnus-outlook-repair-attribution-block ()
 362   "Repair a big broken attribution block."
 363   (save-excursion
 364     (let ((case-fold-search nil)
 365           (inhibit-read-only t)
 366           (cite-marks gnus-outlook-deuglify-cite-marks))
 367       (gnus-with-article-buffer
 368         (article-goto-body)
 369         (if (re-search-forward
 370              (concat "^----* ?[^-]+ ?----*\n"
 371                      "[^\n]+: \\([^\n]+\\)\n"
 372                      "[^\n]+: [^\n]+\n"
 373                      "[^\n]+: [^\n]+\n"
 374                      "[^\n]+: [^\n]+$")
 375              nil t)
 376             (progn
 377               (replace-match "\\1 wrote:")
 378               (match-beginning 0)))))))
 379
 380 ;; On Wed, 16 Jan 2002 23:23:30 +0100, John Doe <john.doe@some.domain> wrote:
 381
 382 (defun gnus-outlook-repair-attribution-other ()
 383   "Repair a broken attribution line (other user agents than Outlook)."
 384   (save-excursion
 385     (let ((case-fold-search nil)
 386           (inhibit-read-only t)
 387           (cite-marks gnus-outlook-deuglify-cite-marks))
 388       (gnus-with-article-buffer
 389         (article-goto-body)
 390         (if (re-search-forward
 391              (concat "^\\("gnus-outlook-deuglify-attrib-cut-regexp"\\)?"
 392                      "\\([^" cite-marks "].+\\)\n\\([^\n" cite-marks "].*\\)?"
 393                      "\\(" gnus-outlook-deuglify-attrib-verb-regexp "\\).*"
 394                      "\\(" gnus-outlook-deuglify-attrib-end-regexp "\\)$")
 395              nil t)
 396             (progn
 397               (replace-match "\\4 \\5\\6\\7")
 398               (match-beginning 0)))))))
 399
 400 ;;;###autoload
 401 (defun gnus-outlook-repair-attribution ()
 402   "Repair a broken attribution line."
 403   (interactive)
 404   (or
 405    (gnus-outlook-repair-attribution-other)
 406    (gnus-outlook-repair-attribution-block)
 407    (gnus-outlook-repair-attribution-outlook)))
 408
 409 (defun gnus-outlook-rearrange-citation ()
 410   "Repair broken citations."
 411   (let ((attrib-start (gnus-outlook-repair-attribution)))
 412     ;; rearrange citations if an attribution line has been recognized
 413     (if attrib-start
 414         (gnus-outlook-rearrange-article attrib-start))))
 415
 416 ;;;###autoload
 417 (defun gnus-outlook-deuglify-article ()
 418   "Deuglify broken Outlook (Express) articles."
 419   (interactive)
 420   ;; apply treatment of dumb quotes
 421   (gnus-article-treat-dumbquotes)
 422   ;; repair wrapped cited lines
 423   (gnus-outlook-unwrap-lines)
 424   ;; repair attribution line
 425   (gnus-outlook-rearrange-citation))
 426
 427 ;;;###autoload
 428 (defun gnus-article-outlook-deuglify-article ()
 429   "Deuglify broken Outlook (Express) articles and redisplay."
 430   (interactive)
 431   (gnus-outlook-deuglify-article)
 432   (with-current-buffer (or gnus-article-buffer (current-buffer))
 433     (gnus-article-prepare-display)))
 434
 435 (provide 'deuglify)
 436
 437 ;; Local Variables:
 438 ;; coding: iso-8859-1
 439 ;; End:
 440
 441 ;;; deuglify.el ends here