git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-mlspl.el

   1 ;;; gnus-mlspl.el --- a group params-based mail splitting mechanism
   2 ;; Copyright (C) 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Oliva <oliva@lsd.ic.unicamp.br>
   6 ;; Keywords: news, mail
   7
   8 ;; This program is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; This program is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with this program; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 (require 'gnus)
  24 (require 'gnus-sum)
  25 (require 'gnus-group)
  26 (require 'nnmail)
  27
  28 (defvar gnus-group-split-updated-hook nil
  29   "Hook called just after nnmail-split-fancy is updated by gnus-group-split-update.")
  30
  31 (defvar gnus-group-split-default-catch-all-group "mail.misc"
  32   "Group used by gnus-group-split and gnus-group-split-update as default catch-all group.")
  33
  34 ;;;###autoload
  35 (defun gnus-group-split-setup (&optional auto-update catch-all)
  36   "Set up the split for nnmail-split-fancy.
  37 Sets things up so that nnmail-split-fancy is used for mail
  38 splitting, and defines the variable nnmail-split-fancy according with
  39 group parameters.
  40
  41 If AUTO-UPDATE is non-nil (prefix argument accepted, if called
  42 interactively), it makes sure nnmail-split-fancy is re-computed before
  43 getting new mail, by adding gnus-group-split-update to
  44 nnmail-pre-get-new-mail-hook."
  45   (interactive "P")
  46   (setq nnmail-split-methods 'nnmail-split-fancy)
  47   (when catch-all
  48     (setq gnus-group-split-default-catch-all-group catch-all))
  49   (gnus-group-split-update)
  50   (when auto-update
  51     (add-hook 'nnmail-pre-get-new-mail-hook 'gnus-group-split-update)))
  52
  53 ;;;###autoload
  54 (defun gnus-group-split-update (&optional catch-all)
  55   "Computes nnmail-split-fancy from group params.
  56 It does this by calling \(gnus-group-split-fancy nil nil DEFAULTGROUP)."
  57   (interactive)
  58   (setq nnmail-split-fancy
  59         (gnus-group-split-fancy
  60          nil nil (or catch-all gnus-group-split-default-catch-all-group)))
  61   (run-hooks 'gnus-group-split-updated-hook))
  62
  63 ;;;###autoload
  64 (defun gnus-group-split ()
  65   "Uses information from group parameters in order to split mail.
  66 See gnus-group-split-fancy for more information.
  67
  68 If no group is defined as catch-all, the value of
  69 gnus-group-split-default-catch-all-group is used.
  70
  71 gnus-group-split is a valid value for nnmail-split-methods."
  72   (let (nnmail-split-fancy)
  73     (gnus-group-split-update
  74      gnus-group-split-default-catch-all-group)
  75     (nnmail-split-fancy)))
  76
  77 ;;;###autoload
  78 (defun gnus-group-split-fancy
  79   (&optional groups no-crosspost catch-all)
  80   "Uses information from group parameters in order to split mail.  It
  81 can be embedded into nnmail-split-fancy lists with the SPLIT
  82
  83 \(: gnus-group-split-fancy GROUPS NO-CROSSPOST CATCH-ALL\)
  84
  85 GROUPS may be a regular expression or a list of group names, that will
  86 be used to select candidate groups.  If it is ommited or nil, all
  87 existing groups are considered.
  88
  89 if NO-CROSSPOST is ommitted or nil, a & split will be returned,
  90 otherwise, a | split, that does not allow crossposting, will be
  91 returned.
  92
  93 if CATCH-ALL is not nil, and there is no selected group whose
  94 SPLIT-REGEXP matches the empty string, nor is there a selected group
  95 whose SPLIT-SPEC is 'catch-all, this group name will be appended to
  96 the returned SPLIT list, as the last element in a '| SPLIT.
  97
  98 For each selected group, a SPLIT is composed like this: if SPLIT-SPEC
  99 is specified, this split is returned as-is (unless it is nil: in this
 100 case, the group is ignored).  Otherwise, if TO-ADDRESS, TO-LIST and/or
 101 EXTRA-ALIASES are specified, a regexp that matches any of them is
 102 constructed (extra-aliases may be a list).  Additionally, if
 103 SPLIT-REGEXP is specified, the regexp will be extended so that it
 104 matches this regexp too, and if SPLIT-EXCLUDE is specified, RESTRICT
 105 clauses will be generated.
 106
 107 For example, given the following group parameters:
 108
 109 nnml:mail.bar:
 110 \((to-address . \"bar@femail.com\")
 111  (split-regexp . \".*@femail\\\\.com\"))
 112 nnml:mail.foo:
 113 \((to-list . \"foo@nowhere.gov\")
 114  (extra-aliases \"foo@localhost\" \"foo-redist@home\")
 115  (split-exclude \"bugs-foo\" \"rambling-foo\")
 116  (admin-address . \"foo-request@nowhere.gov\"))
 117 nnml:mail.others:
 118 \((split-spec . catch-all))
 119
 120 Calling (gnus-group-split-fancy nil nil \"mail.misc\") returns:
 121
 122 \(| (& (any \"\\\\(bar@femail\\\\.com\\\\|.*@femail\\\\.com\\\\)\"
 123            \"mail.bar\")
 124       (any \"\\\\(foo@nowhere\\\\.gov\\\\|foo@localhost\\\\|foo-redist@home\\\\)\"
 125            - \"bugs-foo\" - \"rambling-foo\" \"mail.foo\"))
 126    \"mail.others\")"
 127   (let* ((newsrc (cdr gnus-newsrc-alist))
 128          split)
 129     (dolist (info newsrc)
 130       (let ((group (gnus-info-group info))
 131             (params (gnus-info-params info)))
 132         ;; For all GROUPs that match the specified GROUPS
 133         (when (or (not groups)
 134                   (and (listp groups)
 135                        (memq group groups))
 136                   (and (stringp groups)
 137                        (string-match groups group)))
 138           (let ((split-spec (assoc 'split-spec params)) group-clean)
 139             ;; Remove backend from group name
 140             (setq group-clean (string-match ":" group))
 141             (setq group-clean
 142                   (if group-clean
 143                       (substring group (1+ group-clean))
 144                     group))
 145             (if split-spec
 146                 (when (setq split-spec (cdr split-spec))
 147                   (if (eq split-spec 'catch-all)
 148                       ;; Emit catch-all only when requested
 149                       (when catch-all
 150                         (setq catch-all group-clean))
 151                     ;; Append split-spec to the main split
 152                     (push split-spec split)))
 153               ;; Let's deduce split-spec from other params
 154               (let ((to-address (cdr (assoc 'to-address params)))
 155                     (to-list (cdr (assoc 'to-list params)))
 156                     (extra-aliases (cdr (assoc 'extra-aliases params)))
 157                     (split-regexp (cdr (assoc 'split-regexp params)))
 158                     (split-exclude (cdr (assoc 'split-exclude params))))
 159                 (when (or to-address to-list extra-aliases split-regexp)
 160                   ;; regexp-quote to-address, to-list and extra-aliases
 161                   ;; and add them all to split-regexp
 162                   (setq split-regexp
 163                         (concat
 164                          "\\("
 165                          (mapconcat
 166                           'identity
 167                           (append
 168                            (and to-address (list (regexp-quote to-address)))
 169                            (and to-list (list (regexp-quote to-list)))
 170                            (and extra-aliases
 171                                 (if (listp extra-aliases)
 172                                     (mapcar 'regexp-quote extra-aliases)
 173                                   (list extra-aliases)))
 174                            (and split-regexp (list split-regexp)))
 175                           "\\|")
 176                          "\\)"))
 177                   ;; Now create the new SPLIT
 178                   (push (append
 179                          (list 'any split-regexp)
 180                          ;; Generate RESTRICTs for SPLIT-EXCLUDEs.
 181                          (if (listp split-exclude)
 182                              (mapcon (lambda (arg) (cons '- arg))
 183                                      split-exclude)
 184                            (list '- split-exclude))
 185                          (list group-clean))
 186                         split)
 187                   ;; If it matches the empty string, it is a catch-all
 188                   (when (string-match split-regexp "")
 189                     (setq catch-all nil)))))))))
 190     ;; Add catch-all if not crossposting
 191     (if (and catch-all no-crosspost)
 192         (push split catch-all))
 193     ;; Move it to the tail, while arranging that SPLITs appear in the
 194     ;; same order as groups.
 195     (setq split (reverse split))
 196     ;; Decide whether to accept cross-postings or not.
 197     (push (if no-crosspost '| '&) split)
 198     ;; Even if we can cross-post, catch-all should not get
 199     ;; cross-posts.
 200     (if (and catch-all (not no-crosspost))
 201         (setq split (list '| split catch-all)))
 202     split))
 203
 204 (provide 'gnus-mlspl)