git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Semi-gnus
   2 ;; Copyright (C) 1995,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   5 ;;         Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; Keywords: mail, news, MIME
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method nil
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current', Gnus will use the \"current\" select
  41 method when posting.  If it is nil (which is the default), Gnus will
  42 use the native posting method of the server.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not nil nor `native', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'. It can also be a list of
  49 methods. If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :type `(choice (const nil)
  53                  (const current)
  54                  (const native)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defvar gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names).")
  67
  68 (defvar gnus-mailing-list-groups nil
  69   "*Regexp matching groups that are really mailing lists.
  70 This is useful when you're reading a mailing list that has been
  71 gatewayed to a newsgroup, and you want to followup to an article in
  72 the group.")
  73
  74 (defvar gnus-add-to-list nil
  75   "*If non-nil, add a `to-list' parameter automatically.")
  76
  77 (defvar gnus-crosspost-complaint
  78   "Hi,
  79
  80 You posted the article below with the following Newsgroups header:
  81
  82 Newsgroups: %s
  83
  84 The %s group, at least, was an inappropriate recipient
  85 of this message.  Please trim your Newsgroups header to exclude this
  86 group before posting in the future.
  87
  88 Thank you.
  89
  90 "
  91   "Format string to be inserted when complaining about crossposts.
  92 The first %s will be replaced by the Newsgroups header;
  93 the second with the current group name.")
  94
  95 (defvar gnus-message-setup-hook nil
  96   "Hook run after setting up a message buffer.")
  97
  98 (defvar gnus-bug-create-help-buffer t
  99   "*Should we create the *Gnus Help Bug* buffer?")
 100
 101 (defvar gnus-posting-styles nil
 102   "*Alist of styles to use when posting.")
 103
 104 (defvar gnus-posting-style-alist
 105   '((organization . message-user-organization)
 106     (signature . message-signature)
 107     (signature-file . message-signature-file)
 108     (address . user-mail-address)
 109     (name . user-full-name))
 110   "*Mapping from style parameters to variables.")
 111
 112 ;;; Internal variables.
 113
 114 (defvar gnus-message-buffer "*Mail Gnus*")
 115 (defvar gnus-article-copy nil)
 116 (defvar gnus-last-posting-server nil)
 117 (defvar gnus-message-group-art nil)
 118
 119 (defconst gnus-bug-message
 120   "Sending a bug report to the Gnus Towers.
 121 ========================================
 122
 123 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 124 be sent to the Gnus Bug Exterminators.
 125
 126 At the bottom of the buffer you'll see lots of variable settings.
 127 Please do not delete those.  They will tell the Bug People what your
 128 environment is, so that it will be easier to locate the bugs.
 129
 130 If you have found a bug that makes Emacs go \"beep\", set
 131 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 132 and include the backtrace in your bug report.
 133
 134 Please describe the bug in annoying, painstaking detail.
 135
 136 Thank you for your help in stamping out bugs.
 137 ")
 138
 139 (eval-and-compile
 140   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 141   (autoload 'news-setup "rnewspost")
 142   (autoload 'news-reply-mode "rnewspost")
 143   (autoload 'rmail-dont-reply-to "mail-utils")
 144   (autoload 'rmail-output "rmailout"))
 145
 146 \f
 147 ;;;
 148 ;;; Gnus Posting Functions
 149 ;;;
 150
 151 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 152   "p" gnus-summary-post-news
 153   "f" gnus-summary-followup
 154   "F" gnus-summary-followup-with-original
 155   "c" gnus-summary-cancel-article
 156   "s" gnus-summary-supersede-article
 157   "r" gnus-summary-reply
 158   "R" gnus-summary-reply-with-original
 159   "w" gnus-summary-wide-reply
 160   "W" gnus-summary-wide-reply-with-original
 161   "n" gnus-summary-followup-to-mail
 162   "N" gnus-summary-followup-to-mail-with-original
 163   "m" gnus-summary-mail-other-window
 164   "u" gnus-uu-post-news
 165   "\M-c" gnus-summary-mail-crosspost-complaint
 166   "om" gnus-summary-mail-forward
 167   "op" gnus-summary-post-forward
 168   "Om" gnus-uu-digest-mail-forward
 169   "Op" gnus-uu-digest-post-forward)
 170
 171 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 172   "b" gnus-summary-resend-bounced-mail
 173   ;; "c" gnus-summary-send-draft
 174   "r" gnus-summary-resend-message)
 175
 176 ;;; Internal functions.
 177
 178 (defvar gnus-article-reply nil)
 179 (defmacro gnus-setup-message (config &rest forms)
 180   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 181         (buffer (make-symbol "gnus-setup-message-buffer"))
 182         (article (make-symbol "gnus-setup-message-article"))
 183         (group (make-symbol "gnus-setup-message-group")))
 184     `(let ((,winconf (current-window-configuration))
 185            (,buffer (buffer-name (current-buffer)))
 186            (,article (and gnus-article-reply (gnus-summary-article-number)))
 187            (,group gnus-newsgroup-name)
 188            (message-header-setup-hook
 189             (copy-sequence message-header-setup-hook)))
 190        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 191        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 192        (add-hook 'message-setup-hook 'gnus-configure-posting-styles)
 193        (unwind-protect
 194            (progn
 195              ,@forms)
 196          (gnus-inews-add-send-actions ,winconf ,buffer ,article)
 197          (setq gnus-message-buffer (current-buffer))
 198          (set (make-local-variable 'gnus-message-group-art)
 199               (cons ,group ,article))
 200          (make-local-variable 'gnus-newsgroup-name)
 201          (gnus-run-hooks 'gnus-message-setup-hook))
 202        (gnus-add-buffer)
 203        (gnus-configure-windows ,config t)
 204        (set-buffer-modified-p nil))))
 205
 206 (defun gnus-inews-add-send-actions (winconf buffer article)
 207   (make-local-hook 'message-sent-hook)
 208   (add-hook 'message-sent-hook 'gnus-inews-do-gcc nil t)
 209   (setq message-post-method
 210         `(lambda (arg)
 211            (gnus-post-method arg ,gnus-newsgroup-name)))
 212   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 213   (message-add-action
 214    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 215   (message-add-action
 216    `(when (gnus-buffer-exists-p ,buffer)
 217       (save-excursion
 218         (set-buffer ,buffer)
 219         ,(when article
 220            `(gnus-summary-mark-article-as-replied ,article))))
 221    'send))
 222
 223 (put 'gnus-setup-message 'lisp-indent-function 1)
 224 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 225
 226 ;;; Post news commands of Gnus group mode and summary mode
 227
 228 (defun gnus-group-mail ()
 229   "Start composing a mail."
 230   (interactive)
 231   (gnus-setup-message 'message
 232     (message-mail)))
 233
 234 (defun gnus-group-post-news (&optional arg)
 235   "Start composing a news message.
 236 If ARG, post to the group under point.
 237 If ARG is 1, prompt for a group name."
 238   (interactive "P")
 239   ;; Bind this variable here to make message mode hooks work ok.
 240   (let ((gnus-newsgroup-name
 241          (if arg
 242              (if (= 1 (prefix-numeric-value arg))
 243                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 244                                   (gnus-read-active-file-p))
 245                (gnus-group-group-name))
 246            "")))
 247     (gnus-post-news 'post gnus-newsgroup-name)))
 248
 249 (defun gnus-summary-post-news ()
 250   "Start composing a news message."
 251   (interactive)
 252   (gnus-post-news 'post gnus-newsgroup-name))
 253
 254 (defun gnus-summary-followup (yank &optional force-news)
 255   "Compose a followup to an article.
 256 If prefix argument YANK is non-nil, original article is yanked automatically."
 257   (interactive
 258    (list (and current-prefix-arg
 259               (gnus-summary-work-articles 1))))
 260   (when yank
 261     (gnus-summary-goto-subject (car yank)))
 262   (save-window-excursion
 263     (gnus-summary-select-article))
 264   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 265         (gnus-newsgroup-name gnus-newsgroup-name))
 266     ;; Send a followup.
 267     (gnus-post-news nil gnus-newsgroup-name
 268                     headers gnus-article-buffer
 269                     yank nil force-news)))
 270
 271 (defun gnus-summary-followup-with-original (n &optional force-news)
 272   "Compose a followup to an article and include the original article."
 273   (interactive "P")
 274   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 275
 276 (defun gnus-summary-followup-to-mail (&optional arg)
 277   "Followup to the current mail message via news."
 278   (interactive
 279    (list (and current-prefix-arg
 280               (gnus-summary-work-articles 1))))
 281   (gnus-summary-followup arg t))
 282
 283 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 284   "Followup to the current mail message via news."
 285   (interactive "P")
 286   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 287
 288 (defun gnus-inews-yank-articles (articles)
 289   (let (beg article)
 290     (message-goto-body)
 291     (while (setq article (pop articles))
 292       (save-window-excursion
 293         (set-buffer gnus-summary-buffer)
 294         (gnus-summary-select-article nil nil nil article)
 295         (gnus-summary-remove-process-mark article))
 296       (gnus-copy-article-buffer)
 297       (let ((message-reply-buffer gnus-article-copy)
 298             (message-reply-headers gnus-current-headers))
 299         (message-yank-original)
 300         (setq beg (or beg (mark t))))
 301       (when articles
 302         (insert "\n")))
 303     (push-mark)
 304     (goto-char beg)))
 305
 306 (defun gnus-summary-cancel-article (&optional n symp)
 307   "Cancel an article you posted.
 308 Uses the process-prefix convention.  If given the symbolic
 309 prefix `a', cancel using the standard posting method; if not
 310 post using the current select method."
 311   (interactive (gnus-interactive "P\ny"))
 312   (let ((articles (gnus-summary-work-articles n))
 313         (message-post-method
 314          `(lambda (arg)
 315             (gnus-post-method (not (eq symp 'a)) ,gnus-newsgroup-name)))
 316         article)
 317     (while (setq article (pop articles))
 318       (when (gnus-summary-select-article t nil nil article)
 319         (when (gnus-eval-in-buffer-window gnus-article-buffer
 320                 (save-excursion
 321                   (set-buffer gnus-original-article-buffer)
 322                   (message-cancel-news)))
 323           (gnus-summary-mark-as-read article gnus-canceled-mark)
 324           (gnus-cache-remove-article 1))
 325         (gnus-article-hide-headers-if-wanted))
 326       (gnus-summary-remove-process-mark article))))
 327
 328 (defun gnus-summary-supersede-article ()
 329   "Compose an article that will supersede a previous article.
 330 This is done simply by taking the old article and adding a Supersedes
 331 header line with the old Message-ID."
 332   (interactive)
 333   (let ((article (gnus-summary-article-number)))
 334     (gnus-setup-message 'reply-yank
 335       (gnus-summary-select-article t)
 336       (set-buffer gnus-original-article-buffer)
 337       (message-supersede)
 338       (push
 339        `((lambda ()
 340            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 341              (save-excursion
 342                (set-buffer ,gnus-summary-buffer)
 343                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 344                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 345        message-send-actions))))
 346
 347 \f
 348
 349 (defun gnus-copy-article-buffer (&optional article-buffer)
 350   ;; make a copy of the article buffer with all text properties removed
 351   ;; this copy is in the buffer gnus-article-copy.
 352   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 353   ;; this buffer should be passed to all mail/news reply/post routines.
 354   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 355   (buffer-disable-undo gnus-article-copy)
 356   (let ((article-buffer (or article-buffer gnus-article-buffer))
 357         end beg contents)
 358     (if (not (and (get-buffer article-buffer)
 359                   (gnus-buffer-exists-p article-buffer)))
 360         (error "Can't find any article buffer")
 361       (save-excursion
 362         (set-buffer article-buffer)
 363         (save-restriction
 364           ;; Copy over the (displayed) article buffer, delete
 365           ;; hidden text and remove text properties.
 366           (widen)
 367           (copy-to-buffer gnus-article-copy (point-min) (point-max))
 368           (set-buffer gnus-article-copy)
 369           (gnus-article-delete-text-of-type 'annotation)
 370           (gnus-remove-text-with-property 'gnus-prev)
 371           (gnus-remove-text-with-property 'gnus-next)
 372           (insert
 373            (prog1
 374                (format "%s" (buffer-string))
 375              (erase-buffer)))
 376           ;; Find the original headers.
 377           (set-buffer gnus-original-article-buffer)
 378           (goto-char (point-min))
 379           (while (looking-at message-unix-mail-delimiter)
 380             (forward-line 1))
 381           (setq beg (point))
 382           (setq end (or (search-forward "\n\n" nil t) (point)))
 383           ;; Delete the headers from the displayed articles.
 384           (set-buffer gnus-article-copy)
 385           (delete-region (goto-char (point-min))
 386                          (or (search-forward "\n\n" nil t) (point)))
 387           ;; Insert the original article headers.
 388           (insert-buffer-substring gnus-original-article-buffer beg end)
 389           (gnus-article-decode-rfc1522)))
 390       gnus-article-copy)))
 391
 392 (defun gnus-post-news (post &optional group header article-buffer yank subject
 393                             force-news)
 394   (when article-buffer
 395     (gnus-copy-article-buffer))
 396   (let ((gnus-article-reply article-buffer)
 397         (add-to-list gnus-add-to-list))
 398     (gnus-setup-message (cond (yank 'reply-yank)
 399                               (article-buffer 'reply)
 400                               (t 'message))
 401       (let* ((group (or group gnus-newsgroup-name))
 402              (pgroup group)
 403              to-address to-group mailing-list to-list
 404              newsgroup-p)
 405         (when group
 406           (setq to-address (gnus-group-find-parameter group 'to-address)
 407                 to-group (gnus-group-find-parameter group 'to-group)
 408                 to-list (gnus-group-find-parameter group 'to-list)
 409                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 410                 mailing-list (when gnus-mailing-list-groups
 411                                (string-match gnus-mailing-list-groups group))
 412                 group (gnus-group-real-name group)))
 413         (if (or (and to-group
 414                      (gnus-news-group-p to-group))
 415                 newsgroup-p
 416                 force-news
 417                 (and (gnus-news-group-p
 418                       (or pgroup gnus-newsgroup-name)
 419                       (if header (mail-header-number header)
 420                         gnus-current-article))
 421                      (not mailing-list)
 422                      (not to-list)
 423                      (not to-address)))
 424             ;; This is news.
 425             (if post
 426                 (message-news (or to-group group))
 427               (set-buffer gnus-article-copy)
 428               (gnus-msg-treat-broken-reply-to)
 429               (message-followup (if (or newsgroup-p force-news) nil to-group)))
 430           ;; The is mail.
 431           (if post
 432               (progn
 433                 (message-mail (or to-address to-list))
 434                 ;; Arrange for mail groups that have no `to-address' to
 435                 ;; get that when the user sends off the mail.
 436                 (when (and (not to-list)
 437                            (not to-address)
 438                            add-to-list)
 439                   (push (list 'gnus-inews-add-to-address pgroup)
 440                         message-send-actions)))
 441             (set-buffer gnus-article-copy)
 442             (gnus-msg-treat-broken-reply-to)
 443             (message-wide-reply to-address)))
 444         (when yank
 445           (gnus-inews-yank-articles yank))))))
 446
 447 (defun gnus-msg-treat-broken-reply-to ()
 448   "Remove the Reply-to header iff broken-reply-to."
 449   (when (gnus-group-find-parameter
 450          gnus-newsgroup-name 'broken-reply-to)
 451     (save-restriction
 452       (message-narrow-to-head)
 453       (message-remove-header "reply-to"))))
 454
 455 (defun gnus-post-method (arg group &optional silent)
 456   "Return the posting method based on GROUP and ARG.
 457 If SILENT, don't prompt the user."
 458   (let ((group-method (gnus-find-method-for-group group)))
 459     (cond
 460      ;; If the group-method is nil (which shouldn't happen) we use
 461      ;; the default method.
 462      ((null group-method)
 463       (or (and (null (eq gnus-post-method 'active)) gnus-post-method)
 464                gnus-select-method message-post-method))
 465      ;; We want the inverse of the default
 466      ((and arg (not (eq arg 0)))
 467       (if (eq gnus-post-method 'active)
 468           gnus-select-method
 469         group-method))
 470      ;; We query the user for a post method.
 471      ((or arg
 472           (and gnus-post-method
 473                (not (eq gnus-post-method 'current))
 474                (listp (car gnus-post-method))))
 475       (let* ((methods
 476               ;; Collect all methods we know about.
 477               (append
 478                (when (and gnus-post-method
 479                           (not (eq gnus-post-method 'current)))
 480                  (if (listp (car gnus-post-method))
 481                      gnus-post-method
 482                    (list gnus-post-method)))
 483                gnus-secondary-select-methods
 484                (mapcar 'cdr gnus-server-alist)
 485                (list gnus-select-method)
 486                (list group-method)))
 487              method-alist post-methods method)
 488         ;; Weed out all mail methods.
 489         (while methods
 490           (setq method (gnus-server-get-method "" (pop methods)))
 491           (when (or (gnus-method-option-p method 'post)
 492                     (gnus-method-option-p method 'post-mail))
 493             (push method post-methods)))
 494         ;; Create a name-method alist.
 495         (setq method-alist
 496               (mapcar
 497                (lambda (m)
 498                  (list (concat (cadr m) " (" (symbol-name (car m)) ")") m))
 499                post-methods))
 500         ;; Query the user.
 501         (cadr
 502          (assoc
 503           (setq gnus-last-posting-server
 504                 (if (and silent
 505                          gnus-last-posting-server)
 506                     ;; Just use the last value.
 507                     gnus-last-posting-server
 508                   (completing-read
 509                    "Posting method: " method-alist nil t
 510                    (cons (or gnus-last-posting-server "") 0))))
 511           method-alist))))
 512      ;; Override normal method.
 513      ((and (eq gnus-post-method 'current)
 514            (not (eq (car group-method) 'nndraft))
 515            (not arg))
 516       group-method)
 517      (gnus-post-method
 518       gnus-post-method)
 519      ;; Use the normal select method.
 520      (t gnus-select-method))))
 521
 522 \f
 523
 524 ;; Dummy to avoid byte-compile warning.
 525 (defvar nnspool-rejected-article-hook)
 526 (defvar xemacs-codename)
 527
 528 ;;; Since the X-Newsreader/X-Mailer are ``vanity'' headers, they might
 529 ;;; as well include the Emacs version as well.
 530 ;;; The following function works with later GNU Emacs, and XEmacs.
 531 (defun gnus-extended-version ()
 532   "Stringified gnus version."
 533   (interactive)
 534   gnus-version)
 535
 536 \f
 537 ;;;
 538 ;;; Gnus Mail Functions
 539 ;;;
 540
 541 ;;; Mail reply commands of Gnus summary mode
 542
 543 (defun gnus-summary-reply (&optional yank wide)
 544   "Start composing a reply mail to the current message.
 545 If prefix argument YANK is non-nil, the original article is yanked
 546 automatically."
 547   (interactive
 548    (list (and current-prefix-arg
 549               (gnus-summary-work-articles 1))))
 550   ;; Stripping headers should be specified with mail-yank-ignored-headers.
 551   (when yank
 552     (gnus-summary-goto-subject (car yank)))
 553   (let ((gnus-article-reply t))
 554     (gnus-setup-message (if yank 'reply-yank 'reply)
 555       (gnus-summary-select-article)
 556       (set-buffer (gnus-copy-article-buffer))
 557       (gnus-msg-treat-broken-reply-to)
 558       (message-reply nil wide)
 559       (when yank
 560         (gnus-inews-yank-articles yank)))))
 561
 562 (defun gnus-summary-reply-with-original (n &optional wide)
 563   "Start composing a reply mail to the current message.
 564 The original article will be yanked."
 565   (interactive "P")
 566   (gnus-summary-reply (gnus-summary-work-articles n) wide))
 567
 568 (defun gnus-summary-wide-reply (&optional yank)
 569   "Start composing a wide reply mail to the current message.
 570 If prefix argument YANK is non-nil, the original article is yanked
 571 automatically."
 572   (interactive
 573    (list (and current-prefix-arg
 574               (gnus-summary-work-articles 1))))
 575   (gnus-summary-reply yank t))
 576
 577 (defun gnus-summary-wide-reply-with-original (n)
 578   "Start composing a wide reply mail to the current message.
 579 The original article will be yanked."
 580   (interactive "P")
 581   (gnus-summary-reply-with-original n t))
 582
 583 (defun gnus-summary-mail-forward (&optional full-headers post)
 584   "Forward the current message to another user.
 585 If FULL-HEADERS (the prefix), include full headers when forwarding."
 586   (interactive "P")
 587   (gnus-setup-message 'forward
 588     (gnus-summary-select-article)
 589     (let ((charset default-mime-charset))
 590       (set-buffer gnus-original-article-buffer)
 591       (make-local-variable 'default-mime-charset)
 592       (setq default-mime-charset charset)
 593       )
 594     (let ((message-included-forward-headers
 595            (if full-headers "" message-included-forward-headers)))
 596       (message-forward post))))
 597
 598 (defun gnus-summary-resend-message (address n)
 599   "Resend the current article to ADDRESS."
 600   (interactive "sResend message(s) to: \nP")
 601   (let ((articles (gnus-summary-work-articles n))
 602         article)
 603     (while (setq article (pop articles))
 604       (gnus-summary-select-article nil nil nil article)
 605       (save-excursion
 606         (set-buffer gnus-original-article-buffer)
 607         (message-resend address)))))
 608
 609 (defun gnus-summary-post-forward (&optional full-headers)
 610   "Forward the current article to a newsgroup.
 611 If FULL-HEADERS (the prefix), include full headers when forwarding."
 612   (interactive "P")
 613   (gnus-summary-mail-forward full-headers t))
 614
 615 (defvar gnus-nastygram-message
 616   "The following article was inappropriately posted to %s.\n\n"
 617   "Format string to insert in nastygrams.
 618 The current group name will be inserted at \"%s\".")
 619
 620 (defun gnus-summary-mail-nastygram (n)
 621   "Send a nastygram to the author of the current article."
 622   (interactive "P")
 623   (when (or gnus-expert-user
 624             (gnus-y-or-n-p
 625              "Really send a nastygram to the author of the current article? "))
 626     (let ((group gnus-newsgroup-name))
 627       (gnus-summary-reply-with-original n)
 628       (set-buffer gnus-message-buffer)
 629       (message-goto-body)
 630       (insert (format gnus-nastygram-message group))
 631       (message-send-and-exit))))
 632
 633 (defun gnus-summary-mail-crosspost-complaint (n)
 634   "Send a complaint about crossposting to the current article(s)."
 635   (interactive "P")
 636   (let ((articles (gnus-summary-work-articles n))
 637         article)
 638     (while (setq article (pop articles))
 639       (set-buffer gnus-summary-buffer)
 640       (gnus-summary-goto-subject article)
 641       (let ((group (gnus-group-real-name gnus-newsgroup-name))
 642             newsgroups followup-to)
 643         (gnus-summary-select-article)
 644         (set-buffer gnus-original-article-buffer)
 645         (if (and (<= (length (message-tokenize-header
 646                               (setq newsgroups (mail-fetch-field "newsgroups"))
 647                               ", "))
 648                      1)
 649                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
 650                      (not (member group (message-tokenize-header
 651                                          followup-to ", ")))))
 652             (if followup-to
 653                 (gnus-message 1 "Followup-to restricted")
 654               (gnus-message 1 "Not a crossposted article"))
 655           (set-buffer gnus-summary-buffer)
 656           (gnus-summary-reply-with-original 1)
 657           (set-buffer gnus-message-buffer)
 658           (message-goto-body)
 659           (insert (format gnus-crosspost-complaint newsgroups group))
 660           (message-goto-subject)
 661           (re-search-forward " *$")
 662           (replace-match " (crosspost notification)" t t)
 663           (gnus-deactivate-mark)
 664           (when (gnus-y-or-n-p "Send this complaint? ")
 665             (message-send-and-exit)))))))
 666
 667 (defun gnus-summary-mail-other-window ()
 668   "Compose mail in other window."
 669   (interactive)
 670   (gnus-setup-message 'message
 671     (message-mail)))
 672
 673 (defun gnus-mail-parse-comma-list ()
 674   (let (accumulated
 675         beg)
 676     (skip-chars-forward " ")
 677     (while (not (eobp))
 678       (setq beg (point))
 679       (skip-chars-forward "^,")
 680       (while (zerop
 681               (save-excursion
 682                 (save-restriction
 683                   (let ((i 0))
 684                     (narrow-to-region beg (point))
 685                     (goto-char beg)
 686                     (logand (progn
 687                               (while (search-forward "\"" nil t)
 688                                 (incf i))
 689                               (if (zerop i) 2 i))
 690                             2)))))
 691         (skip-chars-forward ",")
 692         (skip-chars-forward "^,"))
 693       (skip-chars-backward " ")
 694       (push (buffer-substring beg (point))
 695             accumulated)
 696       (skip-chars-forward "^,")
 697       (skip-chars-forward ", "))
 698     accumulated))
 699
 700 (defun gnus-inews-add-to-address (group)
 701   (let ((to-address (mail-fetch-field "to")))
 702     (when (and to-address
 703                (gnus-alive-p))
 704       ;; This mail group doesn't have a `to-list', so we add one
 705       ;; here.  Magic!
 706       (when (gnus-y-or-n-p
 707              (format "Do you want to add this as `to-list': %s " to-address))
 708         (gnus-group-add-parameter group (cons 'to-list to-address))))))
 709
 710 (defun gnus-put-message ()
 711   "Put the current message in some group and return to Gnus."
 712   (interactive)
 713   (let ((reply gnus-article-reply)
 714         (winconf gnus-prev-winconf)
 715         (group gnus-newsgroup-name))
 716
 717     (or (and group (not (gnus-group-read-only-p group)))
 718         (setq group (read-string "Put in group: " nil
 719                                  (gnus-writable-groups))))
 720     (when (gnus-gethash group gnus-newsrc-hashtb)
 721       (error "No such group: %s" group))
 722
 723     (save-excursion
 724       (save-restriction
 725         (widen)
 726         (message-narrow-to-headers)
 727         (let (gnus-deletable-headers)
 728           (if (message-news-p)
 729               (message-generate-headers message-required-news-headers)
 730             (message-generate-headers message-required-mail-headers)))
 731         (goto-char (point-max))
 732         (insert "Gcc: " group "\n")
 733         (widen)))
 734
 735     (gnus-inews-do-gcc)
 736
 737     (when (get-buffer gnus-group-buffer)
 738       (when (gnus-buffer-exists-p (car-safe reply))
 739         (set-buffer (car reply))
 740         (and (cdr reply)
 741              (gnus-summary-mark-article-as-replied
 742               (cdr reply))))
 743       (when winconf
 744         (set-window-configuration winconf)))))
 745
 746 (defun gnus-article-mail (yank)
 747   "Send a reply to the address near point.
 748 If YANK is non-nil, include the original article."
 749   (interactive "P")
 750   (let ((address
 751          (buffer-substring
 752           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
 753           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
 754     (when address
 755       (message-reply address)
 756       (when yank
 757         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
 758
 759 (defvar nntp-server-type)
 760 (defun gnus-bug ()
 761   "Send a bug report to the Gnus maintainers."
 762   (interactive)
 763   (unless (gnus-alive-p)
 764     (error "Gnus has been shut down"))
 765   (gnus-setup-message 'bug
 766     (delete-other-windows)
 767     (when gnus-bug-create-help-buffer
 768       (switch-to-buffer "*Gnus Help Bug*")
 769       (erase-buffer)
 770       (insert gnus-bug-message)
 771       (goto-char (point-min)))
 772     (message-pop-to-buffer "*Gnus Bug*")
 773     (message-setup `((To . ,gnus-maintainer) (Subject . "")))
 774     (when gnus-bug-create-help-buffer
 775       (push `(gnus-bug-kill-buffer) message-send-actions))
 776     (goto-char (point-min))
 777     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
 778     (forward-line 1)
 779     (insert (gnus-version) "\n"
 780             (emacs-version) "\n")
 781     (when (and (boundp 'nntp-server-type)
 782                (stringp nntp-server-type))
 783       (insert nntp-server-type))
 784     (insert "\n\n\n\n\n")
 785     (gnus-debug)
 786     (goto-char (point-min))
 787     (search-forward "Subject: " nil t)
 788     (message "")))
 789
 790 (defun gnus-bug-kill-buffer ()
 791   (when (get-buffer "*Gnus Help Bug*")
 792     (kill-buffer "*Gnus Help Bug*")))
 793
 794 (defun gnus-debug ()
 795   "Attempts to go through the Gnus source file and report what variables have been changed.
 796 The source file has to be in the Emacs load path."
 797   (interactive)
 798   (let ((files '("gnus.el" "gnus-sum.el" "gnus-group.el"
 799                  "gnus-art.el" "gnus-start.el" "gnus-async.el"
 800                  "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 801                  "nnmail.el" "message.el"))
 802         (point (point))
 803         file expr olist sym)
 804     (gnus-message 4 "Please wait while we snoop your variables...")
 805     (sit-for 0)
 806     ;; Go through all the files looking for non-default values for variables.
 807     (save-excursion
 808       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
 809       (buffer-disable-undo (current-buffer))
 810       (while files
 811         (erase-buffer)
 812         (when (and (setq file (locate-library (pop files)))
 813                    (file-exists-p file))
 814           (insert-file-contents file)
 815           (goto-char (point-min))
 816           (if (not (re-search-forward "^;;* *Internal variables" nil t))
 817               (gnus-message 4 "Malformed sources in file %s" file)
 818             (narrow-to-region (point-min) (point))
 819             (goto-char (point-min))
 820             (while (setq expr (ignore-errors (read (current-buffer))))
 821               (ignore-errors
 822                 (and (or (eq (car expr) 'defvar)
 823                          (eq (car expr) 'defcustom))
 824                      (stringp (nth 3 expr))
 825                      (or (not (boundp (nth 1 expr)))
 826                          (not (equal (eval (nth 2 expr))
 827                                      (symbol-value (nth 1 expr)))))
 828                      (push (nth 1 expr) olist)))))))
 829       (kill-buffer (current-buffer)))
 830     (when (setq olist (nreverse olist))
 831       (insert "------------------ Environment follows ------------------\n\n"))
 832     (while olist
 833       (if (boundp (car olist))
 834           (condition-case ()
 835               (pp `(setq ,(car olist)
 836                          ,(if (or (consp (setq sym (symbol-value (car olist))))
 837                                   (and (symbolp sym)
 838                                        (not (or (eq sym nil)
 839                                                 (eq sym t)))))
 840                               (list 'quote (symbol-value (car olist)))
 841                             (symbol-value (car olist))))
 842                   (current-buffer))
 843             (error
 844              (format "(setq %s 'whatever)\n" (car olist))))
 845         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
 846       (setq olist (cdr olist)))
 847     (insert "\n\n")
 848     ;; Remove any control chars - they seem to cause trouble for some
 849     ;; mailers.  (Byte-compiled output from the stuff above.)
 850     (goto-char point)
 851     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
 852       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
 853                      t t))))
 854
 855 ;;; Treatment of rejected articles.
 856 ;;; Bounced mail.
 857
 858 (defun gnus-summary-resend-bounced-mail (&optional fetch)
 859   "Re-mail the current message.
 860 This only makes sense if the current message is a bounce message than
 861 contains some mail you have written which has been bounced back to
 862 you.
 863 If FETCH, try to fetch the article that this is a reply to, if indeed
 864 this is a reply."
 865   (interactive "P")
 866   (gnus-summary-select-article t)
 867   (set-buffer gnus-original-article-buffer)
 868   (gnus-setup-message 'compose-bounce
 869     (let* ((references (mail-fetch-field "references"))
 870            (parent (and references (gnus-parent-id references))))
 871       (message-bounce)
 872       ;; If there are references, we fetch the article we answered to.
 873       (and fetch parent
 874            (gnus-summary-refer-article parent)
 875            (gnus-summary-show-all-headers)))))
 876
 877 ;;; Gcc handling.
 878
 879 ;; Do Gcc handling, which copied the message over to some group.
 880 (defun gnus-inews-do-gcc (&optional gcc)
 881   (interactive)
 882   (when (gnus-alive-p)
 883     (save-excursion
 884       (save-restriction
 885         (message-narrow-to-headers)
 886         (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
 887               (coding-system-for-write 'raw-text)
 888               groups group method)
 889           (when gcc
 890             (message-remove-header "gcc")
 891             (widen)
 892             (setq groups (message-tokenize-header gcc " ,"))
 893             ;; Copy the article over to some group(s).
 894             (while (setq group (pop groups))
 895               (gnus-check-server
 896                (setq method
 897                      (cond ((and (null (gnus-get-info group))
 898                                  (eq (car gnus-message-archive-method)
 899                                      (car
 900                                       (gnus-server-to-method
 901                                        (gnus-group-method group)))))
 902                             ;; If the group doesn't exist, we assume
 903                             ;; it's an archive group...
 904                             gnus-message-archive-method)
 905                            ;; Use the method.
 906                            ((gnus-info-method (gnus-get-info group))
 907                             (gnus-info-method (gnus-get-info group)))
 908                            ;; Find the method.
 909                            (t (gnus-group-method group)))))
 910               (gnus-check-server method)
 911               (unless (gnus-request-group group t method)
 912                 (gnus-request-create-group group method))
 913               (save-excursion
 914                 (nnheader-set-temp-buffer " *acc*")
 915                 (insert-buffer-substring message-encoding-buffer)
 916                 (gnus-run-hooks 'gnus-before-do-gcc-hook)
 917                 (goto-char (point-min))
 918                 (when (re-search-forward
 919                        (concat "^" (regexp-quote mail-header-separator) "$")
 920                        nil t)
 921                   (replace-match "" t t ))
 922                 (unless (gnus-request-accept-article group method t)
 923                   (gnus-message 1 "Couldn't store article in group %s: %s"
 924                                 group (gnus-status-message method))
 925                   (sit-for 2))
 926                 (kill-buffer (current-buffer))))))))))
 927
 928 (defun gnus-inews-insert-gcc ()
 929   "Insert Gcc headers based on `gnus-outgoing-message-group'."
 930   (save-excursion
 931     (save-restriction
 932       (message-narrow-to-headers)
 933       (let* ((group gnus-outgoing-message-group)
 934              (gcc (cond
 935                    ((gnus-functionp group)
 936                     (funcall group))
 937                    ((or (stringp group) (list group))
 938                     group))))
 939         (when gcc
 940           (insert "Gcc: "
 941                   (if (stringp gcc) gcc
 942                     (mapconcat 'identity gcc " "))
 943                   "\n"))))))
 944
 945 (defun gnus-inews-insert-archive-gcc (&optional group)
 946   "Insert the Gcc to say where the article is to be archived."
 947   (let* ((var gnus-message-archive-group)
 948          (group (or group gnus-newsgroup-name ""))
 949          (gcc-self-val
 950           (and gnus-newsgroup-name
 951                (gnus-group-find-parameter
 952                 gnus-newsgroup-name 'gcc-self)))
 953          result
 954          (groups
 955           (cond
 956            ((null gnus-message-archive-method)
 957             ;; Ignore.
 958             nil)
 959            ((stringp var)
 960             ;; Just a single group.
 961             (list var))
 962            ((null var)
 963             ;; We don't want this.
 964             nil)
 965            ((and (listp var) (stringp (car var)))
 966             ;; A list of groups.
 967             var)
 968            ((gnus-functionp var)
 969             ;; A function.
 970             (funcall var group))
 971            (t
 972             ;; An alist of regexps/functions/forms.
 973             (while (and var
 974                         (not
 975                          (setq result
 976                                (cond
 977                                 ((stringp (caar var))
 978                                  ;; Regexp.
 979                                  (when (string-match (caar var) group)
 980                                    (cdar var)))
 981                                 ((gnus-functionp (car var))
 982                                  ;; Function.
 983                                  (funcall (car var) group))
 984                                 (t
 985                                  (eval (car var)))))))
 986               (setq var (cdr var)))
 987             result)))
 988          name)
 989     (when (or groups gcc-self-val)
 990       (when (stringp groups)
 991         (setq groups (list groups)))
 992       (save-excursion
 993         (save-restriction
 994           (message-narrow-to-headers)
 995           (goto-char (point-max))
 996           (insert "Gcc: ")
 997           (if gcc-self-val
 998               ;; Use the `gcc-self' param value instead.
 999               (progn
1000                 (insert
1001                  (if (stringp gcc-self-val)
1002                      gcc-self-val
1003                    group))
1004                 (if (not (eq gcc-self-val 'none))
1005                     (insert "\n")
1006                   (progn
1007                     (beginning-of-line)
1008                     (kill-line))))
1009             ;; Use the list of groups.
1010             (while (setq name (pop groups))
1011               (insert (if (string-match ":" name)
1012                           name
1013                         (gnus-group-prefixed-name
1014                          name gnus-message-archive-method)))
1015               (when groups
1016                 (insert " ")))
1017             (insert "\n")))))))
1018
1019 ;;; Posting styles.
1020
1021 (defun gnus-configure-posting-styles ()
1022   "Configure posting styles according to `gnus-posting-styles'."
1023   (let ((styles gnus-posting-styles)
1024         (gnus-newsgroup-name (or gnus-newsgroup-name ""))
1025         style match variable attribute value value-value)
1026     ;; Go through all styles and look for matches.
1027     (while styles
1028       (setq style (pop styles)
1029             match (pop style))
1030       (when (cond ((stringp match)
1031                    ;; Regexp string match on the group name.
1032                    (string-match match gnus-newsgroup-name))
1033                   ((or (symbolp match)
1034                        (gnus-functionp match))
1035                    (cond ((gnus-functionp match)
1036                           ;; Function to be called.
1037                           (funcall match))
1038                          ((boundp match)
1039                           ;; Variable to be checked.
1040                           (symbol-value match))))
1041                   ((listp match)
1042                    ;; This is a form to be evaled.
1043                    (eval match)))
1044         ;; We have a match, so we set the variables.
1045         (while style
1046           (setq attribute (pop style)
1047                 value (cadr attribute)
1048                 variable nil)
1049           ;; We find the variable that is to be modified.
1050           (if (and (not (stringp (car attribute)))
1051                    (not (eq 'body (car attribute)))
1052                    (not (setq variable (cdr (assq (car attribute)
1053                                                   gnus-posting-style-alist)))))
1054               (message "Couldn't find attribute %s" (car attribute))
1055             ;; We get the value.
1056             (setq value-value
1057                   (cond ((stringp value)
1058                          value)
1059                         ((or (symbolp value)
1060                              (gnus-functionp value))
1061                          (cond ((gnus-functionp value)
1062                                 (funcall value))
1063                                ((boundp value)
1064                                 (symbol-value value))))
1065                         ((listp value)
1066                          (eval value))))
1067             (if variable
1068                 ;; This is an ordinary variable.
1069                 (set (make-local-variable variable) value-value)
1070               ;; This is either a body or a header to be inserted in the
1071               ;; message
1072               (when value-value
1073                 (let ((attr (car attribute)))
1074                   (if (eq 'body attr)
1075                       (save-excursion
1076                         (goto-char (point-max))
1077                         (insert value-value))
1078                     (save-excursion
1079                       (message-goto-eoh)
1080                       (insert (if (stringp attr) attr (symbol-name attr))
1081                               ": " value-value "\n"))))))))))))
1082
1083 ;;; Allow redefinition of functions.
1084
1085 (gnus-ems-redefine)
1086
1087 (provide 'gnus-msg)
1088
1089 ;;; gnus-msg.el ends here