git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-agent.el

   1 ;;; gnus-agent.el --- unplugged support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-cache)
  29 (require 'nnvirtual)
  30 (require 'gnus-sum)
  31 (require 'gnus-score)
  32 (require 'gnus-srvr)
  33 (eval-when-compile
  34   (if (featurep 'xemacs)
  35       (require 'itimer)
  36     (require 'timer))
  37   (require 'cl))
  38
  39 (eval-and-compile
  40   (autoload 'gnus-server-update-server "gnus-srvr"))
  41
  42 (defcustom gnus-agent-directory (nnheader-concat gnus-directory "agent/")
  43   "Where the Gnus agent will store its files."
  44   :group 'gnus-agent
  45   :type 'directory)
  46
  47 (defcustom gnus-agent-plugged-hook nil
  48   "Hook run when plugging into the network."
  49   :group 'gnus-agent
  50   :type 'hook)
  51
  52 (defcustom gnus-agent-unplugged-hook nil
  53   "Hook run when unplugging from the network."
  54   :group 'gnus-agent
  55   :type 'hook)
  56
  57 (defcustom gnus-agent-fetched-hook nil
  58   "Hook run after finishing fetching articles."
  59   :group 'gnus-agent
  60   :type 'hook)
  61
  62 (defcustom gnus-agent-handle-level gnus-level-subscribed
  63   "Groups on levels higher than this variable will be ignored by the Agent."
  64   :group 'gnus-agent
  65   :type 'integer)
  66
  67 (defcustom gnus-agent-expire-days 7
  68   "Read articles older than this will be expired.
  69 This can also be a list of regexp/day pairs.  The regexps will
  70 be matched against group names."
  71   :group 'gnus-agent
  72   :type 'integer)
  73
  74 (defcustom gnus-agent-expire-all nil
  75   "If non-nil, also expire unread, ticked and dormant articles.
  76 If nil, only read articles will be expired."
  77   :group 'gnus-agent
  78   :type 'boolean)
  79
  80 (defcustom gnus-agent-group-mode-hook nil
  81   "Hook run in Agent group minor modes."
  82   :group 'gnus-agent
  83   :type 'hook)
  84
  85 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
  86 (when (featurep 'xemacs)
  87   (add-hook 'gnus-agent-group-mode-hook 'gnus-xmas-agent-group-menu-add))
  88
  89 (defcustom gnus-agent-summary-mode-hook nil
  90   "Hook run in Agent summary minor modes."
  91   :group 'gnus-agent
  92   :type 'hook)
  93
  94 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
  95 (when (featurep 'xemacs)
  96   (add-hook 'gnus-agent-summary-mode-hook 'gnus-xmas-agent-summary-menu-add))
  97
  98 (defcustom gnus-agent-server-mode-hook nil
  99   "Hook run in Agent summary minor modes."
 100   :group 'gnus-agent
 101   :type 'hook)
 102
 103 ;; Extracted from gnus-xmas-redefine in order to preserve user settings
 104 (when (featurep 'xemacs)
 105   (add-hook 'gnus-agent-server-mode-hook 'gnus-xmas-agent-server-menu-add))
 106
 107 (defcustom gnus-agent-confirmation-function 'y-or-n-p
 108   "Function to confirm when error happens."
 109   :version "21.1"
 110   :group 'gnus-agent
 111   :type 'function)
 112
 113 (defcustom gnus-agent-synchronize-flags 'ask
 114   "Indicate if flags are synchronized when you plug in.
 115 If this is `ask' the hook will query the user."
 116   :version "21.1"
 117   :type '(choice (const :tag "Always" t)
 118                  (const :tag "Never" nil)
 119                  (const :tag "Ask" ask))
 120   :group 'gnus-agent)
 121
 122 (defcustom gnus-agent-go-online 'ask
 123   "Indicate if offline servers go online when you plug in.
 124 If this is `ask' the hook will query the user."
 125   :version "21.1"
 126   :type '(choice (const :tag "Always" t)
 127                  (const :tag "Never" nil)
 128                  (const :tag "Ask" ask))
 129   :group 'gnus-agent)
 130
 131 ;;; Internal variables
 132
 133 (defvar gnus-agent-history-buffers nil)
 134 (defvar gnus-agent-buffer-alist nil)
 135 (defvar gnus-agent-article-alist nil)
 136 (defvar gnus-agent-group-alist nil)
 137 (defvar gnus-category-alist nil)
 138 (defvar gnus-agent-current-history nil)
 139 (defvar gnus-agent-overview-buffer nil)
 140 (defvar gnus-category-predicate-cache nil)
 141 (defvar gnus-category-group-cache nil)
 142 (defvar gnus-agent-spam-hashtb nil)
 143 (defvar gnus-agent-file-name nil)
 144 (defvar gnus-agent-send-mail-function nil)
 145 (defvar gnus-agent-file-coding-system 'raw-text)
 146
 147 ;; Dynamic variables
 148 (defvar gnus-headers)
 149 (defvar gnus-score)
 150
 151 ;;;
 152 ;;; Setup
 153 ;;;
 154
 155 (defun gnus-open-agent ()
 156   (setq gnus-agent t)
 157   (gnus-agent-read-servers)
 158   (gnus-category-read)
 159   (gnus-agent-create-buffer)
 160   (add-hook 'gnus-group-mode-hook 'gnus-agent-mode)
 161   (add-hook 'gnus-summary-mode-hook 'gnus-agent-mode)
 162   (add-hook 'gnus-server-mode-hook 'gnus-agent-mode))
 163
 164 (defun gnus-agent-create-buffer ()
 165   (if (gnus-buffer-live-p gnus-agent-overview-buffer)
 166       t
 167     (setq gnus-agent-overview-buffer
 168           (gnus-get-buffer-create " *Gnus agent overview*"))
 169     (with-current-buffer gnus-agent-overview-buffer
 170       (mm-enable-multibyte))
 171     nil))
 172
 173 (gnus-add-shutdown 'gnus-close-agent 'gnus)
 174
 175 (defun gnus-close-agent ()
 176   (setq gnus-agent-covered-methods nil
 177         gnus-category-predicate-cache nil
 178         gnus-category-group-cache nil
 179         gnus-agent-spam-hashtb nil)
 180   (gnus-kill-buffer gnus-agent-overview-buffer))
 181
 182 ;;;
 183 ;;; Utility functions
 184 ;;;
 185
 186 (defun gnus-agent-read-file (file)
 187   "Load FILE and do a `read' there."
 188   (with-temp-buffer
 189     (ignore-errors
 190       (nnheader-insert-file-contents file)
 191       (goto-char (point-min))
 192       (read (current-buffer)))))
 193
 194 (defsubst gnus-agent-method ()
 195   (concat (symbol-name (car gnus-command-method)) "/"
 196           (if (equal (cadr gnus-command-method) "")
 197               "unnamed"
 198             (cadr gnus-command-method))))
 199
 200 (defsubst gnus-agent-directory ()
 201   "Path of the Gnus agent directory."
 202   (nnheader-concat gnus-agent-directory
 203                    (nnheader-translate-file-chars (gnus-agent-method)) "/"))
 204
 205 (defun gnus-agent-lib-file (file)
 206   "The full path of the Gnus agent library FILE."
 207   (expand-file-name file
 208                     (file-name-as-directory
 209                      (expand-file-name "agent.lib" (gnus-agent-directory)))))
 210
 211 ;;; Fetching setup functions.
 212
 213 (defun gnus-agent-start-fetch ()
 214   "Initialize data structures for efficient fetching."
 215   (gnus-agent-open-history)
 216   (setq gnus-agent-current-history (gnus-agent-history-buffer))
 217   (gnus-agent-create-buffer))
 218
 219 (defun gnus-agent-stop-fetch ()
 220   "Save all data structures and clean up."
 221   (gnus-agent-save-history)
 222   (gnus-agent-close-history)
 223   (setq gnus-agent-spam-hashtb nil)
 224   (save-excursion
 225     (set-buffer nntp-server-buffer)
 226     (widen)))
 227
 228 (defmacro gnus-agent-with-fetch (&rest forms)
 229   "Do FORMS safely."
 230   `(unwind-protect
 231        (let ((gnus-agent-fetching t))
 232          (gnus-agent-start-fetch)
 233          ,@forms)
 234      (gnus-agent-stop-fetch)))
 235
 236 (put 'gnus-agent-with-fetch 'lisp-indent-function 0)
 237 (put 'gnus-agent-with-fetch 'edebug-form-spec '(body))
 238
 239 ;;;
 240 ;;; Mode infestation
 241 ;;;
 242
 243 (defvar gnus-agent-mode-hook nil
 244   "Hook run when installing agent mode.")
 245
 246 (defvar gnus-agent-mode nil)
 247 (defvar gnus-agent-mode-status '(gnus-agent-mode " Plugged"))
 248
 249 (defun gnus-agent-mode ()
 250   "Minor mode for providing a agent support in Gnus buffers."
 251   (let* ((buffer (progn (string-match "^gnus-\\(.*\\)-mode$"
 252                                       (symbol-name major-mode))
 253                         (match-string 1 (symbol-name major-mode))))
 254          (mode (intern (format "gnus-agent-%s-mode" buffer))))
 255     (set (make-local-variable 'gnus-agent-mode) t)
 256     (set mode nil)
 257     (set (make-local-variable mode) t)
 258     ;; Set up the menu.
 259     (when (gnus-visual-p 'agent-menu 'menu)
 260       (funcall (intern (format "gnus-agent-%s-make-menu-bar" buffer))))
 261     (unless (assq 'gnus-agent-mode minor-mode-alist)
 262       (push gnus-agent-mode-status minor-mode-alist))
 263     (unless (assq mode minor-mode-map-alist)
 264       (push (cons mode (symbol-value (intern (format "gnus-agent-%s-mode-map"
 265                                                      buffer))))
 266             minor-mode-map-alist))
 267     (when (eq major-mode 'gnus-group-mode)
 268       (gnus-agent-toggle-plugged gnus-plugged))
 269     (gnus-run-hooks 'gnus-agent-mode-hook
 270                     (intern (format "gnus-agent-%s-mode-hook" buffer)))))
 271
 272 (defvar gnus-agent-group-mode-map (make-sparse-keymap))
 273 (gnus-define-keys gnus-agent-group-mode-map
 274   "Ju" gnus-agent-fetch-groups
 275   "Jc" gnus-enter-category-buffer
 276   "Jj" gnus-agent-toggle-plugged
 277   "Js" gnus-agent-fetch-session
 278   "JY" gnus-agent-synchronize-flags
 279   "JS" gnus-group-send-queue
 280   "Ja" gnus-agent-add-group
 281   "Jr" gnus-agent-remove-group
 282   "Jo" gnus-agent-toggle-group-plugged)
 283
 284 (defun gnus-agent-group-make-menu-bar ()
 285   (unless (boundp 'gnus-agent-group-menu)
 286     (easy-menu-define
 287      gnus-agent-group-menu gnus-agent-group-mode-map ""
 288      '("Agent"
 289        ["Toggle plugged" gnus-agent-toggle-plugged t]
 290        ["Toggle group plugged" gnus-agent-toggle-group-plugged t]
 291        ["List categories" gnus-enter-category-buffer t]
 292        ["Send queue" gnus-group-send-queue gnus-plugged]
 293        ("Fetch"
 294         ["All" gnus-agent-fetch-session gnus-plugged]
 295         ["Group" gnus-agent-fetch-group gnus-plugged])))))
 296
 297 (defvar gnus-agent-summary-mode-map (make-sparse-keymap))
 298 (gnus-define-keys gnus-agent-summary-mode-map
 299   "Jj" gnus-agent-toggle-plugged
 300   "Ju" gnus-agent-summary-fetch-group
 301   "J#" gnus-agent-mark-article
 302   "J\M-#" gnus-agent-unmark-article
 303   "@" gnus-agent-toggle-mark
 304   "Jc" gnus-agent-catchup)
 305
 306 (defun gnus-agent-summary-make-menu-bar ()
 307   (unless (boundp 'gnus-agent-summary-menu)
 308     (easy-menu-define
 309      gnus-agent-summary-menu gnus-agent-summary-mode-map ""
 310      '("Agent"
 311        ["Toggle plugged" gnus-agent-toggle-plugged t]
 312        ["Mark as downloadable" gnus-agent-mark-article t]
 313        ["Unmark as downloadable" gnus-agent-unmark-article t]
 314        ["Toggle mark" gnus-agent-toggle-mark t]
 315        ["Fetch downloadable" gnus-aget-summary-fetch-group t]
 316        ["Catchup undownloaded" gnus-agent-catchup t]))))
 317
 318 (defvar gnus-agent-server-mode-map (make-sparse-keymap))
 319 (gnus-define-keys gnus-agent-server-mode-map
 320   "Jj" gnus-agent-toggle-plugged
 321   "Ja" gnus-agent-add-server
 322   "Jr" gnus-agent-remove-server)
 323
 324 (defun gnus-agent-server-make-menu-bar ()
 325   (unless (boundp 'gnus-agent-server-menu)
 326     (easy-menu-define
 327      gnus-agent-server-menu gnus-agent-server-mode-map ""
 328      '("Agent"
 329        ["Toggle plugged" gnus-agent-toggle-plugged t]
 330        ["Add" gnus-agent-add-server t]
 331        ["Remove" gnus-agent-remove-server t]))))
 332
 333 (defun gnus-agent-make-mode-line-string (string mouse-button mouse-func)
 334   (if (and (fboundp 'propertize)
 335            (fboundp 'make-mode-line-mouse-map))
 336       (propertize string 'local-map
 337                   (make-mode-line-mouse-map mouse-button mouse-func))
 338     string))
 339
 340 (defun gnus-agent-toggle-plugged (plugged)
 341   "Toggle whether Gnus is unplugged or not."
 342   (interactive (list (not gnus-plugged)))
 343   (if plugged
 344       (progn
 345         (setq gnus-plugged plugged)
 346         (gnus-run-hooks 'gnus-agent-plugged-hook)
 347         (setcar (cdr gnus-agent-mode-status)
 348                 (gnus-agent-make-mode-line-string " Plugged"
 349                                                   'mouse-2
 350                                                   'gnus-agent-toggle-plugged))
 351         (gnus-agent-go-online gnus-agent-go-online)
 352         (gnus-agent-possibly-synchronize-flags))
 353     (gnus-agent-close-connections)
 354     (setq gnus-plugged plugged)
 355     (gnus-run-hooks 'gnus-agent-unplugged-hook)
 356     (setcar (cdr gnus-agent-mode-status)
 357             (gnus-agent-make-mode-line-string " Unplugged"
 358                                               'mouse-2
 359                                               'gnus-agent-toggle-plugged)))
 360   (set-buffer-modified-p t))
 361
 362 (defun gnus-agent-close-connections ()
 363   "Close all methods covered by the Gnus agent."
 364   (let ((methods gnus-agent-covered-methods))
 365     (while methods
 366       (gnus-close-server (pop methods)))))
 367
 368 ;;;###autoload
 369 (defun gnus-unplugged ()
 370   "Start Gnus unplugged."
 371   (interactive)
 372   (setq gnus-plugged nil)
 373   (gnus))
 374
 375 ;;;###autoload
 376 (defun gnus-plugged ()
 377   "Start Gnus plugged."
 378   (interactive)
 379   (setq gnus-plugged t)
 380   (gnus))
 381
 382 ;;;###autoload
 383 (defun gnus-agentize ()
 384   "Allow Gnus to be an offline newsreader.
 385 The normal usage of this command is to put the following as the
 386 last form in your `.gnus.el' file:
 387
 388 \(gnus-agentize)
 389
 390 This will modify the `gnus-setup-news-hook', and
 391 `message-send-mail-real-function' variables, and install the Gnus agent
 392 minor mode in all Gnus buffers."
 393   (interactive)
 394   (gnus-open-agent)
 395   (add-hook 'gnus-setup-news-hook 'gnus-agent-queue-setup)
 396   (unless gnus-agent-send-mail-function
 397     (setq gnus-agent-send-mail-function (or
 398                                          message-send-mail-real-function
 399                                          message-send-mail-function)
 400           message-send-mail-real-function 'gnus-agent-send-mail))
 401   (unless gnus-agent-covered-methods
 402     (setq gnus-agent-covered-methods (list gnus-select-method))))
 403
 404 (defun gnus-agent-queue-setup ()
 405   "Make sure the queue group exists."
 406   (unless (gnus-gethash "nndraft:queue" gnus-newsrc-hashtb)
 407     (gnus-request-create-group "queue" '(nndraft ""))
 408     (let ((gnus-level-default-subscribed 1))
 409       (gnus-subscribe-group "nndraft:queue" nil '(nndraft "")))
 410     (gnus-group-set-parameter
 411      "nndraft:queue" 'gnus-dummy '((gnus-draft-mode)))))
 412
 413 (defun gnus-agent-send-mail ()
 414   (if gnus-plugged
 415       (funcall gnus-agent-send-mail-function)
 416     (goto-char (point-min))
 417     (re-search-forward
 418      (concat "^" (regexp-quote mail-header-separator) "\n"))
 419     (replace-match "\n")
 420     (gnus-agent-insert-meta-information 'mail)
 421     (gnus-request-accept-article "nndraft:queue" nil t t)))
 422
 423 (defun gnus-agent-insert-meta-information (type &optional method)
 424   "Insert meta-information into the message that says how it's to be posted.
 425 TYPE can be either `mail' or `news'.  If the latter, then METHOD can
 426 be a select method."
 427   (save-excursion
 428     (message-remove-header gnus-agent-meta-information-header)
 429     (goto-char (point-min))
 430     (insert gnus-agent-meta-information-header ": "
 431             (symbol-name type) " " (format "%S" method)
 432             "\n")
 433     (forward-char -1)
 434     (while (search-backward "\n" nil t)
 435       (replace-match "\\n" t t))))
 436
 437 (defun gnus-agent-restore-gcc ()
 438   "Restore GCC field from saved header."
 439   (save-excursion
 440     (goto-char (point-min))
 441     (while (re-search-forward (concat gnus-agent-gcc-header ":") nil t)
 442       (replace-match "Gcc:" 'fixedcase))))
 443
 444 (defun gnus-agent-any-covered-gcc ()
 445   (save-restriction
 446     (message-narrow-to-headers)
 447     (let* ((gcc (mail-fetch-field "gcc" nil t))
 448            (methods (and gcc
 449                          (mapcar 'gnus-inews-group-method
 450                                  (message-unquote-tokens
 451                                   (message-tokenize-header
 452                                    gcc " ,")))))
 453            covered)
 454       (while (and (not covered) methods)
 455         (setq covered (gnus-agent-method-p (car methods))
 456               methods (cdr methods)))
 457       covered)))
 458
 459 (defun gnus-agent-possibly-save-gcc ()
 460   "Save GCC if Gnus is unplugged."
 461   (when (and (not gnus-plugged) (gnus-agent-any-covered-gcc))
 462     (save-excursion
 463       (goto-char (point-min))
 464       (let ((case-fold-search t))
 465         (while (re-search-forward "^gcc:" nil t)
 466           (replace-match (concat gnus-agent-gcc-header ":") 'fixedcase))))))
 467
 468 (defun gnus-agent-possibly-do-gcc ()
 469   "Do GCC if Gnus is plugged."
 470   (when (or gnus-plugged (not (gnus-agent-any-covered-gcc)))
 471     (gnus-inews-do-gcc)))
 472
 473 ;;;
 474 ;;; Group mode commands
 475 ;;;
 476
 477 (defun gnus-agent-fetch-groups (n)
 478   "Put all new articles in the current groups into the Agent."
 479   (interactive "P")
 480   (unless gnus-plugged
 481     (error "Groups can't be fetched when Gnus is unplugged"))
 482   (gnus-group-iterate n 'gnus-agent-fetch-group))
 483
 484 (defun gnus-agent-fetch-group (group)
 485   "Put all new articles in GROUP into the Agent."
 486   (interactive (list (gnus-group-group-name)))
 487   (let ((state gnus-plugged))
 488     (unwind-protect
 489         (progn
 490           (unless group
 491             (error "No group on the current line"))
 492           (unless state
 493             (gnus-agent-toggle-plugged gnus-plugged))
 494           (let ((gnus-command-method (gnus-find-method-for-group group)))
 495             (gnus-agent-with-fetch
 496               (gnus-agent-fetch-group-1 group gnus-command-method)
 497               (gnus-message 5 "Fetching %s...done" group))))
 498       (when (and (not state)
 499                  gnus-plugged)
 500         (gnus-agent-toggle-plugged gnus-plugged)))))
 501
 502 (defun gnus-agent-add-group (category arg)
 503   "Add the current group to an agent category."
 504   (interactive
 505    (list
 506     (intern
 507      (completing-read
 508       "Add to category: "
 509       (mapcar (lambda (cat) (list (symbol-name (car cat))))
 510               gnus-category-alist)
 511       nil t))
 512     current-prefix-arg))
 513   (let ((cat (assq category gnus-category-alist))
 514         c groups)
 515     (gnus-group-iterate arg
 516       (lambda (group)
 517         (when (cadddr (setq c (gnus-group-category group)))
 518           (setf (cadddr c) (delete group (cadddr c))))
 519         (push group groups)))
 520     (setf (cadddr cat) (nconc (cadddr cat) groups))
 521     (gnus-category-write)))
 522
 523 (defun gnus-agent-remove-group (arg)
 524   "Remove the current group from its agent category, if any."
 525   (interactive "P")
 526   (let (c)
 527     (gnus-group-iterate arg
 528       (lambda (group)
 529         (when (cadddr (setq c (gnus-group-category group)))
 530           (setf (cadddr c) (delete group (cadddr c))))))
 531     (gnus-category-write)))
 532
 533 (defun gnus-agent-synchronize-flags ()
 534   "Synchronize unplugged flags with servers."
 535   (interactive)
 536   (save-excursion
 537     (dolist (gnus-command-method gnus-agent-covered-methods)
 538       (when (file-exists-p (gnus-agent-lib-file "flags"))
 539         (gnus-agent-synchronize-flags-server gnus-command-method)))))
 540
 541 (defun gnus-agent-possibly-synchronize-flags ()
 542   "Synchronize flags according to `gnus-agent-synchronize-flags'."
 543   (interactive)
 544   (save-excursion
 545     (dolist (gnus-command-method gnus-agent-covered-methods)
 546       (when (file-exists-p (gnus-agent-lib-file "flags"))
 547         (gnus-agent-possibly-synchronize-flags-server gnus-command-method)))))
 548
 549 (defun gnus-agent-synchronize-flags-server (method)
 550   "Synchronize flags set when unplugged for server."
 551   (let ((gnus-command-method method))
 552     (when (file-exists-p (gnus-agent-lib-file "flags"))
 553       (set-buffer (get-buffer-create " *Gnus Agent flag synchronize*"))
 554       (erase-buffer)
 555       (nnheader-insert-file-contents (gnus-agent-lib-file "flags"))
 556       (if (null (gnus-check-server gnus-command-method))
 557           (message "Couldn't open server %s" (nth 1 gnus-command-method))
 558         (while (not (eobp))
 559           (if (null (eval (read (current-buffer))))
 560               (progn (forward-line)
 561                      (kill-line -1))
 562             (write-file (gnus-agent-lib-file "flags"))
 563             (error "Couldn't set flags from file %s"
 564                    (gnus-agent-lib-file "flags"))))
 565         (delete-file (gnus-agent-lib-file "flags")))
 566       (kill-buffer nil))))
 567
 568 (defun gnus-agent-possibly-synchronize-flags-server (method)
 569   "Synchronize flags for server according to `gnus-agent-synchronize-flags'."
 570   (when (or (and gnus-agent-synchronize-flags
 571                  (not (eq gnus-agent-synchronize-flags 'ask)))
 572             (and (eq gnus-agent-synchronize-flags 'ask)
 573                  (gnus-y-or-n-p (format "Synchronize flags on server `%s'? "
 574                                         (cadr method)))))
 575     (gnus-agent-synchronize-flags-server method)))
 576
 577 ;;;
 578 ;;; Server mode commands
 579 ;;;
 580
 581 (defun gnus-agent-add-server (server)
 582   "Enroll SERVER in the agent program."
 583   (interactive (list (gnus-server-server-name)))
 584   (unless server
 585     (error "No server on the current line"))
 586   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 587     (when (gnus-agent-method-p method)
 588       (error "Server already in the agent program"))
 589     (push method gnus-agent-covered-methods)
 590     (gnus-server-update-server server)
 591     (gnus-agent-write-servers)
 592     (message "Entered %s into the Agent" server)))
 593
 594 (defun gnus-agent-remove-server (server)
 595   "Remove SERVER from the agent program."
 596   (interactive (list (gnus-server-server-name)))
 597   (unless server
 598     (error "No server on the current line"))
 599   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 600     (unless (gnus-agent-method-p method)
 601       (error "Server not in the agent program"))
 602     (setq gnus-agent-covered-methods
 603           (delete method gnus-agent-covered-methods))
 604     (gnus-server-update-server server)
 605     (gnus-agent-write-servers)
 606     (message "Removed %s from the agent" server)))
 607
 608 (defun gnus-agent-read-servers ()
 609   "Read the alist of covered servers."
 610   (setq gnus-agent-covered-methods
 611         (gnus-agent-read-file
 612          (nnheader-concat gnus-agent-directory "lib/servers"))))
 613
 614 (defun gnus-agent-write-servers ()
 615   "Write the alist of covered servers."
 616   (gnus-make-directory (nnheader-concat gnus-agent-directory "lib"))
 617   (let ((coding-system-for-write nnheader-file-coding-system)
 618         (file-name-coding-system nnmail-pathname-coding-system))
 619     (with-temp-file (nnheader-concat gnus-agent-directory "lib/servers")
 620       (prin1 gnus-agent-covered-methods (current-buffer)))))
 621
 622 ;;;
 623 ;;; Summary commands
 624 ;;;
 625
 626 (defun gnus-agent-mark-article (n &optional unmark)
 627   "Mark the next N articles as downloadable.
 628 If N is negative, mark backward instead.  If UNMARK is non-nil, remove
 629 the mark instead.  The difference between N and the actual number of
 630 articles marked is returned."
 631   (interactive "p")
 632   (let ((backward (< n 0))
 633         (n (abs n)))
 634     (while (and
 635             (> n 0)
 636             (progn
 637               (gnus-summary-set-agent-mark
 638                (gnus-summary-article-number) unmark)
 639               (zerop (gnus-summary-next-subject (if backward -1 1) nil t))))
 640       (setq n (1- n)))
 641     (when (/= 0 n)
 642       (gnus-message 7 "No more articles"))
 643     (gnus-summary-recenter)
 644     (gnus-summary-position-point)
 645     n))
 646
 647 (defun gnus-agent-unmark-article (n)
 648   "Remove the downloadable mark from the next N articles.
 649 If N is negative, unmark backward instead.  The difference between N and
 650 the actual number of articles unmarked is returned."
 651   (interactive "p")
 652   (gnus-agent-mark-article n t))
 653
 654 (defun gnus-agent-toggle-mark (n)
 655   "Toggle the downloadable mark from the next N articles.
 656 If N is negative, toggle backward instead.  The difference between N and
 657 the actual number of articles toggled is returned."
 658   (interactive "p")
 659   (gnus-agent-mark-article n 'toggle))
 660
 661 (defun gnus-summary-set-agent-mark (article &optional unmark)
 662   "Mark ARTICLE as downloadable."
 663   (let ((unmark (if (and (not (null unmark)) (not (eq t unmark)))
 664                     (memq article gnus-newsgroup-downloadable)
 665                   unmark)))
 666     (if unmark
 667         (progn
 668           (setq gnus-newsgroup-downloadable
 669                 (delq article gnus-newsgroup-downloadable))
 670           (push article gnus-newsgroup-undownloaded))
 671       (setq gnus-newsgroup-undownloaded
 672             (delq article gnus-newsgroup-undownloaded))
 673       (push article gnus-newsgroup-downloadable))
 674     (gnus-summary-update-mark
 675      (if unmark gnus-undownloaded-mark gnus-downloadable-mark)
 676      'unread)))
 677
 678 (defun gnus-agent-get-undownloaded-list ()
 679   "Mark all unfetched articles as read."
 680   (let ((gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name)))
 681     (when (and (not (gnus-online gnus-command-method))
 682                (gnus-agent-method-p gnus-command-method))
 683       (gnus-agent-load-alist gnus-newsgroup-name)
 684       ;; First mark all undownloaded articles as undownloaded.
 685       (dolist (article (mapcar (lambda (header) (mail-header-number header))
 686                                gnus-newsgroup-headers))
 687         (unless (or (cdr (assq article gnus-agent-article-alist))
 688                     (memq article gnus-newsgroup-downloadable)
 689                     (memq article gnus-newsgroup-cached))
 690           (push article gnus-newsgroup-undownloaded)))
 691       ;; Then mark downloaded downloadable as not-downloadable,
 692       ;; if you get my drift.
 693       (dolist (article gnus-newsgroup-downloadable)
 694         (when (cdr (assq article gnus-agent-article-alist))
 695           (setq gnus-newsgroup-downloadable
 696                 (delq article gnus-newsgroup-downloadable)))))))
 697
 698 (defun gnus-agent-catchup ()
 699   "Mark all undownloaded articles as read."
 700   (interactive)
 701   (save-excursion
 702     (while gnus-newsgroup-undownloaded
 703       (gnus-summary-mark-article
 704        (pop gnus-newsgroup-undownloaded) gnus-catchup-mark)))
 705   (gnus-summary-position-point))
 706
 707 (defun gnus-agent-summary-fetch-group ()
 708   "Fetch the downloadable articles in the group."
 709   (interactive)
 710   (let ((articles gnus-newsgroup-downloadable)
 711         (gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name))
 712         (state gnus-plugged))
 713     (unwind-protect
 714         (progn
 715           (unless state
 716             (gnus-agent-toggle-plugged t))
 717           (unless articles
 718             (error "No articles to download"))
 719           (gnus-agent-with-fetch
 720             (gnus-agent-fetch-articles gnus-newsgroup-name articles))
 721           (save-excursion
 722             (dolist (article articles)
 723               (setq gnus-newsgroup-downloadable
 724                     (delq article gnus-newsgroup-downloadable))
 725               (gnus-summary-mark-article article gnus-unread-mark))))
 726       (when (and (not state)
 727                  gnus-plugged)
 728         (gnus-agent-toggle-plugged nil)))))
 729
 730 ;;;
 731 ;;; Internal functions
 732 ;;;
 733
 734 (defun gnus-agent-save-active (method)
 735   (gnus-agent-save-active-1 method 'gnus-active-to-gnus-format))
 736
 737 (defun gnus-agent-save-active-1 (method function)
 738   (when (gnus-agent-method-p method)
 739     (let* ((gnus-command-method method)
 740            (new (gnus-make-hashtable (count-lines (point-min) (point-max))))
 741            (file (gnus-agent-lib-file "active")))
 742       (funcall function nil new)
 743       (gnus-agent-write-active file new)
 744       (erase-buffer)
 745       (nnheader-insert-file-contents file))))
 746
 747 (defun gnus-agent-write-active (file new)
 748   (let ((orig (gnus-make-hashtable (count-lines (point-min) (point-max))))
 749         (file (gnus-agent-lib-file "active"))
 750         elem osym)
 751     (when (file-exists-p file)
 752       (with-temp-buffer
 753         (nnheader-insert-file-contents file)
 754         (gnus-active-to-gnus-format nil orig))
 755       (mapatoms
 756        (lambda (sym)
 757          (when (and sym (boundp sym))
 758            (if (and (boundp (setq osym (intern (symbol-name sym) orig)))
 759                     (setq elem (symbol-value osym)))
 760                (progn
 761                  (if (and (integerp (car (symbol-value sym)))
 762                           (> (car elem) (car (symbol-value sym))))
 763                      (setcar elem (car (symbol-value sym))))
 764                  (if (integerp (cdr (symbol-value sym)))
 765                      (setcdr elem (cdr (symbol-value sym)))))
 766              (set (intern (symbol-name sym) orig) (symbol-value sym)))))
 767        new))
 768     (gnus-make-directory (file-name-directory file))
 769     (let ((nnmail-active-file-coding-system gnus-agent-file-coding-system))
 770       ;; The hashtable contains real names of groups,  no more prefix
 771       ;; removing, so set `full' to `t'.
 772       (gnus-write-active-file file orig t))))
 773
 774 (defun gnus-agent-save-groups (method)
 775   (gnus-agent-save-active-1 method 'gnus-groups-to-gnus-format))
 776
 777 (defun gnus-agent-save-group-info (method group active)
 778   (when (gnus-agent-method-p method)
 779     (let* ((gnus-command-method method)
 780            (coding-system-for-write nnheader-file-coding-system)
 781            (file-name-coding-system nnmail-pathname-coding-system)
 782            (file (gnus-agent-lib-file "active"))
 783            oactive-min)
 784       (gnus-make-directory (file-name-directory file))
 785       (with-temp-file file
 786         ;; Emacs got problem to match non-ASCII group in multibyte buffer.
 787         (mm-disable-multibyte)
 788         (when (file-exists-p file)
 789           (nnheader-insert-file-contents file))
 790         (goto-char (point-min))
 791         (when (re-search-forward
 792                (concat "^" (regexp-quote group) " ") nil t)
 793           (save-excursion
 794             (read (current-buffer))                      ;; max
 795             (setq oactive-min (read (current-buffer))))  ;; min
 796           (gnus-delete-line))
 797         (insert (format "%S %d %d y\n" (intern group)
 798                         (cdr active)
 799                         (or oactive-min (car active))))
 800         (goto-char (point-max))
 801         (while (search-backward "\\." nil t)
 802           (delete-char 1))))))
 803
 804 (defun gnus-agent-group-path (group)
 805   "Translate GROUP into a path."
 806   (if nnmail-use-long-file-names
 807       (gnus-group-real-name group)
 808     (nnheader-translate-file-chars
 809      (nnheader-replace-chars-in-string
 810       (nnheader-replace-duplicate-chars-in-string
 811        (nnheader-replace-chars-in-string
 812         (gnus-group-real-name group)
 813         ?/ ?_)
 814        ?. ?_)
 815       ?. ?/))))
 816
 817 \f
 818
 819 (defun gnus-agent-get-function (method)
 820   (if (gnus-online method)
 821       (car method)
 822     (require 'nnagent)
 823     'nnagent))
 824
 825 ;;; History functions
 826
 827 (defun gnus-agent-history-buffer ()
 828   (cdr (assoc (gnus-agent-method) gnus-agent-history-buffers)))
 829
 830 (defun gnus-agent-open-history ()
 831   (save-excursion
 832     (push (cons (gnus-agent-method)
 833                 (set-buffer (gnus-get-buffer-create
 834                              (format " *Gnus agent %s history*"
 835                                      (gnus-agent-method)))))
 836           gnus-agent-history-buffers)
 837     (mm-disable-multibyte) ;; everything is binary
 838     (erase-buffer)
 839     (insert "\n")
 840     (let ((file (gnus-agent-lib-file "history")))
 841       (when (file-exists-p file)
 842         (nnheader-insert-file-contents file))
 843       (set (make-local-variable 'gnus-agent-file-name) file))))
 844
 845 (defun gnus-agent-save-history ()
 846   (save-excursion
 847     (set-buffer gnus-agent-current-history)
 848     (gnus-make-directory (file-name-directory gnus-agent-file-name))
 849     (let ((coding-system-for-write gnus-agent-file-coding-system))
 850       (write-region (1+ (point-min)) (point-max)
 851                     gnus-agent-file-name nil 'silent))))
 852
 853 (defun gnus-agent-close-history ()
 854   (when (gnus-buffer-live-p gnus-agent-current-history)
 855     (kill-buffer gnus-agent-current-history)
 856     (setq gnus-agent-history-buffers
 857           (delq (assoc (gnus-agent-method) gnus-agent-history-buffers)
 858                 gnus-agent-history-buffers))))
 859
 860 (defun gnus-agent-enter-history (id group-arts date)
 861   (save-excursion
 862     (set-buffer gnus-agent-current-history)
 863     (goto-char (point-max))
 864     (let ((p (point)))
 865       (insert id "\t" (number-to-string date) "\t")
 866       (while group-arts
 867         (insert (format "%S" (intern (caar group-arts)))
 868                 " " (number-to-string (cdr (pop group-arts)))
 869                 " "))
 870       (insert "\n")
 871       (while (search-backward "\\." p t)
 872         (delete-char 1)))))
 873
 874 (defun gnus-agent-article-in-history-p (id)
 875   (save-excursion
 876     (set-buffer (gnus-agent-history-buffer))
 877     (goto-char (point-min))
 878     (search-forward (concat "\n" id "\t") nil t)))
 879
 880 (defun gnus-agent-history-path (id)
 881   (save-excursion
 882     (set-buffer (gnus-agent-history-buffer))
 883     (goto-char (point-min))
 884     (when (search-forward (concat "\n" id "\t") nil t)
 885       (let ((method (gnus-agent-method)))
 886         (let (paths group)
 887           (while (not (numberp (setq group (read (current-buffer)))))
 888             (push (concat method "/" group) paths))
 889           (nreverse paths))))))
 890
 891 ;;;
 892 ;;; Fetching
 893 ;;;
 894
 895 (defun gnus-agent-fetch-articles (group articles)
 896   "Fetch ARTICLES from GROUP and put them into the Agent."
 897   (when articles
 898     ;; Prune off articles that we have already fetched.
 899     (while (and articles
 900                 (cdr (assq (car articles) gnus-agent-article-alist)))
 901       (pop articles))
 902     (let ((arts articles))
 903       (while (cdr arts)
 904         (if (cdr (assq (cadr arts) gnus-agent-article-alist))
 905             (setcdr arts (cddr arts))
 906           (setq arts (cdr arts)))))
 907     (when articles
 908       (let ((dir (concat
 909                   (gnus-agent-directory)
 910                   (gnus-agent-group-path group) "/"))
 911             (date (time-to-days (current-time)))
 912             (case-fold-search t)
 913             pos crosses id elem)
 914         (gnus-make-directory dir)
 915         (gnus-message 7 "Fetching articles for %s..." group)
 916         ;; Fetch the articles from the backend.
 917         (if (gnus-check-backend-function 'retrieve-articles group)
 918             (setq pos (gnus-retrieve-articles articles group))
 919           (with-temp-buffer
 920             (let (article)
 921               (while (setq article (pop articles))
 922                 (when (or
 923                        (gnus-backlog-request-article group article
 924                                                      nntp-server-buffer)
 925                        (gnus-request-article article group))
 926                   (goto-char (point-max))
 927                   (push (cons article (point)) pos)
 928                   (insert-buffer-substring nntp-server-buffer)))
 929               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 930               (setq pos (nreverse pos)))))
 931         ;; Then save these articles into the Agent.
 932         (save-excursion
 933           (set-buffer nntp-server-buffer)
 934           (while pos
 935             (narrow-to-region (cdar pos) (or (cdadr pos) (point-max)))
 936             (goto-char (point-min))
 937             (when (search-forward "\n\n" nil t)
 938               (when (search-backward "\nXrefs: " nil t)
 939                 ;; Handle crossposting.
 940                 (skip-chars-forward "^ ")
 941                 (skip-chars-forward " ")
 942                 (setq crosses nil)
 943                 (while (looking-at "\\([^: \n]+\\):\\([0-9]+\\) +")
 944                   (push (cons (buffer-substring (match-beginning 1)
 945                                                 (match-end 1))
 946                               (buffer-substring (match-beginning 2)
 947                                                 (match-end 2)))
 948                         crosses)
 949                   (goto-char (match-end 0)))
 950                 (gnus-agent-crosspost crosses (caar pos))))
 951             (goto-char (point-min))
 952             (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
 953                 (setq id "No-Message-ID-in-article")
 954               (setq id (buffer-substring (match-beginning 1) (match-end 1))))
 955             (let ((coding-system-for-write
 956                    gnus-agent-file-coding-system))
 957               (write-region (point-min) (point-max)
 958                             (concat dir (number-to-string (caar pos)))
 959                             nil 'silent))
 960             (when (setq elem (assq (caar pos) gnus-agent-article-alist))
 961               (setcdr elem t))
 962             (gnus-agent-enter-history
 963              id (or crosses (list (cons group (caar pos)))) date)
 964             (widen)
 965             (pop pos)))
 966         (gnus-agent-save-alist group)))))
 967
 968 (defun gnus-agent-crosspost (crosses article)
 969   (let (gnus-agent-article-alist group alist beg end)
 970     (save-excursion
 971       (set-buffer gnus-agent-overview-buffer)
 972       (when (nnheader-find-nov-line article)
 973         (forward-word 1)
 974         (setq beg (point))
 975         (setq end (progn (forward-line 1) (point)))))
 976     (while crosses
 977       (setq group (caar crosses))
 978       (unless (setq alist (assoc group gnus-agent-group-alist))
 979         (push (setq alist (list group (gnus-agent-load-alist (caar crosses))))
 980               gnus-agent-group-alist))
 981       (setcdr alist (cons (cons (cdar crosses) t) (cdr alist)))
 982       (save-excursion
 983         (set-buffer (gnus-get-buffer-create (format " *Gnus agent overview %s*"
 984                                                     group)))
 985         (when (= (point-max) (point-min))
 986           (push (cons group (current-buffer)) gnus-agent-buffer-alist)
 987           (ignore-errors
 988             (nnheader-insert-file-contents
 989              (gnus-agent-article-name ".overview" group))))
 990         (nnheader-find-nov-line (string-to-number (cdar crosses)))
 991         (insert (string-to-number (cdar crosses)))
 992         (insert-buffer-substring gnus-agent-overview-buffer beg end))
 993       (pop crosses))))
 994
 995 (defun gnus-agent-flush-cache ()
 996   (save-excursion
 997     (while gnus-agent-buffer-alist
 998       (set-buffer (cdar gnus-agent-buffer-alist))
 999       (let ((coding-system-for-write
1000              gnus-agent-file-coding-system))
1001         (write-region (point-min) (point-max)
1002                       (gnus-agent-article-name ".overview"
1003                                                (caar gnus-agent-buffer-alist))
1004                       nil 'silent))
1005       (pop gnus-agent-buffer-alist))
1006     (while gnus-agent-group-alist
1007       (with-temp-file (caar gnus-agent-group-alist)
1008         (princ (cdar gnus-agent-group-alist))
1009         (insert "\n"))
1010       (pop gnus-agent-group-alist))))
1011
1012 (defun gnus-agent-fetch-headers (group &optional force)
1013   (let ((articles (gnus-list-of-unread-articles group))
1014         (gnus-decode-encoded-word-function 'identity)
1015         (file (gnus-agent-article-name ".overview" group))
1016         gnus-agent-cache)
1017     ;; Add article with marks to list of article headers we want to fetch.
1018     (dolist (arts (gnus-info-marks (gnus-get-info group)))
1019       (setq articles (gnus-range-add articles (cdr arts))))
1020     (setq articles (sort (gnus-uncompress-sequence articles) '<))
1021     ;; Remove known articles.
1022     (when (gnus-agent-load-alist group)
1023       (setq articles (gnus-sorted-intersection
1024                       articles
1025                       (gnus-uncompress-range
1026                        (cons (1+ (caar (last gnus-agent-article-alist)))
1027                              (cdr (gnus-active group)))))))
1028     ;; Fetch them.
1029     (gnus-make-directory (nnheader-translate-file-chars
1030                           (file-name-directory file) t))
1031     (when articles
1032       (gnus-message 7 "Fetching headers for %s..." group)
1033       (save-excursion
1034         (set-buffer nntp-server-buffer)
1035         (unless (eq 'nov (gnus-retrieve-headers articles group))
1036           (nnvirtual-convert-headers))
1037         ;; Save these headers for later processing.
1038         (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
1039         (when (file-exists-p file)
1040           (gnus-agent-braid-nov group articles file))
1041         (let ((coding-system-for-write
1042                gnus-agent-file-coding-system))
1043           (write-region (point-min) (point-max) file nil 'silent))
1044         (gnus-agent-save-alist group articles nil)
1045         (gnus-agent-enter-history
1046          "last-header-fetched-for-session"
1047          (list (cons group (nth (- (length  articles) 1) articles)))
1048          (time-to-days (current-time)))
1049         articles))))
1050
1051 (defsubst gnus-agent-copy-nov-line (article)
1052   (let (b e)
1053     (set-buffer gnus-agent-overview-buffer)
1054     (unless (eobp)
1055       (setq b (point))
1056       (if (eq article (read (current-buffer)))
1057           (setq e (progn (forward-line 1) (point)))
1058         (progn
1059           (beginning-of-line)
1060           (setq e b)))
1061       (set-buffer nntp-server-buffer)
1062       (insert-buffer-substring gnus-agent-overview-buffer b e))))
1063
1064 (defun gnus-agent-braid-nov (group articles file)
1065   (set-buffer gnus-agent-overview-buffer)
1066   (goto-char (point-min))
1067   (set-buffer nntp-server-buffer)
1068   (erase-buffer)
1069   (nnheader-insert-file-contents file)
1070   (goto-char (point-max))
1071   (if (or (= (point-min) (point-max))
1072           (progn
1073             (forward-line -1)
1074             (< (read (current-buffer)) (car articles))))
1075       ;; We have only headers that are after the older headers,
1076       ;; so we just append them.
1077       (progn
1078         (goto-char (point-max))
1079         (insert-buffer-substring gnus-agent-overview-buffer))
1080     ;; We do it the hard way.
1081     (nnheader-find-nov-line (car articles))
1082     (gnus-agent-copy-nov-line (car articles))
1083     (pop articles)
1084     (while (and articles
1085                 (not (eobp)))
1086       (while (and (not (eobp))
1087                   (< (read (current-buffer)) (car articles)))
1088         (forward-line 1))
1089       (beginning-of-line)
1090       (unless (eobp)
1091         (gnus-agent-copy-nov-line (car articles))
1092         (setq articles (cdr articles))))
1093     (set-buffer nntp-server-buffer)
1094     (when articles
1095       (let (b e)
1096         (set-buffer gnus-agent-overview-buffer)
1097         (setq b (point)
1098               e (point-max))
1099         (while (and (not (eobp))
1100                     (<= (read (current-buffer)) (car articles)))
1101           (forward-line 1)
1102           (setq b (point)))
1103         (set-buffer nntp-server-buffer)
1104         (insert-buffer-substring gnus-agent-overview-buffer b e)))))
1105
1106 (defun gnus-agent-load-alist (group &optional dir)
1107   "Load the article-state alist for GROUP."
1108   (setq gnus-agent-article-alist
1109         (gnus-agent-read-file
1110          (if dir
1111              (expand-file-name ".agentview" dir)
1112            (gnus-agent-article-name ".agentview" group)))))
1113
1114 (defun gnus-agent-save-alist (group &optional articles state dir)
1115   "Save the article-state alist for GROUP."
1116   (let ((file-name-coding-system nnmail-pathname-coding-system)
1117         print-level print-length item)
1118     (dolist (art articles)
1119         (if (setq item (memq art gnus-agent-article-alist))
1120             (setcdr item state)
1121           (push  (cons art state) gnus-agent-article-alist)))
1122     (setq gnus-agent-article-alist
1123           (sort gnus-agent-article-alist 'car-less-than-car))
1124     (with-temp-file (if dir
1125                         (expand-file-name ".agentview" dir)
1126                       (gnus-agent-article-name ".agentview" group))
1127       (princ gnus-agent-article-alist (current-buffer))
1128       (insert "\n"))))
1129
1130 (defun gnus-agent-article-name (article group)
1131   (expand-file-name (if (stringp article) article (string-to-number article))
1132                     (file-name-as-directory
1133                      (expand-file-name (gnus-agent-group-path group)
1134                                        (gnus-agent-directory)))))
1135
1136 (defun gnus-agent-batch-confirmation (msg)
1137   "Show error message and return t."
1138   (gnus-message 1 msg)
1139   t)
1140
1141 ;;;###autoload
1142 (defun gnus-agent-batch-fetch ()
1143   "Start Gnus and fetch session."
1144   (interactive)
1145   (gnus)
1146   (let ((gnus-agent-confirmation-function 'gnus-agent-batch-confirmation))
1147     (gnus-agent-fetch-session))
1148   (gnus-group-exit))
1149
1150 (defun gnus-agent-fetch-session ()
1151   "Fetch all articles and headers that are eligible for fetching."
1152   (interactive)
1153   (unless gnus-agent-covered-methods
1154     (error "No servers are covered by the Gnus agent"))
1155   (unless gnus-plugged
1156     (error "Can't fetch articles while Gnus is unplugged"))
1157   (let ((methods gnus-agent-covered-methods)
1158         groups group gnus-command-method)
1159     (save-excursion
1160       (while methods
1161         (condition-case err
1162             (progn
1163               (setq gnus-command-method (car methods))
1164               (when (and (or (gnus-server-opened gnus-command-method)
1165                              (gnus-open-server gnus-command-method))
1166                          (gnus-online gnus-command-method))
1167                 (setq groups (gnus-groups-from-server (car methods)))
1168                 (gnus-agent-with-fetch
1169                   (while (setq group (pop groups))
1170                     (when (<= (gnus-group-level group) gnus-agent-handle-level)
1171                       (gnus-agent-fetch-group-1 group gnus-command-method))))))
1172           (error
1173            (unless (funcall gnus-agent-confirmation-function
1174                             (format "Error (%s).  Continue? " err))
1175              (error "Cannot fetch articles into the Gnus agent")))
1176           (quit
1177            (unless (funcall gnus-agent-confirmation-function
1178                             (format "Quit fetching session (%s).  Continue? "
1179                                     err))
1180              (signal 'quit "Cannot fetch articles into the Gnus agent"))))
1181         (pop methods))
1182       (run-hooks 'gnus-agent-fetch-hook)
1183       (gnus-message 6 "Finished fetching articles into the Gnus agent"))))
1184
1185 (defun gnus-agent-fetch-group-1 (group method)
1186   "Fetch GROUP."
1187   (let ((gnus-command-method method)
1188         (gnus-newsgroup-name group)
1189         gnus-newsgroup-dependencies gnus-newsgroup-headers
1190         gnus-newsgroup-scored gnus-headers gnus-score
1191         gnus-use-cache articles arts
1192         category predicate info marks score-param
1193         (gnus-summary-expunge-below gnus-summary-expunge-below)
1194         (gnus-summary-mark-below gnus-summary-mark-below)
1195         (gnus-orphan-score gnus-orphan-score)
1196         ;; Maybe some other gnus-summary local variables should also
1197         ;; be put here.
1198         )
1199     (unless (gnus-check-group group)
1200       (error "Can't open server for %s" group))
1201     ;; Fetch headers.
1202     (when (and (or (gnus-active group)
1203                    (gnus-activate-group group))
1204                (setq articles (gnus-agent-fetch-headers group))
1205                (let ((nntp-server-buffer gnus-agent-overview-buffer))
1206                  ;; Parse them and see which articles we want to fetch.
1207                  (setq gnus-newsgroup-dependencies
1208                        (make-vector (length articles) 0))
1209                  (setq gnus-newsgroup-headers
1210                        (gnus-get-newsgroup-headers-xover articles nil nil
1211                                                          group))
1212                  ;; `gnus-agent-overview-buffer' may be killed for
1213                  ;; timeout reason.  If so, recreate it.
1214                  (gnus-agent-create-buffer)))
1215       (setq category (gnus-group-category group))
1216       (setq predicate
1217             (gnus-get-predicate
1218              (or (gnus-group-find-parameter group 'agent-predicate t)
1219                  (cadr category))))
1220       (if (memq predicate '(gnus-agent-true gnus-agent-false))
1221           ;; Simple implementation
1222           (setq arts (and (eq predicate 'gnus-agent-true) articles))
1223         (setq arts nil)
1224         (setq score-param
1225               (or (gnus-group-get-parameter group 'agent-score t)
1226                   (caddr category)))
1227         ;; Translate score-param into real one
1228         (cond
1229          ((not score-param))
1230          ((eq score-param 'file)
1231           (setq score-param (gnus-all-score-files group)))
1232          ((stringp (car score-param)))
1233          (t
1234           (setq score-param (list (list score-param)))))
1235         (when score-param
1236           (gnus-score-headers score-param))
1237         (while (setq gnus-headers (pop gnus-newsgroup-headers))
1238           (setq gnus-score
1239                 (or (cdr (assq (mail-header-number gnus-headers)
1240                                gnus-newsgroup-scored))
1241                     gnus-summary-default-score))
1242           (when (funcall predicate)
1243             (push (mail-header-number gnus-headers)
1244                   arts))))
1245       ;; Fetch the articles.
1246       (when arts
1247         (gnus-agent-fetch-articles group arts)))
1248     ;; Perhaps we have some additional articles to fetch.
1249     (setq arts (assq 'download (gnus-info-marks
1250                                 (setq info (gnus-get-info group)))))
1251     (when (cdr arts)
1252       (gnus-message 8 "Agent is downloading marked articles...")
1253       (gnus-agent-fetch-articles
1254        group (gnus-uncompress-range (cdr arts)))
1255       (setq marks (delq arts (gnus-info-marks info)))
1256       (gnus-info-set-marks info marks)
1257       (gnus-dribble-enter
1258        (concat "(gnus-group-set-info '"
1259                (gnus-prin1-to-string info)
1260                ")")))))
1261
1262 ;;;
1263 ;;; Agent Category Mode
1264 ;;;
1265
1266 (defvar gnus-category-mode-hook nil
1267   "Hook run in `gnus-category-mode' buffers.")
1268
1269 (defvar gnus-category-line-format "     %(%20c%): %g\n"
1270   "Format of category lines.
1271
1272 Valid specifiers include:
1273 %c  Topic name (string)
1274 %g  The number of groups in the topic (integer)
1275
1276 General format specifiers can also be used.  See
1277 (gnus)Formatting Variables.")
1278
1279 (defvar gnus-category-mode-line-format "Gnus: %%b"
1280   "The format specification for the category mode line.")
1281
1282 (defvar gnus-agent-short-article 100
1283   "Articles that have fewer lines than this are short.")
1284
1285 (defvar gnus-agent-long-article 200
1286   "Articles that have more lines than this are long.")
1287
1288 (defvar gnus-agent-low-score 0
1289   "Articles that have a score lower than this have a low score.")
1290
1291 (defvar gnus-agent-high-score 0
1292   "Articles that have a score higher than this have a high score.")
1293
1294
1295 ;;; Internal variables.
1296
1297 (defvar gnus-category-buffer "*Agent Category*")
1298
1299 (defvar gnus-category-line-format-alist
1300   `((?c gnus-tmp-name ?s)
1301     (?g gnus-tmp-groups ?d)))
1302
1303 (defvar gnus-category-mode-line-format-alist
1304   `((?u user-defined ?s)))
1305
1306 (defvar gnus-category-line-format-spec nil)
1307 (defvar gnus-category-mode-line-format-spec nil)
1308
1309 (defvar gnus-category-mode-map nil)
1310 (put 'gnus-category-mode 'mode-class 'special)
1311
1312 (unless gnus-category-mode-map
1313   (setq gnus-category-mode-map (make-sparse-keymap))
1314   (suppress-keymap gnus-category-mode-map)
1315
1316   (gnus-define-keys gnus-category-mode-map
1317     "q" gnus-category-exit
1318     "k" gnus-category-kill
1319     "c" gnus-category-copy
1320     "a" gnus-category-add
1321     "p" gnus-category-edit-predicate
1322     "g" gnus-category-edit-groups
1323     "s" gnus-category-edit-score
1324     "l" gnus-category-list
1325
1326     "\C-c\C-i" gnus-info-find-node
1327     "\C-c\C-b" gnus-bug))
1328
1329 (defvar gnus-category-menu-hook nil
1330   "*Hook run after the creation of the menu.")
1331
1332 (defun gnus-category-make-menu-bar ()
1333   (gnus-turn-off-edit-menu 'category)
1334   (unless (boundp 'gnus-category-menu)
1335     (easy-menu-define
1336      gnus-category-menu gnus-category-mode-map ""
1337      '("Categories"
1338        ["Add" gnus-category-add t]
1339        ["Kill" gnus-category-kill t]
1340        ["Copy" gnus-category-copy t]
1341        ["Edit predicate" gnus-category-edit-predicate t]
1342        ["Edit score" gnus-category-edit-score t]
1343        ["Edit groups" gnus-category-edit-groups t]
1344        ["Exit" gnus-category-exit t]))
1345
1346     (gnus-run-hooks 'gnus-category-menu-hook)))
1347
1348 (defun gnus-category-mode ()
1349   "Major mode for listing and editing agent categories.
1350
1351 All normal editing commands are switched off.
1352 \\<gnus-category-mode-map>
1353 For more in-depth information on this mode, read the manual
1354 (`\\[gnus-info-find-node]').
1355
1356 The following commands are available:
1357
1358 \\{gnus-category-mode-map}"
1359   (interactive)
1360   (when (gnus-visual-p 'category-menu 'menu)
1361     (gnus-category-make-menu-bar))
1362   (kill-all-local-variables)
1363   (gnus-simplify-mode-line)
1364   (setq major-mode 'gnus-category-mode)
1365   (setq mode-name "Category")
1366   (gnus-set-default-directory)
1367   (setq mode-line-process nil)
1368   (use-local-map gnus-category-mode-map)
1369   (buffer-disable-undo)
1370   (setq truncate-lines t)
1371   (setq buffer-read-only t)
1372   (gnus-run-hooks 'gnus-category-mode-hook))
1373
1374 (defalias 'gnus-category-position-point 'gnus-goto-colon)
1375
1376 (defun gnus-category-insert-line (category)
1377   (let* ((gnus-tmp-name (format "%s" (car category)))
1378          (gnus-tmp-groups (length (cadddr category))))
1379     (beginning-of-line)
1380     (gnus-add-text-properties
1381      (point)
1382      (prog1 (1+ (point))
1383        ;; Insert the text.
1384        (eval gnus-category-line-format-spec))
1385      (list 'gnus-category gnus-tmp-name))))
1386
1387 (defun gnus-enter-category-buffer ()
1388   "Go to the Category buffer."
1389   (interactive)
1390   (gnus-category-setup-buffer)
1391   (gnus-configure-windows 'category)
1392   (gnus-category-prepare))
1393
1394 (defun gnus-category-setup-buffer ()
1395   (unless (get-buffer gnus-category-buffer)
1396     (save-excursion
1397       (set-buffer (gnus-get-buffer-create gnus-category-buffer))
1398       (gnus-category-mode))))
1399
1400 (defun gnus-category-prepare ()
1401   (gnus-set-format 'category-mode)
1402   (gnus-set-format 'category t)
1403   (let ((alist gnus-category-alist)
1404         (buffer-read-only nil))
1405     (erase-buffer)
1406     (while alist
1407       (gnus-category-insert-line (pop alist)))
1408     (goto-char (point-min))
1409     (gnus-category-position-point)))
1410
1411 (defun gnus-category-name ()
1412   (or (intern (get-text-property (gnus-point-at-bol) 'gnus-category))
1413       (error "No category on the current line")))
1414
1415 (defun gnus-category-read ()
1416   "Read the category alist."
1417   (setq gnus-category-alist
1418         (or (gnus-agent-read-file
1419              (nnheader-concat gnus-agent-directory "lib/categories"))
1420             (list (list 'default 'short nil nil)))))
1421
1422 (defun gnus-category-write ()
1423   "Write the category alist."
1424   (setq gnus-category-predicate-cache nil
1425         gnus-category-group-cache nil)
1426   (gnus-make-directory (nnheader-concat gnus-agent-directory "lib"))
1427   (with-temp-file (nnheader-concat gnus-agent-directory "lib/categories")
1428     (prin1 gnus-category-alist (current-buffer))))
1429
1430 (defun gnus-category-edit-predicate (category)
1431   "Edit the predicate for CATEGORY."
1432   (interactive (list (gnus-category-name)))
1433   (let ((info (assq category gnus-category-alist)))
1434     (gnus-edit-form
1435      (cadr info) (format "Editing the predicate for category %s" category)
1436      `(lambda (predicate)
1437         (setcar (cdr (assq ',category gnus-category-alist)) predicate)
1438         (gnus-category-write)
1439         (gnus-category-list)))))
1440
1441 (defun gnus-category-edit-score (category)
1442   "Edit the score expression for CATEGORY."
1443   (interactive (list (gnus-category-name)))
1444   (let ((info (assq category gnus-category-alist)))
1445     (gnus-edit-form
1446      (caddr info)
1447      (format "Editing the score expression for category %s" category)
1448      `(lambda (groups)
1449         (setcar (cddr (assq ',category gnus-category-alist)) groups)
1450         (gnus-category-write)
1451         (gnus-category-list)))))
1452
1453 (defun gnus-category-edit-groups (category)
1454   "Edit the group list for CATEGORY."
1455   (interactive (list (gnus-category-name)))
1456   (let ((info (assq category gnus-category-alist)))
1457     (gnus-edit-form
1458      (cadddr info) (format "Editing the group list for category %s" category)
1459      `(lambda (groups)
1460         (setcar (nthcdr 3 (assq ',category gnus-category-alist)) groups)
1461         (gnus-category-write)
1462         (gnus-category-list)))))
1463
1464 (defun gnus-category-kill (category)
1465   "Kill the current category."
1466   (interactive (list (gnus-category-name)))
1467   (let ((info (assq category gnus-category-alist))
1468         (buffer-read-only nil))
1469     (gnus-delete-line)
1470     (setq gnus-category-alist (delq info gnus-category-alist))
1471     (gnus-category-write)))
1472
1473 (defun gnus-category-copy (category to)
1474   "Copy the current category."
1475   (interactive (list (gnus-category-name) (intern (read-string "New name: "))))
1476   (let ((info (assq category gnus-category-alist)))
1477     (push (list to (gnus-copy-sequence (cadr info))
1478                 (gnus-copy-sequence (caddr info)) nil)
1479           gnus-category-alist)
1480     (gnus-category-write)
1481     (gnus-category-list)))
1482
1483 (defun gnus-category-add (category)
1484   "Create a new category."
1485   (interactive "SCategory name: ")
1486   (when (assq category gnus-category-alist)
1487     (error "Category %s already exists" category))
1488   (push (list category 'false nil nil)
1489         gnus-category-alist)
1490   (gnus-category-write)
1491   (gnus-category-list))
1492
1493 (defun gnus-category-list ()
1494   "List all categories."
1495   (interactive)
1496   (gnus-category-prepare))
1497
1498 (defun gnus-category-exit ()
1499   "Return to the group buffer."
1500   (interactive)
1501   (kill-buffer (current-buffer))
1502   (gnus-configure-windows 'group t))
1503
1504 ;; To avoid having 8-bit characters in the source file.
1505 (defvar gnus-category-not (list '! 'not (intern (format "%c" 172))))
1506
1507 (defvar gnus-category-predicate-alist
1508   '((spam . gnus-agent-spam-p)
1509     (short . gnus-agent-short-p)
1510     (long . gnus-agent-long-p)
1511     (low . gnus-agent-low-scored-p)
1512     (high . gnus-agent-high-scored-p)
1513     (true . gnus-agent-true)
1514     (false . gnus-agent-false))
1515   "Mapping from short score predicate symbols to predicate functions.")
1516
1517 (defun gnus-agent-spam-p ()
1518   "Say whether an article is spam or not."
1519   (unless gnus-agent-spam-hashtb
1520     (setq gnus-agent-spam-hashtb (gnus-make-hashtable 1000)))
1521   (if (not (equal (mail-header-references gnus-headers) ""))
1522       nil
1523     (let ((string (gnus-simplify-subject (mail-header-subject gnus-headers))))
1524       (prog1
1525           (gnus-gethash string gnus-agent-spam-hashtb)
1526         (gnus-sethash string t gnus-agent-spam-hashtb)))))
1527
1528 (defun gnus-agent-short-p ()
1529   "Say whether an article is short or not."
1530   (< (mail-header-lines gnus-headers) gnus-agent-short-article))
1531
1532 (defun gnus-agent-long-p ()
1533   "Say whether an article is long or not."
1534   (> (mail-header-lines gnus-headers) gnus-agent-long-article))
1535
1536 (defun gnus-agent-low-scored-p ()
1537   "Say whether an article has a low score or not."
1538   (< gnus-score gnus-agent-low-score))
1539
1540 (defun gnus-agent-high-scored-p ()
1541   "Say whether an article has a high score or not."
1542   (> gnus-score gnus-agent-high-score))
1543
1544 (defun gnus-category-make-function (cat)
1545   "Make a function from category CAT."
1546   (let ((func (gnus-category-make-function-1 cat)))
1547     (if (and (= (length func) 1)
1548              (symbolp (car func)))
1549         (car func)
1550       (gnus-byte-compile `(lambda () ,func)))))
1551
1552 (defun gnus-agent-true ()
1553   "Return t."
1554   t)
1555
1556 (defun gnus-agent-false ()
1557   "Return nil."
1558   nil)
1559
1560 (defun gnus-category-make-function-1 (cat)
1561   "Make a function from category CAT."
1562   (cond
1563    ;; Functions are just returned as is.
1564    ((or (symbolp cat)
1565         (gnus-functionp cat))
1566     `(,(or (cdr (assq cat gnus-category-predicate-alist))
1567            cat)))
1568    ;; More complex category.
1569    ((consp cat)
1570     `(,(cond
1571         ((memq (car cat) '(& and))
1572          'and)
1573         ((memq (car cat) '(| or))
1574          'or)
1575         ((memq (car cat) gnus-category-not)
1576          'not))
1577       ,@(mapcar 'gnus-category-make-function-1 (cdr cat))))
1578    (t
1579     (error "Unknown category type: %s" cat))))
1580
1581 (defun gnus-get-predicate (predicate)
1582   "Return the predicate for CATEGORY."
1583   (or (cdr (assoc predicate gnus-category-predicate-cache))
1584       (cdar (push (cons predicate
1585                         (gnus-category-make-function predicate))
1586                   gnus-category-predicate-cache))))
1587
1588 (defun gnus-group-category (group)
1589   "Return the category GROUP belongs to."
1590   (unless gnus-category-group-cache
1591     (setq gnus-category-group-cache (gnus-make-hashtable 1000))
1592     (let ((cs gnus-category-alist)
1593           groups cat)
1594       (while (setq cat (pop cs))
1595         (setq groups (cadddr cat))
1596         (while groups
1597           (gnus-sethash (pop groups) cat gnus-category-group-cache)))))
1598   (or (gnus-gethash group gnus-category-group-cache)
1599       (assq 'default gnus-category-alist)))
1600
1601 (defun gnus-agent-expire ()
1602   "Expire all old articles."
1603   (interactive)
1604   (let ((methods gnus-agent-covered-methods)
1605         (day (if (numberp gnus-agent-expire-days)
1606                  (- (time-to-days (current-time)) gnus-agent-expire-days)
1607                nil))
1608         (current-day (time-to-days (current-time)))
1609         gnus-command-method sym group articles
1610         history overview file histories elem art nov-file low info
1611         unreads marked article orig lowest highest found days)
1612     (save-excursion
1613       (setq overview (gnus-get-buffer-create " *expire overview*"))
1614       (while (setq gnus-command-method (pop methods))
1615         (when (file-exists-p (gnus-agent-lib-file "active"))
1616           (with-temp-buffer
1617             (nnheader-insert-file-contents (gnus-agent-lib-file "active"))
1618             (gnus-active-to-gnus-format
1619              gnus-command-method
1620              (setq orig (gnus-make-hashtable
1621                          (count-lines (point-min) (point-max))))))
1622           (let ((expiry-hashtb (gnus-make-hashtable 1023)))
1623             (gnus-agent-open-history)
1624             (set-buffer
1625              (setq gnus-agent-current-history
1626                    (setq history (gnus-agent-history-buffer))))
1627             (goto-char (point-min))
1628             (when (> (buffer-size) 1)
1629               (goto-char (point-min))
1630               (while (not (eobp))
1631                 (skip-chars-forward "^\t")
1632                 (if (let ((fetch-date (read (current-buffer))))
1633                       (if (numberp fetch-date)
1634                           ;; We now have the arrival day, so we see
1635                           ;; whether it's old enough to be expired.
1636                           (if (numberp day)
1637                               (> fetch-date day)
1638                             (skip-chars-forward "\t")
1639                             (setq found nil
1640                                   days gnus-agent-expire-days)
1641                             (while (and (not found)
1642                                         days)
1643                               (when (looking-at (caar days))
1644                                 (setq found (cadar days)))
1645                               (pop days))
1646                             (> fetch-date (- current-day found)))
1647                         ;; History file is corrupted.
1648                         (gnus-message
1649                          5
1650                          (format "File %s is corrupted!"
1651                                  (gnus-agent-lib-file "history")))
1652                         (sit-for 1)
1653                         ;; Ignore it
1654                         t))
1655                     ;; New article; we don't expire it.
1656                     (forward-line 1)
1657                   ;; Old article.  Schedule it for possible nuking.
1658                   (while (not (eolp))
1659                     (setq sym (let ((obarray expiry-hashtb) s)
1660                                 (setq s (read (current-buffer)))
1661                                 (if (stringp s) (intern s) s)))
1662                     (if (boundp sym)
1663                         (set sym (cons (cons (read (current-buffer)) (point))
1664                                        (symbol-value sym)))
1665                       (set sym (list (cons (read (current-buffer)) (point)))))
1666                     (skip-chars-forward " "))
1667                   (forward-line 1)))
1668               ;; We now have all articles that can possibly be expired.
1669               (mapatoms
1670                (lambda (sym)
1671                  (setq group (symbol-name sym)
1672                        articles (sort (symbol-value sym) 'car-less-than-car)
1673                        low (car (gnus-active group))
1674                        info (gnus-get-info group)
1675                        unreads (ignore-errors
1676                                  (gnus-list-of-unread-articles group))
1677                        marked (nconc
1678                                (gnus-uncompress-range
1679                                 (cdr (assq 'tick (gnus-info-marks info))))
1680                                (gnus-uncompress-range
1681                                 (cdr (assq 'dormant
1682                                            (gnus-info-marks info)))))
1683                        nov-file (gnus-agent-article-name ".overview" group)
1684                        lowest nil
1685                        highest nil)
1686                  (gnus-agent-load-alist group)
1687                  (gnus-message 5 "Expiring articles in %s" group)
1688                  (set-buffer overview)
1689                  (erase-buffer)
1690                  (when (file-exists-p nov-file)
1691                    (nnheader-insert-file-contents nov-file))
1692                  (goto-char (point-min))
1693                  (setq article 0)
1694                  (while (setq elem (pop articles))
1695                    (setq article (car elem))
1696                    (when (or (null low)
1697                              (< article low)
1698                              gnus-agent-expire-all
1699                              (and (not (memq article unreads))
1700                                   (not (memq article marked))))
1701                      ;; Find and nuke the NOV line.
1702                      (while (and (not (eobp))
1703                                  (or (not (numberp
1704                                            (setq art (read (current-buffer)))))
1705                                      (< art article)))
1706                        (if (and (numberp art)
1707                                 (file-exists-p
1708                                  (gnus-agent-article-name
1709                                   (number-to-string art) group)))
1710                            (progn
1711                              (unless lowest
1712                                (setq lowest art))
1713                              (setq highest art)
1714                              (forward-line 1))
1715                          ;; Remove old NOV lines that have no articles.
1716                          (gnus-delete-line)))
1717                      (if (or (eobp)
1718                              (/= art article))
1719                          (beginning-of-line)
1720                        (gnus-delete-line))
1721                      ;; Nuke the article.
1722                      (when (file-exists-p
1723                             (setq file (gnus-agent-article-name
1724                                         (number-to-string article)
1725                                         group)))
1726                        (delete-file file))
1727                      ;; Schedule the history line for nuking.
1728                      (push (cdr elem) histories)))
1729                  (gnus-make-directory (file-name-directory nov-file))
1730                  (let ((coding-system-for-write
1731                         gnus-agent-file-coding-system))
1732                    (write-region (point-min) (point-max) nov-file nil 'silent))
1733                  ;; Delete the unwanted entries in the alist.
1734                  (setq gnus-agent-article-alist
1735                        (sort gnus-agent-article-alist 'car-less-than-car))
1736                  (let* ((alist gnus-agent-article-alist)
1737                         (prev (cons nil alist))
1738                         (first prev)
1739                         expired)
1740                    (while (and alist
1741                                (<= (caar alist) article))
1742                      (if (or (not (cdar alist))
1743                              (not (file-exists-p
1744                                    (gnus-agent-article-name
1745                                     (number-to-string
1746                                      (caar alist))
1747                                     group))))
1748                          (progn
1749                            (push (caar alist) expired)
1750                            (setcdr prev (setq alist (cdr alist))))
1751                        (setq prev alist
1752                              alist (cdr alist))))
1753                    (setq gnus-agent-article-alist (cdr first))
1754                    (gnus-agent-save-alist group)
1755                    ;; Mark all articles up to the first article
1756                    ;; in `gnus-article-alist' as read.
1757                    (when (and info (caar gnus-agent-article-alist))
1758                      (setcar (nthcdr 2 info)
1759                              (gnus-range-add
1760                               (nth 2 info)
1761                               (cons 1 (- (caar gnus-agent-article-alist) 1)))))
1762                    ;; Maybe everything has been expired from
1763                    ;; `gnus-article-alist' and so the above marking as
1764                    ;; read could not be conducted, or there are
1765                    ;; expired article within the range of the alist.
1766                    (when (and info
1767                               expired
1768                               (or (not (caar gnus-agent-article-alist))
1769                                   (> (car expired)
1770                                      (caar gnus-agent-article-alist))))
1771                      (setcar (nthcdr 2 info)
1772                              (gnus-add-to-range
1773                               (nth 2 info)
1774                               (nreverse expired))))
1775                    (gnus-dribble-enter
1776                     (concat "(gnus-group-set-info '"
1777                             (gnus-prin1-to-string info)
1778                             ")")))
1779                  (when lowest
1780                    (if (gnus-gethash group orig)
1781                        (setcar (gnus-gethash group orig) lowest)
1782                      (gnus-sethash group (cons lowest highest) orig))))
1783                expiry-hashtb)
1784               (set-buffer history)
1785               (setq histories (nreverse (sort histories '<)))
1786               (while histories
1787                 (goto-char (pop histories))
1788                 (gnus-delete-line))
1789               (gnus-agent-save-history)
1790               (gnus-agent-close-history)
1791               (gnus-write-active-file
1792                (gnus-agent-lib-file "active") orig))
1793             (gnus-message 4 "Expiry...done")))))))
1794
1795 ;;;###autoload
1796 (defun gnus-agent-batch ()
1797   (interactive)
1798   (let ((init-file-user "")
1799         (gnus-always-read-dribble-file t))
1800     (gnus))
1801   (let ((gnus-agent-confirmation-function 'gnus-agent-batch-confirmation))
1802     (gnus-group-send-queue)
1803     (gnus-agent-fetch-session)))
1804
1805 (defun gnus-agent-retrieve-headers (articles group &optional fetch-old)
1806   (save-excursion
1807     (gnus-agent-create-buffer)
1808     (let ((gnus-decode-encoded-word-function 'identity)
1809           (file (gnus-agent-article-name ".overview" group))
1810           cached-articles uncached-articles)
1811       (gnus-make-directory (nnheader-translate-file-chars
1812                             (file-name-directory file) t))
1813       (when (file-exists-p file)
1814         (with-current-buffer gnus-agent-overview-buffer
1815           (erase-buffer)
1816           (let ((nnheader-file-coding-system
1817                  gnus-agent-file-coding-system))
1818             (nnheader-insert-file-contents file))
1819           (goto-char (point-min))
1820           (while (not (eobp))
1821             (when (looking-at "[0-9]")
1822               (push (read (current-buffer)) cached-articles))
1823             (forward-line 1))
1824           (setq cached-articles (sort cached-articles '<))))
1825       (if (setq uncached-articles
1826                   (gnus-set-difference articles cached-articles))
1827           (progn
1828             (set-buffer nntp-server-buffer)
1829             (erase-buffer)
1830             (let (gnus-agent-cache)
1831               (unless (eq 'nov
1832                           (gnus-retrieve-headers
1833                            uncached-articles group fetch-old))
1834                 (nnvirtual-convert-headers)))
1835             (set-buffer gnus-agent-overview-buffer)
1836             (erase-buffer)
1837             (set-buffer nntp-server-buffer)
1838             (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
1839             (when (and uncached-articles (file-exists-p file))
1840               (gnus-agent-braid-nov group uncached-articles file))
1841             (set-buffer nntp-server-buffer)
1842             (let ((coding-system-for-write
1843                    gnus-agent-file-coding-system))
1844               (write-region (point-min) (point-max) file nil 'silent))
1845             (gnus-agent-load-alist group)
1846             (gnus-agent-save-alist group uncached-articles nil)
1847             (gnus-agent-open-history)
1848             (setq gnus-agent-current-history (gnus-agent-history-buffer))
1849             (gnus-agent-enter-history
1850              "last-header-fetched-for-session"
1851              (list (cons group (nth (- (length  articles) 1) articles)))
1852              (time-to-days (current-time)))
1853             (gnus-agent-save-history))
1854         (set-buffer nntp-server-buffer)
1855         (erase-buffer)
1856         (insert-buffer-substring gnus-agent-overview-buffer)))
1857     (if (and fetch-old
1858              (not (numberp fetch-old)))
1859         t                               ; Don't remove anything.
1860       (nnheader-nov-delete-outside-range
1861        (if fetch-old (max 1 (- (car articles) fetch-old))
1862          (car articles))
1863        (car (last articles)))
1864       t)
1865     'nov))
1866
1867 (defun gnus-agent-request-article (article group)
1868   "Retrieve ARTICLE in GROUP from the agent cache."
1869   (let* ((gnus-command-method (gnus-find-method-for-group group))
1870          (file (concat
1871                   (gnus-agent-directory)
1872                   (gnus-agent-group-path group) "/"
1873                   (number-to-string article)))
1874         (buffer-read-only nil))
1875     (when (file-exists-p file)
1876       (erase-buffer)
1877       (gnus-kill-all-overlays)
1878       (let ((coding-system-for-read gnus-cache-coding-system))
1879         (insert-file-contents file))
1880       t)))
1881
1882 (defun gnus-agent-regenerate-group (group &optional clean)
1883   "Regenerate GROUP."
1884   (let ((dir (concat (gnus-agent-directory)
1885                      (gnus-agent-group-path group) "/"))
1886         (file (gnus-agent-article-name ".overview" group))
1887         n point arts alist header new-alist changed)
1888     (when (file-exists-p dir)
1889       (setq arts
1890             (sort (mapcar (lambda (name) (string-to-int name))
1891                           (directory-files dir nil "^[0-9]+$" t))
1892                   '<)))
1893     (gnus-make-directory (nnheader-translate-file-chars
1894                           (file-name-directory file) t))
1895     (mm-with-unibyte-buffer
1896       (if (file-exists-p file)
1897           (let ((nnheader-file-coding-system
1898                  gnus-agent-file-coding-system))
1899             (nnheader-insert-file-contents file)))
1900       (goto-char (point-min))
1901       (while (not (eobp))
1902         (while (not (or (eobp) (looking-at "[0-9]")))
1903           (setq point (point))
1904           (forward-line 1)
1905           (delete-region point (point)))
1906         (unless (eobp)
1907           (setq n (read (current-buffer)))
1908           (when (and arts (> n (car arts)))
1909             (beginning-of-line)
1910             (while (and arts (> n (car arts)))
1911               (message "Regenerating NOV %s %d..." group (car arts))
1912               (mm-with-unibyte-buffer
1913                 (nnheader-insert-file-contents
1914                  (concat dir (number-to-string (car arts))))
1915                 (goto-char (point-min))
1916                 (if (search-forward "\n\n" nil t)
1917                     (delete-region (point) (point-max))
1918                   (goto-char (point-max)))
1919                 (setq header (nnheader-parse-head t)))
1920               (mail-header-set-number header (car arts))
1921               (nnheader-insert-nov header)
1922               (setq changed t)
1923               (push (cons (car arts) t) alist)
1924               (pop arts)))
1925           (if (and arts (= n (car arts)))
1926               (progn
1927                 (push (cons n t) alist)
1928                 (pop arts))
1929             (push (cons n nil) alist))
1930           (forward-line 1)))
1931       (if changed
1932           (let ((coding-system-for-write gnus-agent-file-coding-system))
1933             (write-region (point-min) (point-max) file nil 'silent))))
1934     (setq gnus-agent-article-alist nil)
1935     (unless clean
1936       (gnus-agent-load-alist group))
1937     (setq alist (sort alist 'car-less-than-car))
1938     (setq gnus-agent-article-alist (sort gnus-agent-article-alist
1939                                          'car-less-than-car))
1940     (while (and alist gnus-agent-article-alist)
1941       (cond
1942        ((< (caar alist) (caar gnus-agent-article-alist))
1943         (push (pop alist) new-alist))
1944        ((> (caar alist) (caar gnus-agent-article-alist))
1945         (push (list (car (pop gnus-agent-article-alist))) new-alist))
1946        (t
1947         (pop gnus-agent-article-alist)
1948         (while (and gnus-agent-article-alist
1949                     (= (caar alist) (caar gnus-agent-article-alist)))
1950           (pop gnus-agent-article-alist))
1951         (push (pop alist) new-alist))))
1952     (while alist
1953       (push (pop alist) new-alist))
1954     (while gnus-agent-article-alist
1955       (push (list (car (pop gnus-agent-article-alist))) new-alist))
1956     (setq gnus-agent-article-alist (nreverse new-alist))
1957     (gnus-agent-save-alist group)))
1958
1959 (defun gnus-agent-regenerate-history (group article)
1960   (let ((file (concat (gnus-agent-directory)
1961                       (gnus-agent-group-path group) "/"
1962                       (number-to-string article))) id)
1963     (mm-with-unibyte-buffer
1964       (nnheader-insert-file-contents file)
1965       (message-narrow-to-head)
1966       (goto-char (point-min))
1967       (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
1968           (setq id "No-Message-ID-in-article")
1969         (setq id (buffer-substring (match-beginning 1) (match-end 1))))
1970       (gnus-agent-enter-history
1971        id (list (cons group article))
1972        (time-to-days (nth 5 (file-attributes file)))))))
1973
1974 ;;;###autoload
1975 (defun gnus-agent-regenerate (&optional clean)
1976   "Regenerate all agent covered files.
1977 If CLEAN, don't read existing active and agentview files."
1978   (interactive "P")
1979   (message "Regenerating Gnus agent files...")
1980   (dolist (gnus-command-method gnus-agent-covered-methods)
1981     (let ((active-file (gnus-agent-lib-file "active"))
1982           history-hashtb active-hashtb active-changed
1983           history-changed point)
1984       (gnus-make-directory (file-name-directory active-file))
1985       (if clean
1986           (setq active-hashtb (gnus-make-hashtable 1000))
1987         (mm-with-unibyte-buffer
1988           (if (file-exists-p active-file)
1989               (let ((nnheader-file-coding-system
1990                      gnus-agent-file-coding-system))
1991                 (nnheader-insert-file-contents active-file))
1992             (setq active-changed t))
1993           (gnus-active-to-gnus-format
1994            nil (setq active-hashtb
1995                      (gnus-make-hashtable
1996                       (count-lines (point-min) (point-max)))))))
1997       (gnus-agent-open-history)
1998       (setq history-hashtb (gnus-make-hashtable 1000))
1999       (with-current-buffer
2000           (setq gnus-agent-current-history (gnus-agent-history-buffer))
2001         (goto-char (point-min))
2002         (forward-line 1)
2003         (while (not (eobp))
2004           (if (looking-at
2005                "\\([^\t\n]+\\)\t[0-9]+\t\\([^ \n]+\\) \\([0-9]+\\)")
2006               (progn
2007                 (unless (string= (match-string 1)
2008                                  "last-header-fetched-for-session")
2009                   (gnus-sethash (match-string 2)
2010                                 (cons (string-to-number (match-string 3))
2011                                       (gnus-gethash-safe (match-string 2)
2012                                                          history-hashtb))
2013                                 history-hashtb))
2014                 (forward-line 1))
2015             (setq point (point))
2016             (forward-line 1)
2017             (delete-region point (point))
2018             (setq history-changed t))))
2019       (dolist (group (gnus-groups-from-server gnus-command-method))
2020         (gnus-agent-regenerate-group group clean)
2021         (let ((min (or (caar gnus-agent-article-alist) 1))
2022               (max (or (caar (last gnus-agent-article-alist)) 0))
2023               (active (gnus-gethash-safe (gnus-group-real-name group)
2024                                          active-hashtb)))
2025           (if (not active)
2026               (progn
2027                 (setq active (cons min max)
2028                       active-changed t)
2029                 (gnus-sethash group active active-hashtb))
2030             (when (> (car active) min)
2031               (setcar active min)
2032               (setq active-changed t))
2033             (when (< (cdr active) max)
2034               (setcdr active max)
2035               (setq active-changed t))))
2036         (let ((arts (sort (gnus-gethash-safe group history-hashtb) '<))
2037               n)
2038           (gnus-sethash group arts history-hashtb)
2039           (while (and arts gnus-agent-article-alist)
2040             (cond
2041              ((> (car arts) (caar gnus-agent-article-alist))
2042               (when (cdar gnus-agent-article-alist)
2043                 (gnus-agent-regenerate-history
2044                  group (caar gnus-agent-article-alist))
2045                 (setq history-changed t))
2046               (setq n (car (pop gnus-agent-article-alist)))
2047               (while (and gnus-agent-article-alist
2048                           (= n (caar gnus-agent-article-alist)))
2049                 (pop gnus-agent-article-alist)))
2050              ((< (car arts) (caar gnus-agent-article-alist))
2051               (setq n (pop arts))
2052               (while (and arts (= n (car arts)))
2053                 (pop arts)))
2054              (t
2055               (setq n (car (pop gnus-agent-article-alist)))
2056               (while (and gnus-agent-article-alist
2057                           (= n (caar gnus-agent-article-alist)))
2058                 (pop gnus-agent-article-alist))
2059               (setq n (pop arts))
2060               (while (and arts (= n (car arts)))
2061                 (pop arts)))))
2062           (while gnus-agent-article-alist
2063             (when (cdar gnus-agent-article-alist)
2064               (gnus-agent-regenerate-history
2065                group (caar gnus-agent-article-alist))
2066               (setq history-changed t))
2067             (pop gnus-agent-article-alist))))
2068       (when history-changed
2069         (message "Regenerate the history file of %s:%s"
2070                  (car gnus-command-method)
2071                  (cadr gnus-command-method))
2072         (gnus-agent-save-history))
2073       (gnus-agent-close-history)
2074       (when active-changed
2075         (message "Regenerate %s" active-file)
2076         (let ((nnmail-active-file-coding-system gnus-agent-file-coding-system))
2077           (gnus-write-active-file active-file active-hashtb)))))
2078   (message "Regenerating Gnus agent files...done"))
2079
2080 (defun gnus-agent-go-online (&optional force)
2081   "Switch servers into online status."
2082   (interactive (list t))
2083   (dolist (server gnus-opened-servers)
2084     (when (eq (nth 1 server) 'offline)
2085       (if (if (eq force 'ask)
2086               (gnus-y-or-n-p
2087                (format "Switch %s:%s into online status? "
2088                        (caar server) (cadar server)))
2089             force)
2090           (setcar (nthcdr 1 server) 'close)))))
2091
2092 (defun gnus-agent-toggle-group-plugged (group)
2093   "Toggle the status of the server of the current group."
2094   (interactive (list (gnus-group-group-name)))
2095   (let* ((method (gnus-find-method-for-group group))
2096          (status (cadr (assoc method gnus-opened-servers))))
2097     (if (eq status 'offline)
2098         (gnus-server-set-status method 'closed)
2099       (gnus-close-server method)
2100       (gnus-server-set-status method 'offline))
2101     (message "Turn %s:%s from %s to %s." (car method) (cadr method)
2102              (if (eq status 'offline) 'offline 'online)
2103              (if (eq status 'offline) 'online 'offline))))
2104
2105 (provide 'gnus-agent)
2106
2107 ;;; gnus-agent.el ends here