git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-cus.el

   1 ;;; gnus-cus.el --- customization commands for Gnus
   2 ;;
   3 ;; Copyright (C) 1996, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'wid-edit)
  31 (require 'gnus)
  32 (require 'gnus-agent)
  33 (require 'gnus-score)
  34 (require 'gnus-topic)
  35 (require 'gnus-art)
  36
  37 ;;; Widgets:
  38
  39 (defun gnus-custom-mode ()
  40   "Major mode for editing Gnus customization buffers.
  41
  42 The following commands are available:
  43
  44 \\[widget-forward]              Move to next button or editable field.
  45 \\[widget-backward]             Move to previous button or editable field.
  46 \\[widget-button-click]         Activate button under the mouse pointer.
  47 \\[widget-button-press]         Activate button under point.
  48
  49 Entry to this mode calls the value of `gnus-custom-mode-hook'
  50 if that value is non-nil."
  51   (kill-all-local-variables)
  52   (setq major-mode 'gnus-custom-mode
  53         mode-name "Gnus Customize")
  54   (use-local-map widget-keymap)
  55   ;; Emacs 21 stuff:
  56   (when (and (facep 'custom-button-face)
  57              (facep 'custom-button-pressed-face))
  58     (set (make-local-variable 'widget-button-face)
  59          'custom-button-face)
  60     (set (make-local-variable 'widget-button-pressed-face)
  61          'custom-button-pressed-face)
  62     (set (make-local-variable 'widget-mouse-face)
  63          'custom-button-pressed-face))
  64   (when (and (boundp 'custom-raised-buttons)
  65              (symbol-value 'custom-raised-buttons))
  66     (set (make-local-variable 'widget-push-button-prefix) "")
  67     (set (make-local-variable 'widget-push-button-suffix) "")
  68     (set (make-local-variable 'widget-link-prefix) "")
  69     (set (make-local-variable 'widget-link-suffix) ""))
  70   (gnus-run-hooks 'gnus-custom-mode-hook))
  71
  72 ;;; Group Customization:
  73
  74 (defconst gnus-group-parameters
  75   '((extra-aliases (choice
  76                     :tag "Extra Aliases"
  77                     (list
  78                      :tag "List"
  79                      (editable-list
  80                       :inline t
  81                       (gnus-email-address :tag "Address")))
  82                     (gnus-email-address :tag "Address")) "\
  83 Store messages posted from or to this address in this group.
  84
  85 You must be using gnus-group-split for this to work.  The VALUE of the
  86 nnmail-split-fancy SPLIT generated for this group will match these
  87 addresses.")
  88
  89     (split-regexp (regexp :tag "gnus-group-split Regular Expression") "\
  90 Like gnus-group-split Address, but expects a regular expression.")
  91
  92     (split-exclude (list :tag "gnus-group-split Restricts"
  93                          (editable-list
  94                           :inline t (regexp :tag "Restrict"))) "\
  95 Regular expression that cancels gnus-group-split matches.
  96
  97 Each entry is added to the nnmail-split-fancy SPLIT as a separate
  98 RESTRICT clause.")
  99
 100     (split-spec (choice :tag "gnus-group-split Overrider"
 101                         (sexp :tag "Fancy Split")
 102                         (const :tag "Catch All" catch-all)
 103                         (const :tag "Ignore" nil)) "\
 104 Override all other gnus-group-split fields.
 105
 106 In `Fancy Split', you can enter any nnmail-split-fancy SPLIT.  Note
 107 that the name of this group won't be automatically assumed, you have
 108 to add it to the SPLITs yourself.  This means you can use such splits
 109 to split messages to other groups too.
 110
 111 If you select `Catch All', this group will get postings for any
 112 messages not matched in any other group.  It overrides the variable
 113 gnus-group-split-default-catch-all-group.
 114
 115 Selecting `Ignore' forces no SPLIT to be generated for this group,
 116 disabling all other gnus-group-split fields.")
 117
 118     (broken-reply-to (const :tag "Broken Reply To" t) "\
 119 Ignore `Reply-To' headers in this group.
 120
 121 That can be useful if you're reading a mailing list group where the
 122 listserv has inserted `Reply-To' headers that point back to the
 123 listserv itself.  This is broken behavior.  So there!")
 124
 125     (to-group (string :tag "To Group") "\
 126 All posts will be sent to the specified group.")
 127
 128     (gcc-self (choice :tag  "GCC"
 129                       :value t
 130                       (const :tag "To current group" t)
 131                       (const none)
 132                       (string :format "%v" :hide-front-space t)) "\
 133 Specify default value for GCC header.
 134
 135 If this symbol is present in the group parameter list and set to t,
 136 new composed messages will be `Gcc''d to the current group.  If it is
 137 present and set to `none', no `Gcc:' header will be generated, if it
 138 is present and a string, this string will be inserted literally as a
 139 `gcc' header (this symbol takes precedence over any default `Gcc'
 140 rules as described later).")
 141
 142     (expiry-wait (choice :tag  "Expire Wait"
 143                          :value never
 144                          (const never)
 145                          (const immediate)
 146                          (number :hide-front-space t
 147                                  :format "%v")) "\
 148 When to expire.
 149
 150 Overrides any `nnmail-expiry-wait' and `nnmail-expiry-wait-function'
 151 when expiring expirable messages.  The value can either be a number of
 152 days (not necessarily an integer) or the symbols `never' or
 153 `immediate'.")
 154
 155     (expiry-target (choice :tag "Expiry Target"
 156                            :value delete
 157                            (const delete)
 158                            (function :format "%v" nnmail-)
 159                            string) "\
 160 Where expired messages end up.
 161
 162 Overrides `nnmail-expiry-target'.")
 163
 164     (score-file (file :tag "Score File") "\
 165 Make the specified file into the current score file.
 166 This means that all score commands you issue will end up in this file.")
 167
 168     (adapt-file (file :tag "Adapt File") "\
 169 Make the specified file into the current adaptive file.
 170 All adaptive score entries will be put into this file.")
 171
 172     (admin-address (gnus-email-address :tag "Admin Address") "\
 173 Administration address for a mailing list.
 174
 175 When unsubscribing to a mailing list you should never send the
 176 unsubscription notice to the mailing list itself.  Instead, you'd
 177 send messages to the administrative address.  This parameter allows
 178 you to put the admin address somewhere convenient.")
 179
 180     (display (choice :tag "Display"
 181                      :value default
 182                      (const all)
 183                      (integer)
 184                      (const default)
 185                      (sexp  :tag "Other")) "\
 186 Which articles to display on entering the group.
 187
 188 `all'
 189      Display all articles, both read and unread.
 190
 191 `integer'
 192      Display the last NUMBER articles in the group.  This is the same as
 193      entering the group with C-u NUMBER.
 194
 195 `default'
 196      Display the default visible articles, which normally includes
 197      unread and ticked articles.
 198
 199 `Other'
 200      Display the articles that satisfy the S-expression. The S-expression
 201      should be in an array form.")
 202
 203     (comment (string :tag  "Comment") "\
 204 An arbitrary comment on the group.")
 205
 206     (visible (const :tag "Permanently visible" t) "\
 207 Always display this group, even when there are no unread articles
 208 in it..")
 209
 210     (highlight-words
 211      (choice :tag "Highlight words"
 212              :value nil
 213              (repeat (list (regexp :tag "Highlight regexp")
 214                            (number :tag "Group for entire word" 0)
 215                            (number :tag "Group for displayed part" 0)
 216                            (symbol :tag "Face"
 217                                    gnus-emphasis-highlight-words))))
 218      "highlight regexps.
 219 See `gnus-emphasis-alist'.")
 220
 221     (posting-style
 222      (choice :tag "Posting style"
 223              :value nil
 224              (repeat (list
 225                       (choice :tag "Type"
 226                               :value nil
 227                               (const signature)
 228                               (const signature-file)
 229                               (const organization)
 230                               (const address)
 231                               (const name)
 232                               (const body))
 233                       (string :format "%v"))))
 234      "post style.
 235 See `gnus-posting-styles'."))
 236   "Alist of valid group or topic parameters.
 237
 238 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 239 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 240 DOC is a documentation string for the parameter.")
 241
 242 (defconst gnus-extra-topic-parameters
 243   '((subscribe (regexp :tag "Subscribe") "\
 244 If `gnus-subscribe-newsgroup-method' or
 245 `gnus-subscribe-options-newsgroup-method' is set to
 246 `gnus-subscribe-topics', new groups that matches this regexp will
 247 automatically be subscribed to this topic")
 248     (subscribe-level (integer :tag "Subscribe Level" :value 1) "\
 249 If this topic parameter is set, when new groups are subscribed
 250 automatically under this topic (via the `subscribe' topic parameter)
 251 assign this level to the group, rather than the default level
 252 set in `gnus-level-default-subscribed'"))
 253   "Alist of topic parameters that are not also group parameters.
 254
 255 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 256 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 257 DOC is a documentation string for the parameter.")
 258
 259 (defconst gnus-extra-group-parameters
 260   '((uidvalidity (string :tag "IMAP uidvalidity") "\
 261 Server-assigned value attached to IMAP groups, used to maintain consistency."))
 262   "Alist of group parameters that are not also topic parameters.
 263
 264 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 265 itself (a symbol), TYPE is the parameters type (a sexp widget), and
 266 DOC is a documentation string for the parameter.")
 267
 268 (eval-and-compile
 269   (defconst gnus-agent-parameters
 270     '((agent-predicate
 271        (sexp :tag "Selection Predicate" :value false)
 272        "Predicate used to automatically select articles for downloading."
 273        gnus-agent-cat-predicate)
 274       (agent-score
 275        (choice :tag "Score File" :value nil
 276                (const file :tag "Use group's score files")
 277                (repeat (list (string :format "%v" :tag "File name"))))
 278        "Which score files to use when using score to select articles to fetch.
 279
 280     `nil'
 281          All articles will be scored to zero (0).
 282
 283     `file'
 284          The group's score files will be used to score the articles.
 285
 286     `List'
 287          A list of score file names."
 288        gnus-agent-cat-score-file)
 289       (agent-short-article
 290        (integer :tag "Max Length of Short Article" :value "")
 291        "The SHORT predicate will evaluate to true when the article is
 292 shorter than this length."  gnus-agent-cat-length-when-short)
 293       (agent-long-article
 294        (integer :tag "Min Length of Long Article" :value "")
 295        "The LONG predicate will evaluate to true when the article is
 296 longer than this length."  gnus-agent-cat-length-when-long)
 297       (agent-low-score
 298        (integer :tag "Low Score Limit" :value "")
 299        "The LOW predicate will evaluate to true when the article scores
 300 lower than this limit."  gnus-agent-cat-low-score)
 301       (agent-high-score
 302        (integer :tag "High Score Limit" :value "")
 303        "The HIGH predicate will evaluate to true when the article scores
 304 higher than this limit."  gnus-agent-cat-high-score)
 305       (agent-days-until-old
 306        (integer :tag "Days Until Old" :value "")
 307        "The OLD predicate will evaluate to true when the fetched article
 308 has been stored locally for at least this many days."
 309        gnus-agent-cat-days-until-old)
 310       (agent-enable-expiration
 311        (radio :tag "Expire in this Group or Topic" :value nil
 312               (const :format "Enable " ENABLE)
 313               (const :format "Disable " DISABLE))
 314        "\nEnable, or disable, agent expiration in this group or topic."
 315        gnus-agent-cat-enable-expiration)
 316       (agent-disable-undownloaded-faces
 317        (boolean :tag "Disable Agent Faces")
 318        "Have the summary buffer ignore the agent's undownloaded faces.
 319 These faces, when used, act as a warning that an article has not been
 320 fetched into either the agent nor the cache.  This is of most use to
 321 users who use the agent as a cache (i.e. they only operate on articles
 322 that have been downloaded).  Disable to display normal article faces
 323 even when the article hasn't been downloaded."
 324        gnus-agent-cat-disable-undownloaded-faces))
 325     "Alist of group parameters that are not also topic parameters.
 326
 327 Each entry has the form (NAME TYPE DOC ACCESSOR), where NAME is the
 328 parameter itself (a symbol), TYPE is the parameters type (a sexp
 329 widget), DOC is a documentation string for the parameter, and ACCESSOR
 330 is a function (symbol) that extracts the current value from the
 331 category."))
 332
 333 (defvar gnus-custom-params)
 334 (defvar gnus-custom-method)
 335 (defvar gnus-custom-group)
 336 (defvar gnus-custom-topic)
 337
 338 (defun gnus-group-customize (group &optional topic)
 339   "Edit the group or topic on the current line."
 340   (interactive (list (gnus-group-group-name) (gnus-group-topic-name)))
 341   (let (info
 342         (types (mapcar (lambda (entry)
 343                          `(cons :format "%v%h\n"
 344                                 :doc ,(nth 2 entry)
 345                                 (const :format "" ,(nth 0 entry))
 346                                 ,(nth 1 entry)))
 347                        (append (reverse gnus-group-parameters-more)
 348                                gnus-group-parameters
 349                                (if group
 350                                    gnus-extra-group-parameters
 351                                  gnus-extra-topic-parameters))))
 352         (agent (mapcar (lambda (entry)
 353                          (let ((type (nth 1 entry))
 354                                vcons)
 355                            (if (listp type)
 356                                (setq type (copy-sequence type)))
 357
 358                            (setq vcons (cdr (memq :value type)))
 359
 360                            (if (symbolp (car vcons))
 361                                (condition-case nil
 362                                    (setcar vcons (symbol-value (car vcons)))
 363                                  (error)))
 364                            `(cons :format "%v%h\n"
 365                                   :doc ,(nth 2 entry)
 366                                   (const :format "" ,(nth 0 entry))
 367                                   ,type)))
 368                        (if gnus-agent
 369                            gnus-agent-parameters))))
 370     (unless (or group topic)
 371       (error "No group on current line"))
 372     (when (and group topic)
 373       (error "Both a group an topic on current line"))
 374     (unless (or topic (setq info (gnus-get-info group)))
 375       (error "Killed group; can't be edited"))
 376     ;; Ready.
 377     (gnus-kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 378     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 379     (gnus-custom-mode)
 380     (make-local-variable 'gnus-custom-group)
 381     (setq gnus-custom-group group)
 382     (make-local-variable 'gnus-custom-topic)
 383     (setq gnus-custom-topic topic)
 384     (buffer-disable-undo)
 385     (widget-insert "Customize the ")
 386     (if group
 387         (widget-create 'info-link
 388                        :help-echo "Push me to learn more."
 389                        :tag "group parameters"
 390                        "(gnus)Group Parameters")
 391       (widget-create 'info-link
 392                      :help-echo "Push me to learn more."
 393                      :tag  "topic parameters"
 394                      "(gnus)Topic Parameters"))
 395     (widget-insert " for <")
 396     (widget-insert (gnus-group-decoded-name (or group topic)))
 397     (widget-insert "> and press ")
 398     (widget-create 'push-button
 399                    :tag "done"
 400                    :help-echo "Push me when done customizing."
 401                    :action 'gnus-group-customize-done)
 402     (widget-insert ".\n\n")
 403     (make-local-variable 'gnus-custom-params)
 404
 405     (let ((values (if group
 406                       (gnus-info-params info)
 407                     (gnus-topic-parameters topic))))
 408
 409       ;; The parameters in values may contain duplicates.  This is
 410       ;; normally OK as assq returns the first. However, right here
 411       ;; every duplicate ends up being displayed.  So, rather than
 412       ;; display them, remove them from the list.
 413
 414       (let ((tmp (setq values (gnus-copy-sequence values)))
 415             elem)
 416         (while (cdr tmp)
 417           (while (setq elem (assq (caar tmp) (cdr tmp)))
 418             (delq elem tmp))
 419           (setq tmp (cdr tmp))))
 420
 421       (setq gnus-custom-params
 422             (apply 'widget-create 'group
 423                    :value values
 424                    (delq nil
 425                          (list `(set :inline t
 426                                      :greedy t
 427                                      :tag "Parameters"
 428                                      :format "%t:\n%h%v"
 429                                      :doc "\
 430 These special parameters are recognized by Gnus.
 431 Check the [ ] for the parameters you want to apply to this group or
 432 to the groups in this topic, then edit the value to suit your taste."
 433                                      ,@types)
 434                                (when gnus-agent
 435                                  `(set :inline t
 436                                        :greedy t
 437                                        :tag "Agent Parameters"
 438                                        :format "%t:\n%h%v"
 439                                        :doc "\ These agent parameters are
 440 recognized by Gnus.  They control article selection and expiration for
 441 use in the unplugged cache.  Check the [ ] for the parameters you want
 442 to apply to this group or to the groups in this topic, then edit the
 443 value to suit your taste.
 444
 445 For those interested, group parameters override topic parameters while
 446 topic parameters override agent category parameters.  Underlying
 447 category parameters are the customizable variables."  ,@agent))
 448                                '(repeat :inline t
 449                                         :tag "Variables"
 450                                         :format "%t:\n%h%v%i\n\n"
 451                                         :doc "\
 452 Set variables local to the group you are entering.
 453
 454 If you want to turn threading off in `news.answers', you could put
 455 `(gnus-show-threads nil)' in the group parameters of that group.
 456 `gnus-show-threads' will be made into a local variable in the summary
 457 buffer you enter, and the form nil will be `eval'ed there.
 458
 459 This can also be used as a group-specific hook function, if you'd
 460 like.  If you want to hear a beep when you enter a group, you could
 461 put something like `(dummy-variable (ding))' in the parameters of that
 462 group.  `dummy-variable' will be set to the result of the `(ding)'
 463 form, but who cares?"
 464                                         (list :format "%v" :value (nil nil)
 465                                               (symbol :tag "Variable")
 466                                               (sexp :tag
 467                                                     "Value")))
 468
 469                                '(repeat :inline t
 470                                         :tag "Unknown entries"
 471                                         sexp))))))
 472     (when group
 473       (widget-insert "\n\nYou can also edit the ")
 474       (widget-create 'info-link
 475                      :tag "select method"
 476                      :help-echo "Push me to learn more about select methods."
 477                      "(gnus)Select Methods")
 478       (widget-insert " for the group.\n")
 479       (setq gnus-custom-method
 480             (widget-create 'sexp
 481                            :tag "Method"
 482                            :value (gnus-info-method info))))
 483     (use-local-map widget-keymap)
 484     (widget-setup)
 485     (buffer-enable-undo)
 486     (goto-char (point-min))))
 487
 488 (defun gnus-group-customize-done (&rest ignore)
 489   "Apply changes and bury the buffer."
 490   (interactive)
 491   (if gnus-custom-topic
 492       (gnus-topic-set-parameters gnus-custom-topic
 493                                  (widget-value gnus-custom-params))
 494     (gnus-group-edit-group-done 'params gnus-custom-group
 495                                 (widget-value gnus-custom-params))
 496     (gnus-group-edit-group-done 'method gnus-custom-group
 497                                 (widget-value gnus-custom-method)))
 498   (bury-buffer))
 499
 500 ;;; Score Customization:
 501
 502 (defconst gnus-score-parameters
 503   '((mark (number :tag "Mark") "\
 504 The value of this entry should be a number.
 505 Any articles with a score lower than this number will be marked as read.")
 506
 507     (expunge (number :tag "Expunge") "\
 508 The value of this entry should be a number.
 509 Any articles with a score lower than this number will be removed from
 510 the summary buffer.")
 511
 512     (mark-and-expunge (number :tag "Mark-and-expunge") "\
 513 The value of this entry should be a number.
 514 Any articles with a score lower than this number will be marked as
 515 read and removed from the summary buffer.")
 516
 517     (thread-mark-and-expunge (number :tag "Thread-mark-and-expunge") "\
 518 The value of this entry should be a number.
 519 All articles that belong to a thread that has a total score below this
 520 number will be marked as read and removed from the summary buffer.
 521 `gnus-thread-score-function' says how to compute the total score
 522 for a thread.")
 523
 524     (files (repeat :inline t :tag "Files" file) "\
 525 The value of this entry should be any number of file names.
 526 These files are assumed to be score files as well, and will be loaded
 527 the same way this one was.")
 528
 529     (exclude-files (repeat :inline t :tag "Exclude-files" file) "\
 530 The clue of this entry should be any number of files.
 531 These files will not be loaded, even though they would normally be so,
 532 for some reason or other.")
 533
 534     (eval (sexp :tag "Eval" :value nil) "\
 535 The value of this entry will be `eval'el.
 536 This element will be ignored when handling global score files.")
 537
 538     (read-only (boolean :tag "Read-only" :value t) "\
 539 Read-only score files will not be updated or saved.
 540 Global score files should feature this atom.")
 541
 542     (orphan (number :tag "Orphan") "\
 543 The value of this entry should be a number.
 544 Articles that do not have parents will get this number added to their
 545 scores.  Imagine you follow some high-volume newsgroup, like
 546 `comp.lang.c'.  Most likely you will only follow a few of the threads,
 547 also want to see any new threads.
 548
 549 You can do this with the following two score file entries:
 550
 551      (orphan -500)
 552      (mark-and-expunge -100)
 553
 554 When you enter the group the first time, you will only see the new
 555 threads.  You then raise the score of the threads that you find
 556 interesting (with `I T' or `I S'), and ignore (`C y') the rest.
 557 Next time you enter the group, you will see new articles in the
 558 interesting threads, plus any new threads.
 559
 560 I.e.---the orphan score atom is for high-volume groups where there
 561 exist a few interesting threads which can't be found automatically
 562 by ordinary scoring rules.")
 563
 564     (adapt (choice :tag "Adapt"
 565                    (const t)
 566                    (const ignore)
 567                    (sexp :format "%v"
 568                          :hide-front-space t)) "\
 569 This entry controls the adaptive scoring.
 570 If it is t, the default adaptive scoring rules will be used.  If it
 571 is `ignore', no adaptive scoring will be performed on this group.  If
 572 it is a list, this list will be used as the adaptive scoring rules.
 573 If it isn't present, or is something other than t or `ignore', the
 574 default adaptive scoring rules will be used.  If you want to use
 575 adaptive scoring on most groups, you'd set `gnus-use-adaptive-scoring'
 576 to t, and insert an `(adapt ignore)' in the groups where you do not
 577 want adaptive scoring.  If you only want adaptive scoring in a few
 578 groups, you'd set `gnus-use-adaptive-scoring' to nil, and insert
 579 `(adapt t)' in the score files of the groups where you want it.")
 580
 581     (adapt-file (file :tag "Adapt-file") "\
 582 All adaptive score entries will go to the file named by this entry.
 583 It will also be applied when entering the group.  This atom might
 584 be handy if you want to adapt on several groups at once, using the
 585 same adaptive file for a number of groups.")
 586
 587     (local (repeat :tag "Local"
 588                    (group :value (nil nil)
 589                           (symbol :tag "Variable")
 590                           (sexp :tag "Value"))) "\
 591 The value of this entry should be a list of `(VAR VALUE)' pairs.
 592 Each VAR will be made buffer-local to the current summary buffer,
 593 and set to the value specified.  This is a convenient, if somewhat
 594 strange, way of setting variables in some groups if you don't like
 595 hooks much.")
 596     (touched (sexp :format "Touched\n") "Internal variable."))
 597   "Alist of valid symbolic score parameters.
 598
 599 Each entry has the form (NAME TYPE DOC), where NAME is the parameter
 600 itself (a symbol), TYPE is the parameters type (a sexp widget), and DOC is a
 601 documentation string for the parameter.")
 602
 603 (define-widget 'gnus-score-string 'group
 604   "Edit score entries for string-valued headers."
 605   :convert-widget 'gnus-score-string-convert)
 606
 607 (defun gnus-score-string-convert (widget)
 608   ;; Set args appropriately.
 609   (let* ((tag (widget-get widget :tag))
 610          (item `(const :format "" :value ,(downcase tag)))
 611          (match '(string :tag "Match"))
 612          (score '(choice :tag "Score"
 613                          (const :tag "default" nil)
 614                          (integer :format "%v"
 615                                   :hide-front-space t)))
 616          (expire '(choice :tag "Expire"
 617                           (const :tag "off" nil)
 618                           (integer :format "%v"
 619                                    :hide-front-space t)))
 620          (type '(choice :tag "Type"
 621                         :value s
 622                         ;; I should really create a forgiving :match
 623                         ;; function for each type below, that only
 624                         ;; looked at the first letter.
 625                         (const :tag "Regexp" r)
 626                         (const :tag "Regexp (fixed case)" R)
 627                         (const :tag "Substring" s)
 628                         (const :tag "Substring (fixed case)" S)
 629                         (const :tag "Exact" e)
 630                         (const :tag "Exact (fixed case)" E)
 631                         (const :tag "Word" w)
 632                         (const :tag "Word (fixed case)" W)
 633                         (const :tag "default" nil)))
 634          (group `(group ,match ,score ,expire ,type))
 635          (doc (concat (or (widget-get widget :doc)
 636                           (concat "Change score based on the " tag
 637                                   " header.\n"))
 638                       "
 639 You can have an arbitrary number of score entries for this header,
 640 each score entry has four elements:
 641
 642 1. The \"match element\".  This should be the string to look for in the
 643    header.
 644
 645 2. The \"score element\".  This number should be an integer in the
 646    neginf to posinf interval.  This number is added to the score
 647    of the article if the match is successful.  If this element is
 648    not present, the `gnus-score-interactive-default-score' number
 649    will be used instead.  This is 1000 by default.
 650
 651 3. The \"date element\".  This date says when the last time this score
 652    entry matched, which provides a mechanism for expiring the
 653    score entries.  It this element is not present, the score
 654    entry is permanent.  The date is represented by the number of
 655    days since December 31, 1 ce.
 656
 657 4. The \"type element\".  This element specifies what function should
 658    be used to see whether this score entry matches the article.
 659
 660    There are the regexp, as well as substring types, and exact match,
 661    and word match types.  If this element is not present, Gnus will
 662    assume that substring matching should be used.  There is case
 663    sensitive variants of all match types.")))
 664     (widget-put widget :args `(,item
 665                                (repeat :inline t
 666                                        :indent 0
 667                                        :tag ,tag
 668                                        :doc ,doc
 669                                        :format "%t:\n%h%v%i\n\n"
 670                                        (choice :format "%v"
 671                                                :value ("" nil nil s)
 672                                                ,group
 673                                                sexp)))))
 674   widget)
 675
 676 (define-widget 'gnus-score-integer 'group
 677   "Edit score entries for integer-valued headers."
 678   :convert-widget 'gnus-score-integer-convert)
 679
 680 (defun gnus-score-integer-convert (widget)
 681   ;; Set args appropriately.
 682   (let* ((tag (widget-get widget :tag))
 683          (item `(const :format "" :value ,(downcase tag)))
 684          (match '(integer :tag "Match"))
 685          (score '(choice :tag "Score"
 686                          (const :tag "default" nil)
 687                          (integer :format "%v"
 688                                   :hide-front-space t)))
 689          (expire '(choice :tag "Expire"
 690                           (const :tag "off" nil)
 691                           (integer :format "%v"
 692                                    :hide-front-space t)))
 693          (type '(choice :tag "Type"
 694                         :value <
 695                         (const <)
 696                         (const >)
 697                         (const =)
 698                         (const >=)
 699                         (const <=)))
 700          (group `(group ,match ,score ,expire ,type))
 701          (doc (concat (or (widget-get widget :doc)
 702                           (concat "Change score based on the " tag
 703                                   " header.")))))
 704     (widget-put widget :args `(,item
 705                                (repeat :inline t
 706                                        :indent 0
 707                                        :tag ,tag
 708                                        :doc ,doc
 709                                        :format "%t:\n%h%v%i\n\n"
 710                                        ,group))))
 711   widget)
 712
 713 (define-widget 'gnus-score-date 'group
 714   "Edit score entries for date-valued headers."
 715   :convert-widget 'gnus-score-date-convert)
 716
 717 (defun gnus-score-date-convert (widget)
 718   ;; Set args appropriately.
 719   (let* ((tag (widget-get widget :tag))
 720          (item `(const :format "" :value ,(downcase tag)))
 721          (match '(string :tag "Match"))
 722          (score '(choice :tag "Score"
 723                          (const :tag "default" nil)
 724                          (integer :format "%v"
 725                                   :hide-front-space t)))
 726          (expire '(choice :tag "Expire"
 727                           (const :tag "off" nil)
 728                           (integer :format "%v"
 729                                    :hide-front-space t)))
 730          (type '(choice :tag "Type"
 731                         :value regexp
 732                         (const regexp)
 733                         (const before)
 734                         (const at)
 735                         (const after)))
 736          (group `(group ,match ,score ,expire ,type))
 737          (doc (concat (or (widget-get widget :doc)
 738                           (concat "Change score based on the " tag
 739                                   " header."))
 740                       "
 741 For the Date header we have three kinda silly match types: `before',
 742 `at' and `after'.  I can't really imagine this ever being useful, but,
 743 like, it would feel kinda silly not to provide this function.  Just in
 744 case.  You never know.  Better safe than sorry.  Once burnt, twice
 745 shy.  Don't judge a book by its cover.  Never not have sex on a first
 746 date.  (I have been told that at least one person, and I quote,
 747 \"found this function indispensable\", however.)
 748
 749 A more useful match type is `regexp'.  With it, you can match the date
 750 string using a regular expression.  The date is normalized to ISO8601
 751 compact format first---`YYYYMMDDTHHMMSS'.  If you want to match all
 752 articles that have been posted on April 1st in every year, you could
 753 use `....0401.........' as a match string, for instance.  (Note that
 754 the date is kept in its original time zone, so this will match
 755 articles that were posted when it was April 1st where the article was
 756 posted from.  Time zones are such wholesome fun for the whole family,
 757 eh?")))
 758     (widget-put widget :args `(,item
 759                                (repeat :inline t
 760                                        :indent 0
 761                                        :tag ,tag
 762                                        :doc ,doc
 763                                        :format "%t:\n%h%v%i\n\n"
 764                                        ,group))))
 765   widget)
 766
 767 (defvar gnus-custom-scores)
 768 (defvar gnus-custom-score-alist)
 769
 770 (defun gnus-score-customize (file)
 771   "Customize score file FILE.
 772 When called interactively, FILE defaults to the current score file.
 773 This can be changed using the `\\[gnus-score-change-score-file]' command."
 774   (interactive (list gnus-current-score-file))
 775   (unless file
 776     (error (format "No score file for %s"
 777                    (gnus-group-decoded-name gnus-newsgroup-name))))
 778   (let ((scores (gnus-score-load file))
 779         (types (mapcar (lambda (entry)
 780                          `(group :format "%v%h\n"
 781                                  :doc ,(nth 2 entry)
 782                                  (const :format "" ,(nth 0 entry))
 783                                  ,(nth 1 entry)))
 784                        gnus-score-parameters)))
 785     ;; Ready.
 786     (kill-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 787     (switch-to-buffer (gnus-get-buffer-create "*Gnus Customize*"))
 788     (gnus-custom-mode)
 789     (make-local-variable 'gnus-custom-score-alist)
 790     (setq gnus-custom-score-alist scores)
 791     (widget-insert "Customize the ")
 792     (widget-create 'info-link
 793                    :help-echo "Push me to learn more."
 794                    :tag "score entries"
 795                    "(gnus)Score File Format")
 796     (widget-insert " for\n\t")
 797     (widget-insert file)
 798     (widget-insert "\nand press ")
 799     (widget-create 'push-button
 800                    :tag "done"
 801                    :help-echo "Push me when done customizing."
 802                    :action 'gnus-score-customize-done)
 803     (widget-insert ".\n
 804 Check the [ ] for the entries you want to apply to this score file, then
 805 edit the value to suit your taste.  Don't forget to mark the checkbox,
 806 if you do all your changes will be lost.  ")
 807     (widget-create 'push-button
 808                    :action (lambda (&rest ignore)
 809                              (require 'gnus-audio)
 810                              (gnus-audio-play "Evil_Laugh.au"))
 811                    "Bhahahah!")
 812     (widget-insert "\n\n")
 813     (make-local-variable 'gnus-custom-scores)
 814     (setq gnus-custom-scores
 815           (widget-create 'group
 816                          :value scores
 817                          `(checklist :inline t
 818                                      :greedy t
 819                                      (gnus-score-string :tag "From")
 820                                      (gnus-score-string :tag "Subject")
 821                                      (gnus-score-string :tag "References")
 822                                      (gnus-score-string :tag "Xref")
 823                                      (gnus-score-string :tag "Extra")
 824                                      (gnus-score-string :tag "Message-ID")
 825                                      (gnus-score-integer :tag "Lines")
 826                                      (gnus-score-integer :tag "Chars")
 827                                      (gnus-score-date :tag "Date")
 828                                      (gnus-score-string :tag "Head"
 829                                                         :doc "\
 830 Match all headers in the article.
 831
 832 Using one of `Head', `Body', `All' will slow down scoring considerable.
 833 ")
 834                                      (gnus-score-string :tag "Body"
 835                                                         :doc "\
 836 Match the body sans header of the article.
 837
 838 Using one of `Head', `Body', `All' will slow down scoring considerable.
 839 ")
 840                                      (gnus-score-string :tag "All"
 841                                                         :doc "\
 842 Match the entire article, including both headers and body.
 843
 844 Using one of `Head', `Body', `All' will slow down scoring
 845 considerable.
 846 ")
 847                                      (gnus-score-string :tag
 848                                                         "Followup"
 849                                                         :doc "\
 850 Score all followups to the specified authors.
 851
 852 This entry is somewhat special, in that it will match the `From:'
 853 header, and affect the score of not only the matching articles, but
 854 also all followups to the matching articles.  This allows you
 855 e.g. increase the score of followups to your own articles, or decrease
 856 the score of followups to the articles of some known trouble-maker.
 857 ")
 858                                      (gnus-score-string :tag "Thread"
 859                                                         :doc "\
 860 Add a score entry on all articles that are part of a thread.
 861
 862 This match key works along the same lines as the `Followup' match key.
 863 If you say that you want to score on a (sub-)thread that is started by
 864 an article with a `Message-ID' X, then you add a `thread' match.  This
 865 will add a new `thread' match for each article that has X in its
 866 `References' header.  (These new `thread' matches will use the
 867 `Message-ID's of these matching articles.)  This will ensure that you
 868 can raise/lower the score of an entire thread, even though some
 869 articles in the thread may not have complete `References' headers.
 870 Note that using this may lead to undeterministic scores of the
 871 articles in the thread.
 872 ")
 873                                      ,@types)
 874                          '(repeat :inline t
 875                                   :tag "Unknown entries"
 876                                   sexp)))
 877     (use-local-map widget-keymap)
 878     (widget-setup)))
 879
 880 (defun gnus-score-customize-done (&rest ignore)
 881   "Reset the score alist with the present value."
 882   (let ((alist gnus-custom-score-alist)
 883         (value (widget-value gnus-custom-scores)))
 884     (setcar alist (car value))
 885     (setcdr alist (cdr value))
 886     (gnus-score-set 'touched '(t) alist))
 887   (bury-buffer))
 888
 889 (eval-when-compile
 890   (defvar category-fields nil)
 891 )
 892
 893 (defun gnus-trim-whitespace (s)
 894   (when (string-match "\\`[ \n\t]+" s)
 895     (setq s (substring s (match-end 0))))
 896   (when (string-match "[ \n\t]+\\'" s)
 897     (setq s (substring s 0 (match-beginning 0))))
 898   s)
 899
 900 (defmacro gnus-agent-cat-prepare-category-field (parameter)
 901   (let* ((entry (assq parameter gnus-agent-parameters))
 902          (field (nth 3 entry)))
 903     `(let* ((type (copy-sequence
 904                    (nth 1 (assq ',parameter gnus-agent-parameters))))
 905             (val (,field info))
 906             (deflt (if (,field defaults)
 907                        (concat " [" (gnus-trim-whitespace
 908                                      (pp-to-string (,field defaults))) "]")))
 909             symb)
 910
 911        (if (eq (car type) 'radio)
 912            (let* ((rtype (nreverse type))
 913                   (rt rtype))
 914              (while (listp (or (cadr rt) 'not-list))
 915                (setq rt (cdr rt)))
 916
 917              (setcdr rt (cons '(const :format "Inherit " nil) (cdr rt)))
 918              (setq type (nreverse rtype))))
 919
 920        (if deflt
 921            (let ((tag (cdr (memq :tag type))))
 922              (if (string-match "\n" deflt)
 923                  (progn (while (progn (setq deflt (replace-match "\n " t t
 924                                                                  deflt))
 925                                       (string-match "\n" deflt (match-end 0))))
 926                         (setq deflt (concat "\n" deflt))))
 927
 928              (setcar tag (concat (car tag) deflt))))
 929
 930        (widget-insert "\n")
 931
 932        (setq val (if val
 933                      (widget-create type :value val)
 934                    (widget-create type))
 935              symb (set (make-local-variable ',field) val))
 936
 937        (widget-put symb :default val)
 938        (widget-put symb :accessor ',field)
 939        (push symb category-fields))))
 940
 941 (defun gnus-agent-customize-category (category)
 942   "Edit the CATEGORY."
 943   (interactive (list (gnus-category-name)))
 944   (let ((info (assq category gnus-category-alist))
 945         (defaults (list nil '(agent-predicate . false)
 946                         (cons 'agent-enable-expiration
 947                               gnus-agent-enable-expiration)
 948                         '(agent-days-until-old . 7)
 949                         (cons 'agent-length-when-short
 950                               gnus-agent-short-article)
 951                         (cons 'agent-length-when-long gnus-agent-long-article)
 952                         (cons 'agent-low-score gnus-agent-low-score)
 953                         (cons 'agent-high-score gnus-agent-high-score))))
 954
 955     (let ((old (get-buffer "*Gnus Agent Category Customize*")))
 956       (when old
 957         (gnus-kill-buffer old)))
 958     (switch-to-buffer (gnus-get-buffer-create
 959                        "*Gnus Agent Category Customize*"))
 960
 961     (let ((inhibit-read-only t))
 962       (gnus-custom-mode)
 963       (buffer-disable-undo)
 964
 965       (let* ((name (gnus-agent-cat-name info)))
 966         (widget-insert "Customize the Agent Category '")
 967         (widget-insert (symbol-name name))
 968         (widget-insert "' and press ")
 969         (widget-create
 970          'push-button
 971          :notify
 972          '(lambda (&rest ignore)
 973             (let* ((info (assq gnus-agent-cat-name gnus-category-alist))
 974                    (widgets category-fields))
 975               (while widgets
 976                 (let* ((widget (pop widgets))
 977                        (value (ignore-errors (widget-value widget))))
 978                   (eval `(setf (,(widget-get widget :accessor) ',info)
 979                                ',value)))))
 980             (gnus-category-write)
 981             (gnus-kill-buffer (current-buffer))
 982             (when (get-buffer gnus-category-buffer)
 983               (switch-to-buffer (get-buffer gnus-category-buffer))
 984               (gnus-category-list)))
 985                        "Done")
 986         (widget-insert
 987          "\n    Note: Empty fields default to the customizable global\
 988  variables.\n\n")
 989
 990         (set (make-local-variable 'gnus-agent-cat-name)
 991              name))
 992
 993       (set (make-local-variable 'category-fields) nil)
 994       (gnus-agent-cat-prepare-category-field agent-predicate)
 995
 996       (gnus-agent-cat-prepare-category-field agent-score)
 997       (gnus-agent-cat-prepare-category-field agent-short-article)
 998       (gnus-agent-cat-prepare-category-field agent-long-article)
 999       (gnus-agent-cat-prepare-category-field agent-low-score)
1000       (gnus-agent-cat-prepare-category-field agent-high-score)
1001
1002       ;; The group list is NOT handled with
1003       ;; gnus-agent-cat-prepare-category-field as I don't want the
1004       ;; group list to appear when customizing a topic.
1005       (widget-insert "\n")
1006
1007       (let ((symb
1008              (set
1009               (make-local-variable 'gnus-agent-cat-groups)
1010               (widget-create
1011                `(choice
1012                  :format "%[Select Member Groups%]\n%v" :value ignore
1013                  (const :menu-tag "do not change" :tag "" :value ignore)
1014                  (checklist :entry-format "%b %v"
1015                             :menu-tag "display group selectors"
1016                             :greedy t
1017                             :value
1018                             ,(delq nil
1019                                    (mapcar
1020                                     (lambda (newsrc)
1021                                       (car (member
1022                                             (gnus-info-group newsrc)
1023                                             (gnus-agent-cat-groups info))))
1024                                     (cdr gnus-newsrc-alist)))
1025                             ,@(mapcar (lambda (newsrc)
1026                                         `(const ,(gnus-info-group newsrc)))
1027                                       (cdr gnus-newsrc-alist))))))))
1028
1029       (widget-put symb :default (gnus-agent-cat-groups info))
1030       (widget-put symb :accessor 'gnus-agent-cat-groups)
1031       (push symb category-fields))
1032
1033       (widget-insert "\nExpiration Settings ")
1034
1035       (gnus-agent-cat-prepare-category-field agent-enable-expiration)
1036       (gnus-agent-cat-prepare-category-field agent-days-until-old)
1037
1038       (use-local-map widget-keymap)
1039       (widget-setup)
1040       (buffer-enable-undo))))
1041
1042 ;;; The End:
1043
1044 (provide 'gnus-cus)
1045
1046 ;;; gnus-cus.el ends here