git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-spec.el

   1 ;;; gnus-spec.el --- format spec functions for Gnus
   2 ;; Copyright (C) 1996,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29
  30 (require 'gnus)
  31
  32 ;;; Internal variables.
  33
  34 (defvar gnus-summary-mark-positions nil)
  35 (defvar gnus-group-mark-positions nil)
  36 (defvar gnus-group-indentation "")
  37
  38 ;; Format specs.  The chunks below are the machine-generated forms
  39 ;; that are to be evaled as the result of the default format strings.
  40 ;; We write them in here to get them byte-compiled.  That way the
  41 ;; default actions will be quite fast, while still retaining the full
  42 ;; flexibility of the user-defined format specs.
  43
  44 ;; First we have lots of dummy defvars to let the compiler know these
  45 ;; are really dynamic variables.
  46
  47 (defvar gnus-tmp-unread)
  48 (defvar gnus-tmp-replied)
  49 (defvar gnus-tmp-score-char)
  50 (defvar gnus-tmp-indentation)
  51 (defvar gnus-tmp-opening-bracket)
  52 (defvar gnus-tmp-lines)
  53 (defvar gnus-tmp-name)
  54 (defvar gnus-tmp-closing-bracket)
  55 (defvar gnus-tmp-subject-or-nil)
  56 (defvar gnus-tmp-subject)
  57 (defvar gnus-tmp-marked)
  58 (defvar gnus-tmp-marked-mark)
  59 (defvar gnus-tmp-subscribed)
  60 (defvar gnus-tmp-process-marked)
  61 (defvar gnus-tmp-number-of-unread)
  62 (defvar gnus-tmp-group-name)
  63 (defvar gnus-tmp-group)
  64 (defvar gnus-tmp-article-number)
  65 (defvar gnus-tmp-unread-and-unselected)
  66 (defvar gnus-tmp-news-method)
  67 (defvar gnus-tmp-news-server)
  68 (defvar gnus-tmp-article-number)
  69 (defvar gnus-mouse-face)
  70 (defvar gnus-mouse-face-prop)
  71
  72 (defun gnus-summary-line-format-spec ()
  73   (insert gnus-tmp-unread gnus-tmp-replied
  74           gnus-tmp-score-char gnus-tmp-indentation)
  75   (gnus-put-text-property
  76    (point)
  77    (progn
  78      (insert
  79       gnus-tmp-opening-bracket
  80       (format "%4d: %-20s"
  81               gnus-tmp-lines
  82               (if (> (length gnus-tmp-name) 20)
  83                   (substring gnus-tmp-name 0 20)
  84                 gnus-tmp-name))
  85       gnus-tmp-closing-bracket)
  86      (point))
  87    gnus-mouse-face-prop gnus-mouse-face)
  88   (insert " " gnus-tmp-subject-or-nil "\n"))
  89
  90 (defvar gnus-summary-line-format-spec
  91   (gnus-byte-code 'gnus-summary-line-format-spec))
  92
  93 (defun gnus-summary-dummy-line-format-spec ()
  94   (insert "*  ")
  95   (gnus-put-text-property
  96    (point)
  97    (progn
  98      (insert ":                          :")
  99      (point))
 100    gnus-mouse-face-prop gnus-mouse-face)
 101   (insert " " gnus-tmp-subject "\n"))
 102
 103 (defvar gnus-summary-dummy-line-format-spec
 104   (gnus-byte-code 'gnus-summary-dummy-line-format-spec))
 105
 106 (defun gnus-group-line-format-spec ()
 107   (insert gnus-tmp-marked-mark gnus-tmp-subscribed
 108           gnus-tmp-process-marked
 109           gnus-group-indentation
 110           (format "%5s: " gnus-tmp-number-of-unread))
 111   (gnus-put-text-property
 112    (point)
 113    (progn
 114      (insert gnus-tmp-group "\n")
 115      (1- (point)))
 116    gnus-mouse-face-prop gnus-mouse-face))
 117 (defvar gnus-group-line-format-spec
 118   (gnus-byte-code 'gnus-group-line-format-spec))
 119
 120 (defvar gnus-format-specs
 121   `((version . ,emacs-version)
 122     (group "%M\%S\%p\%P\%5y: %(%g%)%l\n" ,gnus-group-line-format-spec)
 123     (summary-dummy "*  %(:                          :%) %S\n"
 124                    ,gnus-summary-dummy-line-format-spec)
 125     (summary "%U\%R\%z\%I\%(%[%4L: %-20,20n%]%) %s\n"
 126              ,gnus-summary-line-format-spec))
 127   "Alist of format specs.")
 128
 129 (defvar gnus-article-mode-line-format-spec nil)
 130 (defvar gnus-summary-mode-line-format-spec nil)
 131 (defvar gnus-group-mode-line-format-spec nil)
 132
 133 ;;; Phew.  All that gruft is over, fortunately.
 134
 135 ;;;###autoload
 136 (defun gnus-update-format (var)
 137   "Update the format specification near point."
 138   (interactive
 139    (list
 140     (save-excursion
 141       (eval-defun nil)
 142       ;; Find the end of the current word.
 143       (re-search-forward "[ \t\n]" nil t)
 144       ;; Search backward.
 145       (when (re-search-backward "\\(gnus-[-a-z]+-line-format\\)" nil t)
 146         (match-string 1)))))
 147   (let* ((type (intern (progn (string-match "gnus-\\([-a-z]+\\)-line" var)
 148                               (match-string 1 var))))
 149          (entry (assq type gnus-format-specs))
 150          value spec)
 151     (when entry
 152       (setq gnus-format-specs (delq entry gnus-format-specs)))
 153     (set
 154      (intern (format "%s-spec" var))
 155      (gnus-parse-format (setq value (symbol-value (intern var)))
 156                         (symbol-value (intern (format "%s-alist" var)))
 157                         (not (string-match "mode" var))))
 158     (setq spec (symbol-value (intern (format "%s-spec" var))))
 159     (push (list type value spec) gnus-format-specs)
 160
 161     (pop-to-buffer "*Gnus Format*")
 162     (erase-buffer)
 163     (lisp-interaction-mode)
 164     (insert (pp-to-string spec))))
 165
 166 (defun gnus-update-format-specifications (&optional force &rest types)
 167   "Update all (necessary) format specifications."
 168   ;; Make the indentation array.
 169   ;; See whether all the stored info needs to be flushed.
 170   (when (or force
 171             (not (equal emacs-version
 172                         (cdr (assq 'version gnus-format-specs))))
 173             (not (equal gnus-version
 174                         (cdr (assq 'gnus-version gnus-format-specs)))))
 175     (message "%s" "Force update format specs.")
 176     (setq gnus-format-specs nil))
 177
 178   ;; Go through all the formats and see whether they need updating.
 179   (let (new-format entry type val)
 180     (while (setq type (pop types))
 181       ;; Jump to the proper buffer to find out the value of
 182       ;; the variable, if possible.  (It may be buffer-local.)
 183       (save-excursion
 184         (let ((buffer (intern (format "gnus-%s-buffer" type)))
 185               val)
 186           (when (and (boundp buffer)
 187                      (setq val (symbol-value buffer))
 188                      (gnus-buffer-exists-p val))
 189             (set-buffer val))
 190           (setq new-format (symbol-value
 191                             (intern (format "gnus-%s-line-format" type)))))
 192         (setq entry (cdr (assq type gnus-format-specs)))
 193         (if (and (car entry)
 194                  (equal (car entry) new-format))
 195             ;; Use the old format.
 196             (set (intern (format "gnus-%s-line-format-spec" type))
 197                  (cadr entry))
 198           ;; This is a new format.
 199           (setq val
 200                 (if (not (stringp new-format))
 201                     ;; This is a function call or something.
 202                     new-format
 203                   ;; This is a "real" format.
 204                   (gnus-parse-format
 205                    new-format
 206                    (symbol-value
 207                     (intern (format "gnus-%s-line-format-alist"
 208                                     (if (eq type 'article-mode)
 209                                         'summary-mode type))))
 210                    (not (string-match "mode$" (symbol-name type))))))
 211           ;; Enter the new format spec into the list.
 212           (if entry
 213               (progn
 214                 (setcar (cdr entry) val)
 215                 (setcar entry new-format))
 216             (push (list type new-format val) gnus-format-specs))
 217           (set (intern (format "gnus-%s-line-format-spec" type)) val)))))
 218
 219   (unless (assq 'version gnus-format-specs)
 220     (push (cons 'version emacs-version) gnus-format-specs))
 221   (unless (assq 'gnus-version gnus-format-specs)
 222     (push (cons 'gnus-version gnus-version) gnus-format-specs)))
 223
 224 (defvar gnus-mouse-face-0 'highlight)
 225 (defvar gnus-mouse-face-1 'highlight)
 226 (defvar gnus-mouse-face-2 'highlight)
 227 (defvar gnus-mouse-face-3 'highlight)
 228 (defvar gnus-mouse-face-4 'highlight)
 229
 230 (defun gnus-mouse-face-function (form type)
 231   `(gnus-put-text-property
 232     (point) (progn ,@form (point))
 233     gnus-mouse-face-prop
 234     ,(if (equal type 0)
 235          'gnus-mouse-face
 236        `(quote ,(symbol-value (intern (format "gnus-mouse-face-%d" type)))))))
 237
 238 (defvar gnus-face-0 'bold)
 239 (defvar gnus-face-1 'italic)
 240 (defvar gnus-face-2 'bold-italic)
 241 (defvar gnus-face-3 'bold)
 242 (defvar gnus-face-4 'bold)
 243
 244 (defun gnus-face-face-function (form type)
 245   `(gnus-add-text-properties
 246     (point) (progn ,@form (point))
 247     '(gnus-face t face ,(symbol-value (intern (format "gnus-face-%d" type))))))
 248
 249 (defun gnus-tilde-max-form (el max-width)
 250   "Return a form that limits EL to MAX-WIDTH."
 251   (let ((max (abs max-width)))
 252     (if (symbolp el)
 253         `(if (> (length ,el) ,max)
 254              ,(if (< max-width 0)
 255                   `(substring ,el (- (length el) ,max))
 256                 `(substring ,el 0 ,max))
 257            ,el)
 258       `(let ((val (eval ,el)))
 259          (if (> (length val) ,max)
 260              ,(if (< max-width 0)
 261                   `(substring val (- (length val) ,max))
 262                 `(substring val 0 ,max))
 263            val)))))
 264
 265 (defun gnus-tilde-cut-form (el cut-width)
 266   "Return a form that cuts CUT-WIDTH off of EL."
 267   (let ((cut (abs cut-width)))
 268     (if (symbolp el)
 269         `(if (> (length ,el) ,cut)
 270              ,(if (< cut-width 0)
 271                   `(substring ,el 0 (- (length el) ,cut))
 272                 `(substring ,el ,cut))
 273            ,el)
 274       `(let ((val (eval ,el)))
 275          (if (> (length val) ,cut)
 276              ,(if (< cut-width 0)
 277                   `(substring val 0 (- (length val) ,cut))
 278                 `(substring val ,cut))
 279            val)))))
 280
 281 (defun gnus-tilde-ignore-form (el ignore-value)
 282   "Return a form that is blank when EL is IGNORE-VALUE."
 283   (if (symbolp el)
 284       `(if (equal ,el ,ignore-value)
 285            "" ,el)
 286     `(let ((val (eval ,el)))
 287        (if (equal val ,ignore-value)
 288            "" val))))
 289
 290 (defun gnus-parse-format (format spec-alist &optional insert)
 291   ;; This function parses the FORMAT string with the help of the
 292   ;; SPEC-ALIST and returns a list that can be eval'ed to return the
 293   ;; string.  If the FORMAT string contains the specifiers %( and %)
 294   ;; the text between them will have the mouse-face text property.
 295   (if (string-match
 296        "\\`\\(.*\\)%[0-9]?[{(]\\(.*\\)%[0-9]?[})]\\(.*\n?\\)\\'"
 297        format)
 298       (gnus-parse-complex-format format spec-alist)
 299     ;; This is a simple format.
 300     (gnus-parse-simple-format format spec-alist insert)))
 301
 302 (defun gnus-parse-complex-format (format spec-alist)
 303   (save-excursion
 304     (gnus-set-work-buffer)
 305     (insert format)
 306     (goto-char (point-min))
 307     (while (re-search-forward "\"" nil t)
 308       (replace-match "\\\"" nil t))
 309     (goto-char (point-min))
 310     (insert "(\"")
 311     (while (re-search-forward "%\\([0-9]+\\)?\\([{}()]\\)" nil t)
 312       (let ((number (if (match-beginning 1)
 313                         (match-string 1) "0"))
 314             (delim (aref (match-string 2) 0)))
 315         (if (or (= delim ?\()
 316                 (= delim ?\{))
 317             (replace-match (concat "\"(" (if (= delim ?\() "mouse" "face")
 318                                    " " number " \""))
 319           (replace-match "\")\""))))
 320     (goto-char (point-max))
 321     (insert "\")")
 322     (goto-char (point-min))
 323     (let ((form (read (current-buffer))))
 324       (cons 'progn (gnus-complex-form-to-spec form spec-alist)))))
 325
 326 (defun gnus-complex-form-to-spec (form spec-alist)
 327   (delq nil
 328         (mapcar
 329          (lambda (sform)
 330            (if (stringp sform)
 331                (gnus-parse-simple-format sform spec-alist t)
 332              (funcall (intern (format "gnus-%s-face-function" (car sform)))
 333                       (gnus-complex-form-to-spec (cddr sform) spec-alist)
 334                       (nth 1 sform))))
 335          form)))
 336
 337 (defun gnus-parse-simple-format (format spec-alist &optional insert)
 338   ;; This function parses the FORMAT string with the help of the
 339   ;; SPEC-ALIST and returns a list that can be eval'ed to return a
 340   ;; string.
 341   (let (max-width
 342         spec flist fstring elem result dontinsert user-defined
 343         type value pad-width spec-beg cut-width ignore-value
 344         tilde-form tilde elem-type
 345         (xemacs-mule-p (and gnus-xemacs (featurep 'mule))))
 346     (save-excursion
 347       (gnus-set-work-buffer)
 348       (insert format)
 349       (goto-char (point-min))
 350       (while (search-forward "%" nil t)
 351         (setq user-defined nil
 352               spec-beg nil
 353               pad-width nil
 354               max-width nil
 355               cut-width nil
 356               ignore-value nil
 357               tilde-form nil)
 358         (setq spec-beg (1- (point)))
 359
 360         ;; Parse this spec fully.
 361         (while
 362             (cond
 363              ((looking-at "\\([-.0-9]+\\)\\(,[-0-9]+\\)?")
 364               (setq pad-width (string-to-number (match-string 1)))
 365               (when (match-beginning 2)
 366                 (setq max-width (string-to-number (buffer-substring
 367                                                    (1+ (match-beginning 2))
 368                                                    (match-end 2)))))
 369               (goto-char (match-end 0)))
 370              ((looking-at "~")
 371               (forward-char 1)
 372               (setq tilde (read (current-buffer))
 373                     type (car tilde)
 374                     value (cadr tilde))
 375               (cond
 376                ((memq type '(pad pad-left))
 377                 (setq pad-width value))
 378                ((eq type 'pad-right)
 379                 (setq pad-width (- value)))
 380                ((memq type '(max-right max))
 381                 (setq max-width value))
 382                ((eq type 'max-left)
 383                 (setq max-width (- value)))
 384                ((memq type '(cut cut-left))
 385                 (setq cut-width value))
 386                ((eq type 'cut-right)
 387                 (setq cut-width (- value)))
 388                ((eq type 'ignore)
 389                 (setq ignore-value
 390                       (if (stringp value) value (format "%s" value))))
 391                ((eq type 'form)
 392                 (setq tilde-form value))
 393                (t
 394                 (error "Unknown tilde type: %s" tilde)))
 395               t)
 396              (t
 397               nil)))
 398         ;; User-defined spec -- find the spec name.
 399         (when (eq (setq spec (char-after)) ?u)
 400           (forward-char 1)
 401           (setq user-defined (char-after)))
 402         (forward-char 1)
 403         (delete-region spec-beg (point))
 404
 405         ;; Now we have all the relevant data on this spec, so
 406         ;; we start doing stuff.
 407         (insert "%")
 408         (if (eq spec ?%)
 409             ;; "%%" just results in a "%".
 410             (insert "%")
 411           (cond
 412            ;; Do tilde forms.
 413            ((eq spec ?@)
 414             (setq elem (list tilde-form ?s)))
 415            ;; Treat user defined format specifiers specially.
 416            (user-defined
 417             (setq elem
 418                   (list
 419                    (list (intern (format "gnus-user-format-function-%c"
 420                                          user-defined))
 421                          'gnus-tmp-header)
 422                    ?s)))
 423            ;; Find the specification from `spec-alist'.
 424            ((setq elem (cdr (assq spec spec-alist))))
 425            (t
 426             (setq elem '("*" ?s))))
 427           (setq elem-type (cadr elem))
 428           ;; Insert the new format elements.
 429           (and pad-width (not xemacs-mule-p)
 430                (insert (number-to-string pad-width)))
 431           ;; Create the form to be evaled.
 432           (if (or max-width cut-width ignore-value
 433                   (and pad-width xemacs-mule-p))
 434               (progn
 435                 (insert ?s)
 436                 (let ((el (car elem)))
 437                   (cond ((= (cadr elem) ?c)
 438                          (setq el (list 'char-to-string el)))
 439                         ((= (cadr elem) ?d)
 440                          (setq el (list 'int-to-string el))))
 441                   (when ignore-value
 442                     (setq el (gnus-tilde-ignore-form el ignore-value)))
 443                   (when cut-width
 444                     (setq el (gnus-tilde-cut-form el cut-width)))
 445                   (when max-width
 446                     (setq el (gnus-tilde-max-form el max-width)))
 447                   (and pad-width xemacs-mule-p
 448                        (setq el (gnus-tilde-pad-form el pad-width)))
 449                   (push el flist)))
 450             (insert elem-type)
 451             (push (car elem) flist))))
 452       (setq fstring (buffer-string)))
 453
 454     ;; Do some postprocessing to increase efficiency.
 455     (setq
 456      result
 457      (cond
 458       ;; Emptyness.
 459       ((string= fstring "")
 460        nil)
 461       ;; Not a format string.
 462       ((not (string-match "%" fstring))
 463        (list fstring))
 464       ;; A format string with just a single string spec.
 465       ((string= fstring "%s")
 466        (list (car flist)))
 467       ;; A single character.
 468       ((string= fstring "%c")
 469        (list (car flist)))
 470       ;; A single number.
 471       ((string= fstring "%d")
 472        (setq dontinsert)
 473        (if insert
 474            (list `(princ ,(car flist)))
 475          (list `(int-to-string ,(car flist)))))
 476       ;; Just lots of chars and strings.
 477       ((string-match "\\`\\(%[cs]\\)+\\'" fstring)
 478        (nreverse flist))
 479       ;; A single string spec at the beginning of the spec.
 480       ((string-match "\\`%[sc][^%]+\\'" fstring)
 481        (list (car flist) (substring fstring 2)))
 482       ;; A single string spec in the middle of the spec.
 483       ((string-match "\\`\\([^%]+\\)%[sc]\\([^%]+\\)\\'" fstring)
 484        (list (match-string 1 fstring) (car flist) (match-string 2 fstring)))
 485       ;; A single string spec in the end of the spec.
 486       ((string-match "\\`\\([^%]+\\)%[sc]\\'" fstring)
 487        (list (match-string 1 fstring) (car flist)))
 488       ;; A more complex spec.
 489       (t
 490        (list (cons 'format (cons fstring (nreverse flist)))))))
 491
 492     (if insert
 493         (when result
 494           (if dontinsert
 495               result
 496             (cons 'insert result)))
 497       (cond ((stringp result)
 498              result)
 499             ((consp result)
 500              (cons 'concat result))
 501             (t "")))))
 502
 503 (defun gnus-eval-format (format &optional alist props)
 504   "Eval the format variable FORMAT, using ALIST.
 505 If PROPS, insert the result."
 506   (let ((form (gnus-parse-format format alist props)))
 507     (if props
 508         (gnus-add-text-properties (point) (progn (eval form) (point)) props)
 509       (eval form))))
 510
 511 (defun gnus-compile ()
 512   "Byte-compile the user-defined format specs."
 513   (interactive)
 514   (require 'bytecomp)
 515   (let ((entries gnus-format-specs)
 516         (byte-compile-warnings '(unresolved callargs redefine))
 517         entry gnus-tmp-func)
 518     (save-excursion
 519       (gnus-message 7 "Compiling format specs...")
 520
 521       (while entries
 522         (setq entry (pop entries))
 523         (if (eq (car entry) 'version)
 524             (setq gnus-format-specs (delq entry gnus-format-specs))
 525           (let ((form (caddr entry)))
 526             (when (and (listp form)
 527                        ;; Under GNU Emacs, it's (byte-code ...)
 528                        (not (eq 'byte-code (car form)))
 529                        ;; Under XEmacs, it's (funcall #<compiled-function ...>)
 530                        (not (and (eq 'funcall (car form))
 531                                  (compiled-function-p (cadr form)))))
 532               (fset 'gnus-tmp-func `(lambda () ,form))
 533               (byte-compile 'gnus-tmp-func)
 534               (setcar (cddr entry) (gnus-byte-code 'gnus-tmp-func))))))
 535
 536       (push (cons 'version emacs-version) gnus-format-specs)
 537       ;; Mark the .newsrc.eld file as "dirty".
 538       (gnus-dribble-touch)
 539       (gnus-message 7 "Compiling user specs...done"))))
 540
 541 (defun gnus-set-format (type &optional insertable)
 542   (set (intern (format "gnus-%s-line-format-spec" type))
 543        (gnus-parse-format
 544         (symbol-value (intern (format "gnus-%s-line-format" type)))
 545         (symbol-value (intern (format "gnus-%s-line-format-alist" type)))
 546         insertable)))
 547
 548
 549 (provide 'gnus-spec)
 550
 551 ;;; gnus-spec.el ends here