git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   8 ;; Keywords: mail, news, MIME, offline
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'nndraft)
  36 (require 'gnus-agent)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Draft minor mode
  40
  41 (defvar gnus-draft-mode nil
  42   "Minor mode for providing a draft summary buffers.")
  43
  44 (defvar gnus-draft-mode-map nil)
  45
  46 (unless gnus-draft-mode-map
  47   (setq gnus-draft-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys gnus-draft-mode-map
  50     "Dt" gnus-draft-toggle-sending
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number))
  99         (group gnus-newsgroup-name))
 100     (gnus-summary-mark-as-read article gnus-canceled-mark)
 101     (gnus-draft-setup article group t)
 102     (set-buffer-modified-p t)
 103     (save-excursion
 104       (save-restriction
 105         (message-narrow-to-headers)
 106         (message-remove-header "date")))
 107     (save-buffer)
 108     (let ((gnus-verbose-backends nil))
 109       (gnus-request-expire-articles (list article) group t))
 110     (push
 111      `((lambda ()
 112          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 113            (save-excursion
 114              (set-buffer ,gnus-summary-buffer)
 115              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 116      message-send-actions)))
 117
 118 (defun gnus-draft-send-message (&optional n)
 119   "Send the current draft."
 120   (interactive "P")
 121   (let* ((articles (gnus-summary-work-articles n))
 122          (total (length articles))
 123          article)
 124     (while (setq article (pop articles))
 125       (gnus-summary-remove-process-mark article)
 126       (unless (memq article gnus-newsgroup-unsendable)
 127         (let ((message-sending-message
 128                (format "Sending message %d of %d..."
 129                        (- total (length articles)) total)))
 130           (gnus-draft-send article gnus-newsgroup-name t))
 131         (gnus-summary-mark-article article gnus-canceled-mark)))))
 132
 133 (defun gnus-draft-send (article &optional group interactive)
 134   "Send message ARTICLE."
 135   (let ((message-syntax-checks (if interactive message-syntax-checks
 136                                  'dont-check-for-anything-just-trust-me))
 137         (message-inhibit-body-encoding (or (not group)
 138                                            (equal group "nndraft:queue")
 139                                            message-inhibit-body-encoding))
 140         (message-send-hook (and group (not (equal group "nndraft:queue"))
 141                                 message-send-hook))
 142         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 143                                  message-setup-hook))
 144         type method move-to)
 145     (gnus-draft-setup article (or group "nndraft:queue"))
 146     ;; We read the meta-information that says how and where
 147     ;; this message is to be sent.
 148     (save-restriction
 149       (message-narrow-to-head)
 150       (when (re-search-forward
 151              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 152                      ":") nil t)
 153         (skip-syntax-forward "-")
 154         (setq move-to (buffer-substring (point) (gnus-point-at-eol)))
 155         (message-remove-header gnus-agent-target-move-group-header))
 156       (goto-char (point-min))
 157       (when (re-search-forward
 158              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 159              nil t)
 160         (setq type (ignore-errors (read (current-buffer)))
 161               method (ignore-errors (read (current-buffer))))
 162         (message-remove-header gnus-agent-meta-information-header)))
 163     ;; Let Agent restore any GCC lines and have message.el perform them.
 164     (gnus-agent-restore-gcc)
 165     ;; Then we send it.  If we have no meta-information, we just send
 166     ;; it and let Message figure out how.
 167     (when (and (or (null method)
 168                    (gnus-server-opened method)
 169                    (gnus-open-server method))
 170                (if type
 171                    (let ((message-this-is-news (eq type 'news))
 172                          (message-this-is-mail (eq type 'mail))
 173                          (gnus-post-method method)
 174                          (message-post-method method))
 175                      (if move-to
 176                          (gnus-inews-do-gcc move-to)
 177                        (message-send-and-exit)))
 178                  (if move-to
 179                      (gnus-inews-do-gcc move-to)
 180                    (message-send-and-exit))))
 181       (let ((gnus-verbose-backends nil))
 182         (gnus-request-expire-articles
 183          (list article) (or group "nndraft:queue") t)))))
 184
 185 (defun gnus-draft-send-all-messages ()
 186   "Send all the sendable drafts."
 187   (interactive)
 188   (gnus-uu-mark-buffer)
 189   (gnus-draft-send-message))
 190
 191 (defun gnus-group-send-queue ()
 192   "Send all sendable articles from the queue group."
 193   (interactive)
 194   (gnus-activate-group "nndraft:queue")
 195   (save-excursion
 196     (let* ((articles (nndraft-articles))
 197            (unsendable (gnus-uncompress-range
 198                         (cdr (assq 'unsend
 199                                    (gnus-info-marks
 200                                     (gnus-get-info "nndraft:queue"))))))
 201            (gnus-posting-styles nil)
 202            (total (length articles))
 203            article)
 204       (while (setq article (pop articles))
 205         (unless (memq article unsendable)
 206           (let ((message-sending-message
 207                  (format "Sending message %d of %d..."
 208                          (- total (length articles)) total)))
 209             (gnus-draft-send article)))))))
 210
 211 ;;;###autoload
 212 (defun gnus-draft-reminder ()
 213   "Reminder user if there are unsent drafts."
 214   (interactive)
 215   (if (gnus-alive-p)
 216       (let (active)
 217         (catch 'continue
 218           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 219             (setq active (gnus-activate-group group))
 220             (if (and active (>= (cdr active) (car active)))
 221                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 222                     (throw 'continue t)
 223                   (error "Stop!"))))))))
 224
 225 ;;; Utility functions
 226
 227 (defcustom gnus-draft-decoding-function
 228   #'mime-edit-decode-message-in-buffer
 229   "*Function called to decode the message from network representation."
 230   :group 'gnus-agent
 231   :type 'function)
 232
 233 ;;;!!!If this is byte-compiled, it fails miserably.
 234 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 235 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 236 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 237
 238 (defun gnus-draft-setup (narticle group &optional restore)
 239   (let (ga)
 240     (gnus-setup-message 'forward
 241       (let ((article narticle))
 242         (message-mail)
 243         (erase-buffer)
 244         (if (not (gnus-request-restore-buffer article group))
 245             (error "Couldn't restore the article")
 246           (when (and restore
 247                      (equal group "nndraft:queue"))
 248             (funcall gnus-draft-decoding-function))
 249           ;; Insert the separator.
 250           (goto-char (point-min))
 251           (search-forward "\n\n")
 252           (forward-char -1)
 253           (insert mail-header-separator)
 254           (forward-line 1)
 255           (setq ga (message-fetch-field gnus-draft-meta-information-header))
 256           (message-set-auto-save-file-name))))
 257     (gnus-backlog-remove-article group narticle)
 258     (when (and ga
 259                (ignore-errors (setq ga (car (read-from-string ga)))))
 260       (setq gnus-newsgroup-name
 261             (if (equal (car ga) "") nil (car ga)))
 262       (gnus-configure-posting-styles)
 263       (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 264       (setq message-post-method
 265             `(lambda (arg)
 266                (gnus-post-method arg ,(car ga))))
 267       (unless (equal (cadr ga) "")
 268         (message-add-action
 269          `(progn
 270             (gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 271             (gnus-request-set-mark ,(car ga) (list (list (list ,(cadr ga))
 272                                                          'add '(reply)))))
 273          'send)))))
 274
 275 (defun gnus-draft-article-sendable-p (article)
 276   "Say whether ARTICLE is sendable."
 277   (not (memq article gnus-newsgroup-unsendable)))
 278
 279 (provide 'gnus-draft)
 280
 281 ;;; gnus-draft.el ends here