git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   8 ;; Keywords: mail, news, MIME, offline
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'message)
  34 (require 'gnus-msg)
  35 (require 'nndraft)
  36 (require 'gnus-agent)
  37 (eval-when-compile (require 'cl))
  38
  39 ;;; Draft minor mode
  40
  41 (defvar gnus-draft-mode nil
  42   "Minor mode for providing a draft summary buffers.")
  43
  44 (defvar gnus-draft-mode-map nil)
  45
  46 (unless gnus-draft-mode-map
  47   (setq gnus-draft-mode-map (make-sparse-keymap))
  48
  49   (gnus-define-keys gnus-draft-mode-map
  50     "Dt" gnus-draft-toggle-sending
  51     "De" gnus-draft-edit-message
  52     "Ds" gnus-draft-send-message
  53     "DS" gnus-draft-send-all-messages))
  54
  55 (defun gnus-draft-make-menu-bar ()
  56   (unless (boundp 'gnus-draft-menu)
  57     (easy-menu-define
  58      gnus-draft-menu gnus-draft-mode-map ""
  59      '("Drafts"
  60        ["Toggle whether to send" gnus-draft-toggle-sending t]
  61        ["Edit" gnus-draft-edit-message t]
  62        ["Send selected message(s)" gnus-draft-send-message t]
  63        ["Send all messages" gnus-draft-send-all-messages t]
  64        ["Delete draft" gnus-summary-delete-article t]))))
  65
  66 (defun gnus-draft-mode (&optional arg)
  67   "Minor mode for providing a draft summary buffers.
  68
  69 \\{gnus-draft-mode-map}"
  70   (interactive "P")
  71   (when (eq major-mode 'gnus-summary-mode)
  72     (when (set (make-local-variable 'gnus-draft-mode)
  73                (if (null arg) (not gnus-draft-mode)
  74                  (> (prefix-numeric-value arg) 0)))
  75       ;; Set up the menu.
  76       (when (gnus-visual-p 'draft-menu 'menu)
  77         (gnus-draft-make-menu-bar))
  78       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number)))
  99     (gnus-summary-mark-as-read article gnus-canceled-mark)
 100     (gnus-draft-setup-for-editing article gnus-newsgroup-name)
 101     (message-save-drafts)
 102     (let ((gnus-verbose-backends nil))
 103       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 104     (push
 105      `((lambda ()
 106          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 107            (save-excursion
 108              (set-buffer ,gnus-summary-buffer)
 109              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 110      message-send-actions)))
 111
 112 (defun gnus-draft-send-message (&optional n)
 113   "Send the current draft."
 114   (interactive "P")
 115   (let* ((articles (gnus-summary-work-articles n))
 116          (total (length articles))
 117          article)
 118     (while (setq article (pop articles))
 119       (gnus-summary-remove-process-mark article)
 120       (unless (memq article gnus-newsgroup-unsendable)
 121         (let ((message-sending-message
 122                (format "Sending message %d of %d..."
 123                        (- total (length articles)) total)))
 124           (gnus-draft-send article gnus-newsgroup-name t))
 125         (gnus-summary-mark-article article gnus-canceled-mark)))))
 126
 127 (defun gnus-draft-send (article &optional group interactive)
 128   "Send message ARTICLE."
 129   (let ((message-syntax-checks (if interactive nil
 130                                  'dont-check-for-anything-just-trust-me))
 131         (message-inhibit-body-encoding (or (not group)
 132                                            (equal group "nndraft:queue")
 133                                            message-inhibit-body-encoding))
 134         (message-send-hook (and group (not (equal group "nndraft:queue"))
 135                                 message-send-hook))
 136         (message-setup-hook (and group (not (equal group "nndraft:queue"))
 137                                  message-setup-hook))
 138         type method)
 139     (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 140     ;; We read the meta-information that says how and where
 141     ;; this message is to be sent.
 142     (save-restriction
 143       (message-narrow-to-head)
 144       (when (re-search-forward
 145              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 146              nil t)
 147         (setq type (ignore-errors (read (current-buffer)))
 148               method (ignore-errors (read (current-buffer))))
 149         (message-remove-header gnus-agent-meta-information-header)))
 150     ;; Let Agent restore any GCC lines and have message.el perform them.
 151     (gnus-agent-restore-gcc)
 152     ;; Then we send it.  If we have no meta-information, we just send
 153     ;; it and let Message figure out how.
 154     (when (let ((mail-header-separator ""))
 155             (cond ((eq type 'news)
 156                    (mime-edit-maybe-split-and-send
 157                     (function
 158                      (lambda ()
 159                        (interactive)
 160                        (funcall message-send-news-function method)
 161                        )))
 162                    (funcall message-send-news-function method)
 163                    )
 164                   ((eq type 'mail)
 165                    (mime-edit-maybe-split-and-send
 166                     (function
 167                      (lambda ()
 168                        (interactive)
 169                        (funcall message-send-mail-function)
 170                        )))
 171                    (funcall message-send-mail-function)
 172                    t)))
 173       (let ((gnus-verbose-backends nil))
 174         (gnus-request-expire-articles
 175          (list article) (or group "nndraft:queue") t)))))
 176
 177 (defun gnus-draft-send-all-messages ()
 178   "Send all the sendable drafts."
 179   (interactive)
 180   (gnus-uu-mark-buffer)
 181   (gnus-draft-send-message))
 182
 183 (defun gnus-group-send-drafts ()
 184   "Send all sendable articles from the queue group."
 185   (interactive)
 186   (gnus-activate-group "nndraft:queue")
 187   (save-excursion
 188     (let* ((articles (nndraft-articles))
 189            (unsendable (gnus-uncompress-range
 190                         (cdr (assq 'unsend
 191                                    (gnus-info-marks
 192                                     (gnus-get-info "nndraft:queue"))))))
 193            (total (length articles))
 194            article)
 195       (while (setq article (pop articles))
 196         (unless (memq article unsendable)
 197           (let ((message-sending-message
 198                  (format "Sending message %d of %d..."
 199                          (- total (length articles)) total)))
 200             (gnus-draft-send article)))))))
 201
 202 ;;;###autoload
 203 (defun gnus-draft-reminder ()
 204   "Reminder user if there are unsent drafts."
 205   (interactive)
 206   (if (gnus-alive-p)
 207       (let (active)
 208         (catch 'continue
 209           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 210             (setq active (gnus-activate-group group))
 211             (if (and active (>= (cdr active) (car active)))
 212                 (if (y-or-n-p "There are unsent drafts. Confirm to exit?")
 213                     (throw 'continue t)
 214                   (error "Stop!"))))))))
 215
 216 ;;; Utility functions
 217
 218 (defcustom gnus-draft-decoding-function
 219   #'mime-edit-decode-message-in-buffer
 220   "*Function called to decode the message from network representation."
 221   :group 'gnus-agent
 222   :type 'function)
 223
 224 ;;;!!!If this is byte-compiled, it fails miserably.
 225 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 226 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 227 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 228
 229 (defun gnus-draft-setup-for-editing (narticle group)
 230   (let (ga)
 231     (gnus-setup-message 'forward
 232       (let ((article narticle))
 233         (message-mail)
 234         (erase-buffer)
 235         (if (not (gnus-request-restore-buffer article group))
 236             (error "Couldn't restore the article")
 237           (funcall gnus-draft-decoding-function)
 238           ;; Insert the separator.
 239           (goto-char (point-min))
 240           (search-forward "\n\n")
 241           (forward-char -1)
 242           (insert mail-header-separator)
 243           (forward-line 1)
 244           (setq ga (message-fetch-field gnus-draft-meta-information-header))
 245           (message-set-auto-save-file-name))))
 246     (when (and ga
 247                (ignore-errors (setq ga (car (read-from-string ga)))))
 248       (setq message-post-method
 249             `(lambda (arg)
 250                (gnus-post-method arg ,(car ga))))
 251       (message-add-action
 252        `(gnus-add-mark ,(car ga) 'replied ,(cadr ga))
 253        'send))))
 254
 255 (defvar gnus-draft-send-draft-buffer " *send draft*")
 256 (defun gnus-draft-setup-for-sending (narticle group)
 257   (let ((article narticle))
 258     (if (not (get-buffer gnus-draft-send-draft-buffer))
 259         (get-buffer-create gnus-draft-send-draft-buffer))
 260     (set-buffer gnus-draft-send-draft-buffer)
 261     (erase-buffer)
 262     (if (not (gnus-request-restore-buffer article group))
 263         (error "Couldn't restore the article")
 264       )))
 265
 266 (defun gnus-draft-article-sendable-p (article)
 267   "Say whether ARTICLE is sendable."
 268   (not (memq article gnus-newsgroup-unsendable)))
 269
 270 (provide 'gnus-draft)
 271
 272 ;;; gnus-draft.el ends here