git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-namazu.el

   1 ;;; gnus-namazu.el --- Search mail with Namazu -*- coding: iso-2022-7bit; -*-
   2
   3 ;; Copyright (C) 2000,2001,2002 TSUCHIYA Masatoshi <tsuchiya@namazu.org>
   4
   5 ;; Author: TSUCHIYA Masatoshi <tsuchiya@namazu.org>
   6 ;; Keywords: mail searching namazu
   7
   8 ;; This file is a part of Semi-Gnus.
   9
  10 ;; This program is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; This program is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with this program; if not, you can either send email to this
  22 ;; program's maintainer or write to: The Free Software Foundation,
  23 ;; Inc.; 59 Temple Place, Suite 330; Boston, MA 02111-1307, USA.
  24
  25
  26 ;;; Commentary:
  27
  28 ;; This file defines the command to search mails and persistent
  29 ;; articles with Namazu and to browse its results with Gnus.
  30 ;;
  31 ;; Namazu is a full-text search engine intended for easy use.  For
  32 ;; more detail about Namazu, visit the following page:
  33 ;;
  34 ;;     http://namazu.org/
  35
  36
  37 ;;; Quick Start:
  38
  39 ;; If this module has already been installed, only 3 steps are
  40 ;; required to search articles with this module.
  41 ;;
  42 ;;   (1) Install Namazu.
  43 ;;   (2) Start Gnus and type M-x gnus-namazu-create-index RET to make
  44 ;;       index of articles.
  45 ;;   (3) In group buffer or in summary buffer, type C-c C-n query RET.
  46
  47
  48 ;;; Install:
  49
  50 ;; Before installing this module, you must install Namazu.
  51 ;;
  52 ;; This file is a part of T-gnus but is not *YET* a part of Gnus.
  53 ;; When you would like to use this module in Gnus (not T-gnus), put
  54 ;; this file into the lisp/ directory in the Gnus source tree and run
  55 ;; `make install'.  And then, put the following expression into your
  56 ;; ~/.gnus.
  57 ;;
  58 ;;      (require 'gnus-namazu)
  59 ;;      (gnus-namazu-insinuate)
  60 ;;
  61 ;; In order to make index of articles with Namazu before using this
  62 ;; module, type M-x gnus-namazu-create-index RET.  Otherwise, you can
  63 ;; create index by yourself with the following commands:
  64 ;;
  65 ;;      % mkdir ~/News/namazu
  66 ;;      % mknmz -a -h -O ~/News/namazu ~/Mail ~/News/cache
  67 ;;
  68 ;; The first command makes the directory for index files, and the
  69 ;; second command generates index files of mails and persistent
  70 ;; articles.
  71 ;;
  72 ;; In order to update indices for incoming articles, this module
  73 ;; automatically runs mknmz, the indexer of Namazu, at an interval of
  74 ;; 3 days; this period is set to `gnus-namazu-index-update-interval'.
  75 ;;
  76 ;; Indices will be updated when `gnus-namazu-search' is called.  If
  77 ;; you want to update indices everywhen Gnus is started, you can put
  78 ;; the following expression to your ~/.gnus.
  79 ;;
  80 ;;      (add-hook 'gnus-startup-hook 'gnus-namazu-update-all-indices)
  81 ;;
  82 ;; In order to control mknmz closely, disable the automatic updating
  83 ;; feature and run mknmz by yourself.  In this case, set nil to the
  84 ;; above option.
  85 ;;
  86 ;;      (setq gnus-namazu-index-update-interval nil)
  87 ;;
  88 ;; When your index is put into the directory other than the default
  89 ;; one (~/News/namazu), it is necessary to set its place to
  90 ;; `gnus-namazu-index-directories' as follows:
  91 ;;
  92 ;;      (setq gnus-namazu-index-directories
  93 ;;            (list (expand-file-name "~/namazu")))
  94
  95
  96 ;;; Code:
  97
  98 (eval-when-compile (require 'cl))
  99 (require 'nnoo)
 100 (require 'nnheader)
 101 (require 'nnmail)
 102 (require 'gnus-sum)
 103
 104 ;; It is required for Mule 2.3.  See the file Mule23@1934.en.
 105 (eval-and-compile
 106   (autoload 'regexp-opt "regexp-opt"))
 107
 108 ;; To suppress byte-compile warning.
 109 (eval-when-compile
 110   (defvar nnml-directory)
 111   (defvar nnmh-directory))
 112
 113
 114 (defgroup gnus-namazu nil
 115   "Search nnmh and nnml groups in Gnus with Namazu."
 116   :group 'namazu
 117   :group 'gnus
 118   :prefix "gnus-namazu-")
 119
 120 (defconst gnus-namazu-default-index-directory
 121   (expand-file-name "namazu" gnus-directory)
 122   "Default place of Namazu index files.")
 123
 124 (defcustom gnus-namazu-index-directories
 125   (list
 126    (or (and (boundp 'gnus-namazu-index-directory)
 127             (symbol-value 'gnus-namazu-index-directory))
 128        (and (boundp 'nnir-namazu-index-directory)
 129             (symbol-value 'nnir-namazu-index-directory))
 130        gnus-namazu-default-index-directory))
 131   "*Places of Namazu index files."
 132   :type '(repeat directory)
 133   :group 'gnus-namazu)
 134
 135 (defcustom gnus-namazu-command
 136   (or (and (boundp 'namazu-command)
 137            (symbol-value 'namazu-command))
 138       (and (boundp 'nnir-namazu-program)
 139            (symbol-value 'nnir-namazu-program))
 140       "namazu")
 141   "*Name of the executable file of Namazu."
 142   :type 'string
 143   :group 'gnus-namazu)
 144
 145 (defcustom gnus-namazu-additional-arguments nil
 146   "*Additional arguments of Namazu.
 147 The options `-q', `-a', and `-l' are always used, very few other
 148 options make any sense in this context."
 149   :type '(repeat string)
 150   :group 'gnus-namazu)
 151
 152 (defcustom gnus-namazu-index-update-interval
 153   259200                                ; 3 days == 259200 seconds.
 154   "*Number of seconds between running the indexer of Namazu."
 155   :type '(choice (const :tag "Never run the indexer" nil)
 156                  (integer :tag "Number of seconds"))
 157   :group 'gnus-namazu)
 158
 159 (defcustom gnus-namazu-make-index-command "mknmz"
 160   "*Name of the executable file of the indexer of Namazu."
 161   :type 'string
 162   :group 'gnus-namazu)
 163
 164 (defcustom gnus-namazu-make-index-arguments
 165   (nconc
 166    (list "--all" "--mailnews" "--deny=^.*[^0-9].*$")
 167    (when (or (and (boundp 'current-language-environment)
 168                   (string= "Japanese"
 169                            (symbol-value 'current-language-environment)))
 170              (boundp 'MULE))
 171      (list "--indexing-lang=ja")))
 172   "*Arguments of the indexer of Namazu."
 173   :type '(repeat string)
 174   :group 'gnus-namazu)
 175
 176 (defcustom gnus-namazu-field-keywords
 177   '("date" "from" "newsgroups" "size" "subject" "summary" "to" "uri")
 178   "*List of keywords to do field-search."
 179   :type '(repeat string)
 180   :group 'gnus-namazu)
 181
 182 (defcustom gnus-namazu-coding-system
 183   (if (memq system-type '(windows-nt OS/2 emx))
 184       (if (boundp 'MULE) '*sjis* 'shift_jis)
 185     (if (boundp 'MULE) '*euc-japan* 'euc-japan))
 186   "*Coding system for Namazu process."
 187   :type 'coding-system
 188   :group 'gnus-namazu)
 189
 190 (defcustom gnus-namazu-need-path-normalization
 191   (and (memq system-type '(windows-nt OS/2 emx)) t)
 192   "*Non-nil means that outputs of namazu may contain drive letters."
 193   :type 'boolean
 194   :group 'gnus-namazu)
 195
 196 (defcustom gnus-namazu-case-sensitive-filesystem
 197   (not (eq system-type 'windows-nt))
 198   "*Non-nil means that the using file system distinguishes cases of characters."
 199   :type 'boolean
 200   :group 'gnus-namazu)
 201
 202 (defcustom gnus-namazu-query-highlight t
 203   "Non-nil means that queried words is highlighted."
 204   :type 'boolean
 205   :group 'gnus-namazu)
 206
 207 (defface gnus-namazu-query-highlight-face
 208   '((((type tty pc) (class color))
 209      (:background "magenta4" :foreground "cyan1"))
 210     (((class color) (background light))
 211      (:background "magenta4" :foreground "lightskyblue1"))
 212     (((class color) (background dark))
 213      (:background "palevioletred2" :foreground "brown4"))
 214     (t (:inverse-video t)))
 215   "Face used for namazu query matching words."
 216   :group 'gnus-namazu)
 217
 218 ;;; Internal Variable:
 219 (defconst gnus-namazu/group-name-regexp "\\`nnvirtual:namazu-search\\?")
 220
 221 ;; Multibyte group name:
 222 (and
 223  (fboundp 'gnus-group-decoded-name)
 224  (let ((gnus-group-name-charset-group-alist
 225         (list (cons gnus-namazu/group-name-regexp gnus-namazu-coding-system)))
 226        (query (decode-coding-string
 227                (string 27 36 66 52 65 59 122 27 40 66)
 228                (if (boundp 'MULE) '*iso-2022-jp* 'iso-2022-7bit))))
 229    (not (string-match query
 230                       (gnus-summary-buffer-name
 231                        (encode-coding-string
 232                         (concat "nnvirtual:namazu-search?query=" query)
 233                         gnus-namazu-coding-system)))))
 234  (let (current-load-list)
 235    (defadvice gnus-summary-buffer-name
 236      (before gnus-namazu-summary-buffer-name activate compile)
 237      "Advised by `gnus-namazu' to handle encoded group names."
 238      (ad-set-arg 0 (gnus-group-decoded-name (ad-get-arg 0))))))
 239
 240 (defmacro gnus-namazu/make-article (group number)
 241   `(cons ,group ,number))
 242 (defmacro gnus-namazu/article-group  (x) `(car ,x))
 243 (defmacro gnus-namazu/article-number (x) `(cdr ,x))
 244
 245 (defsubst gnus-namazu/indexed-servers ()
 246   "Choice appropriate servers from opened ones, and return thier list."
 247   (append
 248    (gnus-servers-using-backend 'nnml)
 249    (gnus-servers-using-backend 'nnmh)))
 250
 251 (defsubst gnus-namazu/default-index-directory ()
 252   (if (member gnus-namazu-default-index-directory
 253               gnus-namazu-index-directories)
 254       gnus-namazu-default-index-directory
 255     (car gnus-namazu-index-directories)))
 256
 257 (defun gnus-namazu/setup ()
 258   (and (boundp 'gnus-group-name-charset-group-alist)
 259        (not (member (cons gnus-namazu/group-name-regexp
 260                           gnus-namazu-coding-system)
 261                     gnus-group-name-charset-group-alist))
 262        (let ((pair (assoc gnus-namazu/group-name-regexp
 263                           gnus-group-name-charset-group-alist)))
 264          (if pair
 265              (setcdr pair gnus-namazu-coding-system)
 266            (push (cons gnus-namazu/group-name-regexp
 267                        gnus-namazu-coding-system)
 268                  gnus-group-name-charset-group-alist))))
 269   (gnus-namazu-update-all-indices))
 270
 271 (defun gnus-namazu/server-directory (server)
 272   "Return the top directory of the server SERVER."
 273   (and (memq (car server) '(nnml nnmh))
 274        (nnoo-change-server (car server) (nth 1 server) (nthcdr 2 server))
 275        (file-name-as-directory
 276         (expand-file-name (if (eq 'nnml (car server))
 277                               nnml-directory
 278                             nnmh-directory)))))
 279
 280 ;;; Functions to call Namazu.
 281 (defsubst gnus-namazu/normalize-results ()
 282   "Normalize file names returned by Namazu in this current buffer."
 283   (goto-char (point-min))
 284   (while (not (eobp))
 285     (when (looking-at "file://")
 286       (delete-region (point) (match-end 0)))
 287     (when (if gnus-namazu-need-path-normalization
 288               (or (not (looking-at "/\\(.\\)|/"))
 289                   (replace-match "\\1:/"))
 290             (eq ?~ (char-after (point))))
 291       (insert (expand-file-name
 292                (buffer-substring (gnus-point-at-bol) (gnus-point-at-eol))))
 293       (delete-region (point) (gnus-point-at-eol)))
 294     (forward-line 1)))
 295
 296 (defsubst gnus-namazu/call-namazu (query)
 297   (let ((coding-system-for-read gnus-namazu-coding-system)
 298         (coding-system-for-write gnus-namazu-coding-system)
 299         (input-coding-system gnus-namazu-coding-system)
 300         (output-coding-system gnus-namazu-coding-system)
 301         (default-process-coding-system
 302           (cons gnus-namazu-coding-system gnus-namazu-coding-system))
 303         program-coding-system-alist
 304         (file-name-coding-system gnus-namazu-coding-system)
 305         (pathname-coding-system gnus-namazu-coding-system))
 306     (apply 'call-process
 307            `(,gnus-namazu-command
 308              nil                        ; input from /dev/null
 309              t                          ; output
 310              nil                        ; don't redisplay
 311              "-q"                       ; don't be verbose
 312              "-a"                       ; show all matches
 313              "-l"                       ; use list format
 314              ,@gnus-namazu-additional-arguments
 315              ,query
 316              ,@gnus-namazu-index-directories))))
 317
 318 (defsubst gnus-namazu/group-prefixed-name (group method)
 319   "Return the whole name from GROUP and METHOD."
 320   (if gnus-namazu-case-sensitive-filesystem
 321       (gnus-group-prefixed-name group method)
 322     (let* ((orig (gnus-group-prefixed-name group method))
 323            (name (downcase orig)))
 324       (catch 'found-group
 325         (mapatoms (lambda (sym)
 326                     (when (string= name (downcase (symbol-name sym)))
 327                       (throw 'found-group (symbol-name sym))))
 328                   gnus-newsrc-hashtb)
 329         orig))))
 330
 331 (defun gnus-namazu/real-group-name (cond str)
 332   "Generate the real group name from the partial path, STR."
 333   (if cond
 334       str
 335     (catch 'found-group
 336       (dolist (group (gnus-namazu/possible-real-groups
 337                       (nnheader-replace-chars-in-string str ?/ ?.)))
 338         (when (gnus-gethash group gnus-newsrc-hashtb)
 339           (throw 'found-group group))))))
 340
 341 (defun gnus-namazu/possible-real-groups (str)
 342   "Regard the string STR as the partial path of the cached article and
 343 generate possible group names from it."
 344   (if (string-match "_\\(_\\(_\\)?\\)?" str)
 345       (let ((prefix (substring str 0 (match-beginning 0)))
 346             (suffix (substring str (match-end 0))))
 347         (cond
 348          ((match-beginning 2) ;; The number of discoverd underscores = 3
 349           (nconc
 350            (gnus-namazu/possible-real-groups (concat prefix "/__" suffix))
 351            (gnus-namazu/possible-real-groups (concat prefix ".._" suffix))))
 352          ((match-beginning 1) ;; The number of discoverd underscores = 2
 353           (nconc
 354            (gnus-namazu/possible-real-groups (concat prefix "//" suffix))
 355            (gnus-namazu/possible-real-groups (concat prefix ".." suffix))))
 356          (t ;; The number of discoverd underscores = 1
 357           (gnus-namazu/possible-real-groups (concat prefix "/" suffix)))))
 358     (if (string-match "\\." str)
 359         ;; Handle the first occurence of period.
 360         (list (concat (substring str 0 (match-beginning 0))
 361                       ":"
 362                       (substring str (match-end 0)))
 363               str)
 364       (list str))))
 365
 366 (defun gnus-namazu/search (groups query)
 367   (with-temp-buffer
 368     (let ((exit-status (gnus-namazu/call-namazu query)))
 369       (unless (zerop exit-status)
 370         (error "Namazu finished abnormally: %d" exit-status))
 371       (let* ((articles)
 372              (server-alist
 373               (delq nil
 374                     (let (dir)
 375                       (mapcar
 376                        (lambda (s)
 377                          (when (setq dir (gnus-namazu/server-directory s))
 378                            (cons (file-name-as-directory dir) s)))
 379                        (gnus-namazu/indexed-servers)))))
 380              (topdir-regexp (regexp-opt (mapcar 'car server-alist)))
 381              (cache-regexp (concat
 382                             (regexp-quote
 383                              (file-name-as-directory
 384                               (expand-file-name gnus-cache-directory)))
 385                             "\\(.*\\)/\\([0-9]+\\)$"))
 386              (agent-regexp (concat
 387                             (regexp-quote
 388                              (file-name-as-directory
 389                               (expand-file-name gnus-agent-directory)))
 390                             "\\(.*\\)/\\([0-9]+\\)$")))
 391         (gnus-namazu/normalize-results)
 392         (goto-char (point-min))
 393         (while (not (eobp))
 394           (let (server group file)
 395             (and (or
 396                   ;; Check the discoverd file is the persistent article.
 397                   (and (looking-at cache-regexp)
 398                        (setq file (match-string-no-properties 2)
 399                              group (gnus-namazu/real-group-name
 400                                     (gnus-use-long-file-name 'not-cache)
 401                                     (match-string-no-properties 1))))
 402                   ;; Check the discoverd file is covered by the agent.
 403                   (and (looking-at agent-regexp)
 404                        (setq file (match-string-no-properties 2)
 405                              group (gnus-namazu/real-group-name
 406                                     nnmail-use-long-file-names
 407                                     (match-string-no-properties 1))))
 408                   ;; Check the discovered file is managed by Gnus servers.
 409                   (and (looking-at topdir-regexp)
 410                        (setq file (buffer-substring-no-properties
 411                                    (match-end 0) (gnus-point-at-eol))
 412                              server (cdr (assoc (match-string-no-properties 0)
 413                                                 server-alist)))
 414                        ;; Check validity of the file name.
 415                        (string-match "/\\([0-9]+\\)\\'" file)
 416                        (progn
 417                          (setq group (substring file 0 (match-beginning 0))
 418                                file (match-string 1 file))
 419                          (setq group
 420                                (gnus-namazu/group-prefixed-name
 421                                 (if nnmail-use-long-file-names
 422                                     group
 423                                   (nnheader-replace-chars-in-string group
 424                                                                     ?/ ?.))
 425                                 server)))))
 426                  (or (not groups)
 427                      (member group groups))
 428                  (push (gnus-namazu/make-article group (string-to-number file))
 429                        articles)))
 430           (forward-line 1))
 431         (nreverse articles)))))
 432
 433
 434 ;;; User Interface:
 435 (defun gnus-namazu/get-target-groups ()
 436   (cond
 437    ((eq major-mode 'gnus-group-mode)
 438     ;; In Group buffer.
 439     (cond
 440      (current-prefix-arg
 441       (gnus-group-process-prefix current-prefix-arg))
 442      (gnus-group-marked
 443       (prog1 gnus-group-marked (gnus-group-unmark-all-groups)))))
 444    ((eq major-mode 'gnus-summary-mode)
 445     ;; In Summary buffer.
 446     (if current-prefix-arg
 447         (list (gnus-read-group "Group: "))
 448       (if (and
 449            (gnus-ephemeral-group-p gnus-newsgroup-name)
 450            (string-match gnus-namazu/group-name-regexp gnus-newsgroup-name))
 451           (cadr (assq 'gnus-namazu-target-groups
 452                       (gnus-info-method (gnus-get-info gnus-newsgroup-name))))
 453         (list gnus-newsgroup-name))))))
 454
 455 (defun gnus-namazu/get-current-query ()
 456   (and (eq major-mode 'gnus-summary-mode)
 457        (gnus-ephemeral-group-p gnus-newsgroup-name)
 458        (string-match gnus-namazu/group-name-regexp gnus-newsgroup-name)
 459        (cadr (assq 'gnus-namazu-current-query
 460                    (gnus-info-method (gnus-get-info gnus-newsgroup-name))))))
 461
 462 (defvar gnus-namazu/read-query-original-buffer nil)
 463 (defvar gnus-namazu/read-query-prompt nil)
 464 (defvar gnus-namazu/read-query-history nil)
 465
 466 (defun gnus-namazu/get-current-subject ()
 467   (and gnus-namazu/read-query-original-buffer
 468        (bufferp gnus-namazu/read-query-original-buffer)
 469        (with-current-buffer gnus-namazu/read-query-original-buffer
 470          (when (eq major-mode 'gnus-summary-mode)
 471            (let ((s (gnus-summary-article-subject)))
 472              ;; Remove typically prefixes of mailing lists.
 473              (when (string-match
 474                     "^\\(\\[[^]]*[0-9]+\\]\\|([^)]*[0-9]+)\\)\\s-*" s)
 475                (setq s (substring s (match-end 0))))
 476              (when (string-match
 477                     "^\\(Re\\(\\^?\\([0-9]+\\|\\[[0-9]+\\]\\)\\)?:\\s-*\\)+" s)
 478                (setq s (substring s (match-end 0))))
 479              (when (string-match "\\s-*(\\(re\\|was\\)\\b" s)
 480                (setq s (substring s 0 (match-beginning 0))))
 481              s)))))
 482
 483 (defun gnus-namazu/get-current-from ()
 484   (and gnus-namazu/read-query-original-buffer
 485        (bufferp gnus-namazu/read-query-original-buffer)
 486        (with-current-buffer gnus-namazu/read-query-original-buffer
 487          (when (eq major-mode 'gnus-summary-mode)
 488            (cadr (mail-extract-address-components
 489                   (mail-header-from
 490                    (gnus-summary-article-header))))))))
 491
 492 (defun gnus-namazu/get-current-to ()
 493   (and gnus-namazu/read-query-original-buffer
 494        (bufferp gnus-namazu/read-query-original-buffer)
 495        (with-current-buffer gnus-namazu/read-query-original-buffer
 496          (when (eq major-mode 'gnus-summary-mode)
 497            (cadr (mail-extract-address-components
 498                   (cdr (assq 'To (mail-header-extra
 499                                   (gnus-summary-article-header))))))))))
 500
 501 (defmacro gnus-namazu/minibuffer-prompt-end ()
 502   (if (fboundp 'minibuffer-prompt-end)
 503       '(minibuffer-prompt-end)
 504     '(point-min)))
 505
 506 (defun gnus-namazu/message (string &rest arguments)
 507   (let* ((s1 (concat
 508               gnus-namazu/read-query-prompt
 509               (buffer-substring (gnus-namazu/minibuffer-prompt-end)
 510                                 (point-max))))
 511          (s2 (apply (function format) string arguments))
 512          (w (- (window-width)
 513                (string-width s1)
 514                (string-width s2)
 515                1)))
 516     (message (if (>= w 0)
 517                  (concat s1 (make-string w ?\ ) s2)
 518                s2))
 519     (if (sit-for 0.3) (message s1))
 520     s2))
 521
 522 (defun gnus-namazu/complete-query ()
 523   (interactive)
 524   (let ((pos (point)))
 525     (cond
 526      ((and (re-search-backward "\\+\\([-a-z]*\\)" nil t)
 527            (= pos (match-end 0)))
 528       (let* ((partial (match-string 1))
 529              (completions
 530               (all-completions
 531                partial
 532                (mapcar 'list gnus-namazu-field-keywords))))
 533         (cond
 534          ((null completions)
 535           (gnus-namazu/message "No completions of %s" partial))
 536          ((= 1 (length completions))
 537           (goto-char (match-beginning 1))
 538           (delete-region (match-beginning 1) (match-end 1))
 539           (insert (car completions) ":")
 540           (setq pos (point))
 541           (gnus-namazu/message "Completed"))
 542          (t
 543           (let ((x (try-completion partial (mapcar 'list completions))))
 544             (if (string= x partial)
 545                 (if (and (eq last-command
 546                              'gnus-namazu/field-keyword-completion)
 547                          completion-auto-help)
 548                     (with-output-to-temp-buffer "*Completions*"
 549                       (display-completion-list completions))
 550                   (gnus-namazu/message "Sole completion"))
 551               (goto-char (match-beginning 1))
 552               (delete-region (match-beginning 1) (match-end 1))
 553               (insert x)
 554               (setq pos (point))))))))
 555      ((and (looking-at "\\+subject:")
 556            (= pos (match-end 0)))
 557       (let ((s (gnus-namazu/get-current-subject)))
 558         (when s
 559           (goto-char pos)
 560           (insert "\"" s "\"")
 561           (setq pos (point)))))
 562      ((and (looking-at "\\+from:")
 563            (= pos (match-end 0)))
 564       (let ((f (gnus-namazu/get-current-from)))
 565         (when f
 566           (goto-char pos)
 567           (insert "\"" f "\"")
 568           (setq pos (point)))))
 569      ((and (looking-at "\\+to:")
 570            (= pos (match-end 0)))
 571       (let ((to (gnus-namazu/get-current-to)))
 572         (when to
 573           (goto-char pos)
 574           (insert "\"" to "\"")
 575           (setq pos (point))))))
 576     (goto-char pos)))
 577
 578 (defvar gnus-namazu/read-query-map
 579   (let ((keymap (copy-keymap minibuffer-local-map)))
 580     (define-key keymap "\t" 'gnus-namazu/complete-query)
 581     keymap))
 582
 583 (defun gnus-namazu/read-query (prompt &optional initial)
 584   (let ((gnus-namazu/read-query-original-buffer (current-buffer))
 585         (gnus-namazu/read-query-prompt prompt))
 586     (unless initial
 587       (when (setq initial (gnus-namazu/get-current-query))
 588         (setq initial (cons initial 0))))
 589     (read-from-minibuffer prompt initial gnus-namazu/read-query-map nil
 590                           'gnus-namazu/read-query-history)))
 591
 592 (defun gnus-namazu/highlight-words (query)
 593   (with-temp-buffer
 594     (insert " " query)
 595     ;; Remove tokens for NOT search
 596     (goto-char (point-min))
 597     (while (re-search-forward "[\e$B!!\e(B \t\r\f\n]+not[\e$B!!\e(B \t\r\f\n]+\
 598 \\([^\e$B!!\e(B \t\r\f\n\"{(/]+\\|\"[^\"]+\"\\|{[^}]+}\\|([^)]+)\\|/[^/]+/\\)+" nil t)
 599       (delete-region (match-beginning 0) (match-end 0)))
 600     ;; Remove tokens for Field search
 601     (goto-char (point-min))
 602     (while (re-search-forward "[\e$B!!\e(B \t\r\f\n]+\\+[^\e$B!!\e(B \t\r\f\n:]+:\
 603 \\([^\e$B!!\e(B \t\r\f\n\"{(/]+\\|\"[^\"]+\"\\|{[^}]+}\\|([^)]+)\\|/[^/]+/\\)+" nil t)
 604       (delete-region (match-beginning 0) (match-end 0)))
 605     ;; Remove tokens for Regexp search
 606     (goto-char (point-min))
 607     (while (re-search-forward "/[^/]+/" nil t)
 608       (delete-region (match-beginning 0) (match-end 0)))
 609     ;; Remove brackets, double quote, asterisk and operators
 610     (goto-char (point-min))
 611     (while (re-search-forward "\\([(){}\"*]\\|\\b\\(and\\|or\\)\\b\\)" nil t)
 612       (delete-region (match-beginning 0) (match-end 0)))
 613     ;; Collect all keywords
 614     (setq query nil)
 615     (goto-char (point-min))
 616     (while (re-search-forward "[^\e$B!!\e(B \t\r\f\n]+" nil t)
 617       (push (match-string 0) query))
 618     (when query
 619       (list (list (regexp-opt query)
 620                   0 0 'gnus-namazu-query-highlight-face)))))
 621
 622 (defun gnus-namazu/truncate-article-list (articles)
 623   (let ((hit (length articles)))
 624     (when (and gnus-large-newsgroup
 625                (> hit gnus-large-newsgroup))
 626       (let* ((cursor-in-echo-area nil)
 627              (input (read-from-minibuffer
 628                      (format "\
 629 Too many articles were retrieved.  How many articles (max %d): "
 630                              hit)
 631                      (cons (number-to-string gnus-large-newsgroup) 0))))
 632         (unless (string-match "\\`[ \t]*\\'" input)
 633           (setcdr (nthcdr (min (1- (string-to-number input)) hit) articles)
 634                   nil)))))
 635   articles)
 636
 637 ;;;###autoload
 638 (defun gnus-namazu-search (groups query)
 639   "Search QUERY through GROUPS with Namazu,
 640 and make a virtual group contains its results."
 641   (interactive
 642    (list
 643     (gnus-namazu/get-target-groups)
 644     (gnus-namazu/read-query "Enter query: ")))
 645   (gnus-namazu/setup)
 646   (let ((articles (gnus-namazu/search groups query)))
 647     (if articles
 648         (let ((real-groups groups)
 649               (vgroup
 650                (apply (function format)
 651                       "nnvirtual:namazu-search?query=%s&groups=%s&id=%d%d%d"
 652                       query
 653                       (if groups (mapconcat 'identity groups ",") "ALL")
 654                       (current-time))))
 655           (gnus-namazu/truncate-article-list articles)
 656           (unless real-groups
 657             (dolist (a articles)
 658               (add-to-list 'real-groups (gnus-namazu/article-group a))))
 659           ;; Generate virtual group which includes all results.
 660           (when (fboundp 'gnus-group-decoded-name)
 661             (setq vgroup
 662                   (encode-coding-string vgroup gnus-namazu-coding-system)))
 663           (setq vgroup
 664                 (gnus-group-read-ephemeral-group
 665                  vgroup
 666                  `(nnvirtual ,vgroup
 667                              (nnvirtual-component-groups ,real-groups)
 668                              (gnus-namazu-target-groups ,groups)
 669                              (gnus-namazu-current-query ,query))
 670                  t (cons (current-buffer) (current-window-configuration)) t))
 671           (when gnus-namazu-query-highlight
 672             (gnus-group-set-parameter vgroup 'highlight-words
 673                                       (gnus-namazu/highlight-words query)))
 674           ;; Generate new summary buffer which contains search results.
 675           (gnus-group-read-group
 676            t t vgroup
 677            (sort (delq nil ;; Ad-hoc fix, to avoid wrong-type-argument error.
 678                        (mapcar
 679                         (lambda (a)
 680                           (nnvirtual-reverse-map-article
 681                            (gnus-namazu/article-group a)
 682                            (gnus-namazu/article-number a)))
 683                         articles))
 684                  '<)))
 685       (message "No entry."))))
 686
 687 (defmacro gnus-namazu/lock-file-name (&optional directory)
 688   `(expand-file-name "NMZ.lock2" ,directory))
 689
 690 (defmacro gnus-namazu/status-file-name (&optional directory)
 691   `(expand-file-name "NMZ.status" ,directory))
 692
 693 (defmacro gnus-namazu/index-file-name (&optional directory)
 694   `(expand-file-name "NMZ.i" ,directory))
 695
 696 (defun gnus-namazu/mknmz-cleanup (directory)
 697   (let ((lockfile (gnus-namazu/lock-file-name directory)))
 698     (when (file-exists-p lockfile)
 699       (delete-file lockfile)
 700       (dolist (tmpfile (directory-files directory t "\\`NMZ\\..*\\.tmp\\'" t))
 701         (delete-file tmpfile)))))
 702
 703 ;;;###autoload
 704 (defun gnus-namazu-create-index (directory &optional target-directories force)
 705   "Create index under DIRECTORY."
 706   (interactive
 707    (list
 708     (if (and current-prefix-arg (> (length gnus-namazu-index-directories) 1))
 709         (completing-read "Directory: "
 710                          (mapcar 'list gnus-namazu-index-directories) nil t)
 711       (gnus-namazu/default-index-directory))
 712     nil t))
 713   (setq directory (file-name-as-directory (expand-file-name directory)))
 714   (unless target-directories
 715     (setq target-directories
 716           (delq nil
 717                 (mapcar (lambda (dir)
 718                           (when (file-directory-p dir) dir))
 719                         (append
 720                          (mapcar 'gnus-namazu/server-directory
 721                                  (gnus-namazu/indexed-servers))
 722                          (list
 723                           (expand-file-name gnus-cache-directory)
 724                           (expand-file-name gnus-agent-directory)))))))
 725   (if (file-exists-p (gnus-namazu/lock-file-name directory))
 726       (when force
 727         (error "Found lock file: %s" (gnus-namazu/lock-file-name directory)))
 728     (with-current-buffer
 729         (get-buffer-create (concat " *mknmz*" directory))
 730       (erase-buffer)
 731       (unless (file-directory-p directory)
 732         (make-directory directory t))
 733       (setq default-directory directory)
 734       (let ((args (append gnus-namazu-make-index-arguments
 735                           target-directories)))
 736         (insert "% " gnus-namazu-make-index-command " "
 737                 (mapconcat 'identity args " ") "\n")
 738         (goto-char (point-max))
 739         (when force
 740           (pop-to-buffer (current-buffer)))
 741         (message "Make index at %s..." directory)
 742         (unwind-protect
 743             (apply 'call-process gnus-namazu-make-index-command nil t t args)
 744           (gnus-namazu/mknmz-cleanup directory))
 745         (message "Make index at %s...done" directory)
 746         (unless force
 747           (kill-buffer (current-buffer)))))))
 748
 749 (defun gnus-namazu/lapse-seconds (start end)
 750   "Return lapse seconds from START to END.
 751 START and END are lists which represent time in Emacs-style."
 752   (+ (* (- (car end) (car start)) 65536)
 753      (cadr end)
 754      (- (cadr start))))
 755
 756 (defun gnus-namazu/index-old-p (directory)
 757   "Return non-nil value when the index under the DIRECTORY is older
 758 than the period that is set to `gnus-namazu-index-update-interval'"
 759   (let ((file (gnus-namazu/index-file-name directory)))
 760     (or (not (file-exists-p file))
 761         (and (integerp gnus-namazu-index-update-interval)
 762              (>= (gnus-namazu/lapse-seconds
 763                   (nth 5 (file-attributes file))
 764                   (current-time))
 765                  gnus-namazu-index-update-interval)))))
 766
 767 (defvar gnus-namazu/update-directories nil)
 768 (defvar gnus-namazu/update-process nil)
 769
 770 (defun gnus-namazu/update-p (directory &optional force)
 771   "Return the DIRECTORY when the index undef the DIRECTORY should be updated."
 772   (setq directory (file-name-as-directory (expand-file-name directory)))
 773   (labels ((error-message (format &rest args)
 774                           (apply (if force 'error 'message) format args)
 775                           nil))
 776     (if gnus-namazu/update-process
 777         (error-message "%s" "Can not run two update processes simultaneously")
 778       (and (or force
 779                (gnus-namazu/index-old-p directory))
 780            (let ((status-file (gnus-namazu/status-file-name directory)))
 781              (or (file-exists-p status-file)
 782                  (error-message "Can not find status file: %s" status-file)))
 783            (let ((lock-file (gnus-namazu/lock-file-name directory)))
 784              (or (not (file-exists-p lock-file))
 785                  (error-message "Found lock file: %s" lock-file)))
 786            directory))))
 787
 788 ;;;###autoload
 789 (defun gnus-namazu-update-index (directory &optional force)
 790   "Update the index under the DIRECTORY."
 791   (interactive
 792    (list
 793     (if (and current-prefix-arg (> (length gnus-namazu-index-directories) 1))
 794         (completing-read "Directory: "
 795                          (mapcar 'list gnus-namazu-index-directories) nil t)
 796       (gnus-namazu/default-index-directory))
 797     t))
 798   (when (setq directory (gnus-namazu/update-p directory force))
 799     (with-current-buffer (get-buffer-create (concat " *mknmz*" directory))
 800       (buffer-disable-undo)
 801       (erase-buffer)
 802       (unless (file-directory-p directory)
 803         (make-directory directory t))
 804       (setq default-directory directory)
 805       (let ((proc (start-process gnus-namazu-make-index-command
 806                                  (current-buffer)
 807                                  gnus-namazu-make-index-command
 808                                  (format "--update=%s" directory))))
 809         (if (processp proc)
 810             (prog1 (setq gnus-namazu/update-process proc)
 811               (process-kill-without-query proc)
 812               (set-process-sentinel proc 'gnus-namazu/update-sentinel)
 813               (add-hook 'kill-emacs-hook 'gnus-namazu-stop-update)
 814               (message "Update index at %s..." directory))
 815           (goto-char (point-min))
 816           (if (re-search-forward "^ERROR:.*$" nil t)
 817               (progn
 818                 (pop-to-buffer (current-buffer))
 819                 (funcall (if force 'error 'message)
 820                          "Update index at %s...%s" directory (match-string 0)))
 821             (kill-buffer (current-buffer))
 822             (funcall (if force 'error 'message)
 823                      "Can not start %s" gnus-namazu-make-index-command))
 824           nil)))))
 825
 826 ;;;###autoload
 827 (defun gnus-namazu-update-all-indices (&optional directories force)
 828   "Update all indices which is set to `gnus-namazu-index-directories'."
 829   (interactive (list nil t))
 830   (when (setq directories
 831               (delq nil (mapcar
 832                          (lambda (d) (gnus-namazu/update-p d force))
 833                          (or directories gnus-namazu-index-directories))))
 834     (setq gnus-namazu/update-directories (cdr directories))
 835     (gnus-namazu-update-index (car directories))))
 836
 837 (defun gnus-namazu/update-sentinel (process event)
 838   (let ((buffer (process-buffer process)))
 839     (when (buffer-name buffer)
 840       (with-current-buffer buffer
 841         (gnus-namazu/mknmz-cleanup default-directory)
 842         (goto-char (point-min))
 843         (cond
 844          ((re-search-forward "^ERROR:.*$" nil t)
 845           (pop-to-buffer (current-buffer))
 846           (message "Update index at %s...%s"
 847                    default-directory (match-string 0))
 848           (setq gnus-namazu/update-directories nil))
 849          ((and (eq 'exit (process-status process))
 850                (zerop (process-exit-status process)))
 851           (message "Update index at %s...done" default-directory)
 852           (unless (or debug-on-error debug-on-quit)
 853             (kill-buffer buffer)))))))
 854   (setq gnus-namazu/update-process nil)
 855   (when gnus-namazu/update-directories
 856     (gnus-namazu-update-all-indices gnus-namazu/update-directories)))
 857
 858 ;;;###autoload
 859 (defun gnus-namazu-stop-update ()
 860   "Stop the running indexer of Namazu."
 861   (interactive)
 862   (setq gnus-namazu/update-directories nil)
 863   (and gnus-namazu/update-process
 864        (processp gnus-namazu/update-process)
 865        (kill-process gnus-namazu/update-process)))
 866
 867 (let (current-load-list)
 868   (defadvice gnus-offer-save-summaries
 869     (before gnus-namazu-kill-summary-buffers activate compile)
 870     "Advised by `gnus-namazu'.
 871 In order to avoid annoying questions, kill summary buffers which
 872 generated by `gnus-namazu' itself before `gnus-offer-save-summaries'
 873 is called."
 874     (let ((buffers (buffer-list)))
 875       (while buffers
 876         (when (with-current-buffer (car buffers)
 877                 (and (eq major-mode 'gnus-summary-mode)
 878                      (gnus-ephemeral-group-p gnus-newsgroup-name)
 879                      (string-match gnus-namazu/group-name-regexp
 880                                    gnus-newsgroup-name)))
 881           (kill-buffer (car buffers)))
 882         (setq buffers (cdr buffers))))))
 883
 884 ;;;###autoload
 885 (defun gnus-namazu-insinuate ()
 886   (add-hook
 887    'gnus-group-mode-hook
 888    (lambda ()
 889      (define-key gnus-group-mode-map "\C-c\C-n" 'gnus-namazu-search)))
 890   (add-hook
 891    'gnus-summary-mode-hook
 892    (lambda ()
 893      (define-key gnus-summary-mode-map "\C-c\C-n" 'gnus-namazu-search))))
 894
 895 (provide 'gnus-namazu)
 896
 897 ;; gnus-namazu.el ends here.