git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                (if (null arg) (not gnus-draft-mode)
  72                  (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (mml-mode)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number)))
  98     (gnus-summary-mark-as-read article gnus-canceled-mark)
  99     (gnus-draft-setup article gnus-newsgroup-name)
 100     (set-buffer-modified-p t)
 101     (save-buffer)
 102     (let ((gnus-verbose-backends nil))
 103       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 104     (push
 105      `((lambda ()
 106          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 107            (save-excursion
 108              (set-buffer ,gnus-summary-buffer)
 109              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 110      message-send-actions)))
 111
 112 (defun gnus-draft-send-message (&optional n)
 113   "Send the current draft."
 114   (interactive "P")
 115   (let ((articles (gnus-summary-work-articles n))
 116         article)
 117     (while (setq article (pop articles))
 118       (gnus-summary-remove-process-mark article)
 119       (unless (memq article gnus-newsgroup-unsendable)
 120         (gnus-draft-send article gnus-newsgroup-name t)
 121         (gnus-summary-mark-article article gnus-canceled-mark)))))
 122
 123 (defun gnus-draft-send (article &optional group interactive)
 124   "Send message ARTICLE."
 125   (gnus-draft-setup article (or group "nndraft:queue"))
 126   (let ((message-syntax-checks (if interactive nil
 127                                  'dont-check-for-anything-just-trust-me))
 128         (message-inhibit-body-encoding (or (not group)
 129                                            (equal group "nndraft:queue")
 130                                            message-inhibit-body-encoding))
 131         (message-send-hook (and group (not (equal group "nndraft:queue"))
 132                                 message-send-hook))
 133         (message-setup-hook nil)
 134         type method)
 135     ;; We read the meta-information that says how and where
 136     ;; this message is to be sent.
 137     (save-restriction
 138       (message-narrow-to-head)
 139       (when (re-search-forward
 140              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 141              nil t)
 142         (setq type (ignore-errors (read (current-buffer)))
 143               method (ignore-errors (read (current-buffer))))
 144         (message-remove-header gnus-agent-meta-information-header)))
 145     ;; Then we send it.  If we have no meta-information, we just send
 146     ;; it and let Message figure out how.
 147     (when (and (or (null method)
 148                    (gnus-server-opened method)
 149                    (gnus-open-server method))
 150                (if type
 151                    (let ((message-this-is-news (eq type 'news))
 152                          (message-this-is-mail (eq type 'mail))
 153                          (gnus-post-method method)
 154                          (message-post-method method))
 155                      (message-send-and-exit))
 156                  (message-send-and-exit)))
 157       (let ((gnus-verbose-backends nil))
 158         (gnus-request-expire-articles
 159          (list article) (or group "nndraft:queue") t)))))
 160
 161 (defun gnus-draft-send-all-messages ()
 162   "Send all the sendable drafts."
 163   (interactive)
 164   (gnus-uu-mark-buffer)
 165   (gnus-draft-send-message))
 166
 167 (defun gnus-group-send-drafts ()
 168   "Send all sendable articles from the queue group."
 169   (interactive)
 170   (gnus-activate-group "nndraft:queue")
 171   (save-excursion
 172     (let ((articles (nndraft-articles))
 173           (unsendable (gnus-uncompress-range
 174                        (cdr (assq 'unsend
 175                                   (gnus-info-marks
 176                                    (gnus-get-info "nndraft:queue"))))))
 177           article)
 178       (while (setq article (pop articles))
 179         (unless (memq article unsendable)
 180           (gnus-draft-send article))))))
 181
 182 ;;; Utility functions
 183
 184 ;;;!!!If this is byte-compiled, it fails miserably.
 185 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 186 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 187 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 188
 189 (progn
 190   (defun gnus-draft-setup (narticle group)
 191     (gnus-setup-message 'forward
 192       (let ((article narticle))
 193         (message-mail)
 194         (erase-buffer)
 195         (if (not (gnus-request-restore-buffer article group))
 196             (error "Couldn't restore the article")
 197           ;; Insert the separator.
 198           (if (equal group "nndraft:queue")
 199               (mime-to-mml))
 200           (goto-char (point-min))
 201           (search-forward "\n\n")
 202           (forward-char -1)
 203           (insert mail-header-separator)
 204           (forward-line 1)
 205           (message-set-auto-save-file-name))))))
 206
 207 (defun gnus-draft-article-sendable-p (article)
 208   "Say whether ARTICLE is sendable."
 209   (not (memq article gnus-newsgroup-unsendable)))
 210
 211 (provide 'gnus-draft)
 212
 213 ;;; gnus-draft.el ends here