git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-agent.el

   1 ;;; gnus-agent.el --- unplugged support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-cache)
  29 (require 'nnvirtual)
  30 (require 'gnus-sum)
  31 (require 'gnus-score)
  32 (eval-when-compile
  33   (if (featurep 'xemacs)
  34       (require 'itimer)
  35     (require 'timer))
  36   (require 'cl))
  37
  38 (eval-and-compile
  39   (autoload 'gnus-server-update-server "gnus-srvr"))
  40
  41 (defcustom gnus-agent-directory (nnheader-concat gnus-directory "agent/")
  42   "Where the Gnus agent will store its files."
  43   :group 'gnus-agent
  44   :type 'directory)
  45
  46 (defcustom gnus-agent-plugged-hook nil
  47   "Hook run when plugging into the network."
  48   :group 'gnus-agent
  49   :type 'hook)
  50
  51 (defcustom gnus-agent-unplugged-hook nil
  52   "Hook run when unplugging from the network."
  53   :group 'gnus-agent
  54   :type 'hook)
  55
  56 (defcustom gnus-agent-handle-level gnus-level-subscribed
  57   "Groups on levels higher than this variable will be ignored by the Agent."
  58   :group 'gnus-agent
  59   :type 'integer)
  60
  61 (defcustom gnus-agent-expire-days 7
  62   "Read articles older than this will be expired."
  63   :group 'gnus-agent
  64   :type 'integer)
  65
  66 (defcustom gnus-agent-expire-all nil
  67   "If non-nil, also expire unread, ticked and dormant articles.
  68 If nil, only read articles will be expired."
  69   :group 'gnus-agent
  70   :type 'boolean)
  71
  72 (defcustom gnus-agent-group-mode-hook nil
  73   "Hook run in Agent group minor modes."
  74   :group 'gnus-agent
  75   :type 'hook)
  76
  77 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
  78 (when (featurep 'xemacs)
  79   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add))
  80
  81 (defcustom gnus-agent-summary-mode-hook nil
  82   "Hook run in Agent summary minor modes."
  83   :group 'gnus-agent
  84   :type 'hook)
  85
  86 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
  87 (when (featurep 'xemacs)
  88   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add))
  89
  90 (defcustom gnus-agent-server-mode-hook nil
  91   "Hook run in Agent summary minor modes."
  92   :group 'gnus-agent
  93   :type 'hook)
  94
  95 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
  96 (when (featurep 'xemacs)
  97   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add))
  98
  99 (defcustom gnus-agent-confirmation-function 'y-or-n-p
 100   "Function to confirm when error happens."
 101   :version "21.1"
 102   :group 'gnus-agent
 103   :type 'function)
 104
 105 (defcustom gnus-agent-synchronize-flags 'ask
 106   "Indicate if flags are synchronized when you plug in.
 107 If this is `ask' the hook will query the user."
 108   :version "21.1"
 109   :type '(choice (const :tag "Always" t)
 110                  (const :tag "Never" nil)
 111                  (const :tag "Ask" ask))
 112   :group 'gnus-agent)
 113
 114 ;;; Internal variables
 115
 116 (defvar gnus-agent-history-buffers nil)
 117 (defvar gnus-agent-buffer-alist nil)
 118 (defvar gnus-agent-article-alist nil)
 119 (defvar gnus-agent-group-alist nil)
 120 (defvar gnus-agent-covered-methods nil)
 121 (defvar gnus-category-alist nil)
 122 (defvar gnus-agent-current-history nil)
 123 (defvar gnus-agent-overview-buffer nil)
 124 (defvar gnus-category-predicate-cache nil)
 125 (defvar gnus-category-group-cache nil)
 126 (defvar gnus-agent-spam-hashtb nil)
 127 (defvar gnus-agent-file-name nil)
 128 (defvar gnus-agent-send-mail-function nil)
 129 (defvar gnus-agent-file-coding-system 'raw-text)
 130
 131 ;; Dynamic variables
 132 (defvar gnus-headers)
 133 (defvar gnus-score)
 134
 135 ;;;
 136 ;;; Setup
 137 ;;;
 138
 139 (defun gnus-open-agent ()
 140   (setq gnus-agent t)
 141   (gnus-agent-read-servers)
 142   (gnus-category-read)
 143   (gnus-agent-create-buffer)
 144   (add-hook 'gnus-group-mode-hook 'gnus-agent-mode)
 145   (add-hook 'gnus-summary-mode-hook 'gnus-agent-mode)
 146   (add-hook 'gnus-server-mode-hook 'gnus-agent-mode))
 147
 148 (defun gnus-agent-create-buffer ()
 149   (if (gnus-buffer-live-p gnus-agent-overview-buffer)
 150       t
 151     (setq gnus-agent-overview-buffer
 152           (gnus-get-buffer-create " *Gnus agent overview*"))
 153     (with-current-buffer gnus-agent-overview-buffer
 154       (mm-enable-multibyte))
 155     nil))
 156
 157 (gnus-add-shutdown 'gnus-close-agent 'gnus)
 158
 159 (defun gnus-close-agent ()
 160   (setq gnus-agent-covered-methods nil
 161         gnus-category-predicate-cache nil
 162         gnus-category-group-cache nil
 163         gnus-agent-spam-hashtb nil)
 164   (gnus-kill-buffer gnus-agent-overview-buffer))
 165
 166 ;;;
 167 ;;; Utility functions
 168 ;;;
 169
 170 (defun gnus-agent-read-file (file)
 171   "Load FILE and do a `read' there."
 172   (with-temp-buffer
 173     (ignore-errors
 174       (nnheader-insert-file-contents file)
 175       (goto-char (point-min))
 176       (read (current-buffer)))))
 177
 178 (defsubst gnus-agent-method ()
 179   (concat (symbol-name (car gnus-command-method)) "/"
 180           (if (equal (cadr gnus-command-method) "")
 181               "unnamed"
 182             (cadr gnus-command-method))))
 183
 184 (defsubst gnus-agent-directory ()
 185   "Path of the Gnus agent directory."
 186   (nnheader-concat gnus-agent-directory
 187                    (nnheader-translate-file-chars (gnus-agent-method)) "/"))
 188
 189 (defun gnus-agent-lib-file (file)
 190   "The full path of the Gnus agent library FILE."
 191   (expand-file-name file
 192                     (file-name-as-directory
 193                      (expand-file-name "agent.lib" (gnus-agent-directory)))))
 194
 195 ;;; Fetching setup functions.
 196
 197 (defun gnus-agent-start-fetch ()
 198   "Initialize data structures for efficient fetching."
 199   (gnus-agent-open-history)
 200   (setq gnus-agent-current-history (gnus-agent-history-buffer))
 201   (gnus-agent-create-buffer))
 202
 203 (defun gnus-agent-stop-fetch ()
 204   "Save all data structures and clean up."
 205   (gnus-agent-save-history)
 206   (gnus-agent-close-history)
 207   (setq gnus-agent-spam-hashtb nil)
 208   (save-excursion
 209     (set-buffer nntp-server-buffer)
 210     (widen)))
 211
 212 (defmacro gnus-agent-with-fetch (&rest forms)
 213   "Do FORMS safely."
 214   `(unwind-protect
 215        (let ((gnus-agent-fetching t))
 216          (gnus-agent-start-fetch)
 217          ,@forms)
 218      (gnus-agent-stop-fetch)))
 219
 220 (put 'gnus-agent-with-fetch 'lisp-indent-function 0)
 221 (put 'gnus-agent-with-fetch 'edebug-form-spec '(body))
 222
 223 ;;;
 224 ;;; Mode infestation
 225 ;;;
 226
 227 (defvar gnus-agent-mode-hook nil
 228   "Hook run when installing agent mode.")
 229
 230 (defvar gnus-agent-mode nil)
 231 (defvar gnus-agent-mode-status '(gnus-agent-mode " Plugged"))
 232
 233 (defun gnus-agent-mode ()
 234   "Minor mode for providing a agent support in Gnus buffers."
 235   (let* ((buffer (progn (string-match "^gnus-\\(.*\\)-mode$"
 236                                       (symbol-name major-mode))
 237                         (match-string 1 (symbol-name major-mode))))
 238          (mode (intern (format "gnus-agent-%s-mode" buffer))))
 239     (set (make-local-variable 'gnus-agent-mode) t)
 240     (set mode nil)
 241     (set (make-local-variable mode) t)
 242     ;; Set up the menu.
 243     (when (gnus-visual-p 'agent-menu 'menu)
 244       (funcall (intern (format "gnus-agent-%s-make-menu-bar" buffer))))
 245     (unless (assq 'gnus-agent-mode minor-mode-alist)
 246       (push gnus-agent-mode-status minor-mode-alist))
 247     (unless (assq mode minor-mode-map-alist)
 248       (push (cons mode (symbol-value (intern (format "gnus-agent-%s-mode-map"
 249                                                      buffer))))
 250             minor-mode-map-alist))
 251     (when (eq major-mode 'gnus-group-mode)
 252       (gnus-agent-toggle-plugged gnus-plugged))
 253     (gnus-run-hooks 'gnus-agent-mode-hook
 254                     (intern (format "gnus-agent-%s-mode-hook" buffer)))))
 255
 256 (defvar gnus-agent-group-mode-map (make-sparse-keymap))
 257 (gnus-define-keys gnus-agent-group-mode-map
 258   "Ju" gnus-agent-fetch-groups
 259   "Jc" gnus-enter-category-buffer
 260   "Jj" gnus-agent-toggle-plugged
 261   "Js" gnus-agent-fetch-session
 262   "JY" gnus-agent-synchronize-flags
 263   "JS" gnus-group-send-drafts
 264   "Ja" gnus-agent-add-group
 265   "Jr" gnus-agent-remove-group)
 266
 267 (defun gnus-agent-group-make-menu-bar ()
 268   (unless (boundp 'gnus-agent-group-menu)
 269     (easy-menu-define
 270      gnus-agent-group-menu gnus-agent-group-mode-map ""
 271      '("Agent"
 272        ["Toggle plugged" gnus-agent-toggle-plugged t]
 273        ["List categories" gnus-enter-category-buffer t]
 274        ["Send drafts" gnus-group-send-drafts gnus-plugged]
 275        ("Fetch"
 276         ["All" gnus-agent-fetch-session gnus-plugged]
 277         ["Group" gnus-agent-fetch-group gnus-plugged])))))
 278
 279 (defvar gnus-agent-summary-mode-map (make-sparse-keymap))
 280 (gnus-define-keys gnus-agent-summary-mode-map
 281   "Jj" gnus-agent-toggle-plugged
 282   "J#" gnus-agent-mark-article
 283   "J\M-#" gnus-agent-unmark-article
 284   "@" gnus-agent-toggle-mark
 285   "Jc" gnus-agent-catchup)
 286
 287 (defun gnus-agent-summary-make-menu-bar ()
 288   (unless (boundp 'gnus-agent-summary-menu)
 289     (easy-menu-define
 290      gnus-agent-summary-menu gnus-agent-summary-mode-map ""
 291      '("Agent"
 292        ["Toggle plugged" gnus-agent-toggle-plugged t]
 293        ["Mark as downloadable" gnus-agent-mark-article t]
 294        ["Unmark as downloadable" gnus-agent-unmark-article t]
 295        ["Toggle mark" gnus-agent-toggle-mark t]
 296        ["Catchup undownloaded" gnus-agent-catchup t]))))
 297
 298 (defvar gnus-agent-server-mode-map (make-sparse-keymap))
 299 (gnus-define-keys gnus-agent-server-mode-map
 300   "Jj" gnus-agent-toggle-plugged
 301   "Ja" gnus-agent-add-server
 302   "Jr" gnus-agent-remove-server)
 303
 304 (defun gnus-agent-server-make-menu-bar ()
 305   (unless (boundp 'gnus-agent-server-menu)
 306     (easy-menu-define
 307      gnus-agent-server-menu gnus-agent-server-mode-map ""
 308      '("Agent"
 309        ["Toggle plugged" gnus-agent-toggle-plugged t]
 310        ["Add" gnus-agent-add-server t]
 311        ["Remove" gnus-agent-remove-server t]))))
 312
 313 (defun gnus-agent-toggle-plugged (plugged)
 314   "Toggle whether Gnus is unplugged or not."
 315   (interactive (list (not gnus-plugged)))
 316   (if plugged
 317       (progn
 318         (setq gnus-plugged plugged)
 319         (gnus-agent-possibly-synchronize-flags)
 320         (gnus-run-hooks 'gnus-agent-plugged-hook)
 321         (setcar (cdr gnus-agent-mode-status) " Plugged"))
 322     (gnus-agent-close-connections)
 323     (setq gnus-plugged plugged)
 324     (gnus-run-hooks 'gnus-agent-unplugged-hook)
 325     (setcar (cdr gnus-agent-mode-status) " Unplugged"))
 326   (set-buffer-modified-p t))
 327
 328 (defun gnus-agent-close-connections ()
 329   "Close all methods covered by the Gnus agent."
 330   (let ((methods gnus-agent-covered-methods))
 331     (while methods
 332       (gnus-close-server (pop methods)))))
 333
 334 ;;;###autoload
 335 (defun gnus-unplugged ()
 336   "Start Gnus unplugged."
 337   (interactive)
 338   (setq gnus-plugged nil)
 339   (gnus))
 340
 341 ;;;###autoload
 342 (defun gnus-plugged ()
 343   "Start Gnus plugged."
 344   (interactive)
 345   (setq gnus-plugged t)
 346   (gnus))
 347
 348 ;;;###autoload
 349 (defun gnus-agentize ()
 350   "Allow Gnus to be an offline newsreader.
 351 The normal usage of this command is to put the following as the
 352 last form in your `.gnus.el' file:
 353
 354 \(gnus-agentize)
 355
 356 This will modify the `gnus-setup-news-hook', and
 357 `message-send-mail-function' variables, and install the Gnus agent
 358 minor mode in all Gnus buffers."
 359   (interactive)
 360   (gnus-open-agent)
 361   (add-hook 'gnus-setup-news-hook 'gnus-agent-queue-setup)
 362   (unless gnus-agent-send-mail-function
 363     (setq gnus-agent-send-mail-function message-send-mail-function
 364           message-send-mail-function 'gnus-agent-send-mail))
 365   (unless gnus-agent-covered-methods
 366     (setq gnus-agent-covered-methods (list gnus-select-method))))
 367
 368 (defun gnus-agent-queue-setup ()
 369   "Make sure the queue group exists."
 370   (unless (gnus-gethash "nndraft:queue" gnus-newsrc-hashtb)
 371     (gnus-request-create-group "queue" '(nndraft ""))
 372     (let ((gnus-level-default-subscribed 1))
 373       (gnus-subscribe-group "nndraft:queue" nil '(nndraft "")))
 374     (gnus-group-set-parameter
 375      "nndraft:queue" 'gnus-dummy '((gnus-draft-mode)))))
 376
 377 (defun gnus-agent-send-mail ()
 378   (if gnus-plugged
 379       (funcall gnus-agent-send-mail-function)
 380     (goto-char (point-min))
 381     (re-search-forward
 382      (concat "^" (regexp-quote mail-header-separator) "\n"))
 383     (replace-match "\n")
 384     (gnus-agent-insert-meta-information 'mail)
 385     (gnus-request-accept-article "nndraft:queue" nil t t)))
 386
 387 (defun gnus-agent-insert-meta-information (type &optional method)
 388   "Insert meta-information into the message that says how it's to be posted.
 389 TYPE can be either `mail' or `news'.  If the latter, then METHOD can
 390 be a select method."
 391   (save-excursion
 392     (message-remove-header gnus-agent-meta-information-header)
 393     (goto-char (point-min))
 394     (insert gnus-agent-meta-information-header ": "
 395             (symbol-name type) " " (format "%S" method)
 396             "\n")
 397     (forward-char -1)
 398     (while (search-backward "\n" nil t)
 399       (replace-match "\\n" t t))))
 400
 401 (defun gnus-agent-restore-gcc ()
 402   "Restore GCC field from saved header."
 403   (save-excursion
 404     (goto-char (point-min))
 405     (while (re-search-forward (concat gnus-agent-gcc-header ":") nil t)
 406       (replace-match "Gcc:" 'fixedcase))))
 407
 408 (defun gnus-agent-any-covered-gcc ()
 409   (save-restriction
 410     (message-narrow-to-headers)
 411     (let* ((gcc (mail-fetch-field "gcc" nil t))
 412            (methods (and gcc
 413                          (mapcar 'gnus-inews-group-method
 414                                  (message-unquote-tokens
 415                                   (message-tokenize-header
 416                                    gcc " ,")))))
 417            covered)
 418       (while (and (not covered) methods)
 419         (setq covered
 420               (member (car methods) gnus-agent-covered-methods)
 421               methods (cdr methods)))
 422       covered)))
 423
 424 (defun gnus-agent-possibly-save-gcc ()
 425   "Save GCC if Gnus is unplugged."
 426   (when (and (not gnus-plugged) (gnus-agent-any-covered-gcc))
 427     (save-excursion
 428       (goto-char (point-min))
 429       (let ((case-fold-search t))
 430         (while (re-search-forward "^gcc:" nil t)
 431           (replace-match (concat gnus-agent-gcc-header ":") 'fixedcase))))))
 432
 433 (defun gnus-agent-possibly-do-gcc ()
 434   "Do GCC if Gnus is plugged."
 435   (when (or gnus-plugged (not (gnus-agent-any-covered-gcc)))
 436     (gnus-inews-do-gcc)))
 437
 438 ;;;
 439 ;;; Group mode commands
 440 ;;;
 441
 442 (defun gnus-agent-fetch-groups (n)
 443   "Put all new articles in the current groups into the Agent."
 444   (interactive "P")
 445   (unless gnus-plugged
 446     (error "Groups can't be fetched when Gnus is unplugged"))
 447   (gnus-group-iterate n 'gnus-agent-fetch-group))
 448
 449 (defun gnus-agent-fetch-group (group)
 450   "Put all new articles in GROUP into the Agent."
 451   (interactive (list (gnus-group-group-name)))
 452   (unless gnus-plugged
 453     (error "Groups can't be fetched when Gnus is unplugged"))
 454   (unless group
 455     (error "No group on the current line"))
 456   (let ((gnus-command-method (gnus-find-method-for-group group)))
 457     (gnus-agent-with-fetch
 458       (gnus-agent-fetch-group-1 group gnus-command-method)
 459       (gnus-message 5 "Fetching %s...done" group))))
 460
 461 (defun gnus-agent-add-group (category arg)
 462   "Add the current group to an agent category."
 463   (interactive
 464    (list
 465     (intern
 466      (completing-read
 467       "Add to category: "
 468       (mapcar (lambda (cat) (list (symbol-name (car cat))))
 469               gnus-category-alist)
 470       nil t))
 471     current-prefix-arg))
 472   (let ((cat (assq category gnus-category-alist))
 473         c groups)
 474     (gnus-group-iterate arg
 475       (lambda (group)
 476         (when (cadddr (setq c (gnus-group-category group)))
 477           (setf (cadddr c) (delete group (cadddr c))))
 478         (push group groups)))
 479     (setf (cadddr cat) (nconc (cadddr cat) groups))
 480     (gnus-category-write)))
 481
 482 (defun gnus-agent-remove-group (arg)
 483   "Remove the current group from its agent category, if any."
 484   (interactive "P")
 485   (let (c)
 486     (gnus-group-iterate arg
 487       (lambda (group)
 488         (when (cadddr (setq c (gnus-group-category group)))
 489           (setf (cadddr c) (delete group (cadddr c))))))
 490     (gnus-category-write)))
 491
 492 (defun gnus-agent-synchronize-flags ()
 493   "Synchronize unplugged flags with servers."
 494   (interactive)
 495   (save-excursion
 496     (dolist (gnus-command-method gnus-agent-covered-methods)
 497       (when (file-exists-p (gnus-agent-lib-file "flags"))
 498         (gnus-agent-synchronize-flags-server gnus-command-method)))))
 499
 500 (defun gnus-agent-possibly-synchronize-flags ()
 501   "Synchronize flags according to `gnus-agent-synchronize-flags'."
 502   (interactive)
 503   (save-excursion
 504     (dolist (gnus-command-method gnus-agent-covered-methods)
 505       (when (file-exists-p (gnus-agent-lib-file "flags"))
 506         (gnus-agent-possibly-synchronize-flags-server gnus-command-method)))))
 507
 508 (defun gnus-agent-synchronize-flags-server (method)
 509   "Synchronize flags set when unplugged for server."
 510   (let ((gnus-command-method method))
 511     (when (file-exists-p (gnus-agent-lib-file "flags"))
 512       (set-buffer (get-buffer-create " *Gnus Agent flag synchronize*"))
 513       (erase-buffer)
 514       (nnheader-insert-file-contents (gnus-agent-lib-file "flags"))
 515       (if (null (gnus-check-server gnus-command-method))
 516           (message "Couldn't open server %s" (nth 1 gnus-command-method))
 517         (while (not (eobp))
 518           (if (null (eval (read (current-buffer))))
 519               (progn (forward-line)
 520                      (kill-line -1))
 521             (write-file (gnus-agent-lib-file "flags"))
 522             (error "Couldn't set flags from file %s"
 523                    (gnus-agent-lib-file "flags"))))
 524         (delete-file (gnus-agent-lib-file "flags")))
 525       (kill-buffer nil))))
 526
 527 (defun gnus-agent-possibly-synchronize-flags-server (method)
 528   "Synchronize flags for server according to `gnus-agent-synchronize-flags'."
 529   (when (or (and gnus-agent-synchronize-flags
 530                  (not (eq gnus-agent-synchronize-flags 'ask)))
 531             (and (eq gnus-agent-synchronize-flags 'ask)
 532                  (gnus-y-or-n-p (format "Synchronize flags on server `%s'? "
 533                                         (cadr method)))))
 534     (gnus-agent-synchronize-flags-server method)))
 535
 536 ;;;
 537 ;;; Server mode commands
 538 ;;;
 539
 540 (defun gnus-agent-add-server (server)
 541   "Enroll SERVER in the agent program."
 542   (interactive (list (gnus-server-server-name)))
 543   (unless server
 544     (error "No server on the current line"))
 545   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 546     (when (member method gnus-agent-covered-methods)
 547       (error "Server already in the agent program"))
 548     (push method gnus-agent-covered-methods)
 549     (gnus-server-update-server server)
 550     (gnus-agent-write-servers)
 551     (message "Entered %s into the Agent" server)))
 552
 553 (defun gnus-agent-remove-server (server)
 554   "Remove SERVER from the agent program."
 555   (interactive (list (gnus-server-server-name)))
 556   (unless server
 557     (error "No server on the current line"))
 558   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 559     (unless (member method gnus-agent-covered-methods)
 560       (error "Server not in the agent program"))
 561     (setq gnus-agent-covered-methods
 562           (delete method gnus-agent-covered-methods))
 563     (gnus-server-update-server server)
 564     (gnus-agent-write-servers)
 565     (message "Removed %s from the agent" server)))
 566
 567 (defun gnus-agent-read-servers ()
 568   "Read the alist of covered servers."
 569   (setq gnus-agent-covered-methods
 570         (gnus-agent-read-file
 571          (nnheader-concat gnus-agent-directory "lib/servers"))))
 572
 573 (defun gnus-agent-write-servers ()
 574   "Write the alist of covered servers."
 575   (gnus-make-directory (nnheader-concat gnus-agent-directory "lib"))
 576   (let ((coding-system-for-write nnheader-file-coding-system)
 577         (file-name-coding-system nnmail-pathname-coding-system))
 578     (with-temp-file (nnheader-concat gnus-agent-directory "lib/servers")
 579       (prin1 gnus-agent-covered-methods (current-buffer)))))
 580
 581 ;;;
 582 ;;; Summary commands
 583 ;;;
 584
 585 (defun gnus-agent-mark-article (n &optional unmark)
 586   "Mark the next N articles as downloadable.
 587 If N is negative, mark backward instead.  If UNMARK is non-nil, remove
 588 the mark instead.  The difference between N and the actual number of
 589 articles marked is returned."
 590   (interactive "p")
 591   (let ((backward (< n 0))
 592         (n (abs n)))
 593     (while (and
 594             (> n 0)
 595             (progn
 596               (gnus-summary-set-agent-mark
 597                (gnus-summary-article-number) unmark)
 598               (zerop (gnus-summary-next-subject (if backward -1 1) nil t))))
 599       (setq n (1- n)))
 600     (when (/= 0 n)
 601       (gnus-message 7 "No more articles"))
 602     (gnus-summary-recenter)
 603     (gnus-summary-position-point)
 604     n))
 605
 606 (defun gnus-agent-unmark-article (n)
 607   "Remove the downloadable mark from the next N articles.
 608 If N is negative, unmark backward instead.  The difference between N and
 609 the actual number of articles unmarked is returned."
 610   (interactive "p")
 611   (gnus-agent-mark-article n t))
 612
 613 (defun gnus-agent-toggle-mark (n)
 614   "Toggle the downloadable mark from the next N articles.
 615 If N is negative, toggle backward instead.  The difference between N and
 616 the actual number of articles toggled is returned."
 617   (interactive "p")
 618   (gnus-agent-mark-article n 'toggle))
 619
 620 (defun gnus-summary-set-agent-mark (article &optional unmark)
 621   "Mark ARTICLE as downloadable."
 622   (let ((unmark (if (and (not (null unmark)) (not (eq t unmark)))
 623                     (memq article gnus-newsgroup-downloadable)
 624                   unmark)))
 625     (if unmark
 626         (progn
 627           (setq gnus-newsgroup-downloadable
 628                 (delq article gnus-newsgroup-downloadable))
 629           (push article gnus-newsgroup-undownloaded))
 630       (setq gnus-newsgroup-undownloaded
 631             (delq article gnus-newsgroup-undownloaded))
 632       (push article gnus-newsgroup-downloadable))
 633     (gnus-summary-update-mark
 634      (if unmark gnus-undownloaded-mark gnus-downloadable-mark)
 635      'unread)))
 636
 637 (defun gnus-agent-get-undownloaded-list ()
 638   "Mark all unfetched articles as read."
 639   (let ((gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name)))
 640     (when (and (not gnus-plugged)
 641                (gnus-agent-method-p gnus-command-method))
 642       (gnus-agent-load-alist gnus-newsgroup-name)
 643       ;; First mark all undownloaded articles as undownloaded.
 644       (dolist (article (mapcar (lambda (header) (mail-header-number header))
 645                                gnus-newsgroup-headers))
 646         (unless (or (cdr (assq article gnus-agent-article-alist))
 647                     (memq article gnus-newsgroup-downloadable)
 648                     (memq article gnus-newsgroup-cached))
 649           (push article gnus-newsgroup-undownloaded)))
 650       ;; Then mark downloaded downloadable as not-downloadable,
 651       ;; if you get my drift.
 652       (dolist (article gnus-newsgroup-downloadable)
 653         (when (cdr (assq article gnus-agent-article-alist))
 654           (setq gnus-newsgroup-downloadable
 655                 (delq article gnus-newsgroup-downloadable)))))))
 656
 657 (defun gnus-agent-catchup ()
 658   "Mark all undownloaded articles as read."
 659   (interactive)
 660   (save-excursion
 661     (while gnus-newsgroup-undownloaded
 662       (gnus-summary-mark-article
 663        (pop gnus-newsgroup-undownloaded) gnus-catchup-mark)))
 664   (gnus-summary-position-point))
 665
 666 ;;;
 667 ;;; Internal functions
 668 ;;;
 669
 670 (defun gnus-agent-save-active (method)
 671   (gnus-agent-save-active-1 method 'gnus-active-to-gnus-format))
 672
 673 (defun gnus-agent-save-active-1 (method function)
 674   (when (gnus-agent-method-p method)
 675     (let* ((gnus-command-method method)
 676            (new (gnus-make-hashtable (count-lines (point-min) (point-max))))
 677            (file (gnus-agent-lib-file "active")))
 678       (funcall function nil new)
 679       (gnus-agent-write-active file new)
 680       (erase-buffer)
 681       (nnheader-insert-file-contents file))))
 682
 683 (defun gnus-agent-write-active (file new)
 684   (let ((orig (gnus-make-hashtable (count-lines (point-min) (point-max))))
 685         (file (gnus-agent-lib-file "active"))
 686         elem osym)
 687     (when (file-exists-p file)
 688       (with-temp-buffer
 689         (nnheader-insert-file-contents file)
 690         (gnus-active-to-gnus-format nil orig))
 691       (mapatoms
 692        (lambda (sym)
 693          (when (and sym (boundp sym))
 694            (if (and (boundp (setq osym (intern (symbol-name sym) orig)))
 695                     (setq elem (symbol-value osym)))
 696                (setcdr elem (cdr (symbol-value sym)))
 697              (set (intern (symbol-name sym) orig) (symbol-value sym)))))
 698        new))
 699     (gnus-make-directory (file-name-directory file))
 700     (let ((coding-system-for-write gnus-agent-file-coding-system))
 701       ;; The hashtable contains real names of groups,  no more prefix
 702       ;; removing, so set `full' to `t'.
 703       (gnus-write-active-file file orig t))))
 704
 705 (defun gnus-agent-save-groups (method)
 706   (gnus-agent-save-active-1 method 'gnus-groups-to-gnus-format))
 707
 708 (defun gnus-agent-save-group-info (method group active)
 709   (when (gnus-agent-method-p method)
 710     (let* ((gnus-command-method method)
 711            (coding-system-for-write nnheader-file-coding-system)
 712            (file-name-coding-system nnmail-pathname-coding-system)
 713            (file (gnus-agent-lib-file "active"))
 714            oactive)
 715       (gnus-make-directory (file-name-directory file))
 716       (with-temp-file file
 717         ;; Emacs got problem to match non-ASCII group in multibyte buffer.
 718         (mm-disable-multibyte)
 719         (when (file-exists-p file)
 720           (nnheader-insert-file-contents file))
 721         (goto-char (point-min))
 722         (when (re-search-forward
 723                (concat "^" (regexp-quote group) " ") nil t)
 724           (save-excursion
 725             (save-restriction
 726               (narrow-to-region (match-beginning 0)
 727                                 (progn
 728                                   (forward-line 1)
 729                                   (point)))
 730               (setq oactive (car (nnmail-parse-active)))))
 731           (gnus-delete-line))
 732         (insert (format "%S %d %d y\n" (intern group)
 733                         (cdr active)
 734                         (or (car oactive) (car active))))
 735         (goto-char (point-max))
 736         (while (search-backward "\\." nil t)
 737           (delete-char 1))))))
 738
 739 (defun gnus-agent-group-path (group)
 740   "Translate GROUP into a path."
 741   (if nnmail-use-long-file-names
 742       (gnus-group-real-name group)
 743     (nnheader-translate-file-chars
 744      (nnheader-replace-chars-in-string
 745       (nnheader-replace-duplicate-chars-in-string
 746        (nnheader-replace-chars-in-string
 747         (gnus-group-real-name group)
 748         ?/ ?_)
 749        ?. ?_)
 750       ?. ?/))))
 751
 752 \f
 753
 754 (defun gnus-agent-method-p (method)
 755   "Say whether METHOD is covered by the agent."
 756   (member method gnus-agent-covered-methods))
 757
 758 (defun gnus-agent-get-function (method)
 759   (if (and (not gnus-plugged)
 760            (gnus-agent-method-p method))
 761       (progn
 762         (require 'nnagent)
 763         'nnagent)
 764     (car method)))
 765
 766 ;;; History functions
 767
 768 (defun gnus-agent-history-buffer ()
 769   (cdr (assoc (gnus-agent-method) gnus-agent-history-buffers)))
 770
 771 (defun gnus-agent-open-history ()
 772   (save-excursion
 773     (push (cons (gnus-agent-method)
 774                 (set-buffer (gnus-get-buffer-create
 775                              (format " *Gnus agent %s history*"
 776                                      (gnus-agent-method)))))
 777           gnus-agent-history-buffers)
 778     (mm-disable-multibyte) ;; everything is binary
 779     (erase-buffer)
 780     (insert "\n")
 781     (let ((file (gnus-agent-lib-file "history")))
 782       (when (file-exists-p file)
 783         (nnheader-insert-file-contents file))
 784       (set (make-local-variable 'gnus-agent-file-name) file))))
 785
 786 (defun gnus-agent-save-history ()
 787   (save-excursion
 788     (set-buffer gnus-agent-current-history)
 789     (gnus-make-directory (file-name-directory gnus-agent-file-name))
 790     (let ((coding-system-for-write gnus-agent-file-coding-system))
 791       (write-region (1+ (point-min)) (point-max)
 792                     gnus-agent-file-name nil 'silent))))
 793
 794 (defun gnus-agent-close-history ()
 795   (when (gnus-buffer-live-p gnus-agent-current-history)
 796     (kill-buffer gnus-agent-current-history)
 797     (setq gnus-agent-history-buffers
 798           (delq (assoc (gnus-agent-method) gnus-agent-history-buffers)
 799                 gnus-agent-history-buffers))))
 800
 801 (defun gnus-agent-enter-history (id group-arts date)
 802   (save-excursion
 803     (set-buffer gnus-agent-current-history)
 804     (goto-char (point-max))
 805     (let ((p (point)))
 806       (insert id "\t" (number-to-string date) "\t")
 807       (while group-arts
 808         (insert (format "%S" (intern (caar group-arts)))
 809                 " " (number-to-string (cdr (pop group-arts)))
 810                 " "))
 811       (insert "\n")
 812       (while (search-backward "\\." p t)
 813         (delete-char 1)))))
 814
 815 (defun gnus-agent-article-in-history-p (id)
 816   (save-excursion
 817     (set-buffer (gnus-agent-history-buffer))
 818     (goto-char (point-min))
 819     (search-forward (concat "\n" id "\t") nil t)))
 820
 821 (defun gnus-agent-history-path (id)
 822   (save-excursion
 823     (set-buffer (gnus-agent-history-buffer))
 824     (goto-char (point-min))
 825     (when (search-forward (concat "\n" id "\t") nil t)
 826       (let ((method (gnus-agent-method)))
 827         (let (paths group)
 828           (while (not (numberp (setq group (read (current-buffer)))))
 829             (push (concat method "/" group) paths))
 830           (nreverse paths))))))
 831
 832 ;;;
 833 ;;; Fetching
 834 ;;;
 835
 836 (defun gnus-agent-fetch-articles (group articles)
 837   "Fetch ARTICLES from GROUP and put them into the Agent."
 838   (when articles
 839     ;; Prune off articles that we have already fetched.
 840     (while (and articles
 841                 (cdr (assq (car articles) gnus-agent-article-alist)))
 842       (pop articles))
 843     (let ((arts articles))
 844       (while (cdr arts)
 845         (if (cdr (assq (cadr arts) gnus-agent-article-alist))
 846             (setcdr arts (cddr arts))
 847           (setq arts (cdr arts)))))
 848     (when articles
 849       (let ((dir (concat
 850                   (gnus-agent-directory)
 851                   (gnus-agent-group-path group) "/"))
 852             (date (time-to-days (current-time)))
 853             (case-fold-search t)
 854             pos crosses id elem)
 855         (gnus-make-directory dir)
 856         (gnus-message 7 "Fetching articles for %s..." group)
 857         ;; Fetch the articles from the backend.
 858         (if (gnus-check-backend-function 'retrieve-articles group)
 859             (setq pos (gnus-retrieve-articles articles group))
 860           (with-temp-buffer
 861             (let (article)
 862               (while (setq article (pop articles))
 863                 (when (or
 864                        (gnus-backlog-request-article group article
 865                                                      nntp-server-buffer)
 866                        (gnus-request-article article group))
 867                   (goto-char (point-max))
 868                   (push (cons article (point)) pos)
 869                   (insert-buffer-substring nntp-server-buffer)))
 870               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 871               (setq pos (nreverse pos)))))
 872         ;; Then save these articles into the Agent.
 873         (save-excursion
 874           (set-buffer nntp-server-buffer)
 875           (while pos
 876             (narrow-to-region (cdar pos) (or (cdadr pos) (point-max)))
 877             (goto-char (point-min))
 878             (when (search-forward "\n\n" nil t)
 879               (when (search-backward "\nXrefs: " nil t)
 880                 ;; Handle crossposting.
 881                 (skip-chars-forward "^ ")
 882                 (skip-chars-forward " ")
 883                 (setq crosses nil)
 884                 (while (looking-at "\\([^: \n]+\\):\\([0-9]+\\) +")
 885                   (push (cons (buffer-substring (match-beginning 1)
 886                                                 (match-end 1))
 887                               (buffer-substring (match-beginning 2)
 888                                                 (match-end 2)))
 889                         crosses)
 890                   (goto-char (match-end 0)))
 891                 (gnus-agent-crosspost crosses (caar pos))))
 892             (goto-char (point-min))
 893             (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
 894                 (setq id "No-Message-ID-in-article")
 895               (setq id (buffer-substring (match-beginning 1) (match-end 1))))
 896             (let ((coding-system-for-write
 897                    gnus-agent-file-coding-system))
 898               (write-region (point-min) (point-max)
 899                             (concat dir (number-to-string (caar pos)))
 900                             nil 'silent))
 901             (when (setq elem (assq (caar pos) gnus-agent-article-alist))
 902               (setcdr elem t))
 903             (gnus-agent-enter-history
 904              id (or crosses (list (cons group (caar pos)))) date)
 905             (widen)
 906             (pop pos)))
 907         (gnus-agent-save-alist group)))))
 908
 909 (defun gnus-agent-crosspost (crosses article)
 910   (let (gnus-agent-article-alist group alist beg end)
 911     (save-excursion
 912       (set-buffer gnus-agent-overview-buffer)
 913       (when (nnheader-find-nov-line article)
 914         (forward-word 1)
 915         (setq beg (point))
 916         (setq end (progn (forward-line 1) (point)))))
 917     (while crosses
 918       (setq group (caar crosses))
 919       (unless (setq alist (assoc group gnus-agent-group-alist))
 920         (push (setq alist (list group (gnus-agent-load-alist (caar crosses))))
 921               gnus-agent-group-alist))
 922       (setcdr alist (cons (cons (cdar crosses) t) (cdr alist)))
 923       (save-excursion
 924         (set-buffer (gnus-get-buffer-create (format " *Gnus agent overview %s*"
 925                                                     group)))
 926         (when (= (point-max) (point-min))
 927           (push (cons group (current-buffer)) gnus-agent-buffer-alist)
 928           (ignore-errors
 929             (nnheader-insert-file-contents
 930              (gnus-agent-article-name ".overview" group))))
 931         (nnheader-find-nov-line (string-to-number (cdar crosses)))
 932         (insert (string-to-number (cdar crosses)))
 933         (insert-buffer-substring gnus-agent-overview-buffer beg end))
 934       (pop crosses))))
 935
 936 (defun gnus-agent-flush-cache ()
 937   (save-excursion
 938     (while gnus-agent-buffer-alist
 939       (set-buffer (cdar gnus-agent-buffer-alist))
 940       (let ((coding-system-for-write
 941              gnus-agent-file-coding-system))
 942         (write-region (point-min) (point-max)
 943                       (gnus-agent-article-name ".overview"
 944                                                (caar gnus-agent-buffer-alist))
 945                       nil 'silent))
 946       (pop gnus-agent-buffer-alist))
 947     (while gnus-agent-group-alist
 948       (with-temp-file (caar gnus-agent-group-alist)
 949         (princ (cdar gnus-agent-group-alist))
 950         (insert "\n"))
 951       (pop gnus-agent-group-alist))))
 952
 953 (defun gnus-agent-fetch-headers (group &optional force)
 954   (let ((articles (gnus-list-of-unread-articles group))
 955         (gnus-decode-encoded-word-function 'identity)
 956         (file (gnus-agent-article-name ".overview" group)))
 957     ;; Add article with marks to list of article headers we want to fetch.
 958     (dolist (arts (gnus-info-marks (gnus-get-info group)))
 959       (setq articles (gnus-union (gnus-uncompress-sequence (cdr arts))
 960                             articles)))
 961     (setq articles (sort articles '<))
 962     ;; Remove known articles.
 963     (when (gnus-agent-load-alist group)
 964       (setq articles (gnus-sorted-intersection
 965                       articles
 966                       (gnus-uncompress-range
 967                        (cons (1+ (caar (last gnus-agent-article-alist)))
 968                              (cdr (gnus-active group)))))))
 969     ;; Fetch them.
 970     (gnus-make-directory (nnheader-translate-file-chars
 971                           (file-name-directory file) t))
 972     (when articles
 973       (gnus-message 7 "Fetching headers for %s..." group)
 974       (save-excursion
 975         (set-buffer nntp-server-buffer)
 976         (unless (eq 'nov (gnus-retrieve-headers articles group))
 977           (nnvirtual-convert-headers))
 978         ;; Save these headers for later processing.
 979         (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
 980         (when (file-exists-p file)
 981           (gnus-agent-braid-nov group articles file))
 982         (let ((coding-system-for-write
 983                gnus-agent-file-coding-system))
 984           (write-region (point-min) (point-max) file nil 'silent))
 985         (gnus-agent-save-alist group articles nil)
 986         (gnus-agent-enter-history
 987          "last-header-fetched-for-session"
 988          (list (cons group (nth (- (length  articles) 1) articles)))
 989          (time-to-days (current-time)))
 990         articles))))
 991
 992 (defsubst gnus-agent-copy-nov-line (article)
 993   (let (b e)
 994     (set-buffer gnus-agent-overview-buffer)
 995     (setq b (point))
 996     (if (eq article (read (current-buffer)))
 997         (setq e (progn (forward-line 1) (point)))
 998       (progn
 999         (beginning-of-line)
1000         (setq e b)))
1001     (set-buffer nntp-server-buffer)
1002     (insert-buffer-substring gnus-agent-overview-buffer b e)))
1003
1004 (defun gnus-agent-braid-nov (group articles file)
1005   (set-buffer gnus-agent-overview-buffer)
1006   (goto-char (point-min))
1007   (set-buffer nntp-server-buffer)
1008   (erase-buffer)
1009   (nnheader-insert-file-contents file)
1010   (goto-char (point-max))
1011   (if (or (= (point-min) (point-max))
1012           (progn
1013             (forward-line -1)
1014             (< (read (current-buffer)) (car articles))))
1015       ;; We have only headers that are after the older headers,
1016       ;; so we just append them.
1017       (progn
1018         (goto-char (point-max))
1019         (insert-buffer-substring gnus-agent-overview-buffer))
1020     ;; We do it the hard way.
1021     (nnheader-find-nov-line (car articles))
1022     (gnus-agent-copy-nov-line (car articles))
1023     (pop articles)
1024     (while (and articles
1025                 (not (eobp)))
1026       (while (and (not (eobp))
1027                   (< (read (current-buffer)) (car articles)))
1028         (forward-line 1))
1029       (beginning-of-line)
1030       (unless (eobp)
1031         (gnus-agent-copy-nov-line (car articles))
1032         (setq articles (cdr articles))))
1033     (when articles
1034       (let (b e)
1035         (set-buffer gnus-agent-overview-buffer)
1036         (setq b (point)
1037               e (point-max))
1038         (set-buffer nntp-server-buffer)
1039         (insert-buffer-substring gnus-agent-overview-buffer b e)))))
1040
1041 (defun gnus-agent-load-alist (group &optional dir)
1042   "Load the article-state alist for GROUP."
1043   (setq gnus-agent-article-alist
1044         (gnus-agent-read-file
1045          (if dir
1046              (expand-file-name ".agentview" dir)
1047            (gnus-agent-article-name ".agentview" group)))))
1048
1049 (defun gnus-agent-save-alist (group &optional articles state dir)
1050   "Save the article-state alist for GROUP."
1051   (let ((file-name-coding-system nnmail-pathname-coding-system))
1052       (with-temp-file (if dir
1053                           (expand-file-name ".agentview" dir)
1054                         (gnus-agent-article-name ".agentview" group))
1055         (princ (setq gnus-agent-article-alist
1056                      (nconc gnus-agent-article-alist
1057                             (mapcar (lambda (article) (cons article state))
1058                                     articles)))
1059                (current-buffer))
1060         (insert "\n"))))
1061
1062 (defun gnus-agent-article-name (article group)
1063   (expand-file-name (if (stringp article) article (string-to-number article))
1064                     (file-name-as-directory
1065                      (expand-file-name (gnus-agent-group-path group)
1066                                        (gnus-agent-directory)))))
1067
1068 (defun gnus-agent-batch-confirmation (msg)
1069   "Show error message and return t."
1070   (gnus-message 1 msg)
1071   t)
1072
1073 ;;;###autoload
1074 (defun gnus-agent-batch-fetch ()
1075   "Start Gnus and fetch session."
1076   (interactive)
1077   (gnus)
1078   (let ((gnus-agent-confirmation-function 'gnus-agent-batch-confirmation))
1079     (gnus-agent-fetch-session))
1080   (gnus-group-exit))
1081
1082 (defun gnus-agent-fetch-session ()
1083   "Fetch all articles and headers that are eligible for fetching."
1084   (interactive)
1085   (unless gnus-agent-covered-methods
1086     (error "No servers are covered by the Gnus agent"))
1087   (unless gnus-plugged
1088     (error "Can't fetch articles while Gnus is unplugged"))
1089   (let ((methods gnus-agent-covered-methods)
1090         groups group gnus-command-method)
1091     (save-excursion
1092       (while methods
1093         (condition-case err
1094             (progn
1095               (setq gnus-command-method (car methods))
1096               (when (or (gnus-server-opened gnus-command-method)
1097                         (gnus-open-server gnus-command-method))
1098                 (setq groups (gnus-groups-from-server (car methods)))
1099                 (gnus-agent-with-fetch
1100                   (while (setq group (pop groups))
1101                     (when (<= (gnus-group-level group) gnus-agent-handle-level)
1102                       (gnus-agent-fetch-group-1 group gnus-command-method))))))
1103           (error
1104            (unless (funcall gnus-agent-confirmation-function
1105                             (format "Error (%s).  Continue? " err))
1106              (error "Cannot fetch articles into the Gnus agent.")))
1107           (quit
1108            (unless (funcall gnus-agent-confirmation-function
1109                             (format "Quit fetching session (%s).  Continue? "
1110                                     err))
1111              (signal 'quit "Cannot fetch articles into the Gnus agent."))))
1112         (pop methods))
1113       (gnus-message 6 "Finished fetching articles into the Gnus agent"))))
1114
1115 (defun gnus-agent-fetch-group-1 (group method)
1116   "Fetch GROUP."
1117   (let ((gnus-command-method method)
1118         (gnus-newsgroup-name group)
1119         gnus-newsgroup-dependencies gnus-newsgroup-headers
1120         gnus-newsgroup-scored gnus-headers gnus-score
1121         gnus-use-cache articles arts
1122         category predicate info marks score-param
1123         (gnus-summary-expunge-below gnus-summary-expunge-below)
1124         (gnus-summary-mark-below gnus-summary-mark-below)
1125         (gnus-orphan-score gnus-orphan-score)
1126         ;; Maybe some other gnus-summary local variables should also
1127         ;; be put here.
1128         )
1129     (unless (gnus-check-group group)
1130       (error "Can't open server for %s" group))
1131     ;; Fetch headers.
1132     (when (and (or (gnus-active group) (gnus-activate-group group))
1133                (setq articles (gnus-agent-fetch-headers group))
1134                (let ((nntp-server-buffer gnus-agent-overview-buffer))
1135                  ;; Parse them and see which articles we want to fetch.
1136                  (setq gnus-newsgroup-dependencies
1137                        (make-vector (length articles) 0))
1138                  (setq gnus-newsgroup-headers
1139                        (gnus-get-newsgroup-headers-xover articles nil nil
1140                                                          group))
1141                  ;; `gnus-agent-overview-buffer' may be killed for
1142                  ;; timeout reason.  If so, recreate it.
1143                  (gnus-agent-create-buffer)))
1144       (setq category (gnus-group-category group))
1145       (setq predicate
1146             (gnus-get-predicate
1147              (or (gnus-group-find-parameter group 'agent-predicate t)
1148                  (cadr category))))
1149       (if (memq (caaddr predicate) '(gnus-agent-true gnus-agent-false))
1150           ;; Simple implementation
1151           (setq arts
1152                 (and (eq (caaddr predicate) 'gnus-agent-true) articles))
1153         (setq arts nil)
1154         (setq score-param
1155               (or (gnus-group-get-parameter group 'agent-score t)
1156                   (caddr category)))
1157         ;; Translate score-param into real one
1158         (cond
1159          ((not score-param))
1160          ((eq score-param 'file)
1161           (setq score-param (gnus-all-score-files group)))
1162          ((stringp (car score-param)))
1163          (t
1164           (setq score-param (list (list score-param)))))
1165         (when score-param
1166           (gnus-score-headers score-param))
1167         (while (setq gnus-headers (pop gnus-newsgroup-headers))
1168           (setq gnus-score
1169                 (or (cdr (assq (mail-header-number gnus-headers)
1170                                gnus-newsgroup-scored))
1171                     gnus-summary-default-score))
1172           (when (funcall predicate)
1173             (push (mail-header-number gnus-headers)
1174                   arts))))
1175       ;; Fetch the articles.
1176       (when arts
1177         (gnus-agent-fetch-articles group arts)))
1178     ;; Perhaps we have some additional articles to fetch.
1179     (setq arts (assq 'download (gnus-info-marks
1180                                 (setq info (gnus-get-info group)))))
1181     (when (cdr arts)
1182       (gnus-agent-fetch-articles
1183        group (gnus-uncompress-range (cdr arts)))
1184       (setq marks (delq arts (gnus-info-marks info)))
1185       (gnus-info-set-marks info marks)
1186       (gnus-dribble-enter
1187        (concat "(gnus-group-set-info '"
1188                (gnus-prin1-to-string info)
1189                ")")))))
1190
1191 ;;;
1192 ;;; Agent Category Mode
1193 ;;;
1194
1195 (defvar gnus-category-mode-hook nil
1196   "Hook run in `gnus-category-mode' buffers.")
1197
1198 (defvar gnus-category-line-format "     %(%20c%): %g\n"
1199   "Format of category lines.")
1200
1201 (defvar gnus-category-mode-line-format "Gnus: %%b"
1202   "The format specification for the category mode line.")
1203
1204 (defvar gnus-agent-short-article 100
1205   "Articles that have fewer lines than this are short.")
1206
1207 (defvar gnus-agent-long-article 200
1208   "Articles that have more lines than this are long.")
1209
1210 (defvar gnus-agent-low-score 0
1211   "Articles that have a score lower than this have a low score.")
1212
1213 (defvar gnus-agent-high-score 0
1214   "Articles that have a score higher than this have a high score.")
1215
1216
1217 ;;; Internal variables.
1218
1219 (defvar gnus-category-buffer "*Agent Category*")
1220
1221 (defvar gnus-category-line-format-alist
1222   `((?c gnus-tmp-name ?s)
1223     (?g gnus-tmp-groups ?d)))
1224
1225 (defvar gnus-category-mode-line-format-alist
1226   `((?u user-defined ?s)))
1227
1228 (defvar gnus-category-line-format-spec nil)
1229 (defvar gnus-category-mode-line-format-spec nil)
1230
1231 (defvar gnus-category-mode-map nil)
1232 (put 'gnus-category-mode 'mode-class 'special)
1233
1234 (unless gnus-category-mode-map
1235   (setq gnus-category-mode-map (make-sparse-keymap))
1236   (suppress-keymap gnus-category-mode-map)
1237
1238   (gnus-define-keys gnus-category-mode-map
1239     "q" gnus-category-exit
1240     "k" gnus-category-kill
1241     "c" gnus-category-copy
1242     "a" gnus-category-add
1243     "p" gnus-category-edit-predicate
1244     "g" gnus-category-edit-groups
1245     "s" gnus-category-edit-score
1246     "l" gnus-category-list
1247
1248     "\C-c\C-i" gnus-info-find-node
1249     "\C-c\C-b" gnus-bug))
1250
1251 (defvar gnus-category-menu-hook nil
1252   "*Hook run after the creation of the menu.")
1253
1254 (defun gnus-category-make-menu-bar ()
1255   (gnus-turn-off-edit-menu 'category)
1256   (unless (boundp 'gnus-category-menu)
1257     (easy-menu-define
1258      gnus-category-menu gnus-category-mode-map ""
1259      '("Categories"
1260        ["Add" gnus-category-add t]
1261        ["Kill" gnus-category-kill t]
1262        ["Copy" gnus-category-copy t]
1263        ["Edit predicate" gnus-category-edit-predicate t]
1264        ["Edit score" gnus-category-edit-score t]
1265        ["Edit groups" gnus-category-edit-groups t]
1266        ["Exit" gnus-category-exit t]))
1267
1268     (gnus-run-hooks 'gnus-category-menu-hook)))
1269
1270 (defun gnus-category-mode ()
1271   "Major mode for listing and editing agent categories.
1272
1273 All normal editing commands are switched off.
1274 \\<gnus-category-mode-map>
1275 For more in-depth information on this mode, read the manual
1276 (`\\[gnus-info-find-node]').
1277
1278 The following commands are available:
1279
1280 \\{gnus-category-mode-map}"
1281   (interactive)
1282   (when (gnus-visual-p 'category-menu 'menu)
1283     (gnus-category-make-menu-bar))
1284   (kill-all-local-variables)
1285   (gnus-simplify-mode-line)
1286   (setq major-mode 'gnus-category-mode)
1287   (setq mode-name "Category")
1288   (gnus-set-default-directory)
1289   (setq mode-line-process nil)
1290   (use-local-map gnus-category-mode-map)
1291   (buffer-disable-undo)
1292   (setq truncate-lines t)
1293   (setq buffer-read-only t)
1294   (gnus-run-hooks 'gnus-category-mode-hook))
1295
1296 (defalias 'gnus-category-position-point 'gnus-goto-colon)
1297
1298 (defun gnus-category-insert-line (category)
1299   (let* ((gnus-tmp-name (car category))
1300          (gnus-tmp-groups (length (cadddr category))))
1301     (beginning-of-line)
1302     (gnus-add-text-properties
1303      (point)
1304      (prog1 (1+ (point))
1305        ;; Insert the text.
1306        (eval gnus-category-line-format-spec))
1307      (list 'gnus-category gnus-tmp-name))))
1308
1309 (defun gnus-enter-category-buffer ()
1310   "Go to the Category buffer."
1311   (interactive)
1312   (gnus-category-setup-buffer)
1313   (gnus-configure-windows 'category)
1314   (gnus-category-prepare))
1315
1316 (defun gnus-category-setup-buffer ()
1317   (unless (get-buffer gnus-category-buffer)
1318     (save-excursion
1319       (set-buffer (gnus-get-buffer-create gnus-category-buffer))
1320       (gnus-category-mode))))
1321
1322 (defun gnus-category-prepare ()
1323   (gnus-set-format 'category-mode)
1324   (gnus-set-format 'category t)
1325   (let ((alist gnus-category-alist)
1326         (buffer-read-only nil))
1327     (erase-buffer)
1328     (while alist
1329       (gnus-category-insert-line (pop alist)))
1330     (goto-char (point-min))
1331     (gnus-category-position-point)))
1332
1333 (defun gnus-category-name ()
1334   (or (get-text-property (gnus-point-at-bol) 'gnus-category)
1335       (error "No category on the current line")))
1336
1337 (defun gnus-category-read ()
1338   "Read the category alist."
1339   (setq gnus-category-alist
1340         (or (gnus-agent-read-file
1341              (nnheader-concat gnus-agent-directory "lib/categories"))
1342             (list (list 'default 'short nil nil)))))
1343
1344 (defun gnus-category-write ()
1345   "Write the category alist."
1346   (setq gnus-category-predicate-cache nil
1347         gnus-category-group-cache nil)
1348   (gnus-make-directory (nnheader-concat gnus-agent-directory "lib"))
1349   (with-temp-file (nnheader-concat gnus-agent-directory "lib/categories")
1350     (prin1 gnus-category-alist (current-buffer))))
1351
1352 (defun gnus-category-edit-predicate (category)
1353   "Edit the predicate for CATEGORY."
1354   (interactive (list (gnus-category-name)))
1355   (let ((info (assq category gnus-category-alist)))
1356     (gnus-edit-form
1357      (cadr info) (format "Editing the predicate for category %s" category)
1358      `(lambda (predicate)
1359         (setcar (cdr (assq ',category gnus-category-alist)) predicate)
1360         (gnus-category-write)
1361         (gnus-category-list)))))
1362
1363 (defun gnus-category-edit-score (category)
1364   "Edit the score expression for CATEGORY."
1365   (interactive (list (gnus-category-name)))
1366   (let ((info (assq category gnus-category-alist)))
1367     (gnus-edit-form
1368      (caddr info)
1369      (format "Editing the score expression for category %s" category)
1370      `(lambda (groups)
1371         (setcar (cddr (assq ',category gnus-category-alist)) groups)
1372         (gnus-category-write)
1373         (gnus-category-list)))))
1374
1375 (defun gnus-category-edit-groups (category)
1376   "Edit the group list for CATEGORY."
1377   (interactive (list (gnus-category-name)))
1378   (let ((info (assq category gnus-category-alist)))
1379     (gnus-edit-form
1380      (cadddr info) (format "Editing the group list for category %s" category)
1381      `(lambda (groups)
1382         (setcar (nthcdr 3 (assq ',category gnus-category-alist)) groups)
1383         (gnus-category-write)
1384         (gnus-category-list)))))
1385
1386 (defun gnus-category-kill (category)
1387   "Kill the current category."
1388   (interactive (list (gnus-category-name)))
1389   (let ((info (assq category gnus-category-alist))
1390         (buffer-read-only nil))
1391     (gnus-delete-line)
1392     (setq gnus-category-alist (delq info gnus-category-alist))
1393     (gnus-category-write)))
1394
1395 (defun gnus-category-copy (category to)
1396   "Copy the current category."
1397   (interactive (list (gnus-category-name) (intern (read-string "New name: "))))
1398   (let ((info (assq category gnus-category-alist)))
1399     (push (list to (gnus-copy-sequence (cadr info))
1400                 (gnus-copy-sequence (caddr info)) nil)
1401           gnus-category-alist)
1402     (gnus-category-write)
1403     (gnus-category-list)))
1404
1405 (defun gnus-category-add (category)
1406   "Create a new category."
1407   (interactive "SCategory name: ")
1408   (when (assq category gnus-category-alist)
1409     (error "Category %s already exists" category))
1410   (push (list category 'false nil nil)
1411         gnus-category-alist)
1412   (gnus-category-write)
1413   (gnus-category-list))
1414
1415 (defun gnus-category-list ()
1416   "List all categories."
1417   (interactive)
1418   (gnus-category-prepare))
1419
1420 (defun gnus-category-exit ()
1421   "Return to the group buffer."
1422   (interactive)
1423   (kill-buffer (current-buffer))
1424   (gnus-configure-windows 'group t))
1425
1426 ;; To avoid having 8-bit characters in the source file.
1427 (defvar gnus-category-not (list '! 'not (intern (format "%c" 172))))
1428
1429 (defvar gnus-category-predicate-alist
1430   '((spam . gnus-agent-spam-p)
1431     (short . gnus-agent-short-p)
1432     (long . gnus-agent-long-p)
1433     (low . gnus-agent-low-scored-p)
1434     (high . gnus-agent-high-scored-p)
1435     (true . gnus-agent-true)
1436     (false . gnus-agent-false))
1437   "Mapping from short score predicate symbols to predicate functions.")
1438
1439 (defun gnus-agent-spam-p ()
1440   "Say whether an article is spam or not."
1441   (unless gnus-agent-spam-hashtb
1442     (setq gnus-agent-spam-hashtb (gnus-make-hashtable 1000)))
1443   (if (not (equal (mail-header-references gnus-headers) ""))
1444       nil
1445     (let ((string (gnus-simplify-subject (mail-header-subject gnus-headers))))
1446       (prog1
1447           (gnus-gethash string gnus-agent-spam-hashtb)
1448         (gnus-sethash string t gnus-agent-spam-hashtb)))))
1449
1450 (defun gnus-agent-short-p ()
1451   "Say whether an article is short or not."
1452   (< (mail-header-lines gnus-headers) gnus-agent-short-article))
1453
1454 (defun gnus-agent-long-p ()
1455   "Say whether an article is long or not."
1456   (> (mail-header-lines gnus-headers) gnus-agent-long-article))
1457
1458 (defun gnus-agent-low-scored-p ()
1459   "Say whether an article has a low score or not."
1460   (< gnus-score gnus-agent-low-score))
1461
1462 (defun gnus-agent-high-scored-p ()
1463   "Say whether an article has a high score or not."
1464   (> gnus-score gnus-agent-high-score))
1465
1466 (defun gnus-category-make-function (cat)
1467   "Make a function from category CAT."
1468   `(lambda () ,(gnus-category-make-function-1 cat)))
1469
1470 (defun gnus-agent-true ()
1471   "Return t."
1472   t)
1473
1474 (defun gnus-agent-false ()
1475   "Return nil."
1476   nil)
1477
1478 (defun gnus-category-make-function-1 (cat)
1479   "Make a function from category CAT."
1480   (cond
1481    ;; Functions are just returned as is.
1482    ((or (symbolp cat)
1483         (gnus-functionp cat))
1484     `(,(or (cdr (assq cat gnus-category-predicate-alist))
1485            cat)))
1486    ;; More complex category.
1487    ((consp cat)
1488     `(,(cond
1489         ((memq (car cat) '(& and))
1490          'and)
1491         ((memq (car cat) '(| or))
1492          'or)
1493         ((memq (car cat) gnus-category-not)
1494          'not))
1495       ,@(mapcar 'gnus-category-make-function-1 (cdr cat))))
1496    (t
1497     (error "Unknown category type: %s" cat))))
1498
1499 (defun gnus-get-predicate (predicate)
1500   "Return the predicate for CATEGORY."
1501   (or (cdr (assoc predicate gnus-category-predicate-cache))
1502       (cdar (push (cons predicate
1503                         (gnus-category-make-function predicate))
1504                   gnus-category-predicate-cache))))
1505
1506 (defun gnus-group-category (group)
1507   "Return the category GROUP belongs to."
1508   (unless gnus-category-group-cache
1509     (setq gnus-category-group-cache (gnus-make-hashtable 1000))
1510     (let ((cs gnus-category-alist)
1511           groups cat)
1512       (while (setq cat (pop cs))
1513         (setq groups (cadddr cat))
1514         (while groups
1515           (gnus-sethash (pop groups) cat gnus-category-group-cache)))))
1516   (or (gnus-gethash group gnus-category-group-cache)
1517       (assq 'default gnus-category-alist)))
1518
1519 (defun gnus-agent-expire ()
1520   "Expire all old articles."
1521   (interactive)
1522   (let ((methods gnus-agent-covered-methods)
1523         (day (- (time-to-days (current-time)) gnus-agent-expire-days))
1524         gnus-command-method sym group articles
1525         history overview file histories elem art nov-file low info
1526         unreads marked article orig lowest highest)
1527     (save-excursion
1528       (setq overview (gnus-get-buffer-create " *expire overview*"))
1529       (while (setq gnus-command-method (pop methods))
1530         (when (file-exists-p (gnus-agent-lib-file "active"))
1531           (with-temp-buffer
1532             (nnheader-insert-file-contents (gnus-agent-lib-file "active"))
1533             (gnus-active-to-gnus-format
1534              gnus-command-method
1535              (setq orig (gnus-make-hashtable
1536                          (count-lines (point-min) (point-max))))))
1537           (let ((expiry-hashtb (gnus-make-hashtable 1023)))
1538             (gnus-agent-open-history)
1539             (set-buffer
1540              (setq gnus-agent-current-history
1541                    (setq history (gnus-agent-history-buffer))))
1542             (goto-char (point-min))
1543             (when (> (buffer-size) 1)
1544               (goto-char (point-min))
1545               (while (not (eobp))
1546                 (skip-chars-forward "^\t")
1547                 (if (let ((fetch-date (read (current-buffer))))
1548                       (if (numberp fetch-date)
1549                           (>  fetch-date day)
1550                         ;; History file is corrupted.
1551                         (gnus-message
1552                          5
1553                          (format "File %s is corrupted!"
1554                                  (gnus-agent-lib-file "history")))
1555                         (sit-for 1)
1556                         ;; Ignore it
1557                         t))
1558                     ;; New article; we don't expire it.
1559                     (forward-line 1)
1560                   ;; Old article.  Schedule it for possible nuking.
1561                   (while (not (eolp))
1562                     (setq sym (let ((obarray expiry-hashtb) s)
1563                                 (setq s (read (current-buffer)))
1564                                 (if (stringp s) (intern s) s)))
1565                     (if (boundp sym)
1566                         (set sym (cons (cons (read (current-buffer)) (point))
1567                                        (symbol-value sym)))
1568                       (set sym (list (cons (read (current-buffer)) (point)))))
1569                     (skip-chars-forward " "))
1570                   (forward-line 1)))
1571               ;; We now have all articles that can possibly be expired.
1572               (mapatoms
1573                (lambda (sym)
1574                  (setq group (symbol-name sym)
1575                        articles (sort (symbol-value sym) 'car-less-than-car)
1576                        low (car (gnus-active group))
1577                        info (gnus-get-info group)
1578                        unreads (ignore-errors
1579                                  (gnus-list-of-unread-articles group))
1580                        marked (nconc
1581                                (gnus-uncompress-range
1582                                 (cdr (assq 'tick (gnus-info-marks info))))
1583                                (gnus-uncompress-range
1584                                 (cdr (assq 'dormant
1585                                            (gnus-info-marks info)))))
1586                        nov-file (gnus-agent-article-name ".overview" group)
1587                        lowest nil
1588                        highest nil)
1589                  (gnus-agent-load-alist group)
1590                  (gnus-message 5 "Expiring articles in %s" group)
1591                  (set-buffer overview)
1592                  (erase-buffer)
1593                  (when (file-exists-p nov-file)
1594                    (nnheader-insert-file-contents nov-file))
1595                  (goto-char (point-min))
1596                  (setq article 0)
1597                  (while (setq elem (pop articles))
1598                    (setq article (car elem))
1599                    (when (or (null low)
1600                              (< article low)
1601                              gnus-agent-expire-all
1602                              (and (not (memq article unreads))
1603                                   (not (memq article marked))))
1604                      ;; Find and nuke the NOV line.
1605                      (while (and (not (eobp))
1606                                  (or (not (numberp
1607                                            (setq art (read (current-buffer)))))
1608                                      (< art article)))
1609                        (if (and (numberp art)
1610                                 (file-exists-p
1611                                  (gnus-agent-article-name
1612                                   (number-to-string art) group)))
1613                            (progn
1614                              (unless lowest
1615                                (setq lowest art))
1616                              (setq highest art)
1617                              (forward-line 1))
1618                          ;; Remove old NOV lines that have no articles.
1619                          (gnus-delete-line)))
1620                      (if (or (eobp)
1621                              (/= art article))
1622                          (beginning-of-line)
1623                        (gnus-delete-line))
1624                      ;; Nuke the article.
1625                      (when (file-exists-p
1626                             (setq file (gnus-agent-article-name
1627                                         (number-to-string article)
1628                                         group)))
1629                        (delete-file file))
1630                      ;; Schedule the history line for nuking.
1631                      (push (cdr elem) histories)))
1632                  (gnus-make-directory (file-name-directory nov-file))
1633                  (let ((coding-system-for-write
1634                         gnus-agent-file-coding-system))
1635                    (write-region (point-min) (point-max) nov-file nil 'silent))
1636                  ;; Delete the unwanted entries in the alist.
1637                  (setq gnus-agent-article-alist
1638                        (sort gnus-agent-article-alist 'car-less-than-car))
1639                  (let* ((alist gnus-agent-article-alist)
1640                         (prev (cons nil alist))
1641                         (first prev)
1642                         expired)
1643                    (while (and alist
1644                                (<= (caar alist) article))
1645                      (if (or (not (cdar alist))
1646                              (not (file-exists-p
1647                                    (gnus-agent-article-name
1648                                     (number-to-string
1649                                      (caar alist))
1650                                     group))))
1651                          (progn
1652                            (push (caar alist) expired)
1653                            (setcdr prev (setq alist (cdr alist))))
1654                        (setq prev alist
1655                              alist (cdr alist))))
1656                    (setq gnus-agent-article-alist (cdr first))
1657                    (gnus-agent-save-alist group)
1658                    ;; Mark all articles up to the first article
1659                    ;; in `gnus-article-alist' as read.
1660                    (when (and info (caar gnus-agent-article-alist))
1661                      (setcar (nthcdr 2 info)
1662                              (gnus-range-add
1663                               (nth 2 info)
1664                               (cons 1 (- (caar gnus-agent-article-alist) 1)))))
1665                    ;; Maybe everything has been expired from `gnus-article-alist'
1666                    ;; and so the above marking as read could not be conducted,
1667                    ;; or there are expired article within the range of the alist.
1668                    (when (and info
1669                               expired
1670                               (or (not (caar gnus-agent-article-alist))
1671                                   (> (car expired)
1672                                      (caar gnus-agent-article-alist))))
1673                      (setcar (nthcdr 2 info)
1674                              (gnus-add-to-range
1675                               (nth 2 info)
1676                               (nreverse expired))))
1677                    (gnus-dribble-enter
1678                     (concat "(gnus-group-set-info '"
1679                             (gnus-prin1-to-string info)
1680                             ")")))
1681                  (when lowest
1682                    (if (gnus-gethash group orig)
1683                        (setcar (gnus-gethash group orig) lowest)
1684                      (gnus-sethash group (cons lowest highest) orig))))
1685                expiry-hashtb)
1686               (set-buffer history)
1687               (setq histories (nreverse (sort histories '<)))
1688               (while histories
1689                 (goto-char (pop histories))
1690                 (gnus-delete-line))
1691               (gnus-agent-save-history)
1692               (gnus-agent-close-history)
1693               (gnus-write-active-file
1694                (gnus-agent-lib-file "active") orig))
1695             (gnus-message 4 "Expiry...done")))))))
1696
1697 ;;;###autoload
1698 (defun gnus-agent-batch ()
1699   (interactive)
1700   (let ((init-file-user "")
1701         (gnus-always-read-dribble-file t))
1702     (gnus))
1703   (gnus-group-send-drafts)
1704   (gnus-agent-fetch-session))
1705
1706 (provide 'gnus-agent)
1707
1708 ;;; gnus-agent.el ends here