git.chise.org Git - elisp/gnus.git-/blob - lisp/dgnushack.el

   1 ;;; dgnushack.el --- a hack to set the load path for byte-compiling
   2 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003,
   3 ;; 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Version: 4.19
   8 ;; Keywords: news, path
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (defvar dgnushack-default-load-path (copy-sequence load-path))
  32
  33 (defalias 'facep 'ignore)
  34
  35 (require 'cl)
  36
  37 (defvar srcdir (or (getenv "srcdir") "."))
  38 (defvar loaddir (and load-file-name (file-name-directory load-file-name)))
  39
  40 (defun my-getenv (str)
  41   (let ((val (getenv str)))
  42     (if (equal val "no") nil val)))
  43
  44 (if (my-getenv "lispdir")
  45     (push (my-getenv "lispdir") load-path))
  46
  47 (push (or (my-getenv "URLDIR") (expand-file-name "../../url/lisp/" loaddir))
  48       load-path)
  49
  50 (push (or (my-getenv "W3DIR") (expand-file-name "../../w3/lisp/" loaddir))
  51       load-path)
  52
  53 ;(push "/usr/share/emacs/site-lisp" load-path)
  54
  55 ;; If we are building w3 in a different directory than the source
  56 ;; directory, we must read *.el from source directory and write *.elc
  57 ;; into the building directory.  For that, we define this function
  58 ;; before loading bytecomp.  Bytecomp doesn't overwrite this function.
  59 (defun byte-compile-dest-file (filename)
  60   "Convert an Emacs Lisp source file name to a compiled file name.
  61  In addition, remove directory name part from FILENAME."
  62   (setq filename (byte-compiler-base-file-name filename))
  63   (setq filename (file-name-sans-versions filename))
  64   (setq filename (file-name-nondirectory filename))
  65   (if (memq system-type '(win32 w32 mswindows windows-nt))
  66       (setq filename (downcase filename)))
  67   (cond ((eq system-type 'vax-vms)
  68          (concat (substring filename 0 (string-match ";" filename)) "c"))
  69         ((string-match emacs-lisp-file-regexp filename)
  70          (concat (substring filename 0 (match-beginning 0)) ".elc"))
  71         (t (concat filename ".elc"))))
  72
  73 (require 'bytecomp)
  74 ;; To avoid having defsubsts and inlines happen.
  75 ;(if (featurep 'xemacs)
  76 ;    (require 'byte-optimize)
  77 ;  (require 'byte-opt))
  78 ;(defun byte-optimize-inline-handler (form)
  79 ;  "byte-optimize-handler for the `inline' special-form."
  80 ;  (cons 'progn (cdr form)))
  81 ;(defalias 'byte-compile-file-form-defsubst 'byte-compile-file-form-defun)
  82
  83 (when (and (not (featurep 'xemacs))
  84            (= emacs-major-version 21)
  85            (>= emacs-minor-version 3)
  86            (condition-case code
  87                (let ((byte-compile-error-on-warn t))
  88                  (byte-optimize-form (quote (pop x)) t)
  89                  nil)
  90              (error (string-match "called for effect"
  91                                   (error-message-string code)))))
  92   (defadvice byte-optimize-form-code-walker (around silence-warn-for-pop
  93                                                     (form for-effect)
  94                                                     activate)
  95     "Silence the warning \"...called for effect\" for the `pop' form.
  96 It is effective only when the `pop' macro is defined by cl.el rather
  97 than subr.el."
  98     (let (tmp)
  99       (if (and (eq (car-safe form) 'car)
 100                for-effect
 101                (setq tmp (get 'car 'side-effect-free))
 102                (not byte-compile-delete-errors)
 103                (not (eq tmp 'error-free))
 104                (eq (car-safe (cadr form)) 'prog1)
 105                (let ((var (cadr (cadr form)))
 106                      (last (nth 2 (cadr form))))
 107                  (and (symbolp var)
 108                       (null (nthcdr 3 (cadr form)))
 109                       (eq (car-safe last) 'setq)
 110                       (eq (cadr last) var)
 111                       (eq (car-safe (nth 2 last)) 'cdr)
 112                       (eq (cadr (nth 2 last)) var))))
 113           (progn
 114             (put 'car 'side-effect-free 'error-free)
 115             (unwind-protect
 116                 ad-do-it
 117               (put 'car 'side-effect-free tmp)))
 118         ad-do-it))))
 119
 120 (when (and (not (featurep 'xemacs))
 121            (byte-optimize-form '(and (> 0 1) foo) t))
 122   (defadvice byte-optimize-form-code-walker
 123     (around fix-bug-in-and/or-forms (form for-effect) activate)
 124     "Optimize the rest of the and/or forms.
 125 It has been fixed in XEmacs before releasing 21.4 and also has been
 126 fixed in Emacs after 21.3."
 127     (if (and for-effect (memq (car-safe form) '(and or)))
 128         (let ((fn (car form))
 129               (backwards (reverse (cdr form))))
 130           (while (and backwards
 131                       (null (setcar backwards
 132                                     (byte-optimize-form (car backwards) t))))
 133             (setq backwards (cdr backwards)))
 134           (if (and (cdr form) (null backwards))
 135               (byte-compile-log
 136                "  all subforms of %s called for effect; deleted" form))
 137           (when backwards
 138             (setcdr backwards
 139                     (mapcar 'byte-optimize-form (cdr backwards))))
 140           (setq ad-return-value (cons fn (nreverse backwards))))
 141       ad-do-it)))
 142
 143 ;; Work around for an incompatibility (XEmacs 21.4 vs. 21.5), see the
 144 ;; following threads:
 145 ;;
 146 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56414
 147 ;; Subject: attachment problems found but not fixed
 148 ;;
 149 ;; http://thread.gmane.org/gmane.emacs.gnus.general/56459
 150 ;; Subject: Splitting mail -- XEmacs 21.4 vs 21.5
 151 ;;
 152 ;; http://thread.gmane.org/gmane.emacs.xemacs.beta/20519
 153 ;; Subject: XEmacs 21.5 and Gnus fancy splitting.
 154 (when (and (featurep 'xemacs)
 155            (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
 156              (modify-syntax-entry ?= " " table)
 157              (with-temp-buffer
 158                (with-syntax-table table
 159                  (insert "foo=bar")
 160                  (goto-char (point-min))
 161                  (forward-sexp 1)
 162                  (eolp)))))
 163   ;; The original `with-syntax-table' uses `copy-syntax-table' which
 164   ;; doesn't seem to copy modified syntax entries in XEmacs 21.5.
 165   (defmacro with-syntax-table (syntab &rest body)
 166     "Evaluate BODY with the SYNTAB as the current syntax table."
 167     `(let ((stab (syntax-table)))
 168        (unwind-protect
 169            (progn
 170              ;;(set-syntax-table (copy-syntax-table ,syntab))
 171              (set-syntax-table ,syntab)
 172              ,@body)
 173          (set-syntax-table stab)))))
 174
 175 (push srcdir load-path)
 176 (push loaddir load-path)
 177 (load (expand-file-name "lpath.el" loaddir) nil t)
 178
 179 (defalias 'device-sound-enabled-p 'ignore)
 180 (defalias 'play-sound-file 'ignore)
 181 (defalias 'nndb-request-article 'ignore)
 182 (defalias 'efs-re-read-dir 'ignore)
 183 (defalias 'ange-ftp-re-read-dir 'ignore)
 184 (defalias 'define-mail-user-agent 'ignore)
 185
 186 (eval-and-compile
 187   (unless (featurep 'xemacs)
 188     (defalias 'get-popup-menu-response 'ignore)
 189     (defalias 'event-object 'ignore)
 190     (defalias 'x-defined-colors 'ignore)
 191     (defalias 'read-color 'ignore)))
 192
 193 (eval-and-compile
 194   (when (featurep 'xemacs)
 195     (unless (fboundp 'defadvice)
 196       (autoload 'defadvice "advice" nil nil 'macro))
 197     (autoload 'Info-directory "info" nil t)
 198     (autoload 'Info-menu "info" nil t)
 199     (autoload 'annotations-at "annotations")
 200     (autoload 'apropos "apropos" nil t)
 201     (autoload 'apropos-command "apropos" nil t)
 202     (autoload 'bbdb-complete-name "bbdb-com" nil t)
 203     (autoload 'browse-url "browse-url" nil t)
 204     (autoload 'c-mode "cc-mode" nil t)
 205     (autoload 'customize-apropos "cus-edit" nil t)
 206     (autoload 'customize-group "cus-edit" nil t)
 207     (autoload 'customize-save-variable "cus-edit" nil t)
 208     (autoload 'customize-set-variable "cus-edit" nil t)
 209     (autoload 'customize-variable "cus-edit" nil t)
 210     (autoload 'delete-annotation "annotations")
 211     (autoload 'dolist "cl-macs" nil nil 'macro)
 212     (autoload 'enriched-decode "enriched")
 213     (autoload 'executable-find "executable")
 214     (autoload 'font-lock-fontify-buffer "font-lock" nil t)
 215     (autoload 'info "info" nil t)
 216     (autoload 'mail-extract-address-components "mail-extr")
 217     (autoload 'mail-fetch-field "mail-utils")
 218     (autoload 'make-annotation "annotations")
 219     (autoload 'make-display-table "disp-table")
 220     (autoload 'pp "pp")
 221     (autoload 'ps-despool "ps-print" nil t)
 222     (autoload 'ps-spool-buffer "ps-print" nil t)
 223     (autoload 'ps-spool-buffer-with-faces "ps-print" nil t)
 224     (autoload 'read-passwd "passwd")
 225     (autoload 'regexp-opt "regexp-opt")
 226     (autoload 'reporter-submit-bug-report "reporter")
 227     (if (and (emacs-version>= 21 5)
 228              (not (featurep 'sxemacs)))
 229         (autoload 'setenv "process" nil t)
 230       (autoload 'setenv "env" nil t))
 231     (autoload 'sgml-mode "psgml" nil t)
 232     (autoload 'smtpmail-send-it "smtpmail")
 233     (autoload 'sort-numeric-fields "sort" nil t)
 234     (autoload 'sort-subr "sort")
 235     (autoload 'trace-function-background "trace" nil t)
 236     (autoload 'w3-do-setup "w3")
 237     (autoload 'w3-prepare-buffer "w3-display")
 238     (autoload 'w3-region "w3-display" nil t)
 239     (defalias 'frame-char-height 'frame-height)
 240     (defalias 'frame-char-width 'frame-width)
 241     (defalias 'frame-parameter 'frame-property)
 242     (defalias 'make-overlay 'ignore)
 243     (defalias 'overlay-end 'ignore)
 244     (defalias 'overlay-get 'ignore)
 245     (defalias 'overlay-put 'ignore)
 246     (defalias 'overlay-start 'ignore)
 247     (defalias 'overlays-in 'ignore)
 248     (defalias 'replace-dehighlight 'ignore)
 249     (defalias 'replace-highlight 'ignore)
 250     (defalias 'w3-coding-system-for-mime-charset 'ignore)))
 251
 252 (defun dgnushack-compile-verbosely ()
 253   "Call dgnushack-compile with warnings ENABLED.  If you are compiling
 254 patches to gnus, you should consider modifying make.bat to call
 255 dgnushack-compile-verbosely.  All other users should continue to use
 256 dgnushack-compile."
 257   (dgnushack-compile t))
 258
 259 (defun dgnushack-compile (&optional warn)
 260   ;;(setq byte-compile-dynamic t)
 261   (unless warn
 262     (setq byte-compile-warnings
 263           '(free-vars unresolved callargs redefine)))
 264   (let ((files (directory-files srcdir nil "^[^=].*\\.el$"))
 265         ;;(byte-compile-generate-call-tree t)
 266         file elc)
 267     ;; Avoid barfing (from gnus-xmas) because the etc directory is not yet
 268     ;; installed.
 269     (when (featurep 'xemacs)
 270       (setq gnus-xmas-glyph-directory "dummy"))
 271     (dolist (file '("dgnushack.el" "lpath.el"))
 272       (setq files (delete file files)))
 273     (when (featurep 'base64)
 274       (setq files (delete "base64.el" files)))
 275     (condition-case code
 276         (require 'w3-parse)
 277       (error
 278        (message "No w3: %s %s" (cadr code) (or (locate-library "w3-parse") ""))
 279        (dolist (file '("nnultimate.el" "webmail.el" "nnwfm.el"))
 280          (setq files (delete file files)))))
 281     (condition-case code
 282         (require 'mh-e)
 283       (error
 284        (message "No mh-e: %s %s" (cadr code) (or (locate-library "mh-e") ""))
 285        (setq files (delete "gnus-mh.el" files))))
 286     (condition-case code
 287         (require 'xml)
 288       (error
 289        (message "No xml: %s %s" (cadr code) (or (locate-library "xml") ""))
 290        (setq files (delete "nnrss.el" files))))
 291     (dolist (file
 292              (if (featurep 'xemacs)
 293                  '("md5.el")
 294                '("gnus-xmas.el" "messagexmas.el" "nnheaderxm.el")))
 295       (setq files (delete file files)))
 296
 297     (dolist (file files)
 298       (setq file (expand-file-name file srcdir))
 299       (when (and (file-exists-p
 300                   (setq elc (concat (file-name-nondirectory file) "c")))
 301                  (file-newer-than-file-p file elc))
 302         (delete-file elc)))
 303
 304     (while (setq file (pop files))
 305       (setq file (expand-file-name file srcdir))
 306       (when (or (not (file-exists-p
 307                       (setq elc (concat (file-name-nondirectory file) "c"))))
 308                 (file-newer-than-file-p file elc))
 309         (ignore-errors
 310           (byte-compile-file file))))))
 311
 312 (defun dgnushack-recompile ()
 313   (require 'gnus)
 314   (byte-recompile-directory "." 0))
 315
 316 (defvar dgnushack-gnus-load-file
 317   (if (featurep 'xemacs)
 318       (expand-file-name "auto-autoloads.el")
 319     (expand-file-name "gnus-load.el")))
 320
 321 (defvar dgnushack-cus-load-file
 322   (if (featurep 'xemacs)
 323       (expand-file-name "custom-load.el")
 324     (expand-file-name "cus-load.el")))
 325
 326 (defun dgnushack-make-cus-load ()
 327   (load "cus-dep")
 328   (let ((cusload-base-file dgnushack-cus-load-file))
 329     (if (fboundp 'custom-make-dependencies)
 330         (custom-make-dependencies)
 331       (Custom-make-dependencies))
 332     (when (featurep 'xemacs)
 333       (message "Compiling %s..." dgnushack-cus-load-file)
 334       (byte-compile-file dgnushack-cus-load-file))))
 335
 336 (defun dgnushack-make-auto-load ()
 337   (require 'autoload)
 338   (unless (make-autoload '(define-derived-mode child parent name
 339                             "docstring" body)
 340                          "file")
 341     (defadvice make-autoload (around handle-define-derived-mode activate)
 342       "Handle `define-derived-mode'."
 343       (if (eq (car-safe (ad-get-arg 0)) 'define-derived-mode)
 344           (setq ad-return-value
 345                 (list 'autoload
 346                       (list 'quote (nth 1 (ad-get-arg 0)))
 347                       (ad-get-arg 1)
 348                       (nth 4 (ad-get-arg 0))
 349                       t nil))
 350         ad-do-it))
 351     (put 'define-derived-mode 'doc-string-elt 3))
 352   (let ((generated-autoload-file dgnushack-gnus-load-file)
 353         (make-backup-files nil)
 354         (autoload-package-name "gnus"))
 355     (if (featurep 'xemacs)
 356         (if (file-exists-p generated-autoload-file)
 357             (delete-file generated-autoload-file))
 358       (with-temp-file generated-autoload-file
 359         (insert ?\014)))
 360     (batch-update-autoloads)))
 361
 362 (defun dgnushack-make-load ()
 363   (unless (featurep 'xemacs)
 364     (message "Generating %s..." dgnushack-gnus-load-file)
 365     (with-temp-file dgnushack-gnus-load-file
 366       (insert-file-contents dgnushack-cus-load-file)
 367       (delete-file dgnushack-cus-load-file)
 368       (goto-char (point-min))
 369       (search-forward ";;; Code:")
 370       (forward-line)
 371       (delete-region (point-min) (point))
 372       (insert "\
 373 ;;; gnus-load.el --- automatically extracted custom dependencies and autoload
 374 ;;
 375 ;;; Code:
 376 ")
 377       (goto-char (point-max))
 378       (if (search-backward "custom-versions-load-alist" nil t)
 379           (forward-line -1)
 380         (forward-line -1)
 381         (while (eq (char-after) ?\;)
 382           (forward-line -1))
 383         (forward-line))
 384       (delete-region (point) (point-max))
 385       (insert "\n")
 386       ;; smiley-* are duplicated. Remove them all.
 387       (let ((point (point)))
 388         (insert-file-contents dgnushack-gnus-load-file)
 389         (goto-char point)
 390         (while (search-forward "smiley-" nil t)
 391           (beginning-of-line)
 392           (if (looking-at "(autoload ")
 393               (delete-region (point) (progn (forward-sexp) (point)))
 394             (forward-line))))
 395       ;;
 396       (goto-char (point-max))
 397       (when (search-backward "\n(provide " nil t)
 398         (forward-line -1)
 399         (delete-region (point) (point-max)))
 400       (insert "\
 401
 402 \(provide 'gnus-load)
 403
 404 ;;; Local Variables:
 405 ;;; version-control: never
 406 ;;; no-byte-compile: t
 407 ;;; no-update-autoloads: t
 408 ;;; End:
 409 ;;; gnus-load.el ends here
 410 ")
 411       ))
 412   (message "Compiling %s..." dgnushack-gnus-load-file)
 413   (byte-compile-file dgnushack-gnus-load-file)
 414   (when (featurep 'xemacs)
 415     (message "Creating dummy gnus-load.el...")
 416     (with-temp-file (expand-file-name "gnus-load.el")
 417       (insert "\
 418
 419 \(provide 'gnus-load)
 420
 421 ;;; Local Variables:
 422 ;;; version-control: never
 423 ;;; no-byte-compile: t
 424 ;;; no-update-autoloads: t
 425 ;;; End:
 426 ;;; gnus-load.el ends here"))))
 427
 428 (defun dgnushack-find-lisp-shadows (&optional lispdir)
 429   "Return a list of directories in which other Gnus installations exist.
 430 This function looks for the other Gnus installations which will shadow
 431 the new Gnus Lisp modules which have been installed in LISPDIR, using
 432 the default `load-path'.  The return value will make sense only when
 433 LISPDIR is existent and is listed in the default `load-path'.  Assume
 434 LISPDIR will be prepended to `load-path' by a user if the default
 435 `load-path' does not contain it."
 436   (unless lispdir
 437     (setq lispdir (getenv "lispdir")))
 438   (when (and lispdir (file-directory-p lispdir))
 439     (setq lispdir (file-truename (directory-file-name lispdir)))
 440     (let ((indices '("gnus.elc" "gnus.el" "gnus.el.bz2" "gnus.el.gz"
 441                      "message.elc" "message.el" "message.el.bz2"
 442                      "message.el.gz"))
 443           (path (delq nil (mapcar
 444                            (lambda (p)
 445                              (condition-case nil
 446                                  (when (and p (file-directory-p p))
 447                                    (file-truename (directory-file-name p)))
 448                                (error nil)))
 449                            dgnushack-default-load-path)))
 450           rest elcs)
 451       (while path
 452         (setq rest (cons (car path) rest)
 453               path (delete (car rest) (cdr path))))
 454       (setq path (nreverse (cdr (member lispdir rest)))
 455             rest nil)
 456       (while path
 457         (setq elcs indices)
 458         (while elcs
 459           (when (file-exists-p (expand-file-name (pop elcs) (car path)))
 460             (setq rest (cons (car path) rest)
 461                   elcs nil)))
 462         (setq path (cdr path)))
 463       (prog1
 464           (setq path (nreverse rest))
 465         (when path
 466           (let (print-level print-length)
 467             (princ (concat "\n\
 468 WARNING: The other Gnus installation" (if (cdr path) "s have" " has") "\
 469  been detected in:\n\n  " (mapconcat 'identity path "\n  ") "\n\n\
 470 You will need to modify the run-time `load-path', remove them manually,
 471 or remove them using `make remove-installed-shadows'.\n\n"))))))))
 472
 473 (defun dgnushack-remove-lisp-shadows (&optional lispdir)
 474   "Remove the other Gnus installations which shadow the recent one."
 475   (let ((path (with-temp-buffer
 476                 (let ((standard-output (current-buffer)))
 477                   (dgnushack-find-lisp-shadows lispdir))))
 478         elcs files shadows file)
 479     (when path
 480       (unless (setq elcs (directory-files srcdir nil "\\.elc\\'"))
 481         (error "You should build .elc files first."))
 482       (setq files
 483             (apply
 484              'append
 485              (mapcar
 486               (lambda (el)
 487                 (list (concat el "c") el (concat el ".bz2") (concat el ".gz")))
 488               (append
 489                (list (file-name-nondirectory dgnushack-gnus-load-file)
 490                      (file-name-nondirectory dgnushack-cus-load-file))
 491                (mapcar (lambda (elc) (substring elc 0 -1)) elcs)))))
 492       (while path
 493         (setq shadows files)
 494         (while shadows
 495           (setq file (expand-file-name (pop shadows) (car path)))
 496           (when (file-exists-p file)
 497             (princ (concat "  Removing " file "..."))
 498             (condition-case nil
 499                 (progn
 500                   (delete-file file)
 501                   (princ "done\n"))
 502               (error (princ "failed\n")))))
 503         (setq path (cdr path))))))
 504
 505 ;;; dgnushack.el ends here
 506
 507 ;;; arch-tag: 579f585a-24eb-4e1c-8d34-4808e11b68f2