git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36
  37 (defcustom gnus-post-method 'current
  38   "*Preferred method for posting USENET news.
  39
  40 If this variable is `current' (which is the default), Gnus will use
  41 the \"current\" select method when posting.  If it is `native', Gnus
  42 will use the native select method when posting.
  43
  44 This method will not be used in mail groups and the like, only in
  45 \"real\" newsgroups.
  46
  47 If not `native' nor `current', the value must be a valid method as discussed
  48 in the documentation of `gnus-select-method'.  It can also be a list of
  49 methods.  If that is the case, the user will be queried for what select
  50 method to use when posting."
  51   :group 'gnus-group-foreign
  52   :link '(custom-manual "(gnus)Posting Server")
  53   :type `(choice (const native)
  54                  (const current)
  55                  (sexp :tag "Methods" ,gnus-select-method)))
  56
  57 (defcustom gnus-outgoing-message-group nil
  58   "*All outgoing messages will be put in this group.
  59 If you want to store all your outgoing mail and articles in the group
  60 \"nnml:archive\", you set this variable to that value.  This variable
  61 can also be a list of group names.
  62
  63 If you want to have greater control over what group to put each
  64 message in, you can set this variable to a function that checks the
  65 current newsgroup name and then returns a suitable group name (or list
  66 of names)."
  67   :group 'gnus-message
  68   :type '(choice (string :tag "Group")
  69                  (function)))
  70
  71 (defcustom gnus-mailing-list-groups nil
  72   "*Regexp matching groups that are really mailing lists.
  73 This is useful when you're reading a mailing list that has been
  74 gatewayed to a newsgroup, and you want to followup to an article in
  75 the group."
  76   :group 'gnus-message
  77   :type 'regexp)
  78
  79 (defcustom gnus-add-to-list nil
  80   "*If non-nil, add a `to-list' parameter automatically."
  81   :group 'gnus-message
  82   :type 'boolean)
  83
  84 (defcustom gnus-crosspost-complaint
  85   "Hi,
  86
  87 You posted the article below with the following Newsgroups header:
  88
  89 Newsgroups: %s
  90
  91 The %s group, at least, was an inappropriate recipient
  92 of this message.  Please trim your Newsgroups header to exclude this
  93 group before posting in the future.
  94
  95 Thank you.
  96
  97 "
  98   "Format string to be inserted when complaining about crossposts.
  99 The first %s will be replaced by the Newsgroups header;
 100 the second with the current group name."
 101   :group 'gnus-message
 102   :type 'string)
 103
 104 (defcustom gnus-message-setup-hook nil
 105   "Hook run after setting up a message buffer."
 106   :group 'gnus-message
 107   :type 'hook)
 108
 109 (defcustom gnus-bug-create-help-buffer t
 110   "*Should we create the *Gnus Help Bug* buffer?"
 111   :group 'gnus-message
 112   :type 'boolean)
 113
 114 (defcustom gnus-posting-styles nil
 115   "*Alist of styles to use when posting.
 116 See Info node `(gnus)Posting Styles'."
 117   :group 'gnus-message
 118   :link '(custom-manual "(gnus)Posting Styles")
 119   :type '(repeat (cons (choice (regexp)
 120                                (variable)
 121                                (list (const header)
 122                                      (string :tag "Header")
 123                                      (regexp :tag "Regexp"))
 124                                (function)
 125                                (sexp))
 126                        (repeat (list
 127                                 (choice (const signature)
 128                                         (const signature-file)
 129                                         (const organization)
 130                                         (const address)
 131                                         (const x-face-file)
 132                                         (const name)
 133                                         (const body)
 134                                         (symbol)
 135                                         (string :tag "Header"))
 136                                 (choice (string)
 137                                         (function)
 138                                         (variable)
 139                                         (sexp)))))))
 140
 141 (defcustom gnus-gcc-mark-as-read nil
 142   "If non-nil, automatically mark Gcc articles as read."
 143   :version "21.1"
 144   :group 'gnus-message
 145   :type 'boolean)
 146
 147 (defvar gnus-inews-mark-gcc-as-read nil
 148   "Obsolete variable. Use `gnus-gcc-mark-as-read' instead.")
 149
 150 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 151                         'gnus-gcc-mark-as-read)
 152
 153 (defcustom gnus-gcc-externalize-attachments nil
 154   "Should local-file attachments be included as external parts in Gcc copies?
 155 If it is `all', attach files as external parts;
 156 if a regexp and matches the Gcc group name, attach files as external parts;
 157 if nil, attach files as normal parts."
 158   :version "21.1"
 159   :group 'gnus-message
 160   :type '(choice (const nil :tag "None")
 161                  (const all :tag "Any")
 162                  (string :tag "Regexp")))
 163
 164 (gnus-define-group-parameter
 165  posting-charset-alist
 166  :type list
 167  :function-document
 168  "Return the permitted unencoded charsets for posting of GROUP."
 169  :variable gnus-group-posting-charset-alist
 170  :variable-default
 171   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 172     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 173     (message-this-is-mail nil nil)
 174     (message-this-is-news nil t))
 175  :variable-document
 176   "Alist of regexps and permitted unencoded charsets for posting.
 177 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 178 TEST is either a regular expression matching the newsgroup header or a
 179 variable to query,
 180 HEADER is the charset which may be left unencoded in the header (nil
 181 means encode all charsets),
 182 BODY-LIST is a list of charsets which may be encoded using 8bit
 183 content-transfer encoding in the body, or one of the special values
 184 nil (always encode using quoted-printable) or t (always use 8bit).
 185
 186 Note that any value other than nil for HEADER infringes some RFCs, so
 187 use this option with care."
 188  :variable-group gnus-charset
 189  :variable-type
 190  '(repeat (list :tag "Permitted unencoded charsets"
 191                 (choice :tag "Where"
 192                         (regexp :tag "Group")
 193                         (const :tag "Mail message" :value message-this-is-mail)
 194                         (const :tag "News article" :value message-this-is-news))
 195                 (choice :tag "Header"
 196                         (const :tag "None" nil)
 197                         (symbol :tag "Charset"))
 198                 (choice :tag "Body"
 199                         (const :tag "Any" :value t)
 200                         (const :tag "None" :value nil)
 201                         (repeat :tag "Charsets"
 202                                 (symbol :tag "Charset")))))
 203  :parameter-type '(choice :tag "Permitted unencoded charsets"
 204                           :value nil
 205                           (repeat (symbol)))
 206  :parameter-document       "\
 207 List of charsets that are permitted to be unencoded.")
 208
 209 (defcustom gnus-debug-files
 210   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 211     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 212     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 213     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 214     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 215   "Files whose variables will be reported in `gnus-bug'."
 216   :version "21.1"
 217   :group 'gnus-message
 218   :type '(repeat (string :tag "File")))
 219
 220 (defcustom gnus-debug-exclude-variables
 221   '(mm-mime-mule-charset-alist
 222     nnmail-split-fancy message-minibuffer-local-map)
 223   "Variables that should not be reported in `gnus-bug'."
 224   :version "21.1"
 225   :group 'gnus-message
 226   :type '(repeat (symbol :tag "Variable")))
 227
 228 (defcustom gnus-discouraged-post-methods
 229   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 230   "A list of back ends that are not used in \"real\" newsgroups.
 231 This variable is used only when `gnus-post-method' is `current'."
 232   :version "21.3"
 233   :group 'gnus-group-foreign
 234   :type '(repeat (symbol :tag "Back end")))
 235
 236 (defcustom gnus-message-replysign
 237   nil
 238   "Automatically sign replys to signed messages.
 239 See also the `mml-default-sign-method' variable."
 240   :group 'gnus-message
 241   :type 'boolean)
 242
 243 (defcustom gnus-message-replyencrypt
 244   nil
 245   "Automatically encrypt replys to encrypted messages.
 246 See also the `mml-default-encrypt-method' variable."
 247   :group 'gnus-message
 248   :type 'boolean)
 249
 250 (defcustom gnus-message-replysignencrypted
 251   t
 252   "Setting this causes automatically encryped messages to also be signed."
 253   :group 'gnus-message
 254   :type 'boolean)
 255
 256 (defcustom gnus-confirm-mail-reply-to-news nil
 257   "If non-nil, Gnus requests confirmation when replying to news.
 258 This is done because new users often reply by mistake when reading
 259 news."
 260   :group 'gnus-message
 261   :type 'boolean)
 262
 263 (defcustom gnus-summary-resend-default-address t
 264   "If non-nil, Gnus tries to suggest a default address to resend to.
 265 If nil, the address field will always be empty after invoking
 266 `gnus-summary-resend-message'."
 267   :group 'gnus-message
 268   :type 'boolean)
 269
 270 ;;; Internal variables.
 271
 272 (defvar gnus-inhibit-posting-styles nil
 273   "Inhibit the use of posting styles.")
 274
 275 (defvar gnus-article-yanked-articles nil)
 276 (defvar gnus-message-buffer "*Mail Gnus*")
 277 (defvar gnus-article-copy nil)
 278 (defvar gnus-check-before-posting nil)
 279 (defvar gnus-last-posting-server nil)
 280 (defvar gnus-message-group-art nil)
 281
 282 (defvar gnus-msg-force-broken-reply-to nil)
 283
 284 (defconst gnus-bug-message
 285   "Sending a bug report to the Gnus Towers.
 286 ========================================
 287
 288 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 289 be sent to the Gnus Bug Exterminators.
 290
 291 The thing near the bottom of the buffer is how the environment
 292 settings will be included in the mail.  Please do not delete that.
 293 They will tell the Bug People what your environment is, so that it
 294 will be easier to locate the bugs.
 295
 296 If you have found a bug that makes Emacs go \"beep\", set
 297 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 298 and include the backtrace in your bug report.
 299
 300 Please describe the bug in annoying, painstaking detail.
 301
 302 Thank you for your help in stamping out bugs.
 303 ")
 304
 305 (eval-and-compile
 306   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 307   (autoload 'news-setup "rnewspost")
 308   (autoload 'news-reply-mode "rnewspost")
 309   (autoload 'rmail-dont-reply-to "mail-utils")
 310   (autoload 'rmail-output "rmailout"))
 311
 312 \f
 313 ;;;
 314 ;;; Gnus Posting Functions
 315 ;;;
 316
 317 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 318   "p" gnus-summary-post-news
 319   "i" gnus-summary-news-other-window
 320   "f" gnus-summary-followup
 321   "F" gnus-summary-followup-with-original
 322   "c" gnus-summary-cancel-article
 323   "s" gnus-summary-supersede-article
 324   "r" gnus-summary-reply
 325   "y" gnus-summary-yank-message
 326   "R" gnus-summary-reply-with-original
 327   "w" gnus-summary-wide-reply
 328   "W" gnus-summary-wide-reply-with-original
 329   "v" gnus-summary-very-wide-reply
 330   "V" gnus-summary-very-wide-reply-with-original
 331   "n" gnus-summary-followup-to-mail
 332   "N" gnus-summary-followup-to-mail-with-original
 333   "m" gnus-summary-mail-other-window
 334   "u" gnus-uu-post-news
 335   "\M-c" gnus-summary-mail-crosspost-complaint
 336   "Br" gnus-summary-reply-broken-reply-to
 337   "BR" gnus-summary-reply-broken-reply-to-with-original
 338   "om" gnus-summary-mail-forward
 339   "op" gnus-summary-post-forward
 340   "Om" gnus-uu-digest-mail-forward
 341   "Op" gnus-uu-digest-post-forward)
 342
 343 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 344   "b" gnus-summary-resend-bounced-mail
 345   ;; "c" gnus-summary-send-draft
 346   "r" gnus-summary-resend-message
 347   "e" gnus-summary-resend-message-edit)
 348
 349 ;;; Internal functions.
 350
 351 (defun gnus-inews-make-draft ()
 352   `(lambda ()
 353      (gnus-inews-make-draft-meta-information
 354       ,gnus-newsgroup-name ,gnus-article-reply)))
 355
 356 (defvar gnus-article-reply nil)
 357 (defmacro gnus-setup-message (config &rest forms)
 358   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 359         (buffer (make-symbol "gnus-setup-message-buffer"))
 360         (article (make-symbol "gnus-setup-message-article"))
 361         (yanked (make-symbol "gnus-setup-yanked-articles"))
 362         (group (make-symbol "gnus-setup-message-group")))
 363     `(let ((,winconf (current-window-configuration))
 364            (,buffer (buffer-name (current-buffer)))
 365            (,article gnus-article-reply)
 366            (,yanked gnus-article-yanked-articles)
 367            (,group gnus-newsgroup-name)
 368            (message-header-setup-hook
 369             (copy-sequence message-header-setup-hook))
 370            (mbl mml-buffer-list)
 371            (message-mode-hook (copy-sequence message-mode-hook)))
 372        (setq mml-buffer-list nil)
 373        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 374        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 375        ;; #### FIXME: for a reason that I did not manage to identify yet,
 376        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 377        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 378        ;; After evaluation of @forms below, it gets the value we actually want
 379        ;; to override, and the posting styles are used. For that reason, I've
 380        ;; added an optional argument to `gnus-configure-posting-styles' to
 381        ;; make sure that the correct value for the group name is used. -- drv
 382        (add-hook 'message-mode-hook
 383                  (lambda ()
 384                    (gnus-configure-posting-styles ,group)))
 385        (gnus-pull ',(intern gnus-draft-meta-information-header)
 386                   message-required-headers)
 387        (when (and ,group
 388                   (not (string= ,group "")))
 389          (push (cons
 390                 (intern gnus-draft-meta-information-header)
 391                 (gnus-inews-make-draft))
 392                message-required-headers))
 393        (unwind-protect
 394            (progn
 395              ,@forms)
 396          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 397                                       ,yanked)
 398          (setq gnus-message-buffer (current-buffer))
 399          (set (make-local-variable 'gnus-message-group-art)
 400               (cons ,group ,article))
 401          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 402          (gnus-run-hooks 'gnus-message-setup-hook)
 403          (if (eq major-mode 'message-mode)
 404              (let ((mbl1 mml-buffer-list))
 405                (setq mml-buffer-list mbl)  ;; Global value
 406                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 407                ;; LOCAL argument of add-hook differs between GNU Emacs
 408                ;; and XEmacs. make-local-hook makes sure they are local.
 409                (make-local-hook 'kill-buffer-hook)
 410                (make-local-hook 'change-major-mode-hook)
 411                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 412                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 413            (mml-destroy-buffers)
 414            (setq mml-buffer-list mbl)))
 415        (gnus-add-buffer)
 416        (gnus-configure-windows ,config t)
 417        (run-hooks 'post-command-hook)
 418        (set-buffer-modified-p nil))))
 419
 420 (defun gnus-inews-make-draft-meta-information (group article)
 421   (concat "(\"" group "\" "
 422           (if article (number-to-string
 423                        (if (listp article)
 424                            (car article)
 425                          article)) "\"\"")
 426           ")"))
 427
 428 ;;;###autoload
 429 (defun gnus-msg-mail (&optional to subject other-headers continue
 430                                 switch-action yank-action send-actions)
 431   "Start editing a mail message to be sent.
 432 Like `message-mail', but with Gnus paraphernalia, particularly the
 433 Gcc: header for archiving purposes."
 434   (interactive)
 435   (let ((buf (current-buffer))
 436         mail-buf)
 437     (gnus-setup-message 'message
 438       (message-mail to subject other-headers continue
 439                     nil yank-action send-actions))
 440     (when switch-action
 441       (setq mail-buf (current-buffer))
 442       (switch-to-buffer buf)
 443       (apply switch-action mail-buf nil)))
 444   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 445   t)
 446
 447 (defvar save-selected-window-window)
 448
 449 ;;;###autoload
 450 (defun gnus-button-mailto (address)
 451   "Mail to ADDRESS."
 452   (set-buffer (gnus-copy-article-buffer))
 453   (gnus-setup-message 'message
 454     (message-reply address))
 455   (and (boundp 'save-selected-window-window)
 456        (not (window-live-p save-selected-window-window))
 457        (setq save-selected-window-window (selected-window))))
 458
 459 ;;;###autoload
 460 (defun gnus-button-reply (&optional to-address wide)
 461   "Like `message-reply'."
 462   (interactive)
 463   (gnus-setup-message 'message
 464     (message-reply to-address wide))
 465   (and (boundp 'save-selected-window-window)
 466        (not (window-live-p save-selected-window-window))
 467        (setq save-selected-window-window (selected-window))))
 468
 469 ;;;###autoload
 470 (define-mail-user-agent 'gnus-user-agent
 471   'gnus-msg-mail 'message-send-and-exit
 472   'message-kill-buffer 'message-send-hook)
 473
 474 (defun gnus-setup-posting-charset (group)
 475   (let ((alist gnus-group-posting-charset-alist)
 476         (group (or group ""))
 477         elem)
 478     (when group
 479       (catch 'found
 480         (while (setq elem (pop alist))
 481           (when (or (and (stringp (car elem))
 482                          (string-match (car elem) group))
 483                     (and (gnus-functionp (car elem))
 484                          (funcall (car elem) group))
 485                     (and (symbolp (car elem))
 486                          (symbol-value (car elem))))
 487             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 488
 489 (defun gnus-inews-add-send-actions (winconf buffer article
 490                                             &optional config yanked)
 491   (make-local-hook 'message-sent-hook)
 492   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 493                                  'gnus-inews-do-gcc) nil t)
 494   (when gnus-agent
 495     (make-local-hook 'message-header-hook)
 496     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 497   (setq message-post-method
 498         `(lambda (arg)
 499            (gnus-post-method arg ,gnus-newsgroup-name)))
 500   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 501   (message-add-action
 502    `(set-window-configuration ,winconf) 'exit 'postpone 'kill)
 503   (message-add-action
 504    `(when (gnus-buffer-exists-p ,buffer)
 505       (save-excursion
 506         (set-buffer ,buffer)
 507         ,(when article
 508            (if (eq config 'forward)
 509                `(gnus-summary-mark-article-as-forwarded ',yanked)
 510              `(gnus-summary-mark-article-as-replied ',yanked)))))
 511    'send))
 512
 513 (put 'gnus-setup-message 'lisp-indent-function 1)
 514 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 515
 516 ;;; Post news commands of Gnus group mode and summary mode
 517
 518 (defun gnus-group-mail (&optional arg)
 519   "Start composing a mail.
 520 If ARG, use the group under the point to find a posting style.
 521 If ARG is 1, prompt for a group name to find the posting style."
 522   (interactive "P")
 523   ;; We can't `let' gnus-newsgroup-name here, since that leads
 524   ;; to local variables leaking.
 525   (let ((group gnus-newsgroup-name)
 526         ;; make sure last viewed article doesn't affect posting styles:
 527         (gnus-article-copy)
 528         (buffer (current-buffer)))
 529     (unwind-protect
 530         (progn
 531           (setq gnus-newsgroup-name
 532                 (if arg
 533                     (if (= 1 (prefix-numeric-value arg))
 534                         (completing-read "Use posting style of group: "
 535                                          gnus-active-hashtb nil
 536                                          (gnus-read-active-file-p))
 537                       (gnus-group-group-name))
 538                   ""))
 539           ;; #### see comment in gnus-setup-message -- drv
 540           (gnus-setup-message 'message (message-mail)))
 541       (save-excursion
 542         (set-buffer buffer)
 543         (setq gnus-newsgroup-name group)))))
 544
 545 (defun gnus-group-news (&optional arg)
 546   "Start composing a news.
 547 If ARG, post to group under point.
 548 If ARG is 1, prompt for group name to post to.
 549
 550 This function prepares a news even when using mail groups.  This is useful
 551 for posting messages to mail groups without actually sending them over the
 552 network.  The corresponding backend must have a 'request-post method."
 553   (interactive "P")
 554   ;; We can't `let' gnus-newsgroup-name here, since that leads
 555   ;; to local variables leaking.
 556   (let ((group gnus-newsgroup-name)
 557         ;; make sure last viewed article doesn't affect posting styles:
 558         (gnus-article-copy)
 559         (buffer (current-buffer)))
 560     (unwind-protect
 561         (progn
 562           (setq gnus-newsgroup-name
 563                 (if arg
 564                     (if (= 1 (prefix-numeric-value arg))
 565                         (completing-read "Use group: "
 566                                          gnus-active-hashtb nil
 567                                          (gnus-read-active-file-p))
 568                       (gnus-group-group-name))
 569                   ""))
 570           ;; #### see comment in gnus-setup-message -- drv
 571           (gnus-setup-message 'message
 572             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 573       (save-excursion
 574         (set-buffer buffer)
 575         (setq gnus-newsgroup-name group)))))
 576
 577 (defun gnus-group-post-news (&optional arg)
 578   "Start composing a message (a news by default).
 579 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 580 Depending on the selected group, the message might be either a mail or
 581 a news."
 582   (interactive "P")
 583   ;; Bind this variable here to make message mode hooks work ok.
 584   (let ((gnus-newsgroup-name
 585          (if arg
 586              (if (= 1 (prefix-numeric-value arg))
 587                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 588                                   (gnus-read-active-file-p))
 589                (gnus-group-group-name))
 590            ""))
 591         ;; make sure last viewed article doesn't affect posting styles:
 592         (gnus-article-copy))
 593     (gnus-post-news 'post gnus-newsgroup-name)))
 594
 595 (defun gnus-summary-mail-other-window (&optional arg)
 596   "Start composing a mail in another window.
 597 Use the posting of the current group by default.
 598 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 599 posting style."
 600   (interactive "P")
 601   ;; We can't `let' gnus-newsgroup-name here, since that leads
 602   ;; to local variables leaking.
 603   (let ((group gnus-newsgroup-name)
 604         ;; make sure last viewed article doesn't affect posting styles:
 605         (gnus-article-copy)
 606         (buffer (current-buffer)))
 607     (unwind-protect
 608         (progn
 609           (setq gnus-newsgroup-name
 610                 (if arg
 611                     (if (= 1 (prefix-numeric-value arg))
 612                         (completing-read "Use group: "
 613                                          gnus-active-hashtb nil
 614                                          (gnus-read-active-file-p))
 615                       "")
 616                   gnus-newsgroup-name))
 617           ;; #### see comment in gnus-setup-message -- drv
 618           (gnus-setup-message 'message (message-mail)))
 619       (save-excursion
 620         (set-buffer buffer)
 621         (setq gnus-newsgroup-name group)))))
 622
 623 (defun gnus-summary-news-other-window (&optional arg)
 624   "Start composing a news in another window.
 625 Post to the current group by default.
 626 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 627
 628 This function prepares a news even when using mail groups.  This is useful
 629 for posting messages to mail groups without actually sending them over the
 630 network.  The corresponding backend must have a 'request-post method."
 631   (interactive "P")
 632   ;; We can't `let' gnus-newsgroup-name here, since that leads
 633   ;; to local variables leaking.
 634   (let ((group gnus-newsgroup-name)
 635         ;; make sure last viewed article doesn't affect posting styles:
 636         (gnus-article-copy)
 637         (buffer (current-buffer)))
 638     (unwind-protect
 639         (progn
 640           (setq gnus-newsgroup-name
 641                 (if arg
 642                     (if (= 1 (prefix-numeric-value arg))
 643                         (completing-read "Use group: "
 644                                          gnus-active-hashtb nil
 645                                          (gnus-read-active-file-p))
 646                       "")
 647                   gnus-newsgroup-name))
 648           ;; #### see comment in gnus-setup-message -- drv
 649           (gnus-setup-message 'message
 650             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 651       (save-excursion
 652         (set-buffer buffer)
 653         (setq gnus-newsgroup-name group)))))
 654
 655 (defun gnus-summary-post-news (&optional arg)
 656   "Start composing a message.  Post to the current group by default.
 657 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 658 Depending on the selected group, the message might be either a mail or
 659 a news."
 660   (interactive "P")
 661   ;; Bind this variable here to make message mode hooks work ok.
 662   (let ((gnus-newsgroup-name
 663          (if arg
 664              (if (= 1 (prefix-numeric-value arg))
 665                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 666                                   (gnus-read-active-file-p))
 667                "")
 668            gnus-newsgroup-name))
 669         ;; make sure last viewed article doesn't affect posting styles:
 670         (gnus-article-copy))
 671     (gnus-post-news 'post gnus-newsgroup-name)))
 672
 673
 674 (defun gnus-summary-followup (yank &optional force-news)
 675   "Compose a followup to an article.
 676 If prefix argument YANK is non-nil, the original article is yanked
 677 automatically.
 678 YANK is a list of elements, where the car of each element is the
 679 article number, and the two following numbers is the region to be
 680 yanked."
 681   (interactive
 682    (list (and current-prefix-arg
 683               (gnus-summary-work-articles 1))))
 684   (when yank
 685     (gnus-summary-goto-subject
 686      (if (listp (car yank))
 687          (caar yank)
 688        (car yank))))
 689   (save-window-excursion
 690     (gnus-summary-select-article))
 691   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 692         (gnus-newsgroup-name gnus-newsgroup-name))
 693     ;; Send a followup.
 694     (gnus-post-news nil gnus-newsgroup-name
 695                     headers gnus-article-buffer
 696                     yank nil force-news)
 697     (gnus-summary-handle-replysign)))
 698
 699 (defun gnus-summary-followup-with-original (n &optional force-news)
 700   "Compose a followup to an article and include the original article."
 701   (interactive "P")
 702   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 703
 704 (defun gnus-summary-followup-to-mail (&optional arg)
 705   "Followup to the current mail message via news."
 706   (interactive
 707    (list (and current-prefix-arg
 708               (gnus-summary-work-articles 1))))
 709   (gnus-summary-followup arg t))
 710
 711 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 712   "Followup to the current mail message via news."
 713   (interactive "P")
 714   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 715
 716 (defun gnus-inews-yank-articles (articles)
 717   (let (beg article yank-string)
 718     (message-goto-body)
 719     (while (setq article (pop articles))
 720       (when (listp article)
 721         (setq yank-string (nth 1 article)
 722               article (nth 0 article)))
 723       (save-window-excursion
 724         (set-buffer gnus-summary-buffer)
 725         (gnus-summary-select-article nil nil nil article)
 726         (gnus-summary-remove-process-mark article))
 727       (gnus-copy-article-buffer nil yank-string)
 728       (let ((message-reply-buffer gnus-article-copy)
 729             (message-reply-headers
 730              ;; The headers are decoded.
 731              (with-current-buffer gnus-article-copy
 732                (save-restriction
 733                  (nnheader-narrow-to-headers)
 734                  (nnheader-parse-naked-head)))))
 735         (message-yank-original)
 736         (setq beg (or beg (mark t))))
 737       (when articles
 738         (insert "\n")))
 739     (push-mark)
 740     (goto-char beg)))
 741
 742 (defun gnus-summary-cancel-article (&optional n symp)
 743   "Cancel an article you posted.
 744 Uses the process-prefix convention.  If given the symbolic
 745 prefix `a', cancel using the standard posting method; if not
 746 post using the current select method."
 747   (interactive (gnus-interactive "P\ny"))
 748   (let ((articles (gnus-summary-work-articles n))
 749         (message-post-method
 750          `(lambda (arg)
 751             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 752         article)
 753     (while (setq article (pop articles))
 754       (when (gnus-summary-select-article t nil nil article)
 755         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 756                 (message-cancel-news))
 757           (gnus-summary-mark-as-read article gnus-canceled-mark)
 758           (gnus-cache-remove-article 1))
 759         (gnus-article-hide-headers-if-wanted))
 760       (gnus-summary-remove-process-mark article))))
 761
 762 (defun gnus-summary-supersede-article ()
 763   "Compose an article that will supersede a previous article.
 764 This is done simply by taking the old article and adding a Supersedes
 765 header line with the old Message-ID."
 766   (interactive)
 767   (let ((article (gnus-summary-article-number)))
 768     (gnus-setup-message 'reply-yank
 769       (gnus-summary-select-article t)
 770       (set-buffer gnus-original-article-buffer)
 771       (message-supersede)
 772       (push
 773        `((lambda ()
 774            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 775              (save-excursion
 776                (set-buffer ,gnus-summary-buffer)
 777                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 778                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 779        message-send-actions))))
 780
 781 \f
 782
 783 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 784   ;; make a copy of the article buffer with all text properties removed
 785   ;; this copy is in the buffer gnus-article-copy.
 786   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 787   ;; this buffer should be passed to all mail/news reply/post routines.
 788   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 789   (save-excursion
 790     (set-buffer gnus-article-copy)
 791     (mm-enable-multibyte))
 792   (let ((article-buffer (or article-buffer gnus-article-buffer))
 793         end beg)
 794     (if (not (and (get-buffer article-buffer)
 795                   (gnus-buffer-exists-p article-buffer)))
 796         (error "Can't find any article buffer")
 797       (save-excursion
 798         (set-buffer article-buffer)
 799         (let ((gnus-newsgroup-charset (or gnus-article-charset
 800                                           gnus-newsgroup-charset))
 801               (gnus-newsgroup-ignored-charsets
 802                (or gnus-article-ignored-charsets
 803                    gnus-newsgroup-ignored-charsets)))
 804           (save-restriction
 805             ;; Copy over the (displayed) article buffer, delete
 806             ;; hidden text and remove text properties.
 807             (widen)
 808             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 809             (set-buffer gnus-article-copy)
 810             (when yank-string
 811               (message-goto-body)
 812               (delete-region (point) (point-max))
 813               (insert yank-string))
 814             (gnus-article-delete-text-of-type 'annotation)
 815             (gnus-remove-text-with-property 'gnus-prev)
 816             (gnus-remove-text-with-property 'gnus-next)
 817             (gnus-remove-text-with-property 'gnus-decoration)
 818             (insert
 819              (prog1
 820                  (buffer-substring-no-properties (point-min) (point-max))
 821                (erase-buffer)))
 822             ;; Find the original headers.
 823             (set-buffer gnus-original-article-buffer)
 824             (goto-char (point-min))
 825             (while (looking-at message-unix-mail-delimiter)
 826               (forward-line 1))
 827             (let ((mail-header-separator ""))
 828               (setq beg (point)
 829                     end (or (message-goto-body) beg)))
 830             ;; Delete the headers from the displayed articles.
 831             (set-buffer gnus-article-copy)
 832             (let ((mail-header-separator ""))
 833               (delete-region (goto-char (point-min))
 834                              (or (message-goto-body) (point-max))))
 835             ;; Insert the original article headers.
 836             (insert-buffer-substring gnus-original-article-buffer beg end)
 837             ;; Decode charsets.
 838             (let ((gnus-article-decode-hook
 839                    (delq 'article-decode-charset
 840                          (copy-sequence gnus-article-decode-hook))))
 841               (run-hooks 'gnus-article-decode-hook)))))
 842       gnus-article-copy)))
 843
 844 (defun gnus-post-news (post &optional group header article-buffer yank subject
 845                             force-news)
 846   (when article-buffer
 847     (gnus-copy-article-buffer))
 848   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 849         (gnus-article-yanked-articles yank)
 850         (add-to-list gnus-add-to-list))
 851     (gnus-setup-message (cond (yank 'reply-yank)
 852                               (article-buffer 'reply)
 853                               (t 'message))
 854       (let* ((group (or group gnus-newsgroup-name))
 855              (charset (gnus-group-name-charset nil group))
 856              (pgroup group)
 857              to-address to-group mailing-list to-list
 858              newsgroup-p)
 859         (when group
 860           (setq to-address (gnus-parameter-to-address group)
 861                 to-group (gnus-group-find-parameter group 'to-group)
 862                 to-list (gnus-parameter-to-list group)
 863                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 864                 mailing-list (when gnus-mailing-list-groups
 865                                (string-match gnus-mailing-list-groups group))
 866                 group (gnus-group-name-decode (gnus-group-real-name group)
 867                                               charset)))
 868         (if (or (and to-group
 869                      (gnus-news-group-p to-group))
 870                 newsgroup-p
 871                 force-news
 872                 (and (gnus-news-group-p
 873                       (or pgroup gnus-newsgroup-name)
 874                       (or header gnus-current-article))
 875                      (not mailing-list)
 876                      (not to-list)
 877                      (not to-address)))
 878             ;; This is news.
 879             (if post
 880                 (message-news (or to-group group))
 881               (set-buffer gnus-article-copy)
 882               (gnus-msg-treat-broken-reply-to)
 883               (message-followup (if (or newsgroup-p force-news)
 884                                     (if (save-restriction
 885                                           (article-narrow-to-head)
 886                                           (message-fetch-field "newsgroups"))
 887                                         nil
 888                                       "")
 889                                   to-group)))
 890           ;; The is mail.
 891           (if post
 892               (progn
 893                 (message-mail (or to-address to-list))
 894                 ;; Arrange for mail groups that have no `to-address' to
 895                 ;; get that when the user sends off the mail.
 896                 (when (and (not to-list)
 897                            (not to-address)
 898                            add-to-list)
 899                   (push (list 'gnus-inews-add-to-address pgroup)
 900                         message-send-actions)))
 901             (set-buffer gnus-article-copy)
 902             (gnus-msg-treat-broken-reply-to)
 903             (message-wide-reply to-address)))
 904         (when yank
 905           (gnus-inews-yank-articles yank))))))
 906
 907 (defun gnus-msg-treat-broken-reply-to (&optional force)
 908   "Remove the Reply-to header if broken-reply-to."
 909   (when (or force
 910             (gnus-group-find-parameter
 911              gnus-newsgroup-name 'broken-reply-to))
 912     (save-restriction
 913       (message-narrow-to-head)
 914       (message-remove-header "reply-to"))))
 915
 916 (defun gnus-post-method (arg group &optional silent)
 917   "Return the posting method based on GROUP and ARG.
 918 If SILENT, don't prompt the user."
 919   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 920                               gnus-post-method))
 921         (group-method (gnus-find-method-for-group group)))
 922     (cond
 923      ;; If the group-method is nil (which shouldn't happen) we use
 924      ;; the default method.
 925      ((null group-method)
 926       (or (and (listp gnus-post-method) ;If not current/native/nil
 927                (not (listp (car gnus-post-method))) ; and not a list of methods
 928                gnus-post-method)        ;then use it.
 929           gnus-select-method
 930           message-post-method))
 931      ;; We want the inverse of the default
 932      ((and arg (not (eq arg 0)))
 933       (if (eq gnus-post-method 'current)
 934           gnus-select-method
 935         group-method))
 936      ;; We query the user for a post method.
 937      ((or arg
 938           (and (listp gnus-post-method)
 939                (listp (car gnus-post-method))))
 940       (let* ((methods
 941               ;; Collect all methods we know about.
 942               (append
 943                (when (listp gnus-post-method)
 944                  (if (listp (car gnus-post-method))
 945                      gnus-post-method
 946                    (list gnus-post-method)))
 947                gnus-secondary-select-methods
 948                (mapcar 'cdr gnus-server-alist)
 949                (mapcar 'car gnus-opened-servers)
 950                (list gnus-select-method)
 951                (list group-method)))
 952              method-alist post-methods method)
 953         ;; Weed out all mail methods.
 954         (while methods
 955           (setq method (gnus-server-get-method "" (pop methods)))
 956           (when (and (or (gnus-method-option-p method 'post)
 957                          (gnus-method-option-p method 'post-mail))
 958                      (not (member method post-methods)))
 959             (push method post-methods)))
 960         ;; Create a name-method alist.
 961         (setq method-alist
 962               (mapcar
 963                (lambda (m)
 964                  (if (equal (cadr m) "")
 965                      (list (symbol-name (car m)) m)
 966                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
 967                post-methods))
 968         ;; Query the user.
 969         (cadr
 970          (assoc
 971           (setq gnus-last-posting-server
 972                 (if (and silent
 973                          gnus-last-posting-server)
 974                     ;; Just use the last value.
 975                     gnus-last-posting-server
 976                   (completing-read
 977                    "Posting method: " method-alist nil t
 978                    (cons (or gnus-last-posting-server "") 0))))
 979           method-alist))))
 980      ;; Override normal method.
 981      ((and (eq gnus-post-method 'current)
 982            (not (memq (car group-method) gnus-discouraged-post-methods))
 983            (gnus-get-function group-method 'request-post t))
 984       (assert (not arg))
 985       group-method)
 986      ;; Use gnus-post-method.
 987      ((listp gnus-post-method)          ;A method...
 988       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
 989       gnus-post-method)
 990      ;; Use the normal select method (nil or native).
 991      (t gnus-select-method))))
 992
 993 \f
 994
 995 ;; Dummies to avoid byte-compile warning.
 996 (eval-when-compile
 997   (defvar nnspool-rejected-article-hook)
 998   (defvar xemacs-codename))
 999
1000 (defun gnus-extended-version ()
1001   "Stringified Gnus version and Emacs version."
1002   (interactive)
1003   (concat
1004    "Gnus/" (prin1-to-string (gnus-continuum-version gnus-version) t)
1005    " (" gnus-version ")"
1006    " "
1007    (cond
1008     ((string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
1009      (concat "Emacs/" (match-string 1 emacs-version)
1010              " (" system-configuration ")"))
1011     ((string-match "\\([A-Z]*[Mm][Aa][Cc][Ss]\\)[^(]*\\(\\((beta.*)\\|'\\)\\)?"
1012                    emacs-version)
1013      (concat (match-string 1 emacs-version)
1014              (format "/%d.%d" emacs-major-version emacs-minor-version)
1015              (if (match-beginning 3)
1016                  (match-string 3 emacs-version)
1017                "")
1018              (if (boundp 'xemacs-codename)
1019                  (concat " (" xemacs-codename ", " system-configuration ")")
1020                "")))
1021     (t emacs-version))))
1022
1023 \f
1024 ;;;
1025 ;;; Gnus Mail Functions
1026 ;;;
1027
1028 ;;; Mail reply commands of Gnus summary mode
1029
1030 (defun gnus-summary-reply (&optional yank wide very-wide)
1031   "Start composing a mail reply to the current message.
1032 If prefix argument YANK is non-nil, the original article is yanked
1033 automatically.
1034 If WIDE, make a wide reply.
1035 If VERY-WIDE, make a very wide reply."
1036   (interactive
1037    (list (and current-prefix-arg
1038               (gnus-summary-work-articles 1))))
1039   ;; Allow user to require confirmation before replying by mail to the
1040   ;; author of a news article.
1041   (when (or (not (gnus-news-group-p gnus-newsgroup-name))
1042             (not gnus-confirm-mail-reply-to-news)
1043             (y-or-n-p "Really reply by mail to article author? "))
1044     (let* ((article
1045             (if (listp (car yank))
1046                 (caar yank)
1047               (car yank)))
1048            (gnus-article-reply (or article (gnus-summary-article-number)))
1049            (gnus-article-yanked-articles yank)
1050            (headers ""))
1051       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1052       (when yank
1053         (gnus-summary-goto-subject article))
1054       (gnus-setup-message (if yank 'reply-yank 'reply)
1055         (if (not very-wide)
1056             (gnus-summary-select-article)
1057           (dolist (article very-wide)
1058             (gnus-summary-select-article nil nil nil article)
1059             (save-excursion
1060               (set-buffer (gnus-copy-article-buffer))
1061               (gnus-msg-treat-broken-reply-to)
1062               (save-restriction
1063                 (message-narrow-to-head)
1064                 (setq headers (concat headers (buffer-string)))))))
1065         (set-buffer (gnus-copy-article-buffer))
1066         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1067         (save-restriction
1068           (message-narrow-to-head)
1069           (when very-wide
1070             (erase-buffer)
1071             (insert headers))
1072           (goto-char (point-max)))
1073         (mml-quote-region (point) (point-max))
1074         (message-reply nil wide)
1075         (when yank
1076           (gnus-inews-yank-articles yank))
1077         (gnus-summary-handle-replysign)))))
1078
1079 (defun gnus-summary-handle-replysign ()
1080   "Check the various replysign variables and take action accordingly."
1081   (when (or gnus-message-replysign gnus-message-replyencrypt)
1082     (let (signed encrypted)
1083       (save-excursion
1084         (set-buffer gnus-article-buffer)
1085         (setq signed (memq 'signed gnus-article-wash-types))
1086         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1087       (cond ((and gnus-message-replyencrypt encrypted)
1088              (mml-secure-message mml-default-encrypt-method
1089                                  (if gnus-message-replysignencrypted
1090                                      'signencrypt
1091                                    'encrypt)))
1092             ((and gnus-message-replysign signed)
1093              (mml-secure-message mml-default-sign-method 'sign))))))
1094
1095 (defun gnus-summary-reply-with-original (n &optional wide)
1096   "Start composing a reply mail to the current message.
1097 The original article will be yanked."
1098   (interactive "P")
1099   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1100
1101 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1102   "Like `gnus-summary-reply' except removing reply-to field.
1103 If prefix argument YANK is non-nil, the original article is yanked
1104 automatically.
1105 If WIDE, make a wide reply.
1106 If VERY-WIDE, make a very wide reply."
1107   (interactive
1108    (list (and current-prefix-arg
1109               (gnus-summary-work-articles 1))))
1110   (let ((gnus-msg-force-broken-reply-to t))
1111     (gnus-summary-reply yank wide very-wide)))
1112
1113 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1114   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1115 The original article will be yanked."
1116   (interactive "P")
1117   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1118
1119 (defun gnus-summary-wide-reply (&optional yank)
1120   "Start composing a wide reply mail to the current message.
1121 If prefix argument YANK is non-nil, the original article is yanked
1122 automatically."
1123   (interactive
1124    (list (and current-prefix-arg
1125               (gnus-summary-work-articles 1))))
1126   (gnus-summary-reply yank t))
1127
1128 (defun gnus-summary-wide-reply-with-original (n)
1129   "Start composing a wide reply mail to the current message.
1130 The original article will be yanked."
1131   (interactive "P")
1132   (gnus-summary-reply-with-original n t))
1133
1134 (defun gnus-summary-very-wide-reply (&optional yank)
1135   "Start composing a very wide reply mail to the current message.
1136 If prefix argument YANK is non-nil, the original article is yanked
1137 automatically."
1138   (interactive
1139    (list (and current-prefix-arg
1140               (gnus-summary-work-articles 1))))
1141   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1142
1143 (defun gnus-summary-very-wide-reply-with-original (n)
1144   "Start composing a very wide reply mail to the current message.
1145 The original article will be yanked."
1146   (interactive "P")
1147   (gnus-summary-reply
1148    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1149
1150 (defun gnus-summary-mail-forward (&optional arg post)
1151   "Forward the current message(s) to another user.
1152 If process marks exist, forward all marked messages;
1153 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1154 if ARG is 1, decode the message and forward directly inline;
1155 if ARG is 2, forward message as an rfc822 MIME section;
1156 if ARG is 3, decode message and forward as an rfc822 MIME section;
1157 if ARG is 4, forward message directly inline;
1158 otherwise, use flipped `message-forward-as-mime'.
1159 If POST, post instead of mail.
1160 For the `inline' alternatives, also see the variable
1161 `message-forward-ignored-headers'."
1162   (interactive "P")
1163   (if (cdr (gnus-summary-work-articles nil))
1164       ;; Process marks are given.
1165       (gnus-uu-digest-mail-forward arg post)
1166     ;; No process marks.
1167     (let ((message-forward-as-mime message-forward-as-mime)
1168           (message-forward-show-mml message-forward-show-mml))
1169       (cond
1170        ((null arg))
1171        ((eq arg 1)
1172         (setq message-forward-as-mime nil
1173               message-forward-show-mml t))
1174        ((eq arg 2)
1175         (setq message-forward-as-mime t
1176               message-forward-show-mml nil))
1177        ((eq arg 3)
1178         (setq message-forward-as-mime t
1179               message-forward-show-mml t))
1180        ((eq arg 4)
1181         (setq message-forward-as-mime nil
1182               message-forward-show-mml nil))
1183        (t
1184         (setq message-forward-as-mime (not message-forward-as-mime))))
1185       (let* ((gnus-article-reply (gnus-summary-article-number))
1186              (gnus-article-yanked-articles (list gnus-article-reply)))
1187         (gnus-setup-message 'forward
1188           (gnus-summary-select-article)
1189           (let ((mail-parse-charset
1190                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1191                           (with-current-buffer gnus-article-buffer
1192                             gnus-article-charset))
1193                      gnus-newsgroup-charset))
1194                 (mail-parse-ignored-charsets
1195                  gnus-newsgroup-ignored-charsets))
1196             (set-buffer gnus-original-article-buffer)
1197             (message-forward post)))))))
1198
1199 (defun gnus-summary-resend-message (address n)
1200   "Resend the current article to ADDRESS."
1201   (interactive
1202    (list (message-read-from-minibuffer
1203           "Resend message(s) to: "
1204           (when (and gnus-summary-resend-default-address
1205                      (gnus-buffer-live-p gnus-original-article-buffer))
1206             ;; If some other article is currently selected, the
1207             ;; initial-contents is wrong. Whatever, it is just the
1208             ;; initial-contents.
1209             (with-current-buffer gnus-original-article-buffer
1210               (nnmail-fetch-field "to"))))
1211          current-prefix-arg))
1212   (let ((articles (gnus-summary-work-articles n))
1213         article)
1214     (while (setq article (pop articles))
1215       (gnus-summary-select-article nil nil nil article)
1216       (save-excursion
1217         (set-buffer gnus-original-article-buffer)
1218         (message-resend address))
1219       (gnus-summary-mark-article-as-forwarded article))))
1220
1221 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1222 (defun gnus-summary-resend-message-edit ()
1223   "Resend an article that has already been sent.
1224 A new buffer will be created to allow the user to modify body and
1225 contents of the message, and then, everything will happen as when
1226 composing a new message."
1227   (interactive)
1228   (let ((article (gnus-summary-article-number)))
1229     (gnus-setup-message 'reply-yank
1230       (gnus-summary-select-article t)
1231       (set-buffer gnus-original-article-buffer)
1232       (let ((cur (current-buffer))
1233             (to (message-fetch-field "to")))
1234         ;; Get a normal message buffer.
1235         (message-pop-to-buffer (message-buffer-name "Resend" to))
1236         (insert-buffer-substring cur)
1237         (mime-to-mml)
1238         (message-narrow-to-head-1)
1239         ;; Gnus will generate a new one when sending.
1240         (message-remove-header "Message-ID")
1241         (message-remove-header message-ignored-resent-headers t)
1242         ;; Remove unwanted headers.
1243         (goto-char (point-max))
1244         (insert mail-header-separator)
1245         (goto-char (point-min))
1246         (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1247         (forward-char 1)
1248         (widen)))))
1249
1250 (defun gnus-summary-post-forward (&optional arg)
1251   "Forward the current article to a newsgroup.
1252 See `gnus-summary-mail-forward' for ARG."
1253   (interactive "P")
1254   (gnus-summary-mail-forward arg t))
1255
1256 (defvar gnus-nastygram-message
1257   "The following article was inappropriately posted to %s.\n\n"
1258   "Format string to insert in nastygrams.
1259 The current group name will be inserted at \"%s\".")
1260
1261 (defun gnus-summary-mail-nastygram (n)
1262   "Send a nastygram to the author of the current article."
1263   (interactive "P")
1264   (when (or gnus-expert-user
1265             (gnus-y-or-n-p
1266              "Really send a nastygram to the author of the current article? "))
1267     (let ((group gnus-newsgroup-name))
1268       (gnus-summary-reply-with-original n)
1269       (set-buffer gnus-message-buffer)
1270       (message-goto-body)
1271       (insert (format gnus-nastygram-message group))
1272       (message-send-and-exit))))
1273
1274 (defun gnus-summary-mail-crosspost-complaint (n)
1275   "Send a complaint about crossposting to the current article(s)."
1276   (interactive "P")
1277   (let ((articles (gnus-summary-work-articles n))
1278         article)
1279     (while (setq article (pop articles))
1280       (set-buffer gnus-summary-buffer)
1281       (gnus-summary-goto-subject article)
1282       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1283             newsgroups followup-to)
1284         (gnus-summary-select-article)
1285         (set-buffer gnus-original-article-buffer)
1286         (if (and (<= (length (message-tokenize-header
1287                               (setq newsgroups
1288                                     (mail-fetch-field "newsgroups"))
1289                               ", "))
1290                      1)
1291                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1292                      (not (member group (message-tokenize-header
1293                                          followup-to ", ")))))
1294             (if followup-to
1295                 (gnus-message 1 "Followup-to restricted")
1296               (gnus-message 1 "Not a crossposted article"))
1297           (set-buffer gnus-summary-buffer)
1298           (gnus-summary-reply-with-original 1)
1299           (set-buffer gnus-message-buffer)
1300           (message-goto-body)
1301           (insert (format gnus-crosspost-complaint newsgroups group))
1302           (message-goto-subject)
1303           (re-search-forward " *$")
1304           (replace-match " (crosspost notification)" t t)
1305           (gnus-deactivate-mark)
1306           (when (gnus-y-or-n-p "Send this complaint? ")
1307             (message-send-and-exit)))))))
1308
1309 (defun gnus-mail-parse-comma-list ()
1310   (let (accumulated
1311         beg)
1312     (skip-chars-forward " ")
1313     (while (not (eobp))
1314       (setq beg (point))
1315       (skip-chars-forward "^,")
1316       (while (zerop
1317               (save-excursion
1318                 (save-restriction
1319                   (let ((i 0))
1320                     (narrow-to-region beg (point))
1321                     (goto-char beg)
1322                     (logand (progn
1323                               (while (search-forward "\"" nil t)
1324                                 (incf i))
1325                               (if (zerop i) 2 i))
1326                             2)))))
1327         (skip-chars-forward ",")
1328         (skip-chars-forward "^,"))
1329       (skip-chars-backward " ")
1330       (push (buffer-substring beg (point))
1331             accumulated)
1332       (skip-chars-forward "^,")
1333       (skip-chars-forward ", "))
1334     accumulated))
1335
1336 (defun gnus-inews-add-to-address (group)
1337   (let ((to-address (mail-fetch-field "to")))
1338     (when (and to-address
1339                (gnus-alive-p))
1340       ;; This mail group doesn't have a `to-list', so we add one
1341       ;; here.  Magic!
1342       (when (gnus-y-or-n-p
1343              (format "Do you want to add this as `to-list': %s " to-address))
1344         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1345
1346 (defun gnus-put-message ()
1347   "Put the current message in some group and return to Gnus."
1348   (interactive)
1349   (let ((reply gnus-article-reply)
1350         (winconf gnus-prev-winconf)
1351         (group gnus-newsgroup-name))
1352     (unless (and group
1353                  (not (gnus-group-read-only-p group)))
1354       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1355
1356     (when (gnus-gethash group gnus-newsrc-hashtb)
1357       (error "No such group: %s" group))
1358     (save-excursion
1359       (save-restriction
1360         (widen)
1361         (message-narrow-to-headers)
1362         (let ((gnus-deletable-headers nil))
1363           (message-generate-headers
1364            (if (message-news-p)
1365                message-required-news-headers
1366              message-required-mail-headers)))
1367         (goto-char (point-max))
1368         (if (string-match " " group)
1369             (insert "Gcc: \"" group "\"\n")
1370           (insert "Gcc: " group "\n"))
1371         (widen)))
1372     (gnus-inews-do-gcc)
1373     (when (and (get-buffer gnus-group-buffer)
1374                (gnus-buffer-exists-p (car-safe reply))
1375                (cdr reply))
1376       (set-buffer (car reply))
1377       (gnus-summary-mark-article-as-replied (cdr reply)))
1378     (when winconf
1379       (set-window-configuration winconf))))
1380
1381 (defun gnus-article-mail (yank)
1382   "Send a reply to the address near point.
1383 If YANK is non-nil, include the original article."
1384   (interactive "P")
1385   (let ((address
1386          (buffer-substring
1387           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1388           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1389     (when address
1390       (gnus-msg-mail address)
1391       (when yank
1392         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1393
1394 (defvar nntp-server-type)
1395 (defun gnus-bug ()
1396   "Send a bug report to the Gnus maintainers."
1397   (interactive)
1398   (unless (gnus-alive-p)
1399     (error "Gnus has been shut down"))
1400   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1401     (unless (message-mail-user-agent)
1402       (delete-other-windows)
1403       (when gnus-bug-create-help-buffer
1404         (switch-to-buffer "*Gnus Help Bug*")
1405         (erase-buffer)
1406         (insert gnus-bug-message)
1407         (goto-char (point-min)))
1408       (message-pop-to-buffer "*Gnus Bug*"))
1409     (let ((message-this-is-mail t))
1410       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1411     (when gnus-bug-create-help-buffer
1412       (push `(gnus-bug-kill-buffer) message-send-actions))
1413     (goto-char (point-min))
1414     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1415     (forward-line 1)
1416     (insert (gnus-version) "\n"
1417             (emacs-version) "\n")
1418     (when (and (boundp 'nntp-server-type)
1419                (stringp nntp-server-type))
1420       (insert nntp-server-type))
1421     (insert "\n\n\n\n\n")
1422     (let (text)
1423       (save-excursion
1424         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1425         (erase-buffer)
1426         (gnus-debug)
1427         (setq text (buffer-string)))
1428       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1429     (goto-char (point-min))
1430     (search-forward "Subject: " nil t)
1431     (message "")))
1432
1433 (defun gnus-bug-kill-buffer ()
1434   (when (get-buffer "*Gnus Help Bug*")
1435     (kill-buffer "*Gnus Help Bug*")))
1436
1437 (defun gnus-summary-yank-message (buffer n)
1438   "Yank the current article into a composed message."
1439   (interactive
1440    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1441          current-prefix-arg))
1442   (gnus-summary-iterate n
1443     (let ((gnus-display-mime-function nil)
1444           (gnus-inhibit-treatment t))
1445       (gnus-summary-select-article))
1446     (save-excursion
1447       (set-buffer buffer)
1448       (message-yank-buffer gnus-article-buffer))))
1449
1450 (defun gnus-debug ()
1451   "Attempts to go through the Gnus source file and report what variables have been changed.
1452 The source file has to be in the Emacs load path."
1453   (interactive)
1454   (let ((files gnus-debug-files)
1455         (point (point))
1456         file expr olist sym)
1457     (gnus-message 4 "Please wait while we snoop your variables...")
1458     (sit-for 0)
1459     ;; Go through all the files looking for non-default values for variables.
1460     (save-excursion
1461       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1462       (while files
1463         (erase-buffer)
1464         (when (and (setq file (locate-library (pop files)))
1465                    (file-exists-p file))
1466           (insert-file-contents file)
1467           (goto-char (point-min))
1468           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1469               (gnus-message 4 "Malformed sources in file %s" file)
1470             (narrow-to-region (point-min) (point))
1471             (goto-char (point-min))
1472             (while (setq expr (ignore-errors (read (current-buffer))))
1473               (ignore-errors
1474                 (and (or (eq (car expr) 'defvar)
1475                          (eq (car expr) 'defcustom))
1476                      (stringp (nth 3 expr))
1477                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1478                      (or (not (boundp (nth 1 expr)))
1479                          (not (equal (eval (nth 2 expr))
1480                                      (symbol-value (nth 1 expr)))))
1481                      (push (nth 1 expr) olist)))))))
1482       (kill-buffer (current-buffer)))
1483     (when (setq olist (nreverse olist))
1484       (insert "------------------ Environment follows ------------------\n\n"))
1485     (while olist
1486       (if (boundp (car olist))
1487           (condition-case ()
1488               (pp `(setq ,(car olist)
1489                          ,(if (or (consp (setq sym (symbol-value (car olist))))
1490                                   (and (symbolp sym)
1491                                        (not (or (eq sym nil)
1492                                                 (eq sym t)))))
1493                               (list 'quote (symbol-value (car olist)))
1494                             (symbol-value (car olist))))
1495                   (current-buffer))
1496             (error
1497              (format "(setq %s 'whatever)\n" (car olist))))
1498         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1499       (setq olist (cdr olist)))
1500     (insert "\n\n")
1501     ;; Remove any control chars - they seem to cause trouble for some
1502     ;; mailers.  (Byte-compiled output from the stuff above.)
1503     (goto-char point)
1504     (while (re-search-forward "[\000-\010\013-\037\200-\237]" nil t)
1505       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1506                      t t))))
1507
1508 ;;; Treatment of rejected articles.
1509 ;;; Bounced mail.
1510
1511 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1512   "Re-mail the current message.
1513 This only makes sense if the current message is a bounce message than
1514 contains some mail you have written which has been bounced back to
1515 you.
1516 If FETCH, try to fetch the article that this is a reply to, if indeed
1517 this is a reply."
1518   (interactive "P")
1519   (gnus-summary-select-article t)
1520   (set-buffer gnus-original-article-buffer)
1521   (gnus-setup-message 'compose-bounce
1522     (let* ((references (mail-fetch-field "references"))
1523            (parent (and references (gnus-parent-id references))))
1524       (message-bounce)
1525       ;; If there are references, we fetch the article we answered to.
1526       (and fetch parent
1527            (gnus-summary-refer-article parent)
1528            (gnus-summary-show-all-headers)))))
1529
1530 ;;; Gcc handling.
1531
1532 (defun gnus-inews-group-method (group)
1533   (cond
1534    ;; If the group doesn't exist, we assume
1535    ;; it's an archive group...
1536    ((and (null (gnus-get-info group))
1537          (eq (car (gnus-server-to-method gnus-message-archive-method))
1538              (car (gnus-server-to-method (gnus-group-method group)))))
1539     gnus-message-archive-method)
1540    ;; Use the method.
1541    ((gnus-info-method (gnus-get-info group))
1542     (gnus-info-method (gnus-get-info group)))
1543    ;; Find the method.
1544    (t (gnus-server-to-method (gnus-group-method group)))))
1545
1546 ;; Do Gcc handling, which copied the message over to some group.
1547 (defun gnus-inews-do-gcc (&optional gcc)
1548   (interactive)
1549   (save-excursion
1550     (save-restriction
1551       (message-narrow-to-headers)
1552       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1553             (cur (current-buffer))
1554             groups group method group-art
1555             mml-externalize-attachments)
1556         (when gcc
1557           (message-remove-header "gcc")
1558           (widen)
1559           (setq groups (message-unquote-tokens
1560                         (message-tokenize-header gcc " ,")))
1561           ;; Copy the article over to some group(s).
1562           (while (setq group (pop groups))
1563             (unless (gnus-check-server
1564                      (setq method (gnus-inews-group-method group)))
1565               (error "Can't open server %s" (if (stringp method) method
1566                                               (car method))))
1567             (unless (gnus-request-group group nil method)
1568               (gnus-request-create-group group method))
1569             (setq mml-externalize-attachments
1570                   (if (stringp gnus-gcc-externalize-attachments)
1571                       (string-match gnus-gcc-externalize-attachments group)
1572                     gnus-gcc-externalize-attachments))
1573             (save-excursion
1574               (nnheader-set-temp-buffer " *acc*")
1575               (insert-buffer-substring cur)
1576               (message-encode-message-body)
1577               (save-restriction
1578                 (message-narrow-to-headers)
1579                 (let* ((mail-parse-charset message-default-charset)
1580                        (newsgroups-field (save-restriction
1581                                            (message-narrow-to-headers-or-head)
1582                                            (message-fetch-field "Newsgroups")))
1583                        (followup-field (save-restriction
1584                                          (message-narrow-to-headers-or-head)
1585                                          (message-fetch-field "Followup-To")))
1586                        ;; BUG: We really need to get the charset for
1587                        ;; each name in the Newsgroups and Followup-To
1588                        ;; lines to allow crossposting between group
1589                        ;; namess with incompatible character sets.
1590                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1591                        (group-field-charset
1592                         (gnus-group-name-charset
1593                          method (or newsgroups-field "")))
1594                        (followup-field-charset
1595                         (gnus-group-name-charset
1596                          method (or followup-field "")))
1597                        (rfc2047-header-encoding-alist
1598                         (append
1599                          (when group-field-charset
1600                            (list (cons "Newsgroups" group-field-charset)))
1601                          (when followup-field-charset
1602                            (list (cons "Followup-To" followup-field-charset)))
1603                          rfc2047-header-encoding-alist)))
1604                   (mail-encode-encoded-word-buffer)))
1605               (goto-char (point-min))
1606               (when (re-search-forward
1607                      (concat "^" (regexp-quote mail-header-separator) "$")
1608                      nil t)
1609                 (replace-match "" t t ))
1610               (unless (setq group-art
1611                             (gnus-request-accept-article group method t t))
1612                 (gnus-message 1 "Couldn't store article in group %s: %s"
1613                               group (gnus-status-message method))
1614                 (sit-for 2))
1615               (when (and group-art
1616                          (or gnus-gcc-mark-as-read
1617                              gnus-inews-mark-gcc-as-read))
1618                 (gnus-group-mark-article-read group (cdr group-art)))
1619               (kill-buffer (current-buffer)))))))))
1620
1621 (defun gnus-inews-insert-gcc ()
1622   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1623   (save-excursion
1624     (save-restriction
1625       (message-narrow-to-headers)
1626       (let* ((group gnus-outgoing-message-group)
1627              (gcc (cond
1628                    ((gnus-functionp group)
1629                     (funcall group))
1630                    ((or (stringp group) (list group))
1631                     group))))
1632         (when gcc
1633           (insert "Gcc: "
1634                   (if (stringp gcc)
1635                       (if (string-match " " gcc)
1636                           (concat "\"" gcc "\"")
1637                         gcc)
1638                     (mapconcat (lambda (group)
1639                                  (if (string-match " " group)
1640                                      (concat "\"" group "\"")
1641                                    group))
1642                                gcc " "))
1643                   "\n"))))))
1644
1645 (defun gnus-inews-insert-archive-gcc (&optional group)
1646   "Insert the Gcc to say where the article is to be archived."
1647   (let* ((var gnus-message-archive-group)
1648          (group (or group gnus-newsgroup-name ""))
1649          (gcc-self-val
1650           (and gnus-newsgroup-name
1651                (not (equal gnus-newsgroup-name ""))
1652                (gnus-group-find-parameter
1653                 gnus-newsgroup-name 'gcc-self)))
1654          result
1655          (groups
1656           (cond
1657            ((null gnus-message-archive-method)
1658             ;; Ignore.
1659             nil)
1660            ((stringp var)
1661             ;; Just a single group.
1662             (list var))
1663            ((null var)
1664             ;; We don't want this.
1665             nil)
1666            ((and (listp var) (stringp (car var)))
1667             ;; A list of groups.
1668             var)
1669            ((gnus-functionp var)
1670             ;; A function.
1671             (funcall var group))
1672            (t
1673             ;; An alist of regexps/functions/forms.
1674             (while (and var
1675                         (not
1676                          (setq result
1677                                (cond
1678                                 ((stringp (caar var))
1679                                  ;; Regexp.
1680                                  (when (string-match (caar var) group)
1681                                    (cdar var)))
1682                                 ((gnus-functionp (car var))
1683                                  ;; Function.
1684                                  (funcall (car var) group))
1685                                 (t
1686                                  (eval (car var)))))))
1687               (setq var (cdr var)))
1688             result)))
1689          name)
1690     (when (or groups gcc-self-val)
1691       (when (stringp groups)
1692         (setq groups (list groups)))
1693       (save-excursion
1694         (save-restriction
1695           (message-narrow-to-headers)
1696           (goto-char (point-max))
1697           (insert "Gcc: ")
1698           (if gcc-self-val
1699               ;; Use the `gcc-self' param value instead.
1700               (progn
1701                 (insert
1702                  (if (stringp gcc-self-val)
1703                      (if (string-match " " gcc-self-val)
1704                          (concat "\"" gcc-self-val "\"")
1705                        gcc-self-val)
1706                    (if (string-match " " group)
1707                        (concat "\"" group "\"")
1708                      group)))
1709                 (if (not (eq gcc-self-val 'none))
1710                     (insert "\n")
1711                   (progn
1712                     (beginning-of-line)
1713                     (kill-line))))
1714             ;; Use the list of groups.
1715             (while (setq name (pop groups))
1716               (let ((str (if (string-match ":" name)
1717                              name
1718                            (gnus-group-prefixed-name
1719                             name gnus-message-archive-method))))
1720                 (insert (if (string-match " " str)
1721                             (concat "\"" str "\"")
1722                           str)))
1723               (when groups
1724                 (insert " ")))
1725             (insert "\n")))))))
1726
1727 ;;; Posting styles.
1728
1729 (defun gnus-configure-posting-styles (&optional group-name)
1730   "Configure posting styles according to `gnus-posting-styles'."
1731   (unless gnus-inhibit-posting-styles
1732     (let ((group (or group-name gnus-newsgroup-name ""))
1733           (styles gnus-posting-styles)
1734           style match variable attribute value v results
1735           filep name address element)
1736       ;; If the group has a posting-style parameter, add it at the end with a
1737       ;; regexp matching everything, to be sure it takes precedence over all
1738       ;; the others.
1739       (when gnus-newsgroup-name
1740         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1741           (when tmp-style
1742             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1743       ;; Go through all styles and look for matches.
1744       (dolist (style styles)
1745         (setq match (pop style))
1746         (goto-char (point-min))
1747         (when (cond
1748                ((stringp match)
1749                 ;; Regexp string match on the group name.
1750                 (string-match match group))
1751                ((eq match 'header)
1752                 ;; Obsolete format of header match.
1753                 (and (gnus-buffer-live-p gnus-article-copy)
1754                      (with-current-buffer gnus-article-copy
1755                        (let ((header (message-fetch-field (pop style))))
1756                          (and header
1757                               (string-match (pop style) header))))))
1758                ((or (symbolp match)
1759                     (gnus-functionp match))
1760                 (cond
1761                  ((gnus-functionp match)
1762                   ;; Function to be called.
1763                   (funcall match))
1764                  ((boundp match)
1765                   ;; Variable to be checked.
1766                   (symbol-value match))))
1767                ((listp match)
1768                 (cond
1769                  ((eq (car match) 'header)
1770                   ;; New format of header match.
1771                   (and (gnus-buffer-live-p gnus-article-copy)
1772                        (with-current-buffer gnus-article-copy
1773                          (let ((header (message-fetch-field (nth 1 match))))
1774                            (and header
1775                                 (string-match (nth 2 match) header))))))
1776                  (t
1777                   ;; This is a form to be evaled.
1778                   (eval match)))))
1779           ;; We have a match, so we set the variables.
1780           (dolist (attribute style)
1781             (setq element (pop attribute)
1782                   variable nil
1783                   filep nil)
1784             (setq value
1785                   (cond
1786                    ((eq (car attribute) :file)
1787                     (setq filep t)
1788                     (cadr attribute))
1789                    ((eq (car attribute) :value)
1790                     (cadr attribute))
1791                    (t
1792                     (car attribute))))
1793             ;; We get the value.
1794             (setq v
1795                   (cond
1796                    ((stringp value)
1797                     value)
1798                    ((or (symbolp value)
1799                         (gnus-functionp value))
1800                     (cond ((gnus-functionp value)
1801                            (funcall value))
1802                           ((boundp value)
1803                            (symbol-value value))))
1804                    ((listp value)
1805                     (eval value))))
1806             ;; Translate obsolescent value.
1807             (cond
1808              ((eq element 'signature-file)
1809               (setq element 'signature
1810                     filep t))
1811              ((eq element 'x-face-file)
1812               (setq element 'x-face
1813                     filep t)))
1814             ;; Get the contents of file elems.
1815             (when (and filep v)
1816               (setq v (with-temp-buffer
1817                         (insert-file-contents v)
1818                         (goto-char (point-max))
1819                         (while (bolp)
1820                           (delete-char -1))
1821                         (buffer-string))))
1822             (setq results (delq (assoc element results) results))
1823             (push (cons element v) results))))
1824       ;; Now we have all the styles, so we insert them.
1825       (setq name (assq 'name results)
1826             address (assq 'address results))
1827       (setq results (delq name (delq address results)))
1828       ;; make-local-hook is not obsolete in Emacs 20 or XEmacs.
1829       (make-local-hook 'message-setup-hook)
1830       (setq results (sort results (lambda (x y)
1831                                     (string-lessp (car x) (car y)))))
1832       (dolist (result results)
1833         (add-hook 'message-setup-hook
1834                   (cond
1835                    ((eq 'eval (car result))
1836                     'ignore)
1837                    ((eq 'body (car result))
1838                     `(lambda ()
1839                        (save-excursion
1840                          (message-goto-body)
1841                          (insert ,(cdr result)))))
1842                    ((eq 'signature (car result))
1843                     (set (make-local-variable 'message-signature) nil)
1844                     (set (make-local-variable 'message-signature-file) nil)
1845                     (if (not (cdr result))
1846                         'ignore
1847                       `(lambda ()
1848                          (save-excursion
1849                            (let ((message-signature ,(cdr result)))
1850                              (when message-signature
1851                                (message-insert-signature)))))))
1852                    (t
1853                     (let ((header
1854                            (if (symbolp (car result))
1855                                (capitalize (symbol-name (car result)))
1856                              (car result))))
1857                       `(lambda ()
1858                          (save-excursion
1859                            (message-remove-header ,header)
1860                            (let ((value ,(cdr result)))
1861                              (when value
1862                                (message-goto-eoh)
1863                                (insert ,header ": " value "\n"))))))))
1864                   nil 'local))
1865       (when (or name address)
1866         (add-hook 'message-setup-hook
1867                   `(lambda ()
1868                      (set (make-local-variable 'user-mail-address)
1869                           ,(or (cdr address) user-mail-address))
1870                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1871                            (user-mail-address
1872                             ,(or (cdr address) user-mail-address)))
1873                        (save-excursion
1874                          (message-remove-header "From")
1875                          (message-goto-eoh)
1876                          (insert "From: " (message-make-from) "\n"))))
1877                   nil 'local)))))
1878
1879 ;;; Allow redefinition of functions.
1880
1881 (gnus-ems-redefine)
1882
1883 (provide 'gnus-msg)
1884
1885 ;;; gnus-msg.el ends here