git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-agent.el

   1 ;;; gnus-agent.el --- unplugged support for Gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'gnus)
  27 (require 'gnus-cache)
  28 (require 'nnvirtual)
  29 (require 'gnus-sum)
  30 (eval-when-compile (require 'cl))
  31
  32 (defcustom gnus-agent-directory (nnheader-concat gnus-directory "agent/")
  33   "Where the Gnus agent will store its files."
  34   :group 'gnus-agent
  35   :type 'directory)
  36
  37 (defcustom gnus-agent-plugged-hook nil
  38   "Hook run when plugging into the network."
  39   :group 'gnus-agent
  40   :type 'hook)
  41
  42 (defcustom gnus-agent-unplugged-hook nil
  43   "Hook run when unplugging from the network."
  44   :group 'gnus-agent
  45   :type 'hook)
  46
  47 (defcustom gnus-agent-handle-level gnus-level-subscribed
  48   "Groups on levels higher than this variable will be ignored by the Agent."
  49   :group 'gnus-agent
  50   :type 'integer)
  51
  52 (defcustom gnus-agent-expire-days 7
  53   "Read articles older than this will be expired."
  54   :group 'gnus-agent
  55   :type 'integer)
  56
  57 (defcustom gnus-agent-expire-all nil
  58   "If non-nil, also expire unread, ticked and dormant articles.
  59 If nil, only read articles will be expired."
  60   :group 'gnus-agent
  61   :type 'boolean)
  62
  63 (defcustom gnus-agent-group-mode-hook nil
  64   "Hook run in Agent group minor modes."
  65   :group 'gnus-agent
  66   :type 'hook)
  67
  68 (defcustom gnus-agent-summary-mode-hook nil
  69   "Hook run in Agent summary minor modes."
  70   :group 'gnus-agent
  71   :type 'hook)
  72
  73 (defcustom gnus-agent-server-mode-hook nil
  74   "Hook run in Agent summary minor modes."
  75   :group 'gnus-agent
  76   :type 'hook)
  77
  78 ;;; Internal variables
  79
  80 (defvar gnus-agent-meta-information-header "X-Gnus-Agent-Meta-Information")
  81
  82 (defvar gnus-agent-history-buffers nil)
  83 (defvar gnus-agent-buffer-alist nil)
  84 (defvar gnus-agent-article-alist nil)
  85 (defvar gnus-agent-group-alist nil)
  86 (defvar gnus-agent-covered-methods nil)
  87 (defvar gnus-category-alist nil)
  88 (defvar gnus-agent-current-history nil)
  89 (defvar gnus-agent-overview-buffer nil)
  90 (defvar gnus-category-predicate-cache nil)
  91 (defvar gnus-category-group-cache nil)
  92 (defvar gnus-agent-spam-hashtb nil)
  93 (defvar gnus-agent-file-name nil)
  94 (defvar gnus-agent-send-mail-function nil)
  95 (defvar gnus-agent-article-file-coding-system 'no-conversion)
  96
  97 ;; Dynamic variables
  98 (defvar gnus-headers)
  99 (defvar gnus-score)
 100
 101 ;;;
 102 ;;; Setup
 103 ;;;
 104
 105 (defun gnus-open-agent ()
 106   (setq gnus-agent t)
 107   (gnus-agent-read-servers)
 108   (gnus-category-read)
 109   (setq gnus-agent-overview-buffer
 110         (get-buffer-create " *Gnus agent overview*"))
 111   (add-hook 'gnus-group-mode-hook 'gnus-agent-mode)
 112   (add-hook 'gnus-summary-mode-hook 'gnus-agent-mode)
 113   (add-hook 'gnus-server-mode-hook 'gnus-agent-mode))
 114
 115 (gnus-add-shutdown 'gnus-close-agent 'gnus)
 116
 117 (defun gnus-close-agent ()
 118   (setq gnus-agent-covered-methods nil
 119         gnus-category-predicate-cache nil
 120         gnus-category-group-cache nil
 121         gnus-agent-spam-hashtb nil)
 122   (gnus-kill-buffer gnus-agent-overview-buffer))
 123
 124 ;;;
 125 ;;; Utility functions
 126 ;;;
 127
 128 (defun gnus-agent-read-file (file)
 129   "Load FILE and do a `read' there."
 130   (nnheader-temp-write nil
 131     (ignore-errors
 132       (insert-file-contents file)
 133       (goto-char (point-min))
 134       (read (current-buffer)))))
 135
 136 (defsubst gnus-agent-method ()
 137   (concat (symbol-name (car gnus-command-method)) "/"
 138           (if (equal (cadr gnus-command-method) "")
 139               "unnamed"
 140             (cadr gnus-command-method))))
 141
 142 (defsubst gnus-agent-directory ()
 143   "Path of the Gnus agent directory."
 144   (nnheader-concat gnus-agent-directory
 145                    (nnheader-translate-file-chars (gnus-agent-method)) "/"))
 146
 147 (defun gnus-agent-lib-file (file)
 148   "The full path of the Gnus agent library FILE."
 149   (concat (gnus-agent-directory) "agent.lib/" file))
 150
 151 ;;; Fetching setup functions.
 152
 153 (defun gnus-agent-start-fetch ()
 154   "Initialize data structures for efficient fetching."
 155   (gnus-agent-open-history)
 156   (setq gnus-agent-current-history (gnus-agent-history-buffer)))
 157
 158 (defun gnus-agent-stop-fetch ()
 159   "Save all data structures and clean up."
 160   (gnus-agent-save-history)
 161   (gnus-agent-close-history)
 162   (setq gnus-agent-spam-hashtb nil)
 163   (save-excursion
 164     (set-buffer nntp-server-buffer)
 165     (widen)))
 166
 167 (defmacro gnus-agent-with-fetch (&rest forms)
 168   "Do FORMS safely."
 169   `(unwind-protect
 170        (progn
 171          (gnus-agent-start-fetch)
 172          ,@forms)
 173      (gnus-agent-stop-fetch)))
 174
 175 (put 'gnus-agent-with-fetch 'lisp-indent-function 0)
 176 (put 'gnus-agent-with-fetch 'edebug-form-spec '(body))
 177
 178 ;;;
 179 ;;; Mode infestation
 180 ;;;
 181
 182 (defvar gnus-agent-mode-hook nil
 183   "Hook run when installing agent mode.")
 184
 185 (defvar gnus-agent-mode nil)
 186 (defvar gnus-agent-mode-status '(gnus-agent-mode " Plugged"))
 187
 188 (defun gnus-agent-mode ()
 189   "Minor mode for providing a agent support in Gnus buffers."
 190   (let* ((buffer (progn (string-match "^gnus-\\(.*\\)-mode$"
 191                                       (symbol-name major-mode))
 192                         (match-string 1 (symbol-name major-mode))))
 193          (mode (intern (format "gnus-agent-%s-mode" buffer))))
 194     (set (make-local-variable 'gnus-agent-mode) t)
 195     (set mode nil)
 196     (set (make-local-variable mode) t)
 197     ;; Set up the menu.
 198     (when (gnus-visual-p 'agent-menu 'menu)
 199       (funcall (intern (format "gnus-agent-%s-make-menu-bar" buffer))))
 200     (unless (assq 'gnus-agent-mode minor-mode-alist)
 201       (push gnus-agent-mode-status minor-mode-alist))
 202     (unless (assq mode minor-mode-map-alist)
 203       (push (cons mode (symbol-value (intern (format "gnus-agent-%s-mode-map"
 204                                                      buffer))))
 205             minor-mode-map-alist))
 206     (gnus-agent-toggle-plugged gnus-plugged)
 207     (gnus-run-hooks 'gnus-agent-mode-hook
 208                     (intern (format "gnus-agent-%s-mode-hook" buffer)))))
 209
 210 (defvar gnus-agent-group-mode-map (make-sparse-keymap))
 211 (gnus-define-keys gnus-agent-group-mode-map
 212   "Ju" gnus-agent-fetch-groups
 213   "Jc" gnus-enter-category-buffer
 214   "Jj" gnus-agent-toggle-plugged
 215   "Js" gnus-agent-fetch-session
 216   "JS" gnus-group-send-drafts
 217   "Ja" gnus-agent-add-group)
 218
 219 (defun gnus-agent-group-make-menu-bar ()
 220   (unless (boundp 'gnus-agent-group-menu)
 221     (easy-menu-define
 222      gnus-agent-group-menu gnus-agent-group-mode-map ""
 223      '("Agent"
 224        ["Toggle plugged" gnus-agent-toggle-plugged t]
 225        ["List categories" gnus-enter-category-buffer t]
 226        ["Send drafts" gnus-group-send-drafts gnus-plugged]
 227        ("Fetch"
 228         ["All" gnus-agent-fetch-session gnus-plugged]
 229         ["Group" gnus-agent-fetch-group gnus-plugged])))))
 230
 231 (defvar gnus-agent-summary-mode-map (make-sparse-keymap))
 232 (gnus-define-keys gnus-agent-summary-mode-map
 233   "Jj" gnus-agent-toggle-plugged
 234   "J#" gnus-agent-mark-article
 235   "J\M-#" gnus-agent-unmark-article
 236   "@" gnus-agent-toggle-mark
 237   "Jc" gnus-agent-catchup)
 238
 239 (defun gnus-agent-summary-make-menu-bar ()
 240   (unless (boundp 'gnus-agent-summary-menu)
 241     (easy-menu-define
 242      gnus-agent-summary-menu gnus-agent-summary-mode-map ""
 243      '("Agent"
 244        ["Toggle plugged" gnus-agent-toggle-plugged t]
 245        ["Mark as downloadable" gnus-agent-mark-article t]
 246        ["Unmark as downloadable" gnus-agent-unmark-article t]
 247        ["Toggle mark" gnus-agent-toggle-mark t]
 248        ["Catchup undownloaded" gnus-agent-catchup t]))))
 249
 250 (defvar gnus-agent-server-mode-map (make-sparse-keymap))
 251 (gnus-define-keys gnus-agent-server-mode-map
 252   "Jj" gnus-agent-toggle-plugged
 253   "Ja" gnus-agent-add-server
 254   "Jr" gnus-agent-remove-server)
 255
 256 (defun gnus-agent-server-make-menu-bar ()
 257   (unless (boundp 'gnus-agent-server-menu)
 258     (easy-menu-define
 259      gnus-agent-server-menu gnus-agent-server-mode-map ""
 260      '("Agent"
 261        ["Toggle plugged" gnus-agent-toggle-plugged t]
 262        ["Add" gnus-agent-add-server t]
 263        ["Remove" gnus-agent-remove-server t]))))
 264
 265 (defun gnus-agent-toggle-plugged (plugged)
 266   "Toggle whether Gnus is unplugged or not."
 267   (interactive (list (not gnus-plugged)))
 268   (if plugged
 269       (progn
 270         (setq gnus-plugged plugged)
 271         (gnus-run-hooks 'gnus-agent-plugged-hook)
 272         (setcar (cdr gnus-agent-mode-status) " Plugged"))
 273     (gnus-agent-close-connections)
 274     (setq gnus-plugged plugged)
 275     (gnus-run-hooks 'gnus-agent-unplugged-hook)
 276     (setcar (cdr gnus-agent-mode-status) " Unplugged"))
 277   (set-buffer-modified-p t))
 278
 279 (defun gnus-agent-close-connections ()
 280   "Close all methods covered by the Gnus agent."
 281   (let ((methods gnus-agent-covered-methods))
 282     (while methods
 283       (gnus-close-server (pop methods)))))
 284
 285 ;;;###autoload
 286 (defun gnus-unplugged ()
 287   "Start Gnus unplugged."
 288   (interactive)
 289   (setq gnus-plugged nil)
 290   (gnus))
 291
 292 ;;;###autoload
 293 (defun gnus-plugged ()
 294   "Start Gnus plugged."
 295   (interactive)
 296   (setq gnus-plugged t)
 297   (gnus))
 298
 299 ;;;###autoload
 300 (defun gnus-agentize ()
 301   "Allow Gnus to be an offline newsreader.
 302 The normal usage of this command is to put the following as the
 303 last form in your `.gnus.el' file:
 304
 305 \(gnus-agentize)
 306
 307 This will modify the `gnus-before-startup-hook', `gnus-post-method',
 308 and `message-send-mail-function' variables, and install the Gnus
 309 agent minor mode in all Gnus buffers."
 310   (interactive)
 311   (gnus-open-agent)
 312   (add-hook 'gnus-setup-news-hook 'gnus-agent-queue-setup)
 313   (unless gnus-agent-send-mail-function
 314     (setq gnus-agent-send-mail-function message-send-mail-function
 315           message-send-mail-function 'gnus-agent-send-mail))
 316   (unless gnus-agent-covered-methods
 317     (setq gnus-agent-covered-methods (list gnus-select-method))))
 318
 319 (defun gnus-agent-queue-setup ()
 320   "Make sure the queue group exists."
 321   (unless (gnus-gethash "nndraft:queue" gnus-newsrc-hashtb)
 322     (gnus-request-create-group "queue" '(nndraft ""))
 323     (let ((gnus-level-default-subscribed 1))
 324       (gnus-subscribe-group "nndraft:queue" nil '(nndraft "")))
 325     (gnus-group-set-parameter
 326      "nndraft:queue" 'gnus-dummy '((gnus-draft-mode)))))
 327
 328 (defun gnus-agent-send-mail ()
 329   (if gnus-plugged
 330       (funcall gnus-agent-send-mail-function)
 331     (goto-char (point-min))
 332     (re-search-forward
 333      (concat "^" (regexp-quote mail-header-separator) "\n"))
 334     (replace-match "\n")
 335     (gnus-agent-insert-meta-information 'mail)
 336     (gnus-request-accept-article "nndraft:queue")))
 337
 338 (defun gnus-agent-insert-meta-information (type &optional method)
 339   "Insert meta-information into the message that says how it's to be posted.
 340 TYPE can be either `mail' or `news'.  If the latter METHOD can
 341 be a select method."
 342   (save-excursion
 343     (message-remove-header gnus-agent-meta-information-header)
 344     (goto-char (point-min))
 345     (insert gnus-agent-meta-information-header ": "
 346             (symbol-name type) " " (format "%S" method)
 347             "\n")
 348     (forward-char -1)
 349     (while (search-backward "\n" nil t)
 350       (replace-match "\\n" t t))))
 351
 352 ;;;
 353 ;;; Group mode commands
 354 ;;;
 355
 356 (defun gnus-agent-fetch-groups (n)
 357   "Put all new articles in the current groups into the Agent."
 358   (interactive "P")
 359   (gnus-group-iterate n 'gnus-agent-fetch-group))
 360
 361 (defun gnus-agent-fetch-group (group)
 362   "Put all new articles in GROUP into the Agent."
 363   (interactive (list (gnus-group-group-name)))
 364   (unless group
 365     (error "No group on the current line"))
 366   (let ((gnus-command-method (gnus-find-method-for-group group)))
 367     (gnus-agent-with-fetch
 368       (gnus-agent-fetch-group-1 group gnus-command-method)
 369       (gnus-message 5 "Fetching %s...done" group))))
 370
 371 (defun gnus-agent-add-group (category arg)
 372   "Add the current group to an agent category."
 373   (interactive
 374    (list
 375     (intern
 376      (completing-read
 377       "Add to category: "
 378       (mapcar (lambda (cat) (list (symbol-name (car cat))))
 379               gnus-category-alist)
 380       nil t))
 381     current-prefix-arg))
 382   (let ((cat (assq category gnus-category-alist))
 383         c groups)
 384     (gnus-group-iterate arg
 385       (lambda (group)
 386         (when (cadddr (setq c (gnus-group-category group)))
 387           (setf (cadddr c) (delete group (cadddr c))))
 388         (push group groups)))
 389     (setf (cadddr cat) (nconc (cadddr cat) groups))
 390     (gnus-category-write)))
 391
 392 ;;;
 393 ;;; Server mode commands
 394 ;;;
 395
 396 (defun gnus-agent-add-server (server)
 397   "Enroll SERVER in the agent program."
 398   (interactive (list (gnus-server-server-name)))
 399   (unless server
 400     (error "No server on the current line"))
 401   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 402     (when (member method gnus-agent-covered-methods)
 403       (error "Server already in the agent program"))
 404     (push method gnus-agent-covered-methods)
 405     (gnus-agent-write-servers)
 406     (message "Entered %s into the Agent" server)))
 407
 408 (defun gnus-agent-remove-server (server)
 409   "Remove SERVER from the agent program."
 410   (interactive (list (gnus-server-server-name)))
 411   (unless server
 412     (error "No server on the current line"))
 413   (let ((method (gnus-server-get-method nil (gnus-server-server-name))))
 414     (unless (member method gnus-agent-covered-methods)
 415       (error "Server not in the agent program"))
 416     (setq gnus-agent-covered-methods
 417           (delete method gnus-agent-covered-methods))
 418     (gnus-agent-write-servers)
 419     (message "Removed %s from the agent" server)))
 420
 421 (defun gnus-agent-read-servers ()
 422   "Read the alist of covered servers."
 423   (setq gnus-agent-covered-methods
 424         (gnus-agent-read-file
 425          (nnheader-concat gnus-agent-directory "lib/servers"))))
 426
 427 (defun gnus-agent-write-servers ()
 428   "Write the alist of covered servers."
 429   (nnheader-temp-write (nnheader-concat gnus-agent-directory "lib/servers")
 430     (prin1 gnus-agent-covered-methods (current-buffer))))
 431
 432 ;;;
 433 ;;; Summary commands
 434 ;;;
 435
 436 (defun gnus-agent-mark-article (n &optional unmark)
 437   "Mark the next N articles as downloadable.
 438 If N is negative, mark backward instead.  If UNMARK is non-nil, remove
 439 the mark instead.  The difference between N and the actual number of
 440 articles marked is returned."
 441   (interactive "p")
 442   (let ((backward (< n 0))
 443         (n (abs n)))
 444     (while (and
 445             (> n 0)
 446             (progn
 447               (gnus-summary-set-agent-mark
 448                (gnus-summary-article-number) unmark)
 449               (zerop (gnus-summary-next-subject (if backward -1 1) nil t))))
 450       (setq n (1- n)))
 451     (when (/= 0 n)
 452       (gnus-message 7 "No more articles"))
 453     (gnus-summary-recenter)
 454     (gnus-summary-position-point)
 455     n))
 456
 457 (defun gnus-agent-unmark-article (n)
 458   "Remove the downloadable mark from the next N articles.
 459 If N is negative, unmark backward instead.  The difference between N and
 460 the actual number of articles unmarked is returned."
 461   (interactive "p")
 462   (gnus-agent-mark-article n t))
 463
 464 (defun gnus-agent-toggle-mark (n)
 465   "Toggle the downloadable mark from the next N articles.
 466 If N is negative, toggle backward instead.  The difference between N and
 467 the actual number of articles toggled is returned."
 468   (interactive "p")
 469   (gnus-agent-mark-article n 'toggle))
 470
 471 (defun gnus-summary-set-agent-mark (article &optional unmark)
 472   "Mark ARTICLE as downloadable."
 473   (let ((unmark (if (and (not (null unmark)) (not (eq t unmark)))
 474                     (memq article gnus-newsgroup-downloadable)
 475                   unmark)))
 476     (if unmark
 477         (progn
 478           (setq gnus-newsgroup-downloadable
 479                 (delq article gnus-newsgroup-downloadable))
 480           (push article gnus-newsgroup-undownloaded))
 481       (setq gnus-newsgroup-undownloaded
 482             (delq article gnus-newsgroup-undownloaded))
 483       (push article gnus-newsgroup-downloadable))
 484     (gnus-summary-update-mark
 485      (if unmark gnus-undownloaded-mark gnus-downloadable-mark)
 486      'unread)))
 487
 488 (defun gnus-agent-get-undownloaded-list ()
 489   "Mark all unfetched articles as read."
 490   (let ((gnus-command-method (gnus-find-method-for-group gnus-newsgroup-name)))
 491     (when (and (not gnus-plugged)
 492                (gnus-agent-method-p gnus-command-method))
 493       (gnus-agent-load-alist gnus-newsgroup-name)
 494       (let ((articles gnus-newsgroup-unreads)
 495             article)
 496         (while (setq article (pop articles))
 497           (unless (or (cdr (assq article gnus-agent-article-alist))
 498                   (memq article gnus-newsgroup-downloadable))
 499             (push article gnus-newsgroup-undownloaded)))))))
 500
 501 (defun gnus-agent-catchup ()
 502   "Mark all undownloaded articles as read."
 503   (interactive)
 504   (save-excursion
 505     (while gnus-newsgroup-undownloaded
 506       (gnus-summary-mark-article
 507        (pop gnus-newsgroup-undownloaded) gnus-catchup-mark)))
 508   (gnus-summary-position-point))
 509
 510 ;;;
 511 ;;; Internal functions
 512 ;;;
 513
 514 (defun gnus-agent-save-active (method)
 515   (when (gnus-agent-method-p method)
 516     (let* ((gnus-command-method method)
 517            (file (gnus-agent-lib-file "active")))
 518       (gnus-make-directory (file-name-directory file))
 519       (let ((coding-system-for-write gnus-agent-article-file-coding-system))
 520         (write-region (point-min) (point-max) file nil 'silent))
 521       (when (file-exists-p (gnus-agent-lib-file "groups"))
 522         (delete-file (gnus-agent-lib-file "groups"))))))
 523
 524 (defun gnus-agent-save-groups (method)
 525   (let* ((gnus-command-method method)
 526          (file (gnus-agent-lib-file "groups")))
 527     (gnus-make-directory (file-name-directory file))
 528     (write-region (point-min) (point-max) file nil 'silent))
 529     (when (file-exists-p (gnus-agent-lib-file "active"))
 530       (delete-file (gnus-agent-lib-file "active"))))
 531
 532 (defun gnus-agent-save-group-info (method group active)
 533   (when (gnus-agent-method-p method)
 534     (let* ((gnus-command-method method)
 535            (file (gnus-agent-lib-file "active")))
 536       (gnus-make-directory (file-name-directory file))
 537       (nnheader-temp-write file
 538         (insert-file-contents file)
 539         (goto-char (point-min))
 540         (when (re-search-forward (concat "^" (regexp-quote group) " ") nil t)
 541           (gnus-delete-line))
 542         (insert group " " (number-to-string (cdr active)) " "
 543                 (number-to-string (car active)) "\n")))))
 544
 545 (defun gnus-agent-group-path (group)
 546   "Translate GROUP into a path."
 547   (if nnmail-use-long-file-names
 548       (gnus-group-real-name group)
 549     (nnheader-replace-chars-in-string
 550      (nnheader-translate-file-chars (gnus-group-real-name group))
 551      ?. ?/)))
 552
 553 \f
 554
 555 (defun gnus-agent-method-p (method)
 556   "Say whether METHOD is covered by the agent."
 557   (member method gnus-agent-covered-methods))
 558
 559 (defun gnus-agent-get-function (method)
 560   (if (and (not gnus-plugged)
 561            (gnus-agent-method-p method))
 562       (progn
 563         (require 'nnagent)
 564         'nnagent)
 565     (car method)))
 566
 567 ;;; History functions
 568
 569 (defun gnus-agent-history-buffer ()
 570   (cdr (assoc (gnus-agent-method) gnus-agent-history-buffers)))
 571
 572 (defun gnus-agent-open-history ()
 573   (save-excursion
 574     (push (cons (gnus-agent-method)
 575                 (set-buffer (get-buffer-create
 576                              (format " *Gnus agent %s history*"
 577                                      (gnus-agent-method)))))
 578           gnus-agent-history-buffers)
 579     (erase-buffer)
 580     (insert "\n")
 581     (let ((file (gnus-agent-lib-file "history")))
 582       (when (file-exists-p file)
 583         (insert-file file))
 584       (set (make-local-variable 'gnus-agent-file-name) file))))
 585
 586 (defun gnus-agent-save-history ()
 587   (save-excursion
 588     (set-buffer gnus-agent-current-history)
 589     (gnus-make-directory (file-name-directory gnus-agent-file-name))
 590     (write-region (1+ (point-min)) (point-max)
 591                   gnus-agent-file-name nil 'silent)))
 592
 593 (defun gnus-agent-close-history ()
 594   (when (gnus-buffer-live-p gnus-agent-current-history)
 595     (kill-buffer gnus-agent-current-history)
 596     (setq gnus-agent-history-buffers
 597           (delq (assoc (gnus-agent-method) gnus-agent-history-buffers)
 598                 gnus-agent-history-buffers))))
 599
 600 (defun gnus-agent-enter-history (id group-arts date)
 601   (save-excursion
 602     (set-buffer gnus-agent-current-history)
 603     (goto-char (point-max))
 604     (insert id "\t" (number-to-string date) "\t")
 605     (while group-arts
 606       (insert (caar group-arts) " " (number-to-string (cdr (pop group-arts)))
 607               " "))
 608     (insert "\n")))
 609
 610 (defun gnus-agent-article-in-history-p (id)
 611   (save-excursion
 612     (set-buffer (gnus-agent-history-buffer))
 613     (goto-char (point-min))
 614     (search-forward (concat "\n" id "\t") nil t)))
 615
 616 (defun gnus-agent-history-path (id)
 617   (save-excursion
 618     (set-buffer (gnus-agent-history-buffer))
 619     (goto-char (point-min))
 620     (when (search-forward (concat "\n" id "\t") nil t)
 621       (let ((method (gnus-agent-method)))
 622         (let (paths group)
 623           (while (not (numberp (setq group (read (current-buffer)))))
 624             (push (concat method "/" group) paths))
 625           (nreverse paths))))))
 626
 627 ;;;
 628 ;;; Fetching
 629 ;;;
 630
 631 (defun gnus-agent-fetch-articles (group articles)
 632   "Fetch ARTICLES from GROUP and put them into the Agent."
 633   (when articles
 634     ;; Prune off articles that we have already fetched.
 635     (while (and articles
 636                 (cdr (assq (car articles) gnus-agent-article-alist)))
 637       (pop articles))
 638     (let ((arts articles))
 639       (while (cdr arts)
 640         (if (cdr (assq (cadr arts) gnus-agent-article-alist))
 641             (setcdr arts (cddr arts))
 642           (setq arts (cdr arts)))))
 643     (when articles
 644       (let ((dir (concat
 645                   (gnus-agent-directory)
 646                   (gnus-agent-group-path group) "/"))
 647             (date (gnus-time-to-day (current-time)))
 648             (case-fold-search t)
 649             pos alists crosses id elem)
 650         (gnus-make-directory dir)
 651         (gnus-message 7 "Fetching articles for %s..." group)
 652         ;; Fetch the articles from the backend.
 653         (if (gnus-check-backend-function 'retrieve-articles group)
 654             (setq pos (gnus-retrieve-articles articles group))
 655           (nnheader-temp-write nil
 656             (let ((buf (current-buffer))
 657                   article)
 658               (while (setq article (pop articles))
 659                 (when (gnus-request-article article group)
 660                   (goto-char (point-max))
 661                   (push (cons article (point)) pos)
 662                   (insert-buffer-substring nntp-server-buffer)))
 663               (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 664               (setq pos (nreverse pos)))))
 665         ;; Then save these articles into the Agent.
 666         (save-excursion
 667           (set-buffer nntp-server-buffer)
 668           (while pos
 669             (narrow-to-region (cdar pos) (or (cdadr pos) (point-max)))
 670             (goto-char (point-min))
 671             (when (search-forward "\n\n" nil t)
 672               (when (search-backward "\nXrefs: " nil t)
 673                 ;; Handle crossposting.
 674                 (skip-chars-forward "^ ")
 675                 (skip-chars-forward " ")
 676                 (setq crosses nil)
 677                 (while (looking-at "\\([^: \n]+\\):\\([0-9]+\\) +")
 678                   (push (cons (buffer-substring (match-beginning 1)
 679                                                 (match-end 1))
 680                               (buffer-substring (match-beginning 2)
 681                                                 (match-end 2)))
 682                         crosses)
 683                   (goto-char (match-end 0)))
 684                 (gnus-agent-crosspost crosses (caar pos))))
 685             (goto-char (point-min))
 686             (if (not (re-search-forward "^Message-ID: *<\\([^>\n]+\\)>" nil t))
 687                 (setq id "No-Message-ID-in-article")
 688               (setq id (buffer-substring (match-beginning 1) (match-end 1))))
 689             (let ((coding-system-for-write
 690                    gnus-agent-article-file-coding-system))
 691               (write-region (point-min) (point-max)
 692                             (concat dir (number-to-string (caar pos)))
 693                             nil 'silent))
 694             (when (setq elem (assq (caar pos) gnus-agent-article-alist))
 695               (setcdr elem t))
 696             (gnus-agent-enter-history
 697              id (or crosses (list (cons group (caar pos)))) date)
 698             (widen)
 699             (pop pos)))
 700         (gnus-agent-save-alist group)))))
 701
 702 (defun gnus-agent-crosspost (crosses article)
 703   (let (gnus-agent-article-alist group alist beg end)
 704     (save-excursion
 705       (set-buffer gnus-agent-overview-buffer)
 706       (when (nnheader-find-nov-line article)
 707         (forward-word 1)
 708         (setq beg (point))
 709         (setq end (progn (forward-line 1) (point)))))
 710     (while crosses
 711       (setq group (caar crosses))
 712       (unless (setq alist (assoc group gnus-agent-group-alist))
 713         (push (setq alist (list group (gnus-agent-load-alist (caar crosses))))
 714               gnus-agent-group-alist))
 715       (setcdr alist (cons (cons (cdar crosses) t) (cdr alist)))
 716       (save-excursion
 717         (set-buffer (get-buffer-create (format " *Gnus agent overview %s*"
 718                                                group)))
 719         (when (= (point-max) (point-min))
 720           (push (cons group (current-buffer)) gnus-agent-buffer-alist)
 721           (ignore-errors
 722             (insert-file-contents
 723              (gnus-agent-article-name ".overview" group))))
 724         (nnheader-find-nov-line (string-to-number (cdar crosses)))
 725         (insert (string-to-number (cdar crosses)))
 726         (insert-buffer-substring gnus-agent-overview-buffer beg end))
 727       (pop crosses))))
 728
 729 (defun gnus-agent-flush-cache ()
 730   (save-excursion
 731     (while gnus-agent-buffer-alist
 732       (set-buffer (cdar gnus-agent-buffer-alist))
 733       (write-region (point-min) (point-max)
 734                     (gnus-agent-article-name ".overview"
 735                                              (caar gnus-agent-buffer-alist))
 736                      nil 'silent)
 737       (pop gnus-agent-buffer-alist))
 738     (while gnus-agent-group-alist
 739       (nnheader-temp-write (caar gnus-agent-group-alist)
 740         (princ (cdar gnus-agent-group-alist))
 741         (insert "\n"))
 742       (pop gnus-agent-group-alist))))
 743
 744 (defun gnus-agent-fetch-headers (group articles &optional force)
 745   (gnus-agent-load-alist group)
 746   ;; Find out what headers we need to retrieve.
 747   (when articles
 748     (while (and articles
 749                 (assq (car articles) gnus-agent-article-alist))
 750       (pop articles))
 751     (let ((arts articles))
 752       (while (cdr arts)
 753         (if (assq (cadr arts) gnus-agent-article-alist)
 754             (setcdr arts (cddr arts))
 755           (setq arts (cdr arts)))))
 756     ;; Fetch them.
 757     (when articles
 758       (gnus-message 7 "Fetching headers for %s..." group)
 759       (save-excursion
 760         (set-buffer nntp-server-buffer)
 761         (unless (eq 'nov (gnus-retrieve-headers articles group))
 762           (nnvirtual-convert-headers))
 763         ;; Save these headers for later processing.
 764         (copy-to-buffer gnus-agent-overview-buffer (point-min) (point-max))
 765         (let (file)
 766           (when (file-exists-p
 767                  (setq file (gnus-agent-article-name ".overview" group)))
 768             (gnus-agent-braid-nov group articles file))
 769           (gnus-make-directory (nnheader-translate-file-chars
 770                                 (file-name-directory file)))
 771           (write-region (point-min) (point-max) file nil 'silent)
 772           (gnus-agent-save-alist group articles nil)
 773           (gnus-agent-enter-history "last-header-fetched-for-session"
 774                                     (list (cons group (nth (- (length  articles) 1) articles)))
 775                                     (gnus-time-to-day (current-time)))
 776         t)))))
 777
 778 (defsubst gnus-agent-copy-nov-line (article)
 779   (let (b e)
 780     (set-buffer gnus-agent-overview-buffer)
 781     (setq b (point))
 782     (if (eq article (read (current-buffer)))
 783         (setq e (progn (forward-line 1) (point)))
 784       (setq e b))
 785     (set-buffer nntp-server-buffer)
 786     (insert-buffer-substring gnus-agent-overview-buffer b e)))
 787
 788 (defun gnus-agent-braid-nov (group articles file)
 789   (let (beg end)
 790     (set-buffer gnus-agent-overview-buffer)
 791     (goto-char (point-min))
 792     (set-buffer nntp-server-buffer)
 793     (erase-buffer)
 794     (insert-file-contents file)
 795     (goto-char (point-min))
 796     (if (or (= (point-min) (point-max))
 797             (progn
 798               (forward-line -1)
 799               (< (read (current-buffer)) (car articles))))
 800         ;; We have only headers that are after the older headers,
 801         ;; so we just append them.
 802         (progn
 803           (goto-char (point-max))
 804           (insert-buffer-substring gnus-agent-overview-buffer))
 805       ;; We do it the hard way.
 806       (nnheader-find-nov-line (car articles))
 807       (gnus-agent-copy-nov-line (car articles))
 808       (pop articles)
 809       (while (and articles
 810                   (not (eobp)))
 811         (while (and (not (eobp))
 812                     (< (read (current-buffer)) (car articles)))
 813           (forward-line 1))
 814         (beginning-of-line)
 815         (unless (eobp)
 816           (gnus-agent-copy-nov-line (car articles))
 817           (setq articles (cdr articles))))
 818       (when articles
 819         (let (b e)
 820           (set-buffer gnus-agent-overview-buffer)
 821           (setq b (point)
 822                 e (point-max))
 823           (set-buffer nntp-server-buffer)
 824           (insert-buffer-substring gnus-agent-overview-buffer b e))))))
 825
 826 (defun gnus-agent-load-alist (group &optional dir)
 827   "Load the article-state alist for GROUP."
 828   (setq gnus-agent-article-alist
 829         (gnus-agent-read-file
 830          (if dir
 831              (concat dir ".agentview")
 832            (gnus-agent-article-name ".agentview" group)))))
 833
 834 (defun gnus-agent-save-alist (group &optional articles state dir)
 835   "Load the article-state alist for GROUP."
 836   (nnheader-temp-write (if dir
 837                            (concat dir ".agentview")
 838                          (gnus-agent-article-name ".agentview" group))
 839     (princ (setq gnus-agent-article-alist
 840                  (nconc gnus-agent-article-alist
 841                         (mapcar (lambda (article) (cons article state))
 842                                 articles)))
 843            (current-buffer))
 844     (insert "\n")))
 845
 846 (defun gnus-agent-article-name (article group)
 847   (concat (gnus-agent-directory) (gnus-agent-group-path group) "/"
 848           (if (stringp article) article (string-to-number article))))
 849
 850 ;;;###autoload
 851 (defun gnus-agent-batch-fetch ()
 852   "Start Gnus and fetch session."
 853   (interactive)
 854   (gnus)
 855   (gnus-agent-fetch-session)
 856   (gnus-group-exit))
 857
 858 (defun gnus-agent-fetch-session ()
 859   "Fetch all articles and headers that are eligible for fetching."
 860   (interactive)
 861   (unless gnus-agent-covered-methods
 862     (error "No servers are covered by the Gnus agent"))
 863   (unless gnus-plugged
 864     (error "Can't fetch articles while Gnus is unplugged"))
 865   (let ((methods gnus-agent-covered-methods)
 866         groups group gnus-command-method)
 867     (save-excursion
 868       (while methods
 869         (setq gnus-command-method (car methods))
 870         (when (or (gnus-server-opened gnus-command-method)
 871                   (gnus-open-server gnus-command-method))
 872           (setq groups (gnus-groups-from-server (car methods)))
 873           (gnus-agent-with-fetch
 874             (while (setq group (pop groups))
 875               (when (<= (gnus-group-level group) gnus-agent-handle-level)
 876                 (gnus-agent-fetch-group-1 group gnus-command-method)))))
 877         (pop methods))
 878       (gnus-message 6 "Finished fetching articles into the Gnus agent"))))
 879
 880 (defun gnus-agent-fetch-group-1 (group method)
 881   "Fetch GROUP."
 882   (let ((gnus-command-method method)
 883         gnus-newsgroup-dependencies gnus-newsgroup-headers
 884         gnus-newsgroup-scored gnus-headers gnus-score
 885         gnus-use-cache articles score arts
 886         category predicate info marks score-param)
 887     ;; Fetch headers.
 888     (when (and (or (gnus-active group) (gnus-activate-group group))
 889                (setq articles (gnus-list-of-unread-articles group))
 890                (gnus-agent-fetch-headers group articles))
 891       ;; Parse them and see which articles we want to fetch.
 892       (setq gnus-newsgroup-dependencies
 893             (make-vector (length articles) 0))
 894       (setq gnus-newsgroup-headers
 895             (gnus-get-newsgroup-headers-xover articles nil nil group))
 896       (setq category (gnus-group-category group))
 897       (setq predicate
 898             (gnus-get-predicate
 899              (or (gnus-group-get-parameter group 'agent-predicate)
 900                  (cadr category))))
 901       (setq score-param
 902             (or (gnus-group-get-parameter group 'agent-score)
 903                 (caddr category)))
 904       (when score-param
 905         (gnus-score-headers (list (list score-param))))
 906       (setq arts nil)
 907       (while (setq gnus-headers (pop gnus-newsgroup-headers))
 908         (setq gnus-score
 909               (or (cdr (assq (mail-header-number gnus-headers)
 910                              gnus-newsgroup-scored))
 911                   gnus-summary-default-score))
 912         (when (funcall predicate)
 913           (push (mail-header-number gnus-headers)
 914                 arts)))
 915       ;; Fetch the articles.
 916       (when arts
 917         (gnus-agent-fetch-articles group arts)))
 918     ;; Perhaps we have some additional articles to fetch.
 919     (setq arts (assq 'download (gnus-info-marks
 920                                 (setq info (gnus-get-info group)))))
 921     (when (cdr arts)
 922       (gnus-agent-fetch-articles
 923        group (gnus-uncompress-range (cdr arts)))
 924       (setq marks (delq arts (gnus-info-marks info)))
 925       (gnus-info-set-marks info marks))))
 926
 927 ;;;
 928 ;;; Agent Category Mode
 929 ;;;
 930
 931 (defvar gnus-category-mode-hook nil
 932   "Hook run in `gnus-category-mode' buffers.")
 933
 934 (defvar gnus-category-line-format "     %(%20c%): %g\n"
 935   "Format of category lines.")
 936
 937 (defvar gnus-category-mode-line-format "Gnus: %%b"
 938   "The format specification for the category mode line.")
 939
 940 (defvar gnus-agent-short-article 100
 941   "Articles that have fewer lines than this are short.")
 942
 943 (defvar gnus-agent-long-article 200
 944   "Articles that have more lines than this are long.")
 945
 946 (defvar gnus-agent-low-score 0
 947   "Articles that have a score lower than this have a low score.")
 948
 949 (defvar gnus-agent-high-score 0
 950   "Articles that have a score higher than this have a high score.")
 951
 952
 953 ;;; Internal variables.
 954
 955 (defvar gnus-category-buffer "*Agent Category*")
 956
 957 (defvar gnus-category-line-format-alist
 958   `((?c name ?s)
 959     (?g groups ?d)))
 960
 961 (defvar gnus-category-mode-line-format-alist
 962   `((?u user-defined ?s)))
 963
 964 (defvar gnus-category-line-format-spec nil)
 965 (defvar gnus-category-mode-line-format-spec nil)
 966
 967 (defvar gnus-category-mode-map nil)
 968 (put 'gnus-category-mode 'mode-class 'special)
 969
 970 (unless gnus-category-mode-map
 971   (setq gnus-category-mode-map (make-sparse-keymap))
 972   (suppress-keymap gnus-category-mode-map)
 973
 974   (gnus-define-keys gnus-category-mode-map
 975     "q" gnus-category-exit
 976     "k" gnus-category-kill
 977     "c" gnus-category-copy
 978     "a" gnus-category-add
 979     "p" gnus-category-edit-predicate
 980     "g" gnus-category-edit-groups
 981     "s" gnus-category-edit-score
 982     "l" gnus-category-list
 983
 984     "\C-c\C-i" gnus-info-find-node
 985     "\C-c\C-b" gnus-bug))
 986
 987 (defvar gnus-category-menu-hook nil
 988   "*Hook run after the creation of the menu.")
 989
 990 (defun gnus-category-make-menu-bar ()
 991   (gnus-turn-off-edit-menu 'category)
 992   (unless (boundp 'gnus-category-menu)
 993     (easy-menu-define
 994      gnus-category-menu gnus-category-mode-map ""
 995      '("Categories"
 996        ["Add" gnus-category-add t]
 997        ["Kill" gnus-category-kill t]
 998        ["Copy" gnus-category-copy t]
 999        ["Edit predicate" gnus-category-edit-predicate t]
1000        ["Edit score" gnus-category-edit-score t]
1001        ["Edit groups" gnus-category-edit-groups t]
1002        ["Exit" gnus-category-exit t]))
1003
1004     (gnus-run-hooks 'gnus-category-menu-hook)))
1005
1006 (defun gnus-category-mode ()
1007   "Major mode for listing and editing agent categories.
1008
1009 All normal editing commands are switched off.
1010 \\<gnus-category-mode-map>
1011 For more in-depth information on this mode, read the manual
1012 (`\\[gnus-info-find-node]').
1013
1014 The following commands are available:
1015
1016 \\{gnus-category-mode-map}"
1017   (interactive)
1018   (when (gnus-visual-p 'category-menu 'menu)
1019     (gnus-category-make-menu-bar))
1020   (kill-all-local-variables)
1021   (gnus-simplify-mode-line)
1022   (setq major-mode 'gnus-category-mode)
1023   (setq mode-name "Category")
1024   (gnus-set-default-directory)
1025   (setq mode-line-process nil)
1026   (use-local-map gnus-category-mode-map)
1027   (buffer-disable-undo (current-buffer))
1028   (setq truncate-lines t)
1029   (setq buffer-read-only t)
1030   (gnus-run-hooks 'gnus-category-mode-hook))
1031
1032 (defalias 'gnus-category-position-point 'gnus-goto-colon)
1033
1034 (defun gnus-category-insert-line (category)
1035   (let* ((name (car category))
1036          (groups (length (cadddr category))))
1037     (beginning-of-line)
1038     (gnus-add-text-properties
1039      (point)
1040      (prog1 (1+ (point))
1041        ;; Insert the text.
1042        (eval gnus-category-line-format-spec))
1043      (list 'gnus-category name))))
1044
1045 (defun gnus-enter-category-buffer ()
1046   "Go to the Category buffer."
1047   (interactive)
1048   (gnus-category-setup-buffer)
1049   (gnus-configure-windows 'category)
1050   (gnus-category-prepare))
1051
1052 (defun gnus-category-setup-buffer ()
1053   (unless (get-buffer gnus-category-buffer)
1054     (save-excursion
1055       (set-buffer (get-buffer-create gnus-category-buffer))
1056       (gnus-add-current-to-buffer-list)
1057       (gnus-category-mode))))
1058
1059 (defun gnus-category-prepare ()
1060   (gnus-set-format 'category-mode)
1061   (gnus-set-format 'category t)
1062   (let ((alist gnus-category-alist)
1063         (buffer-read-only nil))
1064     (erase-buffer)
1065     (while alist
1066       (gnus-category-insert-line (pop alist)))
1067     (goto-char (point-min))
1068     (gnus-category-position-point)))
1069
1070 (defun gnus-category-name ()
1071   (or (get-text-property (gnus-point-at-bol) 'gnus-category)
1072       (error "No category on the current line")))
1073
1074 (defun gnus-category-read ()
1075   "Read the category alist."
1076   (setq gnus-category-alist
1077         (or (gnus-agent-read-file
1078              (nnheader-concat gnus-agent-directory "lib/categories"))
1079             (list (list 'default 'short nil nil)))))
1080
1081 (defun gnus-category-write ()
1082   "Write the category alist."
1083   (setq gnus-category-predicate-cache nil
1084         gnus-category-group-cache nil)
1085   (nnheader-temp-write (nnheader-concat gnus-agent-directory "lib/categories")
1086     (prin1 gnus-category-alist (current-buffer))))
1087
1088 (defun gnus-category-edit-predicate (category)
1089   "Edit the predicate for CATEGORY."
1090   (interactive (list (gnus-category-name)))
1091   (let ((info (assq category gnus-category-alist)))
1092     (gnus-edit-form
1093      (cadr info) (format "Editing the predicate for category %s" category)
1094      `(lambda (predicate)
1095         (setf (cadr (assq ',category gnus-category-alist)) predicate)
1096         (gnus-category-write)
1097         (gnus-category-list)))))
1098
1099 (defun gnus-category-edit-score (category)
1100   "Edit the score expression for CATEGORY."
1101   (interactive (list (gnus-category-name)))
1102   (let ((info (assq category gnus-category-alist)))
1103     (gnus-edit-form
1104      (caddr info)
1105      (format "Editing the score expression for category %s" category)
1106      `(lambda (groups)
1107         (setf (caddr (assq ',category gnus-category-alist)) groups)
1108         (gnus-category-write)
1109         (gnus-category-list)))))
1110
1111 (defun gnus-category-edit-groups (category)
1112   "Edit the group list for CATEGORY."
1113   (interactive (list (gnus-category-name)))
1114   (let ((info (assq category gnus-category-alist)))
1115     (gnus-edit-form
1116      (cadddr info) (format "Editing the group list for category %s" category)
1117      `(lambda (groups)
1118         (setf (cadddr (assq ',category gnus-category-alist)) groups)
1119         (gnus-category-write)
1120         (gnus-category-list)))))
1121
1122 (defun gnus-category-kill (category)
1123   "Kill the current category."
1124   (interactive (list (gnus-category-name)))
1125   (let ((info (assq category gnus-category-alist))
1126         (buffer-read-only nil))
1127     (gnus-delete-line)
1128     (gnus-category-write)
1129     (setq gnus-category-alist (delq info gnus-category-alist))))
1130
1131 (defun gnus-category-copy (category to)
1132   "Copy the current category."
1133   (interactive (list (gnus-category-name) (intern (read-string "New name: "))))
1134   (let ((info (assq category gnus-category-alist)))
1135     (push (list to (gnus-copy-sequence (cadr info))
1136                 (gnus-copy-sequence (caddr info)) nil)
1137           gnus-category-alist)
1138     (gnus-category-write)
1139     (gnus-category-list)))
1140
1141 (defun gnus-category-add (category)
1142   "Create a new category."
1143   (interactive "SCategory name: ")
1144   (when (assq category gnus-category-alist)
1145     (error "Category %s already exists" category))
1146   (push (list category 'true nil nil)
1147         gnus-category-alist)
1148   (gnus-category-write)
1149   (gnus-category-list))
1150
1151 (defun gnus-category-list ()
1152   "List all categories."
1153   (interactive)
1154   (gnus-category-prepare))
1155
1156 (defun gnus-category-exit ()
1157   "Return to the group buffer."
1158   (interactive)
1159   (kill-buffer (current-buffer))
1160   (gnus-configure-windows 'group t))
1161
1162 ;; To avoid having 8-bit characters in the source file.
1163 (defvar gnus-category-not (list '! 'not (intern (format "%c" 172))))
1164
1165 (defvar gnus-category-predicate-alist
1166   '((spam . gnus-agent-spam-p)
1167     (short . gnus-agent-short-p)
1168     (long . gnus-agent-long-p)
1169     (low . gnus-agent-low-scored-p)
1170     (high . gnus-agent-high-scored-p)
1171     (true . gnus-agent-true)
1172     (false . gnus-agent-false))
1173   "Mapping from short score predicate symbols to predicate functions.")
1174
1175 (defun gnus-agent-spam-p ()
1176   "Say whether an article is spam or not."
1177   (unless gnus-agent-spam-hashtb
1178     (setq gnus-agent-spam-hashtb (gnus-make-hashtable 1000)))
1179   (if (not (equal (mail-header-references gnus-headers) ""))
1180       nil
1181     (let ((string (gnus-simplify-subject (mail-header-subject gnus-headers))))
1182       (prog1
1183           (gnus-gethash string gnus-agent-spam-hashtb)
1184         (gnus-sethash string t gnus-agent-spam-hashtb)))))
1185
1186 (defun gnus-agent-short-p ()
1187   "Say whether an article is short or not."
1188   (< (mail-header-lines gnus-headers) gnus-agent-short-article))
1189
1190 (defun gnus-agent-long-p ()
1191   "Say whether an article is long or not."
1192   (> (mail-header-lines gnus-headers) gnus-agent-long-article))
1193
1194 (defun gnus-agent-low-scored-p ()
1195   "Say whether an article has a low score or not."
1196   (< gnus-score gnus-agent-low-score))
1197
1198 (defun gnus-agent-high-scored-p ()
1199   "Say whether an article has a high score or not."
1200   (> gnus-score gnus-agent-high-score))
1201
1202 (defun gnus-category-make-function (cat)
1203   "Make a function from category CAT."
1204   `(lambda () ,(gnus-category-make-function-1 cat)))
1205
1206 (defun gnus-agent-true ()
1207   "Return t."
1208   t)
1209
1210 (defun gnus-agent-false ()
1211   "Return nil."
1212   nil)
1213
1214 (defun gnus-category-make-function-1 (cat)
1215   "Make a function from category CAT."
1216   (cond
1217    ;; Functions are just returned as is.
1218    ((or (symbolp cat)
1219         (gnus-functionp cat))
1220     `(,(or (cdr (assq cat gnus-category-predicate-alist))
1221            cat)))
1222    ;; More complex category.
1223    ((consp cat)
1224     `(,(cond
1225         ((memq (car cat) '(& and))
1226          'and)
1227         ((memq (car cat) '(| or))
1228          'or)
1229         ((memq (car cat) gnus-category-not)
1230          'not))
1231       ,@(mapcar 'gnus-category-make-function-1 (cdr cat))))
1232    (t
1233     (error "Unknown category type: %s" cat))))
1234
1235 (defun gnus-get-predicate (predicate)
1236   "Return the predicate for CATEGORY."
1237   (or (cdr (assoc predicate gnus-category-predicate-cache))
1238       (cdar (push (cons predicate
1239                         (gnus-category-make-function predicate))
1240                   gnus-category-predicate-cache))))
1241
1242 (defun gnus-group-category (group)
1243   "Return the category GROUP belongs to."
1244   (unless gnus-category-group-cache
1245     (setq gnus-category-group-cache (gnus-make-hashtable 1000))
1246     (let ((cs gnus-category-alist)
1247           groups cat)
1248       (while (setq cat (pop cs))
1249         (setq groups (cadddr cat))
1250         (while groups
1251           (gnus-sethash (pop groups) cat gnus-category-group-cache)))))
1252   (or (gnus-gethash group gnus-category-group-cache)
1253       (assq 'default gnus-category-alist)))
1254
1255 (defun gnus-agent-expire ()
1256   "Expire all old articles."
1257   (interactive)
1258   (let ((methods gnus-agent-covered-methods)
1259         (day (- (gnus-time-to-day (current-time)) gnus-agent-expire-days))
1260         gnus-command-method sym group articles
1261         history overview file histories elem art nov-file low info
1262         unreads marked article)
1263     (save-excursion
1264       (setq overview (get-buffer-create " *expire overview*"))
1265       (while (setq gnus-command-method (pop methods))
1266         (let ((expiry-hashtb (gnus-make-hashtable 1023)))
1267         (gnus-agent-open-history)
1268         (set-buffer
1269          (setq gnus-agent-current-history
1270                (setq history (gnus-agent-history-buffer))))
1271         (goto-char (point-min))
1272         (when (> (buffer-size) 1)
1273           (goto-char (point-min))
1274           (while (not (eobp))
1275             (skip-chars-forward "^\t")
1276             (if (> (read (current-buffer)) day)
1277                 ;; New article; we don't expire it.
1278                 (forward-line 1)
1279               ;; Old article.  Schedule it for possible nuking.
1280               (while (not (eolp))
1281                 (setq sym (let ((obarray expiry-hashtb))
1282                             (read (current-buffer))))
1283                 (if (boundp sym)
1284                     (set sym (cons (cons (read (current-buffer)) (point))
1285                                    (symbol-value sym)))
1286                   (set sym (list (cons (read (current-buffer)) (point)))))
1287                 (skip-chars-forward " "))
1288               (forward-line 1)))
1289           ;; We now have all articles that can possibly be expired.
1290           (mapatoms
1291            (lambda (sym)
1292              (setq group (symbol-name sym)
1293                    articles (sort (symbol-value sym) 'car-less-than-car)
1294                    low (car (gnus-active group))
1295                    info (gnus-get-info group)
1296                    unreads (ignore-errors (gnus-list-of-unread-articles group))
1297                    marked (nconc (gnus-uncompress-range
1298                                   (cdr (assq 'tick (gnus-info-marks info))))
1299                                  (gnus-uncompress-range
1300                                   (cdr (assq 'dormant
1301                                              (gnus-info-marks info)))))
1302                    nov-file (gnus-agent-article-name ".overview" group))
1303              (gnus-agent-load-alist group)
1304              (gnus-message 5 "Expiring articles in %s" group)
1305              (set-buffer overview)
1306              (erase-buffer)
1307              (when (file-exists-p nov-file)
1308                (insert-file-contents nov-file))
1309              (goto-char (point-min))
1310              (setq article 0)
1311              (while (setq elem (pop articles))
1312                (setq article (car elem))
1313                (when (or (null low)
1314                          (< article low)
1315                          gnus-agent-expire-all
1316                          (and (not (memq article unreads))
1317                               (not (memq article marked))))
1318                  ;; Find and nuke the NOV line.
1319                  (while (and (not (eobp))
1320                              (or (not (numberp
1321                                        (setq art (read (current-buffer)))))
1322                                  (< art article)))
1323                    (if (file-exists-p
1324                         (gnus-agent-article-name
1325                          (number-to-string art) group))
1326                        (forward-line 1)
1327                      ;; Remove old NOV lines that have no articles.
1328                      (gnus-delete-line)))
1329                  (if (or (eobp)
1330                          (/= art article))
1331                      (beginning-of-line)
1332                    (gnus-delete-line))
1333                  ;; Nuke the article.
1334                  (when (file-exists-p (setq file (gnus-agent-article-name
1335                                                   (number-to-string article)
1336                                                   group)))
1337                    (delete-file file))
1338                  ;; Schedule the history line for nuking.
1339                  (push (cdr elem) histories)))
1340              (write-region (point-min) (point-max) nov-file nil 'silent)
1341              ;; Delete the unwanted entries in the alist.
1342              (setq gnus-agent-article-alist
1343                    (sort gnus-agent-article-alist 'car-less-than-car))
1344              (let* ((alist gnus-agent-article-alist)
1345                     (prev (cons nil alist))
1346                     (first prev))
1347                (while (and alist
1348                            (<= (caar alist) article))
1349                  (if (or (not (cdar alist))
1350                          (not (file-exists-p
1351                                (gnus-agent-article-name
1352                                 (number-to-string
1353                                  (caar alist))
1354                                 group))))
1355                      (setcdr prev (setq alist (cdr alist)))
1356                    (setq prev alist
1357                          alist (cdr alist))))
1358                (setq gnus-agent-article-alist (cdr first))
1359                ;;; Mark all articles up to the first article
1360                ;;; in `gnus-article-alist' as read.
1361                (setcar (nthcdr 2 info)
1362                        (gnus-range-add
1363                         (nth 2 info) (cons 1 (- (caar gnus-agent-article-alist) 1))))
1364                (gnus-dribble-enter
1365                 (concat "(gnus-group-set-info '"
1366                         (gnus-prin1-to-string info)
1367                         ")"))
1368                (gnus-agent-save-alist group)))
1369            expiry-hashtb)
1370           (set-buffer history)
1371           (setq histories (nreverse (sort histories '<)))
1372           (while histories
1373             (goto-char (pop histories))
1374             (gnus-delete-line))
1375           (gnus-agent-save-history)
1376           (gnus-agent-close-history))
1377         (gnus-message 4 "Expiry...done"))))))
1378
1379 ;;;###autoload
1380 (defun gnus-agent-batch ()
1381   (interactive)
1382   (let ((init-file-user "")
1383         (gnus-always-read-dribble-file t))
1384     (gnus))
1385   (gnus-group-send-drafts)
1386   (gnus-agent-fetch-session))
1387
1388 (provide 'gnus-agent)
1389
1390 ;;; gnus-agent.el ends here