git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   9 ;; Keywords: mail, news, MIME, offline
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34 (require 'message)
  35 (require 'gnus-msg)
  36 (require 'nndraft)
  37 (require 'gnus-agent)
  38 (eval-when-compile (require 'cl))
  39
  40 ;;; Draft minor mode
  41
  42 (defvar gnus-draft-mode nil
  43   "Minor mode for providing a draft summary buffers.")
  44
  45 (defvar gnus-draft-mode-map nil)
  46
  47 (unless gnus-draft-mode-map
  48   (setq gnus-draft-mode-map (make-sparse-keymap))
  49
  50   (gnus-define-keys gnus-draft-mode-map
  51     "Dt" gnus-draft-toggle-sending
  52     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  53     "De" gnus-draft-edit-message
  54     "Ds" gnus-draft-send-message
  55     "DS" gnus-draft-send-all-messages))
  56
  57 (defun gnus-draft-make-menu-bar ()
  58   (unless (boundp 'gnus-draft-menu)
  59     (easy-menu-define
  60      gnus-draft-menu gnus-draft-mode-map ""
  61      '("Drafts"
  62        ["Toggle whether to send" gnus-draft-toggle-sending t]
  63        ["Edit" gnus-draft-edit-message t]
  64        ["Send selected message(s)" gnus-draft-send-message t]
  65        ["Send all messages" gnus-draft-send-all-messages t]
  66        ["Delete draft" gnus-summary-delete-article t]))))
  67
  68 (defun gnus-draft-mode (&optional arg)
  69   "Minor mode for providing a draft summary buffers.
  70
  71 \\{gnus-draft-mode-map}"
  72   (interactive "P")
  73   (when (eq major-mode 'gnus-summary-mode)
  74     (when (set (make-local-variable 'gnus-draft-mode)
  75                (if (null arg) (not gnus-draft-mode)
  76                  (> (prefix-numeric-value arg) 0)))
  77       ;; Set up the menu.
  78       (when (gnus-visual-p 'draft-menu 'menu)
  79         (gnus-draft-make-menu-bar))
  80       (add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  81       (gnus-run-hooks 'gnus-draft-mode-hook))))
  82
  83 ;;; Commands
  84
  85 (defun gnus-draft-toggle-sending (article)
  86   "Toggle whether to send an article or not."
  87   (interactive (list (gnus-summary-article-number)))
  88   (if (gnus-draft-article-sendable-p article)
  89       (progn
  90         (push article gnus-newsgroup-unsendable)
  91         (gnus-summary-mark-article article gnus-unsendable-mark))
  92     (setq gnus-newsgroup-unsendable
  93           (delq article gnus-newsgroup-unsendable))
  94     (gnus-summary-mark-article article gnus-unread-mark))
  95   (gnus-summary-position-point))
  96
  97 (defun gnus-draft-edit-message ()
  98   "Enter a mail/post buffer to edit and send the draft."
  99   (interactive)
 100   (let ((article (gnus-summary-article-number))
 101         (group gnus-newsgroup-name))
 102     (gnus-draft-check-draft-articles (list article))
 103     (gnus-summary-mark-as-read article gnus-canceled-mark)
 104     (gnus-draft-setup article group t)
 105     (set-buffer-modified-p t)
 106     (save-excursion
 107       (save-restriction
 108         (message-narrow-to-headers)
 109         (message-remove-header "date")))
 110     (save-buffer)
 111     (let ((gnus-verbose-backends nil))
 112       (gnus-request-expire-articles (list article) group t))
 113     (push
 114      `((lambda ()
 115          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 116            (save-excursion
 117              (set-buffer ,gnus-summary-buffer)
 118              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 119      message-send-actions)))
 120
 121 (defun gnus-draft-send-message (&optional n)
 122   "Send the current draft."
 123   (interactive "P")
 124   (let* ((articles (gnus-summary-work-articles n))
 125          (total (length articles))
 126          article)
 127     (gnus-draft-check-draft-articles articles)
 128     (while (setq article (pop articles))
 129       (gnus-summary-remove-process-mark article)
 130       (unless (memq article gnus-newsgroup-unsendable)
 131         (let ((message-sending-message
 132                (format "Sending message %d of %d..."
 133                        (- total (length articles)) total)))
 134           (gnus-draft-send article gnus-newsgroup-name t))
 135         (gnus-summary-mark-article article gnus-canceled-mark)))))
 136
 137 (defun gnus-draft-send (article &optional group interactive)
 138   "Send message ARTICLE."
 139   (let* ((is-queue (or (not group)
 140                        (equal group "nndraft:queue")))
 141          (message-syntax-checks (if interactive message-syntax-checks
 142                                   'dont-check-for-anything-just-trust-me))
 143          (message-hidden-headers nil)
 144          (message-inhibit-body-encoding (or is-queue
 145                                             message-inhibit-body-encoding))
 146          (message-send-hook (and (not is-queue)
 147                                  message-send-hook))
 148          (message-setup-hook (and (not is-queue)
 149                                   message-setup-hook))
 150          (message-signature (and (not is-queue)
 151                                  message-signature))
 152          (gnus-agent-queue-mail (and (not is-queue)
 153                                      gnus-agent-queue-mail))
 154          (rfc2047-encode-encoded-words nil)
 155          type method move-to)
 156     (gnus-draft-setup article (or group "nndraft:queue"))
 157     ;; We read the meta-information that says how and where
 158     ;; this message is to be sent.
 159     (save-restriction
 160       (message-narrow-to-headers)
 161       (when (re-search-forward
 162              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 163                      ":") nil t)
 164         (skip-syntax-forward "-")
 165         (setq move-to (buffer-substring (point) (point-at-eol)))
 166         (message-remove-header gnus-agent-target-move-group-header))
 167       (goto-char (point-min))
 168       (when (re-search-forward
 169              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 170              nil t)
 171         (setq type (ignore-errors (read (current-buffer)))
 172               method (ignore-errors (read (current-buffer))))
 173         (message-remove-header gnus-agent-meta-information-header)))
 174     ;; Let Agent restore any GCC lines and have message.el perform them.
 175     (gnus-agent-restore-gcc)
 176     ;; Then we send it.  If we have no meta-information, we just send
 177     ;; it and let Message figure out how.
 178     (when (and (or (null method)
 179                    (gnus-server-opened method)
 180                    (gnus-open-server method))
 181                (if type
 182                    (let ((message-this-is-news (eq type 'news))
 183                          (message-this-is-mail (eq type 'mail))
 184                          (gnus-post-method method)
 185                          (message-post-method method))
 186                      (if move-to
 187                          (gnus-inews-do-gcc move-to)
 188                        (message-send-and-exit)))
 189                  (if move-to
 190                      (gnus-inews-do-gcc move-to)
 191                    (message-send-and-exit))))
 192       (let ((gnus-verbose-backends nil))
 193         (gnus-request-expire-articles
 194          (list article) (or group "nndraft:queue") t)))))
 195
 196 (defun gnus-draft-send-all-messages ()
 197   "Send all the sendable drafts."
 198   (interactive)
 199   (when (or
 200          gnus-expert-user
 201          (gnus-y-or-n-p
 202           "Send all drafts? "))
 203     (gnus-uu-mark-buffer)
 204     (gnus-draft-send-message)))
 205
 206 (defun gnus-group-send-queue ()
 207   "Send all sendable articles from the queue group."
 208   (interactive)
 209   (when (or gnus-plugged
 210             (not gnus-agent-prompt-send-queue)
 211             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 212     (gnus-activate-group "nndraft:queue")
 213     (save-excursion
 214       (let* ((articles (nndraft-articles))
 215              (unsendable (gnus-uncompress-range
 216                           (cdr (assq 'unsend
 217                                      (gnus-info-marks
 218                                       (gnus-get-info "nndraft:queue"))))))
 219              (gnus-posting-styles nil)
 220              (total (length articles))
 221              article)
 222         (while (setq article (pop articles))
 223           (unless (memq article unsendable)
 224             (let ((message-sending-message
 225                    (format "Sending message %d of %d..."
 226                            (- total (length articles)) total)))
 227               (gnus-draft-send article))))))))
 228
 229 ;;;###autoload
 230 (defun gnus-draft-reminder ()
 231   "Reminder user if there are unsent drafts."
 232   (interactive)
 233   (if (gnus-alive-p)
 234       (let (active)
 235         (catch 'continue
 236           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 237             (setq active (gnus-activate-group group))
 238             (if (and active (>= (cdr active) (car active)))
 239                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 240                     (throw 'continue t)
 241                   (error "Stop!"))))))))
 242
 243 ;;; Utility functions
 244
 245 (defcustom gnus-draft-decoding-function
 246   #'mime-edit-decode-message-in-buffer
 247   "*Function called to decode the message from network representation."
 248   :group 'gnus-agent
 249   :type 'function)
 250
 251 ;;;!!!If this is byte-compiled, it fails miserably.
 252 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 253 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 254 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 255
 256 (defun gnus-draft-setup (narticle group &optional restore)
 257   (let (ga)
 258     (gnus-setup-message 'forward
 259       (let ((article narticle))
 260         (message-mail)
 261         (erase-buffer)
 262         (if (not (gnus-request-restore-buffer article group))
 263             (error "Couldn't restore the article")
 264           (when (and restore
 265                      (equal group "nndraft:queue"))
 266             (funcall gnus-draft-decoding-function))
 267           ;; Insert the separator.
 268           (goto-char (point-min))
 269           (search-forward "\n\n")
 270           (forward-char -1)
 271           (save-restriction
 272             (narrow-to-region (point-min) (point))
 273             (setq ga
 274                   (message-fetch-field gnus-draft-meta-information-header)))
 275           (insert mail-header-separator)
 276           (forward-line 1)
 277           (message-set-auto-save-file-name))))
 278     (gnus-backlog-remove-article group narticle)
 279     (when (and ga
 280                (ignore-errors (setq ga (car (read-from-string ga)))))
 281       (setq gnus-newsgroup-name
 282             (if (equal (car ga) "") nil (car ga)))
 283       (gnus-configure-posting-styles)
 284       (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 285       (setq message-post-method
 286             `(lambda (arg)
 287                (gnus-post-method arg ,(car ga))))
 288       (unless (equal (cadr ga) "")
 289         (dolist (article (cdr ga))
 290           (message-add-action
 291            `(progn
 292               (gnus-add-mark ,(car ga) 'replied ,article)
 293               (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 294                                                            'add '(reply)))))
 295            'send))))))
 296
 297 (defun gnus-draft-article-sendable-p (article)
 298   "Say whether ARTICLE is sendable."
 299   (not (memq article gnus-newsgroup-unsendable)))
 300
 301 (defun gnus-draft-check-draft-articles (articles)
 302   "Check whether the draft articles ARTICLES are under edit."
 303   (when (equal gnus-newsgroup-name "nndraft:drafts")
 304     (let ((buffers (buffer-list))
 305           file buffs buff)
 306       (save-current-buffer
 307         (while (and articles
 308                     (not buff))
 309           (setq file (nndraft-article-filename (pop articles))
 310                 buffs buffers)
 311           (while buffs
 312             (set-buffer (setq buff (pop buffs)))
 313             (if (and buffer-file-name
 314                      (string-equal (file-truename buffer-file-name)
 315                                    (file-truename file))
 316                      (buffer-modified-p))
 317                 (setq buffs nil)
 318               (setq buff nil)))))
 319       (when buff
 320         (let* ((window (get-buffer-window buff t))
 321                (frame (and window (window-frame window))))
 322           (if frame
 323               (gnus-select-frame-set-input-focus frame)
 324             (pop-to-buffer buff t)))
 325         (error "The draft %s is under edit" file)))))
 326
 327 (provide 'gnus-draft)
 328
 329 ;;; gnus-draft.el ends here