git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   8 ;; Keywords: mail, news, MIME, offline
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'nndraft)
  36 (require 'gnus-agent)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Draft minor mode
  40
  41 (defvar gnus-draft-mode nil
  42   "Minor mode for providing a draft summary buffers.")
  43
  44 (defvar gnus-draft-mode-map nil)
  45
  46 (unless gnus-draft-mode-map
  47   (setq gnus-draft-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys gnus-draft-mode-map
  50     "Dt" gnus-draft-toggle-sending
  51     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  52     "De" gnus-draft-edit-message
  53     "Ds" gnus-draft-send-message
  54     "DS" gnus-draft-send-all-messages))
  55
  56 (defun gnus-draft-make-menu-bar ()
  57   (unless (boundp 'gnus-draft-menu)
  58     (easy-menu-define
  59      gnus-draft-menu gnus-draft-mode-map ""
  60      '("Drafts"
  61        ["Toggle whether to send" gnus-draft-toggle-sending t]
  62        ["Edit" gnus-draft-edit-message t]
  63        ["Send selected message(s)" gnus-draft-send-message t]
  64        ["Send all messages" gnus-draft-send-all-messages t]
  65        ["Delete draft" gnus-summary-delete-article t]))))
  66
  67 (defun gnus-draft-mode (&optional arg)
  68   "Minor mode for providing a draft summary buffers.
  69
  70 \\{gnus-draft-mode-map}"
  71   (interactive "P")
  72   (when (eq major-mode 'gnus-summary-mode)
  73     (when (set (make-local-variable 'gnus-draft-mode)
  74                (if (null arg) (not gnus-draft-mode)
  75                  (> (prefix-numeric-value arg) 0)))
  76       ;; Set up the menu.
  77       (when (gnus-visual-p 'draft-menu 'menu)
  78         (gnus-draft-make-menu-bar))
  79       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  80       (gnus-run-hooks 'gnus-draft-mode-hook))))
  81
  82 ;;; Commands
  83
  84 (defun gnus-draft-toggle-sending (article)
  85   "Toggle whether to send an article or not."
  86   (interactive (list (gnus-summary-article-number)))
  87   (if (gnus-draft-article-sendable-p article)
  88       (progn
  89         (push article gnus-newsgroup-unsendable)
  90         (gnus-summary-mark-article article gnus-unsendable-mark))
  91     (setq gnus-newsgroup-unsendable
  92           (delq article gnus-newsgroup-unsendable))
  93     (gnus-summary-mark-article article gnus-unread-mark))
  94   (gnus-summary-position-point))
  95
  96 (defun gnus-draft-edit-message ()
  97   "Enter a mail/post buffer to edit and send the draft."
  98   (interactive)
  99   (let ((article (gnus-summary-article-number))
 100         (group gnus-newsgroup-name))
 101     (gnus-summary-mark-as-read article gnus-canceled-mark)
 102     (gnus-draft-setup article group t)
 103     (set-buffer-modified-p t)
 104     (save-excursion
 105       (save-restriction
 106         (message-narrow-to-headers)
 107         (message-remove-header "date")))
 108     (save-buffer)
 109     (let ((gnus-verbose-backends nil))
 110       (gnus-request-expire-articles (list article) group t))
 111     (push
 112      `((lambda ()
 113          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 114            (save-excursion
 115              (set-buffer ,gnus-summary-buffer)
 116              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 117      message-send-actions)))
 118
 119 (defun gnus-draft-send-message (&optional n)
 120   "Send the current draft."
 121   (interactive "P")
 122   (let* ((articles (gnus-summary-work-articles n))
 123          (total (length articles))
 124          article)
 125     (while (setq article (pop articles))
 126       (gnus-summary-remove-process-mark article)
 127       (unless (memq article gnus-newsgroup-unsendable)
 128         (let ((message-sending-message
 129                (format "Sending message %d of %d..."
 130                        (- total (length articles)) total)))
 131           (gnus-draft-send article gnus-newsgroup-name t))
 132         (gnus-summary-mark-article article gnus-canceled-mark)))))
 133
 134 (defun gnus-draft-send (article &optional group interactive)
 135   "Send message ARTICLE."
 136   (let ((message-syntax-checks (if interactive message-syntax-checks
 137                                  'dont-check-for-anything-just-trust-me))
 138         (message-hidden-headers nil)
 139         (message-inhibit-body-encoding (or (not group)
 140                                            (equal group "nndraft:queue")
 141                                            message-inhibit-body-encoding))
 142         (message-send-hook (and group (not (equal group "nndraft:queue"))
 143                                 message-send-hook))
 144         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 145                                  message-setup-hook))
 146         type method move-to)
 147     (gnus-draft-setup article (or group "nndraft:queue"))
 148     ;; We read the meta-information that says how and where
 149     ;; this message is to be sent.
 150     (save-restriction
 151       (message-narrow-to-head)
 152       (when (re-search-forward
 153              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 154                      ":") nil t)
 155         (skip-syntax-forward "-")
 156         (setq move-to (buffer-substring (point) (gnus-point-at-eol)))
 157         (message-remove-header gnus-agent-target-move-group-header))
 158       (goto-char (point-min))
 159       (when (re-search-forward
 160              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 161              nil t)
 162         (setq type (ignore-errors (read (current-buffer)))
 163               method (ignore-errors (read (current-buffer))))
 164         (message-remove-header gnus-agent-meta-information-header)))
 165     ;; Let Agent restore any GCC lines and have message.el perform them.
 166     (gnus-agent-restore-gcc)
 167     ;; Then we send it.  If we have no meta-information, we just send
 168     ;; it and let Message figure out how.
 169     (when (and (or (null method)
 170                    (gnus-server-opened method)
 171                    (gnus-open-server method))
 172                (if type
 173                    (let ((message-this-is-news (eq type 'news))
 174                          (message-this-is-mail (eq type 'mail))
 175                          (gnus-post-method method)
 176                          (message-post-method method))
 177                      (if move-to
 178                          (gnus-inews-do-gcc move-to)
 179                        (message-send-and-exit)))
 180                  (if move-to
 181                      (gnus-inews-do-gcc move-to)
 182                    (message-send-and-exit))))
 183       (let ((gnus-verbose-backends nil))
 184         (gnus-request-expire-articles
 185          (list article) (or group "nndraft:queue") t)))))
 186
 187 (defun gnus-draft-send-all-messages ()
 188   "Send all the sendable drafts."
 189   (interactive)
 190   (when (or
 191          gnus-expert-user
 192          (gnus-y-or-n-p
 193           "Send all drafts? "))
 194     (gnus-uu-mark-buffer)
 195     (gnus-draft-send-message)))
 196
 197 (defun gnus-group-send-queue ()
 198   "Send all sendable articles from the queue group."
 199   (interactive)
 200   (gnus-activate-group "nndraft:queue")
 201   (save-excursion
 202     (let* ((articles (nndraft-articles))
 203            (unsendable (gnus-uncompress-range
 204                         (cdr (assq 'unsend
 205                                    (gnus-info-marks
 206                                     (gnus-get-info "nndraft:queue"))))))
 207            (gnus-posting-styles nil)
 208            (total (length articles))
 209            article)
 210       (while (setq article (pop articles))
 211         (unless (memq article unsendable)
 212           (let ((message-sending-message
 213                  (format "Sending message %d of %d..."
 214                          (- total (length articles)) total)))
 215             (gnus-draft-send article)))))))
 216
 217 ;;;###autoload
 218 (defun gnus-draft-reminder ()
 219   "Reminder user if there are unsent drafts."
 220   (interactive)
 221   (if (gnus-alive-p)
 222       (let (active)
 223         (catch 'continue
 224           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 225             (setq active (gnus-activate-group group))
 226             (if (and active (>= (cdr active) (car active)))
 227                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 228                     (throw 'continue t)
 229                   (error "Stop!"))))))))
 230
 231 ;;; Utility functions
 232
 233 (defcustom gnus-draft-decoding-function
 234   #'mime-edit-decode-message-in-buffer
 235   "*Function called to decode the message from network representation."
 236   :group 'gnus-agent
 237   :type 'function)
 238
 239 ;;;!!!If this is byte-compiled, it fails miserably.
 240 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 241 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 242 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 243
 244 (defun gnus-draft-setup (narticle group &optional restore)
 245   (let (ga)
 246     (gnus-setup-message 'forward
 247       (let ((article narticle))
 248         (message-mail)
 249         (erase-buffer)
 250         (if (not (gnus-request-restore-buffer article group))
 251             (error "Couldn't restore the article")
 252           (when (and restore
 253                      (equal group "nndraft:queue"))
 254             (funcall gnus-draft-decoding-function))
 255           ;; Insert the separator.
 256           (goto-char (point-min))
 257           (search-forward "\n\n")
 258           (forward-char -1)
 259           (insert mail-header-separator)
 260           (forward-line 1)
 261           (setq ga (message-fetch-field gnus-draft-meta-information-header))
 262           (message-set-auto-save-file-name))))
 263     (gnus-backlog-remove-article group narticle)
 264     (when (and ga
 265                (ignore-errors (setq ga (car (read-from-string ga)))))
 266       (setq gnus-newsgroup-name
 267             (if (equal (car ga) "") nil (car ga)))
 268       (gnus-configure-posting-styles)
 269       (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 270       (setq message-post-method
 271             `(lambda (arg)
 272                (gnus-post-method arg ,(car ga))))
 273       (unless (equal (cadr ga) "")
 274         (message-add-action
 275          `(progn
 276             (gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 277             (gnus-request-set-mark ,(car ga) (list (list (list ,(cadr ga))
 278                                                          'add '(reply)))))
 279          'send)))))
 280
 281 (defun gnus-draft-article-sendable-p (article)
 282   "Say whether ARTICLE is sendable."
 283   (not (memq article gnus-newsgroup-unsendable)))
 284
 285 (provide 'gnus-draft)
 286
 287 ;;; gnus-draft.el ends here