git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; Keywords: mail, news, MIME, offline
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "De" gnus-draft-edit-message
  50     "Ds" gnus-draft-send-message
  51     "DS" gnus-draft-send-all-messages))
  52
  53 (defun gnus-draft-make-menu-bar ()
  54   (unless (boundp 'gnus-draft-menu)
  55     (easy-menu-define
  56      gnus-draft-menu gnus-draft-mode-map ""
  57      '("Drafts"
  58        ["Toggle whether to send" gnus-draft-toggle-sending t]
  59        ["Edit" gnus-draft-edit-message t]
  60        ["Send selected message(s)" gnus-draft-send-message t]
  61        ["Send all messages" gnus-draft-send-all-messages t]
  62        ["Delete draft" gnus-summary-delete-article t]))))
  63
  64 (defun gnus-draft-mode (&optional arg)
  65   "Minor mode for providing a draft summary buffers.
  66
  67 \\{gnus-draft-mode-map}"
  68   (interactive "P")
  69   (when (eq major-mode 'gnus-summary-mode)
  70     (when (set (make-local-variable 'gnus-draft-mode)
  71                   (if (null arg) (not gnus-draft-mode)
  72                     (> (prefix-numeric-value arg) 0)))
  73       ;; Set up the menu.
  74       (when (gnus-visual-p 'draft-menu 'menu)
  75         (gnus-draft-make-menu-bar))
  76       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  77       (gnus-run-hooks 'gnus-draft-mode-hook))))
  78
  79 ;;; Commands
  80
  81 (defun gnus-draft-toggle-sending (article)
  82   "Toggle whether to send an article or not."
  83   (interactive (list (gnus-summary-article-number)))
  84   (if (gnus-draft-article-sendable-p article)
  85       (progn
  86         (push article gnus-newsgroup-unsendable)
  87         (gnus-summary-mark-article article gnus-unsendable-mark))
  88     (setq gnus-newsgroup-unsendable
  89           (delq article gnus-newsgroup-unsendable))
  90     (gnus-summary-mark-article article gnus-unread-mark))
  91   (gnus-summary-position-point))
  92
  93 (defun gnus-draft-edit-message ()
  94   "Enter a mail/post buffer to edit and send the draft."
  95   (interactive)
  96   (let ((article (gnus-summary-article-number)))
  97     (gnus-summary-mark-as-read article gnus-canceled-mark)
  98     (gnus-draft-setup-for-editing article gnus-newsgroup-name)
  99     (set-buffer-modified-p t)
 100     (save-buffer)
 101     (let ((gnus-verbose-backends nil))
 102       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 103     (push
 104      `((lambda ()
 105          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 106            (save-excursion
 107              (set-buffer ,gnus-summary-buffer)
 108              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 109      message-send-actions)))
 110
 111 (defun gnus-draft-send-message (&optional n)
 112   "Send the current draft."
 113   (interactive "P")
 114   (let ((articles (gnus-summary-work-articles n))
 115         article)
 116     (while (setq article (pop articles))
 117       (gnus-summary-remove-process-mark article)
 118       (unless (memq article gnus-newsgroup-unsendable)
 119         (gnus-draft-send article gnus-newsgroup-name)
 120         (gnus-summary-mark-article article gnus-canceled-mark)))))
 121
 122 (defun gnus-draft-send (article &optional group)
 123   "Send message ARTICLE."
 124   (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 125   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 126         message-send-hook type method)
 127     ;; We read the meta-information that says how and where
 128     ;; this message is to be sent.
 129     (save-restriction
 130       (message-narrow-to-head)
 131       (when (re-search-forward
 132              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 133              nil t)
 134         (setq type (ignore-errors (read (current-buffer)))
 135               method (ignore-errors (read (current-buffer))))
 136         (message-remove-header gnus-agent-meta-information-header)))
 137     ;; Then we send it.  If we have no meta-information, we just send
 138     ;; it and let Message figure out how.
 139     (when (let ((mail-header-separator ""))
 140             (cond ((eq type 'news)
 141                    (mime-edit-maybe-split-and-send
 142                     (function
 143                      (lambda ()
 144                        (interactive)
 145                        (funcall message-send-news-function method)
 146                        )))
 147                    (funcall message-send-news-function method)
 148                    )
 149                   ((eq type 'mail)
 150                    (mime-edit-maybe-split-and-send
 151                     (function
 152                      (lambda ()
 153                        (interactive)
 154                        (funcall message-send-mail-function)
 155                        )))
 156                    (funcall message-send-mail-function)
 157                    t)))
 158       (let ((gnus-verbose-backends nil))
 159         (gnus-request-expire-articles
 160          (list article) (or group "nndraft:queue") t)))))
 161
 162 (defun gnus-draft-send-all-messages ()
 163   "Send all the sendable drafts."
 164   (interactive)
 165   (gnus-uu-mark-buffer)
 166   (gnus-draft-send-message))
 167
 168 (defun gnus-group-send-drafts ()
 169   "Send all sendable articles from the queue group."
 170   (interactive)
 171   (gnus-activate-group "nndraft:queue")
 172   (save-excursion
 173     (let ((articles (nndraft-articles))
 174           (unsendable (gnus-uncompress-range
 175                        (cdr (assq 'unsend
 176                                   (gnus-info-marks
 177                                    (gnus-get-info "nndraft:queue"))))))
 178           article)
 179       (while (setq article (pop articles))
 180         (unless (memq article unsendable)
 181           (gnus-draft-send article))))))
 182
 183 ;;; Utility functions
 184
 185 (defcustom gnus-draft-decoding-function
 186   (function
 187    (lambda ()
 188      (mime-edit-decode-message-in-buffer nil)
 189      (eword-decode-header)
 190      ))
 191   "*Function called to decode the message from network representation."
 192   :group 'gnus-agent
 193   :type 'function)
 194
 195 ;;;!!!If this is byte-compiled, it fails miserably.
 196 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 197 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 198 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 199
 200 (defun gnus-draft-setup-for-editing (narticle group)
 201   (gnus-setup-message 'forward
 202     (let ((article narticle))
 203       (message-mail)
 204       (erase-buffer)
 205       (if (not (gnus-request-restore-buffer article group))
 206           (error "Couldn't restore the article")
 207         ;; Insert the separator.
 208         (funcall gnus-draft-decoding-function)
 209         (goto-char (point-min))
 210         (search-forward "\n\n")
 211         (forward-char -1)
 212         (insert mail-header-separator)
 213         (forward-line 1)
 214         (message-set-auto-save-file-name)))))
 215 ;;
 216 (defvar gnus-draft-send-draft-buffer " *send draft*")
 217 (defun gnus-draft-setup-for-sending (narticle group)
 218   (let ((article narticle))
 219     (if (not (get-buffer gnus-draft-send-draft-buffer))
 220         (get-buffer-create gnus-draft-send-draft-buffer))
 221     (set-buffer gnus-draft-send-draft-buffer)
 222     (erase-buffer)
 223     (if (not (gnus-request-restore-buffer article group))
 224         (error "Couldn't restore the article")
 225       )))
 226 ;; For draft TEST
 227
 228 (defun gnus-draft-article-sendable-p (article)
 229   "Say whether ARTICLE is sendable."
 230   (not (memq article gnus-newsgroup-unsendable)))
 231
 232 (provide 'gnus-draft)
 233
 234 ;;; gnus-draft.el ends here