git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-demon.el

   1 ;;; gnus-demon.el --- daemonic Gnus behaviour
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31 (require 'gnus-int)
  32 (require 'nnheader)
  33 (require 'nntp)
  34 (require 'nnmail)
  35 (require 'gnus-util)
  36 (eval-and-compile
  37   (if (string-match "XEmacs" (emacs-version))
  38       (require 'itimer)
  39     (require 'timer)))
  40
  41 (defgroup gnus-demon nil
  42   "Demonic behaviour."
  43   :group 'gnus)
  44
  45 (defcustom gnus-demon-handlers nil
  46   "Alist of daemonic handlers to be run at intervals.
  47 Each handler is a list on the form
  48
  49 \(FUNCTION TIME IDLE)
  50
  51 FUNCTION is the function to be called.
  52 TIME is the number of `gnus-demon-timestep's between each call.
  53 If nil, never call.  If t, call each `gnus-demon-timestep'.
  54 If IDLE is t, only call if Emacs has been idle for a while.  If IDLE
  55 is a number, only call when Emacs has been idle more than this number
  56 of `gnus-demon-timestep's.  If IDLE is nil, don't care about
  57 idleness.  If IDLE is a number and TIME is nil, then call once each
  58 time Emacs has been idle for IDLE `gnus-demon-timestep's."
  59   :group 'gnus-demon
  60   :type '(repeat (list function
  61                        (choice :tag "Time"
  62                                (const :tag "never" nil)
  63                                (const :tag "one" t)
  64                                (integer :tag "steps" 1))
  65                        (choice :tag "Idle"
  66                                (const :tag "don't care" nil)
  67                                (const :tag "for a while" t)
  68                                (integer :tag "steps" 1)))))
  69
  70 (defcustom gnus-demon-timestep 60
  71   "*Number of seconds in each demon timestep."
  72   :group 'gnus-demon
  73   :type 'integer)
  74
  75 ;;; Internal variables.
  76
  77 (defvar gnus-demon-timer nil)
  78 (defvar gnus-demon-idle-has-been-called nil)
  79 (defvar gnus-demon-idle-time 0)
  80 (defvar gnus-demon-handler-state nil)
  81 (defvar gnus-demon-last-keys nil)
  82 (defvar gnus-inhibit-demon nil
  83   "*If non-nil, no daemonic function will be run.")
  84
  85 ;;; Functions.
  86
  87 (defun gnus-demon-add-handler (function time idle)
  88   "Add the handler FUNCTION to be run at TIME and IDLE."
  89   ;; First remove any old handlers that use this function.
  90   (gnus-demon-remove-handler function)
  91   ;; Then add the new one.
  92   (push (list function time idle) gnus-demon-handlers)
  93   (gnus-demon-init))
  94
  95 (defun gnus-demon-remove-handler (function &optional no-init)
  96   "Remove the handler FUNCTION from the list of handlers."
  97   (gnus-pull function gnus-demon-handlers)
  98   (unless no-init
  99     (gnus-demon-init)))
 100
 101 (defun gnus-demon-init ()
 102   "Initialize the Gnus daemon."
 103   (interactive)
 104   (gnus-demon-cancel)
 105   (when gnus-demon-handlers
 106     ;; Set up the timer.
 107     (setq gnus-demon-timer
 108           (nnheader-run-at-time
 109            gnus-demon-timestep gnus-demon-timestep 'gnus-demon))
 110     ;; Reset control variables.
 111     (setq gnus-demon-handler-state
 112           (mapcar
 113            (lambda (handler)
 114              (list (car handler) (gnus-demon-time-to-step (nth 1 handler))
 115                    (nth 2 handler)))
 116            gnus-demon-handlers))
 117     (setq gnus-demon-idle-time 0)
 118     (setq gnus-demon-idle-has-been-called nil)
 119     (setq gnus-use-demon t)))
 120
 121 (gnus-add-shutdown 'gnus-demon-cancel 'gnus)
 122
 123 (defun gnus-demon-cancel ()
 124   "Cancel any Gnus daemons."
 125   (interactive)
 126   (when gnus-demon-timer
 127     (nnheader-cancel-timer gnus-demon-timer))
 128   (setq gnus-demon-timer nil
 129         gnus-use-demon nil
 130         gnus-demon-idle-has-been-called nil)
 131   (condition-case ()
 132       (nnheader-cancel-function-timers 'gnus-demon)
 133     (error t)))
 134
 135 (defun gnus-demon-is-idle-p ()
 136   "Whether Emacs is idle or not."
 137   ;; We do this simply by comparing the 100 most recent keystrokes
 138   ;; with the ones we had last time.  If they are the same, one might
 139   ;; guess that Emacs is indeed idle.  This only makes sense if one
 140   ;; calls this function seldom -- like once a minute, which is what
 141   ;; we do here.
 142   (let ((keys (recent-keys)))
 143     (or (equal keys gnus-demon-last-keys)
 144         (progn
 145           (setq gnus-demon-last-keys keys)
 146           nil))))
 147
 148 (defun gnus-demon-time-to-step (time)
 149   "Find out how many seconds to TIME, which is on the form \"17:43\"."
 150   (if (not (stringp time))
 151       time
 152     (let* ((now (current-time))
 153            ;; obtain NOW as discrete components -- make a vector for speed
 154            (nowParts (decode-time now))
 155            ;; obtain THEN as discrete components
 156            (thenParts (parse-time-string time))
 157            (thenHour (string-to-int (elt thenParts 0)))
 158            (thenMin (string-to-int (elt thenParts 1)))
 159            ;; convert time as elements into number of seconds since EPOCH.
 160            (then (encode-time 0
 161                               thenMin
 162                               thenHour
 163                               ;; If THEN is earlier than NOW, make it
 164                               ;; same time tomorrow. Doc for encode-time
 165                               ;; says that this is OK.
 166                               (+ (elt nowParts 3)
 167                                  (if (or (< thenHour (elt nowParts 2))
 168                                          (and (= thenHour (elt nowParts 2))
 169                                               (<= thenMin (elt nowParts 1))))
 170                                      1 0))
 171                               (elt nowParts 4)
 172                               (elt nowParts 5)
 173                               (elt nowParts 6)
 174                               (elt nowParts 7)
 175                               (elt nowParts 8)))
 176            ;; calculate number of seconds between NOW and THEN
 177            (diff (+ (* 65536 (- (car then) (car now)))
 178                     (- (cadr then) (cadr now)))))
 179       ;; return number of timesteps in the number of seconds
 180       (round (/ diff gnus-demon-timestep)))))
 181
 182 (defun gnus-demon ()
 183   "The Gnus daemon that takes care of running all Gnus handlers."
 184   ;; Increase or reset the time Emacs has been idle.
 185   (if (gnus-demon-is-idle-p)
 186       (incf gnus-demon-idle-time)
 187     (setq gnus-demon-idle-time 0)
 188     (setq gnus-demon-idle-has-been-called nil))
 189   ;; Disable all daemonic stuff if we're in the minibuffer
 190   (when (and (not (window-minibuffer-p (selected-window)))
 191              (not gnus-inhibit-demon))
 192     ;; Then we go through all the handler and call those that are
 193     ;; sufficiently ripe.
 194     (let ((handlers gnus-demon-handler-state)
 195           (gnus-inhibit-demon t)
 196           handler time idle)
 197       (while handlers
 198         (setq handler (pop handlers))
 199         (cond
 200          ((numberp (setq time (nth 1 handler)))
 201           ;; These handlers use a regular timeout mechanism.  We decrease
 202           ;; the timer if it hasn't reached zero yet.
 203           (unless (zerop time)
 204             (setcar (nthcdr 1 handler) (decf time)))
 205           (and (zerop time)             ; If the timer now is zero...
 206                ;; Test for appropriate idleness
 207                (progn
 208                  (setq idle (nth 2 handler))
 209                  (cond
 210                   ((null idle) t)       ; Don't care about idle.
 211                   ((numberp idle)       ; Numerical idle...
 212                    (< idle gnus-demon-idle-time)) ; Idle timed out.
 213                   (t (< 0 gnus-demon-idle-time)))) ; Or just need to be idle.
 214                ;; So we call the handler.
 215                (progn
 216                  (ignore-errors (funcall (car handler)))
 217                  ;; And reset the timer.
 218                  (setcar (nthcdr 1 handler)
 219                          (gnus-demon-time-to-step
 220                           (nth 1 (assq (car handler) gnus-demon-handlers)))))))
 221          ;; These are only supposed to be called when Emacs is idle.
 222          ((null (setq idle (nth 2 handler)))
 223           ;; We do nothing.
 224           )
 225          ((and (not (numberp idle))
 226                (gnus-demon-is-idle-p))
 227           ;; We want to call this handler each and every time that
 228           ;; Emacs is idle.
 229           (ignore-errors (funcall (car handler))))
 230          (t
 231           ;; We want to call this handler only if Emacs has been idle
 232           ;; for a specified number of timesteps.
 233           (and (not (memq (car handler) gnus-demon-idle-has-been-called))
 234                (< idle gnus-demon-idle-time)
 235                (gnus-demon-is-idle-p)
 236                (progn
 237                  (ignore-errors (funcall (car handler)))
 238                  ;; Make sure the handler won't be called once more in
 239                  ;; this idle-cycle.
 240                  (push (car handler) gnus-demon-idle-has-been-called)))))))))
 241
 242 (defun gnus-demon-add-nocem ()
 243   "Add daemonic NoCeM handling to Gnus."
 244   (gnus-demon-add-handler 'gnus-demon-scan-nocem 60 30))
 245
 246 (defun gnus-demon-scan-nocem ()
 247   "Scan NoCeM groups for NoCeM messages."
 248   (save-window-excursion
 249     (gnus-nocem-scan-groups)))
 250
 251 (defun gnus-demon-add-disconnection ()
 252   "Add daemonic server disconnection to Gnus."
 253   (gnus-demon-add-handler 'gnus-demon-close-connections nil 30))
 254
 255 (defun gnus-demon-close-connections ()
 256   (save-window-excursion
 257     (gnus-close-backends)))
 258
 259 (defun gnus-demon-add-nntp-close-connection ()
 260   "Add daemonic nntp server disconnection to Gnus.
 261 If no commands have gone out via nntp during the last five
 262 minutes, the connection is closed."
 263   (gnus-demon-add-handler 'gnus-demon-close-connections 5 nil))
 264
 265 (defun gnus-demon-nntp-close-connection ()
 266   (save-window-excursion
 267     (when (time-less-p '(0 300) (time-since nntp-last-command-time))
 268       (nntp-close-server))))
 269
 270 (defun gnus-demon-add-scanmail ()
 271   "Add daemonic scanning of mail from the mail backends."
 272   (gnus-demon-add-handler 'gnus-demon-scan-mail 120 60))
 273
 274 (defun gnus-demon-scan-mail ()
 275   (save-window-excursion
 276     (let ((servers gnus-opened-servers)
 277           server)
 278       (gnus-clear-inboxes-moved)
 279       (while (setq server (car (pop servers)))
 280         (and (gnus-check-backend-function 'request-scan (car server))
 281              (or (gnus-server-opened server)
 282                  (gnus-open-server server))
 283              (gnus-request-scan nil server))))))
 284
 285 (defun gnus-demon-add-rescan ()
 286   "Add daemonic scanning of new articles from all backends."
 287   (gnus-demon-add-handler 'gnus-demon-scan-news 120 60))
 288
 289 (defun gnus-demon-scan-news ()
 290   (let ((win (current-window-configuration)))
 291     (unwind-protect
 292         (save-window-excursion
 293           (save-excursion
 294             (when (gnus-alive-p)
 295               (save-excursion
 296                 (set-buffer gnus-group-buffer)
 297                 (gnus-group-get-new-news)))))
 298       (set-window-configuration win))))
 299
 300 (defun gnus-demon-add-scan-timestamps ()
 301   "Add daemonic updating of timestamps in empty newgroups."
 302   (gnus-demon-add-handler 'gnus-demon-scan-timestamps nil 30))
 303
 304 (defun gnus-demon-scan-timestamps ()
 305   "Set the timestamp on all newsgroups with no unread and no ticked articles."
 306   (when (gnus-alive-p)
 307     (let ((cur-time (current-time))
 308           (newsrc (cdr gnus-newsrc-alist))
 309           info group unread has-ticked)
 310       (while (setq info (pop newsrc))
 311         (setq group (gnus-info-group info)
 312               unread (gnus-group-unread group)
 313               has-ticked (cdr (assq 'tick (gnus-info-marks info))))
 314         (when (and (numberp unread)
 315                    (= unread 0)
 316                    (not has-ticked))
 317           (gnus-group-set-parameter group 'timestamp cur-time))))))
 318
 319 (provide 'gnus-demon)
 320
 321 ;;; gnus-demon.el ends here