git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-picon.el

   1 ;;; gnus-picon.el --- displaying pretty icons in Gnus
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Wes Hardaker <hardaker@ece.ucdavis.edu>
   7 ;; Keywords: news xpm annotation glyph faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'gnus)
  31 ;; (require 'xpm)
  32 (require 'annotations)
  33 (require 'custom)
  34 (require 'gnus-art)
  35 (require 'gnus-win)
  36
  37 ;;; User variables:
  38
  39 (defgroup picons nil
  40   "Show pictures of people, domains, and newsgroups (XEmacs).
  41 For this to work, you must switch on the `gnus-treat-display-picons'
  42 variable."
  43   :group 'gnus-visual)
  44
  45 (defcustom gnus-picons-display-where 'picons
  46   "Where to display the group and article icons.
  47 Valid values are `article' and `picons'."
  48   :type '(choice symbol string)
  49   :group 'picons)
  50
  51 (defcustom gnus-picons-has-modeline-p t
  52   "*Whether the picons window should have a modeline.
  53 This is only useful if `gnus-picons-display-where' is `picons'."
  54   :type 'boolean
  55   :group 'picons)
  56
  57 (defcustom gnus-picons-database "/usr/local/faces"
  58   "*Defines the location of the faces database.
  59 For information on obtaining this database of pretty pictures, please
  60 see http://www.cs.indiana.edu/picons/ftp/index.html"
  61   :type 'directory
  62   :group 'picons)
  63
  64 (defcustom gnus-picons-news-directories '("news")
  65   "*List of directories to search for newsgroups faces."
  66   :type '(repeat string)
  67   :group 'picons)
  68 (define-obsolete-variable-alias 'gnus-picons-news-directory
  69   'gnus-picons-news-directories)
  70
  71 (defcustom gnus-picons-user-directories '("local" "users" "usenix" "misc")
  72   "*List of directories to search for user faces."
  73   :type '(repeat string)
  74   :group 'picons)
  75
  76 (defcustom gnus-picons-domain-directories '("domains")
  77   "*List of directories to search for domain faces.
  78 Some people may want to add \"unknown\" to this list."
  79   :type '(repeat string)
  80   :group 'picons)
  81
  82 (defcustom gnus-picons-refresh-before-display nil
  83   "*If non-nil, display the article buffer before computing the picons."
  84   :type 'boolean
  85   :group 'picons)
  86
  87 (defcustom gnus-picons-group-excluded-groups nil
  88   "*If this regexp matches the group name, group picons will be disabled."
  89   :type 'regexp
  90   :group 'picons)
  91
  92 (defcustom gnus-picons-display-as-address t
  93   "*If t display textual email addresses along with pictures."
  94   :type 'boolean
  95   :group 'picons)
  96
  97 (defcustom gnus-picons-file-suffixes
  98   (when (featurep 'x)
  99     (let ((types (list "xbm")))
 100       (when (featurep 'gif)
 101         (push "gif" types))
 102       (when (featurep 'xpm)
 103         (push "xpm" types))
 104       types))
 105   "*List of suffixes on picon file names to try."
 106   :type '(repeat string)
 107   :group 'picons)
 108
 109 (defcustom gnus-picons-display-article-move-p nil
 110   "*Whether to move point to first empty line when displaying picons.
 111 This has only an effect if `gnus-picons-display-where' has value `article'."
 112   :type 'boolean
 113   :group 'picons)
 114
 115 (defcustom gnus-picons-clear-cache-on-shutdown t
 116   "*Whether to clear the picons cache when exiting gnus.
 117 Gnus caches every picons it finds while it is running.  This saves
 118 some time in the search process but eats some memory.  If this
 119 variable is set to nil, Gnus will never clear the cache itself; you
 120 will have to manually call `gnus-picons-clear-cache' to clear it.
 121 Otherwise the cache will be cleared every time you exit Gnus."
 122   :type 'boolean
 123   :group 'picons)
 124
 125 (defcustom gnus-picons-piconsearch-url nil
 126   "*The url to query for picons.  Setting this to nil will disable it.
 127 The only publicly available address currently known is
 128 http://www.cs.indiana.edu:800/piconsearch.  If you know of any other,
 129 please tell me so that we can list it."
 130   :type '(choice (const :tag "Disable" :value nil)
 131                  (const :tag "www.cs.indiana.edu"
 132                         :value "http://www.cs.indiana.edu:800/piconsearch")
 133                  (string))
 134   :group 'picons)
 135
 136 (defface gnus-picons-xbm-face '((t (:foreground "black" :background "white")))
 137   "Face to show xbm picons in."
 138   :group 'picons)
 139
 140 (defface gnus-picons-face '((t (:foreground "black" :background "white")))
 141   "Face to show picons in."
 142   :group 'picons)
 143
 144 (defcustom gnus-picons-setup-hook nil
 145   "Hook run in Picons buffers."
 146   :group 'picons
 147   :type 'hook)
 148
 149 ;;; Internal variables:
 150
 151 (defvar gnus-picons-setup-p nil)
 152 (defvar gnus-picons-processes-alist nil
 153   "Picons processes currently running and their environment.")
 154 (defvar gnus-picons-glyph-alist nil
 155   "Picons glyphs cache.
 156 List of pairs (KEY . GLYPH) where KEY is either a filename or an URL.")
 157 (defvar gnus-picons-url-alist nil
 158   "Picons file names cache.
 159 List of pairs (KEY . NAME) where KEY is (USER HOST DBS) and NAME is an URL.")
 160
 161 (defvar gnus-picons-jobs-alist nil
 162   "List of jobs that still need be done.
 163 This is a list of (SYM-ANN TAG ARGS...) where SYM-ANN three annotations list,
 164 TAG is one of `picon' or `search' indicating that the job should query a
 165 picon or do a search for picons file names, and ARGS is some additionnal
 166 arguments necessary for the job.")
 167
 168 (defvar gnus-picons-job-already-running nil
 169   "Lock to ensure only one stream of http requests is running.")
 170
 171 ;;; Functions:
 172
 173 (defun gnus-picons-remove-all ()
 174   "Removes all picons from the Gnus display(s)."
 175   (interactive)
 176   (map-extents (function (lambda (ext unused) (delete-annotation ext) nil))
 177                nil nil nil nil nil 'gnus-picon)
 178   (setq gnus-picons-jobs-alist '())
 179   ;; notify running job that it may have been preempted
 180   (if (and (listp gnus-picons-job-already-running)
 181            gnus-picons-job-already-running)
 182       (setq gnus-picons-job-already-running t)))
 183
 184 (defun gnus-get-buffer-name (variable)
 185   "Returns the buffer name associated with the contents of a variable."
 186   (let ((buf (gnus-get-buffer-create
 187               (gnus-window-to-buffer-helper
 188                (cdr (assq variable gnus-window-to-buffer))))))
 189     (and buf
 190          (buffer-name buf))))
 191
 192 (defun gnus-picons-buffer-name ()
 193   (cond ((or (stringp gnus-picons-display-where)
 194              (bufferp gnus-picons-display-where))
 195          gnus-picons-display-where)
 196         ((eq gnus-picons-display-where 'picons)
 197          (if gnus-single-article-buffer
 198              "*Picons*"
 199            (concat "*Picons " gnus-newsgroup-name "*")))
 200         (t
 201          (gnus-get-buffer-name gnus-picons-display-where))))
 202
 203 (defun gnus-picons-kill-buffer ()
 204   (let ((buf (get-buffer (gnus-picons-buffer-name))))
 205     (when (and (buffer-live-p buf)
 206                (string-match "Picons" (buffer-name buf)))
 207       (kill-buffer buf))))
 208
 209 (defun gnus-picons-setup-buffer ()
 210   (let ((name (gnus-picons-buffer-name)))
 211     (save-excursion
 212       (if (and (get-buffer name)
 213                (with-current-buffer name
 214                  gnus-picons-setup-p))
 215           (set-buffer name)
 216         (set-buffer (gnus-get-buffer-create name))
 217         (buffer-disable-undo)
 218         (setq buffer-read-only t)
 219         (run-hooks 'gnus-picons-setup-hook)
 220         (set (make-local-variable 'gnus-picons-setup-p) t)
 221         (add-hook 'gnus-summary-prepare-exit-hook 'gnus-picons-kill-buffer))
 222       (current-buffer))))
 223
 224 (defun gnus-picons-set-buffer ()
 225   (set-buffer (gnus-picons-setup-buffer))
 226   (goto-char (point-min))
 227   (if (and (eq gnus-picons-display-where 'article)
 228            gnus-picons-display-article-move-p)
 229       (if (search-forward "\n\n" nil t)
 230           (forward-line -1)
 231         (goto-char (point-max)))
 232     (setq buffer-read-only t)
 233     (unless gnus-picons-has-modeline-p
 234       (set-specifier has-modeline-p
 235                      (list (list (current-buffer)
 236                                  (cons nil gnus-picons-has-modeline-p)))))))
 237
 238 (defun gnus-picons-prepare-for-annotations ()
 239   "Prepare picons buffer for putting annotations."
 240   ;; let drawing catch up
 241   (when gnus-picons-refresh-before-display
 242     (sit-for 0))
 243   (gnus-picons-set-buffer)
 244   (gnus-picons-remove-all))
 245
 246 (defun gnus-picons-make-annotation (&rest args)
 247   (let ((annot (apply 'make-annotation args)))
 248     (set-extent-property annot 'gnus-picon t)
 249     (set-extent-property annot 'duplicable t)
 250     annot))
 251
 252 (defun gnus-article-display-picons ()
 253   "Display faces for an author and her domain in gnus-picons-display-where."
 254   (interactive)
 255   (let (from at-idx)
 256     (when (and (featurep 'xpm)
 257                (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 258                (setq from (mail-fetch-field "from"))
 259                (setq from (downcase (or (cadr (mail-extract-address-components
 260                                                from))
 261                                         "")))
 262                (or (setq at-idx (string-match "@" from))
 263                    (setq at-idx (length from))))
 264       (save-excursion
 265         (let ((username (downcase (substring from 0 at-idx)))
 266               (addrs (if (eq at-idx (length from))
 267                          (if gnus-local-domain
 268                              (message-tokenize-header gnus-local-domain "."))
 269                        (message-tokenize-header (substring from (1+ at-idx))
 270                                                 "."))))
 271           (gnus-picons-prepare-for-annotations)
 272           (gnus-group-display-picons)
 273           (unless gnus-picons-display-article-move-p
 274             (let ((buffer-read-only nil)
 275                   (case-fold-search t))
 276               (when (re-search-forward "^From *: *" nil t)
 277                 (when (search-forward from (gnus-point-at-eol) t)
 278                   (gnus-put-text-property
 279                    (match-beginning 0) (match-end 0)
 280                    'invisible t)))))
 281           (if (null gnus-picons-piconsearch-url)
 282               (progn
 283                 (gnus-picons-display-pairs (gnus-picons-lookup-pairs
 284                                             addrs
 285                                             gnus-picons-domain-directories)
 286                                            gnus-picons-display-as-address
 287                                            "." t)
 288                 (if (and gnus-picons-display-as-address addrs)
 289                     (gnus-picons-make-annotation
 290                      [string :data "@"] nil 'text nil nil nil t))
 291                 (gnus-picons-display-picon-or-name
 292                  (gnus-picons-lookup-user username addrs)
 293                  username t))
 294             (push (list 'gnus-article-annotations 'search username addrs
 295                         gnus-picons-domain-directories t (point-marker))
 296                   gnus-picons-jobs-alist)
 297             (gnus-picons-next-job)))))))
 298
 299 (defun gnus-group-display-picons ()
 300   "Display icons for the group in the `gnus-picons-display-where' buffer."
 301   (interactive)
 302   (when (and (featurep 'xpm)
 303              (or (not (fboundp 'device-type)) (equal (device-type) 'x))
 304              (or (null gnus-picons-group-excluded-groups)
 305                  (not (string-match gnus-picons-group-excluded-groups
 306                                     gnus-newsgroup-name))))
 307     (let* ((newsgroups (mail-fetch-field "newsgroups"))
 308            (groups
 309             (if (or gnus-picons-display-article-move-p
 310                     (not newsgroups))
 311                 (list (gnus-group-real-name gnus-newsgroup-name))
 312               (split-string newsgroups ",")))
 313            group)
 314       (save-excursion
 315         (gnus-picons-prepare-for-annotations)
 316         (while (setq group (pop groups))
 317           (unless gnus-picons-display-article-move-p
 318             (let ((buffer-read-only nil)
 319                   (case-fold-search t))
 320               (goto-char (point-min))
 321               (if (and (re-search-forward "^Newsgroups *: *" nil t)
 322                        (search-forward group (gnus-point-at-eol) t))
 323                   (gnus-put-text-property
 324                    (match-beginning 0) (match-end 0)
 325                    'invisible t)
 326                 (let ((article-goto-body-goes-to-point-min-p nil))
 327                   (article-goto-body))
 328                 (unless (bobp)
 329                   (backward-char 1)))))
 330           (if (null gnus-picons-piconsearch-url)
 331               (gnus-picons-display-pairs
 332                (gnus-picons-lookup-pairs
 333                 (reverse (split-string group "\\."))
 334                 gnus-picons-news-directories)
 335                t ".")
 336             (push (list 'gnus-group-annotations 'search nil
 337                         (split-string group "\\.")
 338                         (if (listp gnus-picons-news-directories)
 339                             gnus-picons-news-directories
 340                           (list gnus-picons-news-directories))
 341                         nil (point-marker))
 342                   gnus-picons-jobs-alist)
 343             (gnus-picons-next-job))
 344
 345           (add-hook 'gnus-summary-exit-hook 'gnus-picons-remove-all))))))
 346
 347 (defun gnus-picons-lookup-internal (addrs dir)
 348   (setq dir (expand-file-name dir gnus-picons-database))
 349   (gnus-picons-try-face (dolist (part (reverse addrs) dir)
 350                           (setq dir (expand-file-name part dir)))))
 351
 352 (defun gnus-picons-lookup (addrs dirs)
 353   "Lookup the picon for ADDRS in databases DIRS.
 354 Returns the picon filename or NIL if none found."
 355   (let (result)
 356     (while (and dirs (null result))
 357       (setq result (gnus-picons-lookup-internal addrs (pop dirs))))
 358     result))
 359
 360 (defun gnus-picons-lookup-user-internal (user domains)
 361   (let ((dirs gnus-picons-user-directories)
 362         domains-tmp dir picon)
 363     (while (and dirs (null picon))
 364       (setq domains-tmp domains
 365             dir (pop dirs))
 366       (while (and domains-tmp
 367                   (null (setq picon (gnus-picons-lookup-internal
 368                                      (cons user domains-tmp) dir))))
 369         (pop domains-tmp))
 370       ;; Also make a try in MISC subdir
 371       (unless picon
 372         (setq picon (gnus-picons-lookup-internal (list user "MISC") dir))))
 373     picon))
 374
 375 (defun gnus-picons-lookup-user (user domains)
 376   "Lookup the picon for USER at DOMAINS.
 377 USER is a string containing a name.
 378 DOMAINS is a list of strings from the fully qualified domain name."
 379   (or (gnus-picons-lookup-user-internal user domains)
 380       (gnus-picons-lookup-user-internal "unknown" domains)))
 381
 382 (defun gnus-picons-lookup-pairs (domains directories)
 383   "Lookup picons for DOMAINS and all its parents in DIRECTORIES.
 384 Returns a list of PAIRS whose CAR is the picon filename or NIL if
 385 none, and whose CDR is the corresponding element of DOMAINS."
 386   (let (picons)
 387     (setq directories (if (listp directories)
 388                           directories
 389                         (list directories)))
 390     (while domains
 391       (push (list (gnus-picons-lookup (cons "unknown" domains) directories)
 392                   (pop domains))
 393             picons))
 394     picons))
 395
 396 (defun gnus-picons-display-picon-or-name (picon name &optional right-p)
 397   (cond (picon (gnus-picons-display-glyph picon name right-p))
 398         (gnus-picons-display-as-address (list (gnus-picons-make-annotation
 399                                                (vector 'string :data name)
 400                                                nil 'text
 401                                                nil nil nil right-p)))))
 402
 403 (defun gnus-picons-display-pairs (pairs &optional bar-p dot-p right-p)
 404   "Display picons in list PAIRS."
 405   (let ((domain-p (and gnus-picons-display-as-address dot-p))
 406         pair picons)
 407     (when (and bar-p domain-p right-p
 408                gnus-picons-display-article-move-p)
 409       (setq picons (gnus-picons-display-glyph
 410                     (let ((gnus-picons-file-suffixes '("xbm")))
 411                       (gnus-picons-try-face
 412                        gnus-xmas-glyph-directory "bar."))
 413                     nil right-p)))
 414     (while (setq pair (pop pairs))
 415       (setq picons (nconc picons
 416                           (gnus-picons-display-picon-or-name
 417                            (car pair) (cadr pair) right-p)
 418                           (if (and domain-p pairs)
 419                               (list (gnus-picons-make-annotation
 420                                      (vector 'string :data dot-p)
 421                                      nil 'text nil nil nil right-p))))))
 422     picons))
 423
 424 (defun gnus-picons-try-face (dir &optional filebase)
 425   (let* ((dir (file-name-as-directory dir))
 426          (filebase (or filebase "face."))
 427          (key (concat dir filebase))
 428          (glyph (cdr (assoc key gnus-picons-glyph-alist)))
 429          (suffixes gnus-picons-file-suffixes)
 430          f suf)
 431     (while (setq suf (pop suffixes))
 432       (when (file-exists-p (setq f (expand-file-name
 433                                     (concat filebase suf)
 434                                     dir)))
 435         (setq suffixes nil
 436               glyph (make-glyph f))
 437         (if (equal suf "xbm")
 438             (set-glyph-face glyph 'gnus-picons-xbm-face)
 439           (set-glyph-face glyph 'gnus-picons-face))
 440         (push (cons key glyph) gnus-picons-glyph-alist)))
 441     glyph))
 442
 443 (defun gnus-picons-display-glyph (glyph &optional part rightp)
 444   (set-glyph-baseline glyph 70)
 445   (let ((new (gnus-picons-make-annotation
 446               glyph (point) 'text nil nil nil rightp)))
 447     (when (and part gnus-picons-display-as-address)
 448       (set-annotation-data
 449        new (cons new (make-glyph (vector 'string :data part))))
 450       (set-annotation-action new 'gnus-picons-action-toggle))
 451     (nconc
 452      (list new)
 453      (if (and (eq major-mode 'gnus-article-mode)
 454               (not gnus-picons-display-as-address)
 455               (not part))
 456          (list (gnus-picons-make-annotation [string :data " "] (point)
 457                                             'text nil nil nil rightp))))))
 458
 459 (defun gnus-picons-action-toggle (data)
 460   "Toggle annotation."
 461   (interactive "e")
 462   (let* ((annot (car data))
 463          (glyph (annotation-glyph annot)))
 464     (set-annotation-glyph annot (cdr data))
 465     (set-annotation-data annot (cons annot glyph))))
 466
 467 (defun gnus-picons-clear-cache ()
 468   "Clear the picons cache."
 469   (interactive)
 470   (setq gnus-picons-glyph-alist nil
 471         gnus-picons-url-alist nil))
 472
 473 (gnus-add-shutdown 'gnus-picons-close 'gnus)
 474
 475 (defun gnus-picons-close ()
 476   "Shut down the picons."
 477   (if gnus-picons-clear-cache-on-shutdown
 478       (gnus-picons-clear-cache)))
 479
 480 ;;; Query a remote DB.  This requires some stuff from w3 !
 481
 482 (eval-and-compile
 483   (ignore-errors
 484     (require 'url)
 485     (require 'w3-forms)))
 486
 487 (defun gnus-picons-url-retrieve (url fn arg)
 488   (let ((old-asynch (default-value 'url-be-asynchronous))
 489         (url-working-buffer (generate-new-buffer " *picons*"))
 490         (url-package-name "Gnus")
 491         (url-package-version gnus-version-number)
 492         url-request-method)
 493     (setq-default url-be-asynchronous t)
 494     (save-excursion
 495       (set-buffer url-working-buffer)
 496       (setq url-be-asynchronous t
 497             url-current-callback-data arg
 498             url-current-callback-func fn)
 499       (url-retrieve url t))
 500     (setq-default url-be-asynchronous old-asynch)))
 501
 502 (defun gnus-picons-make-glyph (type)
 503   "Make a TYPE glyph using current buffer as data.  Handles xbm nicely."
 504   (cond ((null type) nil)
 505         ((eq type 'xbm) (let ((fname (make-temp-name "/tmp/picon")))
 506                           (write-region (point-min) (point-max) fname
 507                                         nil 'quiet)
 508                           (prog1 (make-glyph (vector 'xbm :file fname))
 509                             (delete-file fname))))
 510         (t (make-glyph (vector type :data (buffer-string))))))
 511
 512 ;;; Parsing of piconsearch result page.
 513
 514 ;; Assumes:
 515 ;; 1 - each value field has the form: "<strong>key</strong> = <kbd>value</kbd>"
 516 ;; 2 - a "<p>" separates the keywords from the results
 517 ;; 3 - every results begins by the path within the database at the beginning
 518 ;;     of the line in raw text.
 519 ;; 3b - and the href following it is the preferred image type.
 520
 521 ;; if 1 or 2 is not met, it will probably cause an error.  The other
 522 ;; will go undetected
 523
 524 (defun gnus-picons-parse-value (name)
 525   (goto-char (point-min))
 526   (if (re-search-forward (concat "<strong>"
 527                                  (regexp-quote name)
 528                                  "</strong> *= *<kbd> *\\([^ <][^<]*\\) *</kbd>")
 529                          nil t)
 530       (buffer-substring (match-beginning 1) (match-end 1))))
 531
 532 (defun gnus-picons-parse-filenames ()
 533   ;; returns an alist of ((USER ADDRS DB) . URL)
 534   (let ((case-fold-search t)
 535         (user (gnus-picons-parse-value "user"))
 536         (host (gnus-picons-parse-value "host"))
 537         (dbs (message-tokenize-header (gnus-picons-parse-value "db") " "))
 538         start-re cur-db cur-host cur-user types res)
 539     ;; now point will be somewhere in the header.  Find beginning of
 540     ;; entries
 541     (when (and user host dbs)
 542       (setq start-re
 543             (concat
 544              ;; dbs
 545              "^\\(" (mapconcat 'regexp-quote dbs "\\|") "\\)/"
 546              ;; host
 547              "\\(\\(" (mapconcat 'regexp-quote
 548                                  (message-tokenize-header host ".") "/\\|")
 549              "/\\|MISC/\\)*\\)"
 550              ;; user
 551              "\\(" (regexp-quote user) "\\|unknown\\)/"
 552              "face\\."))
 553       (re-search-forward "<p>[ \t\n]*")
 554       (while (re-search-forward start-re nil t)
 555         (setq cur-db (buffer-substring (match-beginning 1) (match-end 1))
 556               cur-host (buffer-substring (match-beginning 2) (match-end 2))
 557               cur-user (buffer-substring (match-beginning 4) (match-end 4))
 558               cur-host (nreverse (message-tokenize-header cur-host "/")))
 559         ;; XXX - KLUDGE: there is a blank picon in news/MISC/unknown
 560         (unless (and (string-equal cur-db "news")
 561                      (string-equal cur-user "unknown")
 562                      (equal cur-host '("MISC")))
 563           ;; ok now we have found an entry (USER HOST DB), find the
 564           ;; corresponding picon URL
 565           (save-restriction
 566             ;; restrict region to this entry
 567             (narrow-to-region (point) (search-forward "<br>"))
 568             (goto-char (point-min))
 569             (setq types gnus-picons-file-suffixes)
 570             (while (and types
 571                         (not (re-search-forward
 572                               (concat "<a[ \t\n]+href=\"\\([^\"]*\\."
 573                                       (regexp-quote (car types)) "\\)\"")
 574                               nil t)))
 575               (pop types))
 576             (push (cons (list cur-user cur-host cur-db)
 577                         (buffer-substring (match-beginning 1) (match-end 1)))
 578                   res))))
 579       (nreverse res))))
 580
 581 ;;; picon network display functions :
 582
 583 (defun gnus-picons-network-display-internal (sym-ann glyph part right-p marker)
 584   (let ((buf (marker-buffer marker))
 585         (pos (marker-position marker)))
 586     (if (and buf pos)
 587         (save-excursion
 588           (set-buffer buf)
 589           (goto-char pos)
 590           (gnus-picons-display-picon-or-name glyph part right-p))))
 591   (gnus-picons-next-job-internal))
 592
 593 (defun gnus-picons-network-display-callback (url part sym-ann right-p marker)
 594   (let ((glyph (gnus-picons-make-glyph (cdr (assoc url-current-mime-type
 595                                                    w3-image-mappings)))))
 596     (kill-buffer (current-buffer))
 597     (push (cons url glyph) gnus-picons-glyph-alist)
 598     ;; only do the job if it has not been preempted.
 599     (if (equal gnus-picons-job-already-running
 600                (list sym-ann 'picon url part right-p marker))
 601         (gnus-picons-network-display-internal
 602          sym-ann glyph part right-p marker)
 603       (gnus-picons-next-job-internal))))
 604
 605 (defun gnus-picons-network-display (url part sym-ann right-p marker)
 606   (let ((cache (assoc url gnus-picons-glyph-alist)))
 607     (if (or cache (null url))
 608         (gnus-picons-network-display-internal
 609          sym-ann (cdr cache) part right-p marker)
 610       (gnus-picons-url-retrieve url 'gnus-picons-network-display-callback
 611                                 (list url part sym-ann right-p marker)))))
 612
 613 ;;; search job functions
 614
 615 (defun gnus-picons-display-bar-p ()
 616   (if (eq gnus-picons-display-where 'article)
 617       gnus-picons-display-article-move-p
 618     gnus-picons-display-as-address))
 619
 620 (defun gnus-picons-network-search-internal (user addrs dbs sym-ann right-p
 621                                                  marker &optional fnames)
 622   (let (curkey dom pfx url dbs-tmp cache new-jobs)
 623     ;; First do the domain search
 624     (dolist (part (if right-p
 625                       (reverse addrs)
 626                     addrs))
 627       (setq pfx (nconc (list part) pfx)
 628             dom (cond ((and dom right-p) (concat part "." dom))
 629                       (dom (concat dom "." part))
 630                       (t part))
 631             curkey (list "unknown" dom dbs))
 632       (when (null (setq cache (assoc curkey gnus-picons-url-alist)))
 633         ;; This one is not yet in the cache, create a new entry
 634         ;; Search for an entry
 635         (setq dbs-tmp dbs
 636               url nil)
 637         (while (and dbs-tmp (null url))
 638           (setq url (or (cdr (assoc (list "unknown" pfx (car dbs-tmp)) fnames))
 639                         (and (eq dom part)
 640                              ;; This is the first component.  Try the
 641                              ;; catch-all MISC component
 642                              (cdr (assoc (list "unknown"
 643                                                '("MISC")
 644                                                (car dbs-tmp))
 645                                          fnames)))))
 646           (pop dbs-tmp))
 647         (push (setq cache (cons curkey url)) gnus-picons-url-alist))
 648       ;; Put this glyph in the job list
 649       (if (and (not (eq dom part)) gnus-picons-display-as-address)
 650           (push (list sym-ann "." right-p marker) new-jobs))
 651       (push (list sym-ann 'picon (cdr cache) part right-p marker) new-jobs))
 652     ;; next, the user search
 653     (when user
 654       (setq curkey (list user dom gnus-picons-user-directories))
 655       (if (null (setq cache (assoc curkey gnus-picons-url-alist)))
 656           (let ((users (list user "unknown"))
 657                 dirs usr domains-tmp dir picon)
 658             (while (and users (null picon))
 659               (setq dirs gnus-picons-user-directories
 660                     usr (pop users))
 661               (while (and dirs (null picon))
 662                 (setq domains-tmp addrs
 663                       dir (pop dirs))
 664                 (while (and domains-tmp
 665                             (null (setq picon (assoc (list usr domains-tmp dir)
 666                                                      fnames))))
 667                   (pop domains-tmp))
 668                 (unless picon
 669                   (setq picon (assoc (list usr '("MISC") dir) fnames)))))
 670             (push (setq cache (cons curkey (cdr picon)))
 671                   gnus-picons-url-alist)))
 672       (if (and gnus-picons-display-as-address new-jobs)
 673           (push (list sym-ann "@" right-p marker) new-jobs))
 674       (push (list sym-ann 'picon (cdr cache) user right-p marker) new-jobs))
 675     (if (and (gnus-picons-display-bar-p) (not right-p))
 676         (push (list sym-ann 'bar right-p marker) new-jobs))
 677     ;; only put the jobs in the queue if this job has not been preempted.
 678     (if (equal gnus-picons-job-already-running
 679                (list sym-ann 'search user addrs dbs right-p marker))
 680         (setq gnus-picons-jobs-alist
 681               (nconc (if (and (gnus-picons-display-bar-p) right-p)
 682                          (list (list sym-ann 'bar right-p marker)))
 683                      (nreverse new-jobs)
 684                      gnus-picons-jobs-alist)))
 685     (gnus-picons-next-job-internal)))
 686
 687 (defun gnus-picons-network-search-callback (user addrs dbs sym-ann right-p
 688                                                  marker)
 689   (gnus-picons-network-search-internal
 690    user addrs dbs sym-ann right-p marker
 691    (prog1
 692        (gnus-picons-parse-filenames)
 693      (kill-buffer (current-buffer)))))
 694
 695 ;; Initiate a query on the picon database
 696 (defun gnus-picons-network-search (user addrs dbs sym-ann right-p marker)
 697   (let* ((host (mapconcat 'identity addrs "."))
 698          (key (list (or user "unknown") host (if user
 699                                                  gnus-picons-user-directories
 700                                                dbs)))
 701          (cache (assoc key gnus-picons-url-alist)))
 702     (if (null cache)
 703         (gnus-picons-url-retrieve
 704          (concat gnus-picons-piconsearch-url
 705                  "?user=" (w3-form-encode-xwfu (or user "unknown"))
 706                  "&host=" (w3-form-encode-xwfu host)
 707                  "&db=" (mapconcat 'w3-form-encode-xwfu
 708                                    (if user
 709                                        (append dbs
 710                                                gnus-picons-user-directories)
 711                                      dbs)
 712                                    "+"))
 713          'gnus-picons-network-search-callback
 714          (list user addrs dbs sym-ann right-p marker))
 715       (gnus-picons-network-search-internal
 716        user addrs dbs sym-ann right-p marker))))
 717
 718 ;;; Main jobs dispatcher function
 719
 720 (defun gnus-picons-next-job-internal ()
 721   (when (setq gnus-picons-job-already-running (pop gnus-picons-jobs-alist))
 722     (let* ((job gnus-picons-job-already-running)
 723            (sym-ann (pop job))
 724            (tag (pop job)))
 725       (when tag
 726         (cond
 727          ((stringp tag);; (SYM-ANN "..." RIGHT-P MARKER)
 728           (gnus-picons-network-display-internal
 729            sym-ann nil tag (pop job) (pop job)))
 730          ((eq 'bar tag);; (SYM-ANN 'bar RIGHT-P MARKER)
 731           (gnus-picons-network-display-internal
 732            sym-ann
 733            (let ((gnus-picons-file-suffixes '("xbm")))
 734              (gnus-picons-try-face
 735               gnus-xmas-glyph-directory "bar."))
 736            nil (pop job) (pop job)))
 737          ((eq 'search tag);; (SYM-ANN 'search USER ADDRS DBS RIGHT-P MARKER)
 738           (gnus-picons-network-search
 739            (pop job) (pop job) (pop job) sym-ann (pop job) (pop job)))
 740          ((eq 'picon tag);; (SYM-ANN 'picon URL PART RIGHT-P MARKER)
 741           (gnus-picons-network-display
 742            (pop job) (pop job) sym-ann (pop job) (pop job)))
 743          (t
 744           (setq gnus-picons-job-already-running nil)
 745           (error "Unknown picon job tag %s" tag)))))))
 746
 747 (defun gnus-picons-next-job ()
 748   "Start processing the job queue if it is not in progress."
 749   (unless gnus-picons-job-already-running
 750     (gnus-picons-next-job-internal)))
 751
 752 (provide 'gnus-picon)
 753
 754 ;;; gnus-picon.el ends here