git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   7 ;; Keywords: mail, news, MIME, offline
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "De" gnus-draft-edit-message
  51     "Ds" gnus-draft-send-message
  52     "DS" gnus-draft-send-all-messages))
  53
  54 (defun gnus-draft-make-menu-bar ()
  55   (unless (boundp 'gnus-draft-menu)
  56     (easy-menu-define
  57      gnus-draft-menu gnus-draft-mode-map ""
  58      '("Drafts"
  59        ["Toggle whether to send" gnus-draft-toggle-sending t]
  60        ["Edit" gnus-draft-edit-message t]
  61        ["Send selected message(s)" gnus-draft-send-message t]
  62        ["Send all messages" gnus-draft-send-all-messages t]
  63        ["Delete draft" gnus-summary-delete-article t]))))
  64
  65 (defun gnus-draft-mode (&optional arg)
  66   "Minor mode for providing a draft summary buffers.
  67
  68 \\{gnus-draft-mode-map}"
  69   (interactive "P")
  70   (when (eq major-mode 'gnus-summary-mode)
  71     (when (set (make-local-variable 'gnus-draft-mode)
  72                   (if (null arg) (not gnus-draft-mode)
  73                     (> (prefix-numeric-value arg) 0)))
  74       ;; Set up the menu.
  75       (when (gnus-visual-p 'draft-menu 'menu)
  76         (gnus-draft-make-menu-bar))
  77       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number)))
  98     (gnus-summary-mark-as-read article gnus-canceled-mark)
  99     (gnus-draft-setup-for-editing article gnus-newsgroup-name)
 100     (set-buffer-modified-p t)
 101     (save-buffer)
 102     (let ((gnus-verbose-backends nil))
 103       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 104     (push
 105      `((lambda ()
 106          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 107            (save-excursion
 108              (set-buffer ,gnus-summary-buffer)
 109              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 110      message-send-actions)))
 111
 112 (defun gnus-draft-send-message (&optional n)
 113   "Send the current draft."
 114   (interactive "P")
 115   (let ((articles (gnus-summary-work-articles n))
 116         article)
 117     (while (setq article (pop articles))
 118       (gnus-summary-remove-process-mark article)
 119       (unless (memq article gnus-newsgroup-unsendable)
 120         (gnus-draft-send article gnus-newsgroup-name t)
 121         (gnus-summary-mark-article article gnus-canceled-mark)))))
 122
 123 (defun gnus-draft-send (article &optional group interactive)
 124   "Send message ARTICLE."
 125   (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 126   (let ((message-syntax-checks (if interactive nil
 127                                  'dont-check-for-anything-just-trust-me))
 128         message-send-hook type method)
 129     ;; We read the meta-information that says how and where
 130     ;; this message is to be sent.
 131     (save-restriction
 132       (message-narrow-to-head)
 133       (when (re-search-forward
 134              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 135              nil t)
 136         (setq type (ignore-errors (read (current-buffer)))
 137               method (ignore-errors (read (current-buffer))))
 138         (message-remove-header gnus-agent-meta-information-header)))
 139     ;; Then we send it.  If we have no meta-information, we just send
 140     ;; it and let Message figure out how.
 141     (when (let ((mail-header-separator ""))
 142             (cond ((eq type 'news)
 143                    (mime-edit-maybe-split-and-send
 144                     (function
 145                      (lambda ()
 146                        (interactive)
 147                        (funcall message-send-news-function method)
 148                        )))
 149                    (funcall message-send-news-function method)
 150                    )
 151                   ((eq type 'mail)
 152                    (mime-edit-maybe-split-and-send
 153                     (function
 154                      (lambda ()
 155                        (interactive)
 156                        (funcall message-send-mail-function)
 157                        )))
 158                    (funcall message-send-mail-function)
 159                    t)))
 160       (let ((gnus-verbose-backends nil))
 161         (gnus-request-expire-articles
 162          (list article) (or group "nndraft:queue") t)))))
 163
 164 (defun gnus-draft-send-all-messages ()
 165   "Send all the sendable drafts."
 166   (interactive)
 167   (gnus-uu-mark-buffer)
 168   (gnus-draft-send-message))
 169
 170 (defun gnus-group-send-drafts ()
 171   "Send all sendable articles from the queue group."
 172   (interactive)
 173   (gnus-activate-group "nndraft:queue")
 174   (save-excursion
 175     (let ((articles (nndraft-articles))
 176           (unsendable (gnus-uncompress-range
 177                        (cdr (assq 'unsend
 178                                   (gnus-info-marks
 179                                    (gnus-get-info "nndraft:queue"))))))
 180           article)
 181       (while (setq article (pop articles))
 182         (unless (memq article unsendable)
 183           (gnus-draft-send article))))))
 184
 185 ;;; Utility functions
 186
 187 (defcustom gnus-draft-decoding-function
 188   #'mime-edit-decode-message-in-buffer
 189   "*Function called to decode the message from network representation."
 190   :group 'gnus-agent
 191   :type 'function)
 192
 193 ;;;!!!If this is byte-compiled, it fails miserably.
 194 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 195 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 196 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 197
 198 (defun gnus-draft-setup-for-editing (narticle group)
 199   (gnus-setup-message 'forward
 200     (let ((article narticle))
 201       (message-mail)
 202       (erase-buffer)
 203       (if (not (gnus-request-restore-buffer article group))
 204           (error "Couldn't restore the article")
 205         ;; Insert the separator.
 206         (funcall gnus-draft-decoding-function)
 207         (goto-char (point-min))
 208         (search-forward "\n\n")
 209         (forward-char -1)
 210         (insert mail-header-separator)
 211         (forward-line 1)
 212         (message-set-auto-save-file-name)))))
 213
 214 (defvar gnus-draft-send-draft-buffer " *send draft*")
 215 (defun gnus-draft-setup-for-sending (narticle group)
 216   (let ((article narticle))
 217     (if (not (get-buffer gnus-draft-send-draft-buffer))
 218         (get-buffer-create gnus-draft-send-draft-buffer))
 219     (set-buffer gnus-draft-send-draft-buffer)
 220     (erase-buffer)
 221     (if (not (gnus-request-restore-buffer article group))
 222         (error "Couldn't restore the article")
 223       )))
 224
 225 (defun gnus-draft-article-sendable-p (article)
 226   "Say whether ARTICLE is sendable."
 227   (not (memq article gnus-newsgroup-unsendable)))
 228
 229 (provide 'gnus-draft)
 230
 231 ;;; gnus-draft.el ends here