git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (mml-mode)
  80       (gnus-run-hooks 'gnus-draft-mode-hook))))
  81
  82 ;;; Commands
  83
  84 (defun gnus-draft-toggle-sending (article)
  85   "Toggle whether to send an article or not."
  86   (interactive (list (gnus-summary-article-number)))
  87   (if (gnus-draft-article-sendable-p article)
  88       (progn
  89         (push article gnus-newsgroup-unsendable)
  90         (gnus-summary-mark-article article gnus-unsendable-mark))
  91     (setq gnus-newsgroup-unsendable
  92           (delq article gnus-newsgroup-unsendable))
  93     (gnus-summary-mark-article article gnus-unread-mark))
  94   (gnus-summary-position-point))
  95
  96 (defun gnus-draft-edit-message ()
  97   "Enter a mail/post buffer to edit and send the draft."
  98   (interactive)
  99   (let ((article (gnus-summary-article-number))
 100         (group gnus-newsgroup-name))
 101     (gnus-draft-check-draft-articles (list article))
 102     (gnus-summary-mark-as-read article gnus-canceled-mark)
 103     (gnus-draft-setup article group t)
 104     (set-buffer-modified-p t)
 105     (save-excursion
 106       (save-restriction
 107         (message-narrow-to-headers)
 108         (message-remove-header "date")))
 109     (save-buffer)
 110     (let ((gnus-verbose-backends nil))
 111       (gnus-request-expire-articles (list article) group t))
 112     (push
 113      `((lambda ()
 114          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 115            (save-excursion
 116              (set-buffer ,gnus-summary-buffer)
 117              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 118      message-send-actions)))
 119
 120 (defun gnus-draft-send-message (&optional n)
 121   "Send the current draft."
 122   (interactive "P")
 123   (let* ((articles (gnus-summary-work-articles n))
 124          (total (length articles))
 125          article)
 126     (gnus-draft-check-draft-articles articles)
 127     (while (setq article (pop articles))
 128       (gnus-summary-remove-process-mark article)
 129       (unless (memq article gnus-newsgroup-unsendable)
 130         (let ((message-sending-message
 131                (format "Sending message %d of %d..."
 132                        (- total (length articles)) total)))
 133           (gnus-draft-send article gnus-newsgroup-name t))
 134         (gnus-summary-mark-article article gnus-canceled-mark)))))
 135
 136 (defun gnus-draft-send (article &optional group interactive)
 137   "Send message ARTICLE."
 138   (let* ((is-queue (or (not group)
 139                        (equal group "nndraft:queue")))
 140          (message-syntax-checks (if interactive message-syntax-checks
 141                                   'dont-check-for-anything-just-trust-me))
 142          (message-hidden-headers nil)
 143          (message-inhibit-body-encoding (or is-queue
 144                                             message-inhibit-body-encoding))
 145          (message-send-hook (and (not is-queue)
 146                                  message-send-hook))
 147          (message-setup-hook (and (not is-queue)
 148                                   message-setup-hook))
 149          (message-signature (and (not is-queue)
 150                                  message-signature))
 151          (gnus-agent-queue-mail (and (not is-queue)
 152                                      gnus-agent-queue-mail))
 153          (rfc2047-encode-encoded-words nil)
 154          type method move-to)
 155     (gnus-draft-setup article (or group "nndraft:queue"))
 156     ;; We read the meta-information that says how and where
 157     ;; this message is to be sent.
 158     (save-restriction
 159       (message-narrow-to-headers)
 160       (when (re-search-forward
 161              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 162                      ":") nil t)
 163         (skip-syntax-forward "-")
 164         (setq move-to (buffer-substring (point) (point-at-eol)))
 165         (message-remove-header gnus-agent-target-move-group-header))
 166       (goto-char (point-min))
 167       (when (re-search-forward
 168              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 169              nil t)
 170         (setq type (ignore-errors (read (current-buffer)))
 171               method (ignore-errors (read (current-buffer))))
 172         (message-remove-header gnus-agent-meta-information-header)))
 173     ;; Let Agent restore any GCC lines and have message.el perform them.
 174     (gnus-agent-restore-gcc)
 175     ;; Then we send it.  If we have no meta-information, we just send
 176     ;; it and let Message figure out how.
 177     (when (and (or (null method)
 178                    (gnus-server-opened method)
 179                    (gnus-open-server method))
 180                (if type
 181                    (let ((message-this-is-news (eq type 'news))
 182                          (message-this-is-mail (eq type 'mail))
 183                          (gnus-post-method method)
 184                          (message-post-method method))
 185                      (if move-to
 186                          (gnus-inews-do-gcc move-to)
 187                        (message-send-and-exit)))
 188                  (if move-to
 189                      (gnus-inews-do-gcc move-to)
 190                    (message-send-and-exit))))
 191       (let ((gnus-verbose-backends nil))
 192         (gnus-request-expire-articles
 193          (list article) (or group "nndraft:queue") t)))))
 194
 195 (defun gnus-draft-send-all-messages ()
 196   "Send all the sendable drafts."
 197   (interactive)
 198   (when (or
 199          gnus-expert-user
 200          (gnus-y-or-n-p
 201           "Send all drafts? "))
 202     (gnus-uu-mark-buffer)
 203     (gnus-draft-send-message)))
 204
 205 (defun gnus-group-send-queue ()
 206   "Send all sendable articles from the queue group."
 207   (interactive)
 208   (when (or gnus-plugged
 209             (not gnus-agent-prompt-send-queue)
 210             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 211     (gnus-activate-group "nndraft:queue")
 212     (save-excursion
 213       (let* ((articles (nndraft-articles))
 214              (unsendable (gnus-uncompress-range
 215                           (cdr (assq 'unsend
 216                                      (gnus-info-marks
 217                                       (gnus-get-info "nndraft:queue"))))))
 218              (gnus-posting-styles nil)
 219              (total (length articles))
 220              article)
 221         (while (setq article (pop articles))
 222           (unless (memq article unsendable)
 223             (let ((message-sending-message
 224                    (format "Sending message %d of %d..."
 225                            (- total (length articles)) total)))
 226               (gnus-draft-send article))))))))
 227
 228 ;;;###autoload
 229 (defun gnus-draft-reminder ()
 230   "Reminder user if there are unsent drafts."
 231   (interactive)
 232   (if (gnus-alive-p)
 233       (let (active)
 234         (catch 'continue
 235           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 236             (setq active (gnus-activate-group group))
 237             (if (and active (>= (cdr active) (car active)))
 238                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 239                     (throw 'continue t)
 240                   (error "Stop!"))))))))
 241
 242 ;;; Utility functions
 243
 244 ;;;!!!If this is byte-compiled, it fails miserably.
 245 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 246 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 247 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 248
 249 (progn
 250   (defun gnus-draft-setup (narticle group &optional restore)
 251     (let (ga)
 252       (gnus-setup-message 'forward
 253         (let ((article narticle))
 254           (message-mail)
 255           (erase-buffer)
 256           (if (not (gnus-request-restore-buffer article group))
 257               (error "Couldn't restore the article")
 258             (when (and restore
 259                        (equal group "nndraft:queue"))
 260               (mime-to-mml))
 261             ;; Insert the separator.
 262             (goto-char (point-min))
 263             (search-forward "\n\n")
 264             (forward-char -1)
 265             (save-restriction
 266               (narrow-to-region (point-min) (point))
 267               (setq ga
 268                     (message-fetch-field gnus-draft-meta-information-header)))
 269             (insert mail-header-separator)
 270             (forward-line 1)
 271             (message-set-auto-save-file-name))))
 272       (gnus-backlog-remove-article group narticle)
 273       (when (and ga
 274                  (ignore-errors (setq ga (car (read-from-string ga)))))
 275         (setq gnus-newsgroup-name
 276               (if (equal (car ga) "") nil (car ga)))
 277         (gnus-configure-posting-styles)
 278         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 279         (setq message-post-method
 280               `(lambda (arg)
 281                  (gnus-post-method arg ,(car ga))))
 282         (unless (equal (cadr ga) "")
 283           (dolist (article (cdr ga))
 284             (message-add-action
 285              `(progn
 286                 (gnus-add-mark ,(car ga) 'replied ,article)
 287                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 288                                                              'add '(reply)))))
 289              'send)))))))
 290
 291 (defun gnus-draft-article-sendable-p (article)
 292   "Say whether ARTICLE is sendable."
 293   (not (memq article gnus-newsgroup-unsendable)))
 294
 295 (defun gnus-draft-check-draft-articles (articles)
 296   "Check whether the draft articles ARTICLES are under edit."
 297   (when (equal gnus-newsgroup-name "nndraft:drafts")
 298     (let ((buffers (buffer-list))
 299           file buffs buff)
 300       (save-current-buffer
 301         (while (and articles
 302                     (not buff))
 303           (setq file (nndraft-article-filename (pop articles))
 304                 buffs buffers)
 305           (while buffs
 306             (set-buffer (setq buff (pop buffs)))
 307             (if (and buffer-file-name
 308                      (string-equal (file-truename buffer-file-name)
 309                                    (file-truename file))
 310                      (buffer-modified-p))
 311                 (setq buffs nil)
 312               (setq buff nil)))))
 313       (when buff
 314         (let* ((window (get-buffer-window buff t))
 315                (frame (and window (window-frame window))))
 316           (if frame
 317               (gnus-select-frame-set-input-focus frame)
 318             (pop-to-buffer buff t)))
 319         (error "The draft %s is under edit" file)))))
 320
 321 (provide 'gnus-draft)
 322
 323 ;;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 324 ;;; gnus-draft.el ends here