git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'gnus)
  29 (require 'gnus-sum)
  30 (require 'message)
  31 (require 'gnus-msg)
  32 (require 'nndraft)
  33 (require 'gnus-agent)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Draft minor mode
  37
  38 (defvar gnus-draft-mode nil
  39   "Minor mode for providing a draft summary buffers.")
  40
  41 (defvar gnus-draft-mode-map nil)
  42
  43 (unless gnus-draft-mode-map
  44   (setq gnus-draft-mode-map (make-sparse-keymap))
  45
  46   (gnus-define-keys gnus-draft-mode-map
  47     "Dt" gnus-draft-toggle-sending
  48     "De" gnus-draft-edit-message
  49     "Ds" gnus-draft-send-message
  50     "DS" gnus-draft-send-all-messages))
  51
  52 (defun gnus-draft-make-menu-bar ()
  53   (unless (boundp 'gnus-draft-menu)
  54     (easy-menu-define
  55      gnus-draft-menu gnus-draft-mode-map ""
  56      '("Drafts"
  57        ["Toggle whether to send" gnus-draft-toggle-sending t]
  58        ["Edit" gnus-draft-edit-message t]
  59        ["Send selected message(s)" gnus-draft-send-message t]
  60        ["Send all messages" gnus-draft-send-all-messages t]
  61        ["Delete draft" gnus-summary-delete-article t]))))
  62
  63 (defun gnus-draft-mode (&optional arg)
  64   "Minor mode for providing a draft summary buffers.
  65
  66 \\{gnus-draft-mode-map}"
  67   (interactive "P")
  68   (when (eq major-mode 'gnus-summary-mode)
  69     (when (set (make-local-variable 'gnus-draft-mode)
  70                   (if (null arg) (not gnus-draft-mode)
  71                     (> (prefix-numeric-value arg) 0)))
  72       ;; Set up the menu.
  73       (when (gnus-visual-p 'draft-menu 'menu)
  74         (gnus-draft-make-menu-bar))
  75       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  76       (gnus-run-hooks 'gnus-draft-mode-hook))))
  77
  78 ;;; Commands
  79
  80 (defun gnus-draft-toggle-sending (article)
  81   "Toggle whether to send an article or not."
  82   (interactive (list (gnus-summary-article-number)))
  83   (if (gnus-draft-article-sendable-p article)
  84       (progn
  85         (push article gnus-newsgroup-unsendable)
  86         (gnus-summary-mark-article article gnus-unsendable-mark))
  87     (setq gnus-newsgroup-unsendable
  88           (delq article gnus-newsgroup-unsendable))
  89     (gnus-summary-mark-article article gnus-unread-mark))
  90   (gnus-summary-position-point))
  91
  92 (defun gnus-draft-edit-message ()
  93   "Enter a mail/post buffer to edit and send the draft."
  94   (interactive)
  95   (let ((article (gnus-summary-article-number)))
  96     (gnus-summary-mark-as-read article gnus-canceled-mark)
  97     (gnus-draft-setup article gnus-newsgroup-name)
  98     (push
  99      `((lambda ()
 100          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 101            (save-excursion
 102              (set-buffer ,gnus-summary-buffer)
 103              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 104      message-send-actions)))
 105
 106 (defun gnus-draft-send-message (&optional n)
 107   "Send the current draft."
 108   (interactive "P")
 109   (let ((articles (gnus-summary-work-articles n))
 110         article)
 111     (while (setq article (pop articles))
 112       (gnus-summary-remove-process-mark article)
 113       (unless (memq article gnus-newsgroup-unsendable)
 114         (gnus-draft-send article gnus-newsgroup-name)
 115         (gnus-summary-mark-article article gnus-canceled-mark)))))
 116
 117 (defun gnus-draft-send (article &optional group)
 118   "Send message ARTICLE."
 119   (gnus-draft-setup article (or group "nndraft:queue"))
 120   (let ((message-syntax-checks 'dont-check-for-anything-just-trust-me)
 121         message-send-hook type method)
 122     ;; We read the meta-information that says how and where
 123     ;; this message is to be sent.
 124     (save-restriction
 125       (message-narrow-to-head)
 126       (when (re-search-forward
 127              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 128              nil t)
 129         (setq type (ignore-errors (read (current-buffer)))
 130               method (ignore-errors (read (current-buffer))))
 131         (message-remove-header gnus-agent-meta-information-header)))
 132     ;; Then we send it.  If we have no meta-information, we just send
 133     ;; it and let Message figure out how.
 134     (when (if type
 135               (let ((message-this-is-news (eq type 'news))
 136                     (message-this-is-mail (eq type 'mail))
 137                     (gnus-post-method method)
 138                     (message-post-method method))
 139                 (message-send-and-exit))
 140             (message-send-and-exit))
 141       (let ((gnus-verbose-backends nil))
 142         (gnus-request-expire-articles
 143          (list article) (or group "nndraft:queue") t)))))
 144
 145 (defun gnus-draft-send-all-messages ()
 146   "Send all the sendable drafts."
 147   (interactive)
 148   (gnus-uu-mark-buffer)
 149   (gnus-draft-send-message))
 150
 151 (defun gnus-group-send-drafts ()
 152   "Send all sendable articles from the queue group."
 153   (interactive)
 154   (gnus-activate-group "nndraft:queue")
 155   (save-excursion
 156     (let ((articles (nndraft-articles))
 157           (unsendable (gnus-uncompress-range
 158                        (cdr (assq 'unsend
 159                                   (gnus-info-marks
 160                                    (gnus-get-info "nndraft:queue"))))))
 161           article)
 162       (while (setq article (pop articles))
 163         (unless (memq article unsendable)
 164           (gnus-draft-send article))))))
 165
 166 ;;; Utility functions
 167
 168 ;;;!!!If this is byte-compiled, it fails miserably.
 169 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 170 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 171 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 172
 173 (progn
 174 (defun gnus-draft-setup (narticle group)
 175   (gnus-setup-message 'forward
 176     (let ((article narticle))
 177       (message-mail)
 178       (erase-buffer)
 179       (if (not (gnus-request-restore-buffer article group))
 180           (error "Couldn't restore the article")
 181         ;; Insert the separator.
 182         (goto-char (point-min))
 183         (search-forward "\n\n")
 184         (forward-char -1)
 185         (insert mail-header-separator)
 186         (forward-line 1)
 187         (message-set-auto-save-file-name))))))
 188
 189 (defun gnus-draft-article-sendable-p (article)
 190   "Say whether ARTICLE is sendable."
 191   (not (memq article gnus-newsgroup-unsendable)))
 192
 193 (provide 'gnus-draft)
 194
 195 ;;; gnus-draft.el ends here