git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Semi-gnus
   2 ;; Copyright (C) 1997,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;;      Tatsuya Ichikawa <t-ichi@po.shiojiri.ne.jp>
   7 ;; Keywords: mail, news, MIME, offline
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 (require 'gnus-sum)
  32 (require 'message)
  33 (require 'gnus-msg)
  34 (require 'nndraft)
  35 (require 'gnus-agent)
  36 (eval-when-compile (require 'cl))
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode nil
  41   "Minor mode for providing a draft summary buffers.")
  42
  43 (defvar gnus-draft-mode-map nil)
  44
  45 (unless gnus-draft-mode-map
  46   (setq gnus-draft-mode-map (make-sparse-keymap))
  47
  48   (gnus-define-keys gnus-draft-mode-map
  49     "Dt" gnus-draft-toggle-sending
  50     "De" gnus-draft-edit-message
  51     "Ds" gnus-draft-send-message
  52     "DS" gnus-draft-send-all-messages))
  53
  54 (defun gnus-draft-make-menu-bar ()
  55   (unless (boundp 'gnus-draft-menu)
  56     (easy-menu-define
  57      gnus-draft-menu gnus-draft-mode-map ""
  58      '("Drafts"
  59        ["Toggle whether to send" gnus-draft-toggle-sending t]
  60        ["Edit" gnus-draft-edit-message t]
  61        ["Send selected message(s)" gnus-draft-send-message t]
  62        ["Send all messages" gnus-draft-send-all-messages t]
  63        ["Delete draft" gnus-summary-delete-article t]))))
  64
  65 (defun gnus-draft-mode (&optional arg)
  66   "Minor mode for providing a draft summary buffers.
  67
  68 \\{gnus-draft-mode-map}"
  69   (interactive "P")
  70   (when (eq major-mode 'gnus-summary-mode)
  71     (when (set (make-local-variable 'gnus-draft-mode)
  72                   (if (null arg) (not gnus-draft-mode)
  73                     (> (prefix-numeric-value arg) 0)))
  74       ;; Set up the menu.
  75       (when (gnus-visual-p 'draft-menu 'menu)
  76         (gnus-draft-make-menu-bar))
  77       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  78       (gnus-run-hooks 'gnus-draft-mode-hook))))
  79
  80 ;;; Commands
  81
  82 (defun gnus-draft-toggle-sending (article)
  83   "Toggle whether to send an article or not."
  84   (interactive (list (gnus-summary-article-number)))
  85   (if (gnus-draft-article-sendable-p article)
  86       (progn
  87         (push article gnus-newsgroup-unsendable)
  88         (gnus-summary-mark-article article gnus-unsendable-mark))
  89     (setq gnus-newsgroup-unsendable
  90           (delq article gnus-newsgroup-unsendable))
  91     (gnus-summary-mark-article article gnus-unread-mark))
  92   (gnus-summary-position-point))
  93
  94 (defun gnus-draft-edit-message ()
  95   "Enter a mail/post buffer to edit and send the draft."
  96   (interactive)
  97   (let ((article (gnus-summary-article-number)))
  98     (gnus-summary-mark-as-read article gnus-canceled-mark)
  99     (gnus-draft-setup-for-editing article gnus-newsgroup-name)
 100     (message-save-drafts)
 101     (let ((gnus-verbose-backends nil))
 102       (gnus-request-expire-articles (list article) gnus-newsgroup-name t))
 103     (push
 104      `((lambda ()
 105          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 106            (save-excursion
 107              (set-buffer ,gnus-summary-buffer)
 108              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 109      message-send-actions)))
 110
 111 (defun gnus-draft-send-message (&optional n)
 112   "Send the current draft."
 113   (interactive "P")
 114   (let ((articles (gnus-summary-work-articles n))
 115         article)
 116     (while (setq article (pop articles))
 117       (gnus-summary-remove-process-mark article)
 118       (unless (memq article gnus-newsgroup-unsendable)
 119         (gnus-draft-send article gnus-newsgroup-name t)
 120         (gnus-summary-mark-article article gnus-canceled-mark)))))
 121
 122 (defun gnus-draft-send (article &optional group interactive)
 123   "Send message ARTICLE."
 124   (gnus-draft-setup-for-sending article (or group "nndraft:queue"))
 125   (let ((message-syntax-checks (if interactive nil
 126                                  'dont-check-for-anything-just-trust-me))
 127         (message-inhibit-body-encoding (or (not group)
 128                                            (equal group "nndraft:queue")
 129                                            message-inhibit-body-encoding))
 130         (message-send-hook (and group (not (equal group "nndraft:queue"))
 131                                 message-send-hook))
 132         type method)
 133     ;; We read the meta-information that says how and where
 134     ;; this message is to be sent.
 135     (save-restriction
 136       (message-narrow-to-head)
 137       (when (re-search-forward
 138              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 139              nil t)
 140         (setq type (ignore-errors (read (current-buffer)))
 141               method (ignore-errors (read (current-buffer))))
 142         (message-remove-header gnus-agent-meta-information-header)))
 143     ;; Then we send it.  If we have no meta-information, we just send
 144     ;; it and let Message figure out how.
 145     (when (let ((mail-header-separator ""))
 146             (cond ((eq type 'news)
 147                    (mime-edit-maybe-split-and-send
 148                     (function
 149                      (lambda ()
 150                        (interactive)
 151                        (funcall message-send-news-function method)
 152                        )))
 153                    (funcall message-send-news-function method)
 154                    )
 155                   ((eq type 'mail)
 156                    (mime-edit-maybe-split-and-send
 157                     (function
 158                      (lambda ()
 159                        (interactive)
 160                        (funcall message-send-mail-function)
 161                        )))
 162                    (funcall message-send-mail-function)
 163                    t)))
 164       (let ((gnus-verbose-backends nil))
 165         (gnus-request-expire-articles
 166          (list article) (or group "nndraft:queue") t)))))
 167
 168 (defun gnus-draft-send-all-messages ()
 169   "Send all the sendable drafts."
 170   (interactive)
 171   (gnus-uu-mark-buffer)
 172   (gnus-draft-send-message))
 173
 174 (defun gnus-group-send-drafts ()
 175   "Send all sendable articles from the queue group."
 176   (interactive)
 177   (gnus-activate-group "nndraft:queue")
 178   (save-excursion
 179     (let* ((articles (nndraft-articles))
 180            (unsendable (gnus-uncompress-range
 181                         (cdr (assq 'unsend
 182                                    (gnus-info-marks
 183                                     (gnus-get-info "nndraft:queue"))))))
 184            (n (length articles))
 185            article i)
 186       (while (setq article (pop articles))
 187         (setq i (- n (length articles)))
 188         (message "Sending message %d of %d." i n)
 189         (if (memq article unsendable)
 190             (message "Message %d of %d is unsendable." i n)
 191           (gnus-draft-send article))))))
 192
 193 ;;; Utility functions
 194
 195 (defcustom gnus-draft-decoding-function
 196   #'mime-edit-decode-message-in-buffer
 197   "*Function called to decode the message from network representation."
 198   :group 'gnus-agent
 199   :type 'function)
 200
 201 ;;;!!!If this is byte-compiled, it fails miserably.
 202 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 203 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 204 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 205
 206 (defun gnus-draft-setup-for-editing (narticle group)
 207   (gnus-setup-message 'forward
 208     (let ((article narticle))
 209       (message-mail)
 210       (erase-buffer)
 211       (if (not (gnus-request-restore-buffer article group))
 212           (error "Couldn't restore the article")
 213         ;; Insert the separator.
 214         (funcall gnus-draft-decoding-function)
 215         (goto-char (point-min))
 216         (search-forward "\n\n")
 217         (forward-char -1)
 218         (insert mail-header-separator)
 219         (forward-line 1)
 220         (message-set-auto-save-file-name)))))
 221
 222 (defvar gnus-draft-send-draft-buffer " *send draft*")
 223 (defun gnus-draft-setup-for-sending (narticle group)
 224   (let ((article narticle))
 225     (if (not (get-buffer gnus-draft-send-draft-buffer))
 226         (get-buffer-create gnus-draft-send-draft-buffer))
 227     (set-buffer gnus-draft-send-draft-buffer)
 228     (erase-buffer)
 229     (if (not (gnus-request-restore-buffer article group))
 230         (error "Couldn't restore the article")
 231       )))
 232
 233 (defun gnus-draft-article-sendable-p (article)
 234   "Say whether ARTICLE is sendable."
 235   (not (memq article gnus-newsgroup-unsendable)))
 236
 237 (provide 'gnus-draft)
 238
 239 ;;; gnus-draft.el ends here