git.chise.org Git - elisp/gnus.git-/blob - lisp/gnus-xmas.el

   1 ;;; gnus-xmas.el --- Gnus functions for XEmacs
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'text-props)
  32 (defvar menu-bar-mode (featurep 'menubar))
  33 (require 'messagexmas)
  34 (require 'wid-edit)
  35
  36 (defgroup gnus-xmas nil
  37   "XEmacsoid support for Gnus"
  38   :group 'gnus)
  39
  40 (defcustom gnus-xmas-glyph-directory nil
  41   "Directory where Gnus logos and icons are located.
  42 If this variable is nil, Gnus will try to locate the directory
  43 automatically."
  44   :type '(choice (const :tag "autodetect" nil)
  45                  directory)
  46   :group 'gnus-xmas)
  47
  48 (unless gnus-xmas-glyph-directory
  49   (unless (setq gnus-xmas-glyph-directory
  50                 (message-xmas-find-glyph-directory "gnus"))
  51     (error "Can't find glyph directory. \
  52 Possibly the `etc' directory has not been installed.")))
  53
  54 ;;; Internal variables.
  55
  56 ;; Don't warn about these undefined variables.
  57
  58 ;;defined in gnus.el
  59 (defvar gnus-active-hashtb)
  60 (defvar gnus-article-buffer)
  61 (defvar gnus-auto-center-summary)
  62 (defvar gnus-current-headers)
  63 (defvar gnus-level-killed)
  64 (defvar gnus-level-zombie)
  65 (defvar gnus-newsgroup-bookmarks)
  66 (defvar gnus-newsgroup-dependencies)
  67 (defvar gnus-newsgroup-selected-overlay)
  68 (defvar gnus-newsrc-hashtb)
  69 (defvar gnus-read-mark)
  70 (defvar gnus-refer-article-method)
  71 (defvar gnus-reffed-article-number)
  72 (defvar gnus-unread-mark)
  73 (defvar gnus-version)
  74 (defvar gnus-view-pseudos)
  75 (defvar gnus-view-pseudos-separately)
  76 (defvar gnus-visual)
  77 (defvar gnus-zombie-list)
  78 ;;defined in gnus-msg.el
  79 (defvar gnus-article-copy)
  80 (defvar gnus-check-before-posting)
  81 ;;defined in gnus-vis.el
  82 (defvar gnus-article-button-face)
  83 (defvar gnus-article-mouse-face)
  84 (defvar gnus-summary-selected-face)
  85 (defvar gnus-group-reading-menu)
  86 (defvar gnus-group-group-menu)
  87 (defvar gnus-group-misc-menu)
  88 (defvar gnus-summary-article-menu)
  89 (defvar gnus-summary-thread-menu)
  90 (defvar gnus-summary-misc-menu)
  91 (defvar gnus-summary-post-menu)
  92 (defvar gnus-summary-kill-menu)
  93 (defvar gnus-article-article-menu)
  94 (defvar gnus-article-treatment-menu)
  95 (defvar gnus-mouse-2)
  96 (defvar standard-display-table)
  97 (defvar gnus-tree-minimize-window)
  98
  99 (defun gnus-xmas-set-text-properties (start end props &optional buffer)
 100   "You should NEVER use this function.  It is ideologically blasphemous.
 101 It is provided only to ease porting of broken FSF Emacs programs."
 102   (if (stringp buffer)
 103       nil
 104     (map-extents (lambda (extent ignored)
 105                    (remove-text-properties
 106                     start end
 107                     (list (extent-property extent 'text-prop) nil)
 108                     buffer)
 109                    nil)
 110                  buffer start end nil nil 'text-prop)
 111     (gnus-add-text-properties start end props buffer)))
 112
 113 (defun gnus-xmas-highlight-selected-summary ()
 114   ;; Highlight selected article in summary buffer
 115   (when gnus-summary-selected-face
 116     (when gnus-newsgroup-selected-overlay
 117       (delete-extent gnus-newsgroup-selected-overlay))
 118     (setq gnus-newsgroup-selected-overlay
 119           (make-extent (gnus-point-at-bol) (gnus-point-at-eol)))
 120     (set-extent-face gnus-newsgroup-selected-overlay
 121                      gnus-summary-selected-face)))
 122
 123 (defcustom gnus-xmas-force-redisplay nil
 124   "*If non-nil, force a redisplay before recentering the summary buffer.
 125 This is ugly, but it works around a bug in `window-displayed-height'."
 126   :type 'boolean
 127   :group 'gnus-xmas)
 128
 129 (defun gnus-xmas-switch-horizontal-scrollbar-off ()
 130   (when (featurep 'scrollbar)
 131     (set-specifier scrollbar-height (cons (current-buffer) 0))))
 132
 133 (defun gnus-xmas-summary-recenter ()
 134   "\"Center\" point in the summary window.
 135 If `gnus-auto-center-summary' is nil, or the article buffer isn't
 136 displayed, no centering will be performed."
 137   ;; Suggested by earle@mahendo.JPL.NASA.GOV (Greg Earle).
 138   ;; Recenter only when requested.  Suggested by popovich@park.cs.columbia.edu.
 139   ;; Force redisplay to get properly computed window height.
 140   (when gnus-xmas-force-redisplay
 141     (sit-for 0))
 142   (when gnus-auto-center-summary
 143     (let* ((height (if (fboundp 'window-displayed-height)
 144                        (window-displayed-height)
 145                      (- (window-height) 2)))
 146            (top (cond ((< height 4) 0)
 147                       ((< height 7) 1)
 148                       (t (if (numberp gnus-auto-center-summary)
 149                              gnus-auto-center-summary
 150                            2))))
 151            (bottom (save-excursion (goto-char (point-max))
 152                                    (forward-line (- height))
 153                                    (point)))
 154            (window (get-buffer-window (current-buffer))))
 155       (when (get-buffer-window gnus-article-buffer)
 156         ;; Only do recentering when the article buffer is displayed,
 157         ;; Set the window start to either `bottom', which is the biggest
 158         ;; possible valid number, or the second line from the top,
 159         ;; whichever is the least.
 160         ;; NOFORCE parameter suggested by Daniel Pittman <daniel@danann.net>.
 161         (set-window-start
 162          window (min bottom (save-excursion (forward-line (- top)) (point)))
 163          t))
 164       ;; Do horizontal recentering while we're at it.
 165       (when (and (get-buffer-window (current-buffer) t)
 166                  (not (eq gnus-auto-center-summary 'vertical)))
 167         (let ((selected (selected-window)))
 168           (select-window (get-buffer-window (current-buffer) t))
 169           (gnus-summary-position-point)
 170           (gnus-horizontal-recenter)
 171           (select-window selected))))))
 172
 173 (defun gnus-xmas-summary-set-display-table ()
 174   ;; Setup the display table -- like `gnus-summary-setup-display-table',
 175   ;; but done in an XEmacsish way.
 176   (let ((table (make-display-table))
 177         (i 32))
 178     ;; Nix out all the control chars...
 179     (while (>= (setq i (1- i)) 0)
 180       (aset table i [??]))
 181     ;; ... but not newline and cr, of course.  (cr is necessary for the
 182     ;; selective display).
 183     (aset table ?\n nil)
 184     (aset table ?\r nil)
 185     ;; We keep TAB as well.
 186     (aset table ?\t nil)
 187     ;; We nix out any glyphs over 126 below ctl-arrow.
 188     (let ((i (if (integerp ctl-arrow) ctl-arrow 160)))
 189       (while (>= (setq i (1- i)) 127)
 190         (unless (aref table i)
 191           (aset table i [??]))))
 192     ;; Can't use `set-specifier' because of a bug in 19.14 and earlier
 193     (add-spec-to-specifier current-display-table table (current-buffer) nil)))
 194
 195 (defun gnus-xmas-add-text-properties (start end props &optional object)
 196   (add-text-properties start end props object)
 197   (put-text-property start end 'start-closed nil object))
 198
 199 (defun gnus-xmas-put-text-property (start end prop value &optional object)
 200   (put-text-property start end prop value object)
 201   (put-text-property start end 'start-closed nil object))
 202
 203 (defun gnus-xmas-extent-start-open (point)
 204   (map-extents (lambda (extent arg)
 205                  (set-extent-property extent 'start-open t))
 206                nil point (min (1+ (point)) (point-max))))
 207
 208 (defun gnus-xmas-article-push-button (event)
 209   "Check text under the mouse pointer for a callback function.
 210 If the text under the mouse pointer has a `gnus-callback' property,
 211 call it with the value of the `gnus-data' text property."
 212   (interactive "e")
 213   (set-buffer (window-buffer (event-window event)))
 214   (let* ((pos (event-closest-point event))
 215          (data (get-text-property pos 'gnus-data))
 216          (fun (get-text-property pos 'gnus-callback)))
 217     (goto-char pos)
 218     (when fun
 219       (funcall fun data))))
 220
 221 (defun gnus-xmas-move-overlay (extent start end &optional buffer)
 222   (set-extent-endpoints extent start end buffer))
 223
 224 (defun gnus-xmas-kill-all-overlays ()
 225   "Delete all extents in the current buffer."
 226   (map-extents (lambda (extent ignore)
 227                  (delete-extent extent)
 228                  nil)))
 229
 230 (defun gnus-xmas-window-top-edge (&optional window)
 231   (nth 1 (window-pixel-edges window)))
 232
 233 (defun gnus-xmas-tree-minimize ()
 234   (when (and gnus-tree-minimize-window
 235              (not (one-window-p)))
 236     (let* ((window-min-height 2)
 237            (height (1+ (count-lines (point-min) (point-max))))
 238            (min (max (1- window-min-height) height))
 239            (tot (if (numberp gnus-tree-minimize-window)
 240                     (min gnus-tree-minimize-window min)
 241                   min))
 242            (win (get-buffer-window (current-buffer)))
 243            (wh (and win (1- (window-height win)))))
 244       (when (and win
 245                  (not (eq tot wh)))
 246         (let ((selected (selected-window)))
 247           (select-window win)
 248           (enlarge-window (- tot wh))
 249           (select-window selected))))))
 250
 251 ;; Select the lowest window on the frame.
 252 (defun gnus-xmas-appt-select-lowest-window ()
 253   (let* ((lowest-window (selected-window))
 254          (bottom-edge (car (cdr (cdr (cdr (window-pixel-edges))))))
 255          (last-window (previous-window))
 256          (window-search t))
 257     (while window-search
 258       (let* ((this-window (next-window))
 259              (next-bottom-edge (car (cdr (cdr (cdr
 260                                                (window-pixel-edges
 261                                                 this-window)))))))
 262         (when (< bottom-edge next-bottom-edge)
 263           (setq bottom-edge next-bottom-edge)
 264           (setq lowest-window this-window))
 265
 266         (select-window this-window)
 267         (when (eq last-window this-window)
 268           (select-window lowest-window)
 269           (setq window-search nil))))))
 270
 271 (defmacro gnus-xmas-menu-add (type &rest menus)
 272   `(gnus-xmas-menu-add-1 ',type ',menus))
 273 (put 'gnus-xmas-menu-add 'lisp-indent-function 1)
 274
 275 (defun gnus-xmas-menu-add-1 (type menus)
 276   (when (and menu-bar-mode
 277              (gnus-visual-p (intern (format "%s-menu" type)) 'menu))
 278     (while menus
 279       (easy-menu-add (symbol-value (pop menus))))))
 280
 281 (defun gnus-xmas-group-menu-add ()
 282   (gnus-xmas-menu-add group
 283     gnus-group-reading-menu gnus-group-group-menu gnus-group-misc-menu))
 284
 285 (defun gnus-xmas-summary-menu-add ()
 286   (gnus-xmas-menu-add summary
 287     gnus-summary-misc-menu gnus-summary-kill-menu
 288     gnus-summary-article-menu gnus-summary-thread-menu
 289     gnus-summary-post-menu ))
 290
 291 (defun gnus-xmas-article-menu-add ()
 292   (gnus-xmas-menu-add article
 293     gnus-article-article-menu gnus-article-treatment-menu
 294     gnus-article-post-menu gnus-article-commands-menu))
 295
 296 (defun gnus-xmas-score-menu-add ()
 297   (gnus-xmas-menu-add score
 298     gnus-score-menu))
 299
 300 (defun gnus-xmas-pick-menu-add ()
 301   (gnus-xmas-menu-add pick
 302     gnus-pick-menu))
 303
 304 (defun gnus-xmas-topic-menu-add ()
 305   (gnus-xmas-menu-add topic
 306     gnus-topic-menu))
 307
 308 (defun gnus-xmas-binary-menu-add ()
 309   (gnus-xmas-menu-add binary
 310     gnus-binary-menu))
 311
 312 (defun gnus-xmas-agent-summary-menu-add ()
 313   (gnus-xmas-menu-add agent-summary
 314     gnus-agent-summary-menu))
 315
 316 (defun gnus-xmas-agent-group-menu-add ()
 317   (gnus-xmas-menu-add agent-group
 318     gnus-agent-group-menu))
 319
 320 (defun gnus-xmas-agent-server-menu-add ()
 321   (gnus-xmas-menu-add agent-server
 322     gnus-agent-server-menu))
 323
 324 (defun gnus-xmas-tree-menu-add ()
 325   (gnus-xmas-menu-add tree
 326     gnus-tree-menu))
 327
 328 (defun gnus-xmas-draft-menu-add ()
 329   (gnus-xmas-menu-add draft
 330     gnus-draft-menu))
 331
 332 (defun gnus-xmas-server-menu-add ()
 333   (gnus-xmas-menu-add menu
 334     gnus-server-server-menu gnus-server-connections-menu))
 335
 336 (defun gnus-xmas-browse-menu-add ()
 337   (gnus-xmas-menu-add browse
 338     gnus-browse-menu))
 339
 340 (defun gnus-xmas-grouplens-menu-add ()
 341   (gnus-xmas-menu-add grouplens
 342     gnus-grouplens-menu))
 343
 344 (defun gnus-xmas-read-event-char (&optional prompt)
 345   "Get the next event."
 346   (when prompt
 347     (message "%s" prompt))
 348   (let ((event (next-command-event)))
 349     (sit-for 0)
 350     ;; We junk all non-key events.  Is this naughty?
 351     (while (not (or (key-press-event-p event)
 352                     (button-press-event-p event)))
 353       (dispatch-event event)
 354       (setq event (next-command-event)))
 355     (cons (and (key-press-event-p event)
 356                (event-to-character event))
 357           event)))
 358
 359 (defun gnus-xmas-define ()
 360   (setq gnus-mouse-2 [button2])
 361   (setq gnus-mouse-3 [button3])
 362   (setq gnus-widget-button-keymap widget-button-keymap)
 363
 364   (unless (memq 'underline (face-list))
 365     (and (fboundp 'make-face)
 366          (funcall (intern "make-face") 'underline)))
 367   ;; Must avoid calling set-face-underline-p directly, because it
 368   ;; is a defsubst in emacs19, and will make the .elc files non
 369   ;; portable!
 370   (unless (face-differs-from-default-p 'underline)
 371     (funcall (intern "set-face-underline-p") 'underline t))
 372
 373   (cond
 374    ((fboundp 'char-or-char-int-p)
 375     ;; Handle both types of marks for XEmacs-20.x.
 376     (defalias 'gnus-characterp 'char-or-char-int-p))
 377    ;; V19 of XEmacs, probably.
 378    (t
 379     (defalias 'gnus-characterp 'characterp)))
 380
 381   (defalias 'gnus-make-overlay 'make-extent)
 382   (defalias 'gnus-delete-overlay 'delete-extent)
 383   (defalias 'gnus-overlay-put 'set-extent-property)
 384   (defalias 'gnus-move-overlay 'gnus-xmas-move-overlay)
 385   (defalias 'gnus-overlay-buffer 'extent-object)
 386   (defalias 'gnus-overlay-start 'extent-start-position)
 387   (defalias 'gnus-overlay-end 'extent-end-position)
 388   (defalias 'gnus-kill-all-overlays 'gnus-xmas-kill-all-overlays)
 389   (defalias 'gnus-extent-detached-p 'extent-detached-p)
 390   (defalias 'gnus-add-text-properties 'gnus-xmas-add-text-properties)
 391   (defalias 'gnus-put-text-property 'gnus-xmas-put-text-property)
 392   (defalias 'gnus-deactivate-mark 'ignore)
 393   (defalias 'gnus-window-edges 'window-pixel-edges)
 394
 395   (if (and (<= emacs-major-version 19)
 396            (< emacs-minor-version 14))
 397       (defalias 'gnus-set-text-properties 'gnus-xmas-set-text-properties))
 398
 399   (unless (boundp 'standard-display-table)
 400     (setq standard-display-table nil))
 401
 402   (defvar gnus-mouse-face-prop 'highlight)
 403
 404   (defun gnus-byte-code (func)
 405     "Return a form that can be `eval'ed based on FUNC."
 406     (let ((fval (indirect-function func)))
 407       (if (compiled-function-p fval)
 408           (list 'funcall fval)
 409         (cons 'progn (cdr (cdr fval))))))
 410
 411   (defalias 'gnus-x-color-values
 412     (if (fboundp 'x-color-values)
 413         'x-color-values
 414       (lambda (color)
 415         (color-instance-rgb-components
 416          (make-color-instance color))))))
 417
 418 (defun gnus-xmas-redefine ()
 419   "Redefine lots of Gnus functions for XEmacs."
 420   (defalias 'gnus-summary-set-display-table 'gnus-xmas-summary-set-display-table)
 421   (defalias 'gnus-visual-turn-off-edit-menu 'identity)
 422   (defalias 'gnus-summary-recenter 'gnus-xmas-summary-recenter)
 423   (defalias 'gnus-extent-start-open 'gnus-xmas-extent-start-open)
 424   (defalias 'gnus-article-push-button 'gnus-xmas-article-push-button)
 425   (defalias 'gnus-window-top-edge 'gnus-xmas-window-top-edge)
 426   (defalias 'gnus-read-event-char 'gnus-xmas-read-event-char)
 427   (defalias 'gnus-group-startup-message 'gnus-xmas-group-startup-message)
 428   (defalias 'gnus-tree-minimize 'gnus-xmas-tree-minimize)
 429   (defalias 'gnus-appt-select-lowest-window
 430     'gnus-xmas-appt-select-lowest-window)
 431   (defalias 'gnus-mail-strip-quoted-names 'gnus-xmas-mail-strip-quoted-names)
 432   (defalias 'gnus-character-to-event 'character-to-event)
 433   (defalias 'gnus-mode-line-buffer-identification
 434     'gnus-xmas-mode-line-buffer-identification)
 435   (defalias 'gnus-key-press-event-p 'key-press-event-p)
 436   (defalias 'gnus-region-active-p 'region-active-p)
 437   (defalias 'gnus-mark-active-p 'region-exists-p)
 438   (defalias 'gnus-annotation-in-region-p 'gnus-xmas-annotation-in-region-p)
 439   (defalias 'gnus-mime-button-menu 'gnus-xmas-mime-button-menu)
 440   (defalias 'gnus-image-type-available-p 'gnus-xmas-image-type-available-p)
 441   (defalias 'gnus-put-image 'gnus-xmas-put-image)
 442   (defalias 'gnus-create-image 'gnus-xmas-create-image)
 443   (defalias 'gnus-remove-image 'gnus-xmas-remove-image)
 444
 445   (when (or (< emacs-major-version 21)
 446             (and (= emacs-major-version 21)
 447                  (< emacs-minor-version 3)))
 448     (defalias 'gnus-completing-read 'gnus-xmas-completing-read))
 449
 450   ;; These ones are not defcutom'ed, sometimes not even defvar'ed. They
 451   ;; probably should. If that is done, the code below should then be moved
 452   ;; where each variable is defined, in order not to mess with user settings.
 453   ;; -- didier
 454   (add-hook 'gnus-score-mode-hook 'gnus-xmas-score-menu-add)
 455   (add-hook 'gnus-binary-mode-hook 'gnus-xmas-binary-menu-add)
 456   (add-hook 'gnus-grouplens-mode-hook 'gnus-xmas-grouplens-menu-add)
 457   (add-hook 'gnus-server-mode-hook 'gnus-xmas-server-menu-add)
 458   (add-hook 'gnus-browse-mode-hook 'gnus-xmas-browse-menu-add)
 459   (add-hook 'gnus-draft-mode-hook 'gnus-xmas-draft-menu-add)
 460   (add-hook 'gnus-mailing-list-mode-hook 'gnus-xmas-mailing-list-menu-add)
 461
 462   (when (featurep 'mule)
 463     (defun gnus-truncate-string (str end-column &optional start-column padding)
 464       "Truncate string STR to end at column END-COLUMN.
 465 The optional 2nd arg START-COLUMN, if non-nil, specifies
 466 the starting column; that means to return the characters occupying
 467 columns START-COLUMN ... END-COLUMN of STR.
 468
 469 The optional 3rd arg PADDING, if non-nil, specifies a padding character
 470 to add at the end of the result if STR doesn't reach column END-COLUMN,
 471 or if END-COLUMN comes in the middle of a character in STR.
 472 PADDING is also added at the beginning of the result
 473 if column START-COLUMN appears in the middle of a character in STR.
 474
 475 If PADDING is nil, no padding is added in these cases, so
 476 the resulting string may be narrower than END-COLUMN.
 477 \[Emacs 20.3 emulating function]"
 478       (or start-column
 479           (setq start-column 0))
 480       (let ((len (length str))
 481             (idx 0)
 482             (column 0)
 483             (head-padding "") (tail-padding "")
 484             ch last-column last-idx from-idx)
 485         (condition-case nil
 486             (while (< column start-column)
 487               (setq ch (aref str idx)
 488                     column (+ column (char-width ch))
 489                     idx (1+ idx)))
 490           (args-out-of-range (setq idx len)))
 491         (if (< column start-column)
 492             (if padding (make-string end-column padding) "")
 493           (if (and padding (> column start-column))
 494               (setq head-padding
 495                     (make-string (- column start-column) padding)))
 496           (setq from-idx idx)
 497           (if (< end-column column)
 498               (setq idx from-idx)
 499             (condition-case nil
 500                 (while (< column end-column)
 501                   (setq last-column column
 502                         last-idx idx
 503                         ch (aref str idx)
 504                         column (+ column (char-width ch))
 505                         idx (1+ idx)))
 506               (args-out-of-range (setq idx len)))
 507             (if (> column end-column)
 508                 (setq column last-column idx last-idx))
 509             (if (and padding (< column end-column))
 510                 (setq tail-padding
 511                       (make-string (- end-column column) padding))))
 512           (setq str (substring str from-idx idx))
 513           (if padding
 514               (concat head-padding str tail-padding)
 515             str))))))
 516
 517 ;;; XEmacs logo and toolbar.
 518
 519 (defun gnus-xmas-group-startup-message (&optional x y)
 520   "Insert startup message in current buffer."
 521   ;; Insert the message.
 522   (erase-buffer)
 523   (cond
 524    ((and (console-on-window-system-p)
 525          (or (featurep 'xpm)
 526              (featurep 'xbm)))
 527     (let* ((logo-xpm (expand-file-name "gnus.xpm" gnus-xmas-glyph-directory))
 528            (logo-xbm (expand-file-name "gnus.xbm" gnus-xmas-glyph-directory))
 529            (glyph (make-glyph
 530                    (cond ((featurep 'xpm)
 531                           `[xpm
 532                             :file ,logo-xpm
 533                             :color-symbols
 534                             (("thing" . ,(car gnus-logo-colors))
 535                              ("shadow" . ,(cadr gnus-logo-colors))
 536                              ("oort" . "#eeeeee")
 537                              ("background" . ,(face-background 'default)))])
 538                          ((featurep 'xbm)
 539                           `[xbm :file ,logo-xbm])
 540                          (t [nothing]))))
 541            (wpheight (window-pixel-height))
 542            (rest (max 0 (1- (/ (* (- wpheight (glyph-height glyph))
 543                                   (window-height))
 544                                wpheight 2)))))
 545       (insert " ")
 546       (set-extent-begin-glyph (make-extent (point) (point)) glyph)
 547       (goto-char (point-min))
 548       (while (not (eobp))
 549         (insert (make-string (/ (max (- (window-width) (or x 35)) 0) 2)
 550                              ?\ ))
 551         (forward-line 1))
 552       (setq gnus-simple-splash nil)
 553       (goto-char (point-min))
 554       (insert gnus-product-name " " gnus-version-number
 555               (if (zerop (string-to-number gnus-revision-number))
 556                   ""
 557                 (concat " (r" gnus-revision-number ")"))
 558               " based on " gnus-original-product-name " v"
 559               gnus-original-version-number "\n")
 560       (end-of-line 0)
 561       (put-text-property (point-min) (point) 'face 'gnus-splash-face)
 562       (insert-char ?\  (prog1
 563                            (max 0 (/ (- (window-width) (point)) 2))
 564                          (goto-char (point-min))))
 565       (forward-line 1)
 566       (insert-char ?\n rest)
 567       (set-window-start (selected-window) (point-min))))
 568    (t
 569     (insert "
 570           _    ___ _             _
 571           _ ___ __ ___  __    _ ___
 572           __   _     ___    __  ___
 573               _           ___     _
 574              _  _ __             _
 575              ___   __            _
 576                    __           _
 577                     _      _   _
 578                    _      _    _
 579                       _  _    _
 580                   __  ___
 581                  _   _ _     _
 582                 _   _
 583               _    _
 584              _    _
 585             _
 586           __
 587
 588 "
 589             )
 590     (goto-char (point-min))
 591     (insert gnus-product-name " " gnus-version-number
 592             (if (zerop (string-to-number gnus-revision-number))
 593                 ""
 594               (concat " (r" gnus-revision-number ")"))
 595             " based on " gnus-original-product-name " v"
 596             gnus-original-version-number)
 597     (insert-char ?\  (prog1
 598                          (max 0 (/ (- (window-width) (point)) 2))
 599                        (goto-char (point-min))))
 600     (forward-line 1)
 601     ;; And then hack it.
 602     (gnus-indent-rigidly (point) (point-max)
 603                          (/ (max (- (window-width) (or x 46)) 0) 2))
 604     (goto-char (point-min))
 605     (forward-line 1)
 606     (let* ((pheight (count-lines (point-min) (point-max)))
 607            (wheight (window-height))
 608            (rest (- wheight pheight)))
 609       (insert (make-string (max 0 (* 2 (/ rest 3))) ?\n)))
 610     ;; Paint it.
 611     (put-text-property (point-min) (point-max) 'face 'gnus-splash-face)))
 612   (goto-char (point-min))
 613   (setq modeline-buffer-identification
 614         (list (concat gnus-version ": *Group*")))
 615   (set-buffer-modified-p t))
 616
 617
 618 ;;; The toolbar.
 619
 620 (defcustom gnus-use-toolbar (if (featurep 'toolbar)
 621                                 'default-toolbar
 622                               nil)
 623   "*If nil, do not use a toolbar.
 624 If it is non-nil, it must be a toolbar.  The five valid values are
 625 `default-toolbar', `top-toolbar', `bottom-toolbar',
 626 `right-toolbar', and `left-toolbar'."
 627   :type '(choice (const default-toolbar)
 628                  (const top-toolbar) (const bottom-toolbar)
 629                  (const left-toolbar) (const right-toolbar)
 630                  (const :tag "no toolbar" nil))
 631   :group 'gnus-xmas)
 632
 633 (defvar gnus-group-toolbar
 634   '([gnus-group-get-new-news gnus-group-get-new-news t "Get new news"]
 635     [gnus-group-get-new-news-this-group
 636      gnus-group-get-new-news-this-group t "Get new news in this group"]
 637     [gnus-group-catchup-current
 638      gnus-group-catchup-current t "Catchup group"]
 639     [gnus-group-describe-group
 640      gnus-group-describe-group t "Describe group"]
 641     [gnus-group-unsubscribe gnus-group-unsubscribe t "Unsubscribe group"]
 642     [gnus-group-subscribe gnus-group-subscribe t "Subscribe group"]
 643     [gnus-group-kill-group gnus-group-kill-group t "Kill group"]
 644     [gnus-summary-mail-save
 645      gnus-group-save-newsrc t "Save .newsrc files"] ; borrowed icon.
 646     [gnus-group-exit gnus-group-exit t "Exit Gnus"])
 647   "The group buffer toolbar.")
 648
 649 (defvar gnus-summary-toolbar
 650   '([gnus-summary-prev-unread
 651      gnus-summary-prev-page-or-article t "Page up"]
 652     [gnus-summary-next-unread
 653      gnus-summary-next-page t "Page down"]
 654     [gnus-summary-post-news
 655      gnus-summary-post-news t "Post an article"]
 656     [gnus-summary-followup-with-original
 657      gnus-summary-followup-with-original t
 658      "Post a followup and yank the original"]
 659     [gnus-summary-followup
 660      gnus-summary-followup t "Post a followup"]
 661     [gnus-summary-reply-with-original
 662      gnus-summary-reply-with-original t "Mail a reply and yank the original"]
 663     [gnus-summary-reply
 664      gnus-summary-reply t "Mail a reply"]
 665     [gnus-summary-caesar-message
 666      gnus-summary-caesar-message t "Rot 13"]
 667     [gnus-uu-decode-uu
 668      gnus-uu-decode-uu t "Decode uuencoded articles"]
 669     [gnus-summary-save-article-file
 670      gnus-summary-save-article-file t "Save article in file"]
 671     [gnus-summary-save-article
 672      gnus-summary-save-article t "Save article"]
 673     [gnus-uu-post-news
 674      gnus-uu-post-news t "Post a uuencoded article"]
 675     [gnus-summary-cancel-article
 676      gnus-summary-cancel-article t "Cancel article"]
 677     [gnus-summary-catchup
 678      gnus-summary-catchup t "Catchup"]
 679     [gnus-summary-catchup-and-exit
 680      gnus-summary-catchup-and-exit t "Catchup and exit"]
 681     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 682   "The summary buffer toolbar.")
 683
 684 (defvar gnus-summary-mail-toolbar
 685   '(
 686     [gnus-summary-prev-unread
 687      gnus-summary-prev-unread-article t "Prev unread article"]
 688     [gnus-summary-next-unread
 689      gnus-summary-next-unread-article t "Next unread article"]
 690     [gnus-summary-mail-reply gnus-summary-reply t "Reply"]
 691     [gnus-summary-mail-originate gnus-summary-post-news t "Originate"]
 692     [gnus-summary-mail-save gnus-summary-save-article t "Save"]
 693     [gnus-summary-mail-copy gnus-summary-copy-article t "Copy message"]
 694     [gnus-summary-mail-forward gnus-summary-mail-forward t "Forward message"]
 695     [gnus-summary-caesar-message
 696      gnus-summary-caesar-message t "Rot 13"]
 697     [gnus-uu-decode-uu
 698      gnus-uu-decode-uu t "Decode uuencoded articles"]
 699     [gnus-summary-save-article-file
 700      gnus-summary-save-article-file t "Save article in file"]
 701     [gnus-summary-save-article
 702      gnus-summary-save-article t "Save article"]
 703     [gnus-summary-cancel-article ; usenet : cancellation :: mail : deletion.
 704      gnus-summary-delete-article t "Delete message"]
 705     [gnus-summary-catchup
 706      gnus-summary-catchup t "Catchup"]
 707     [gnus-summary-catchup-and-exit
 708      gnus-summary-catchup-and-exit t "Catchup and exit"]
 709     [gnus-summary-exit gnus-summary-exit t "Exit this summary"])
 710   "The summary buffer mail toolbar.")
 711
 712 (defun gnus-xmas-setup-group-toolbar ()
 713   (and gnus-use-toolbar
 714        (message-xmas-setup-toolbar gnus-group-toolbar nil "gnus")
 715        (set-specifier (symbol-value gnus-use-toolbar)
 716                       (cons (current-buffer) gnus-group-toolbar))))
 717
 718 (defun gnus-xmas-setup-summary-toolbar ()
 719   (let ((bar (if (gnus-news-group-p gnus-newsgroup-name)
 720                  gnus-summary-toolbar gnus-summary-mail-toolbar)))
 721     (and gnus-use-toolbar
 722          (message-xmas-setup-toolbar bar nil "gnus")
 723          (set-specifier (symbol-value gnus-use-toolbar)
 724                         (cons (current-buffer) bar)))))
 725
 726 (defun gnus-xmas-mail-strip-quoted-names (address)
 727   "Protect mail-strip-quoted-names from nil input.
 728 XEmacs compatibility workaround."
 729   (if (null address)
 730       nil
 731     (mail-strip-quoted-names address)))
 732
 733 (defun gnus-xmas-call-region (command &rest args)
 734   (apply
 735    'call-process-region (point-min) (point-max) command t '(t nil) nil
 736    args))
 737
 738 (defvar gnus-xmas-modeline-left-extent
 739   (let ((ext (copy-extent modeline-buffer-id-left-extent)))
 740     ext))
 741
 742 (defvar gnus-xmas-modeline-right-extent
 743   (let ((ext (copy-extent modeline-buffer-id-right-extent)))
 744     ext))
 745
 746 (defvar gnus-xmas-modeline-glyph
 747   (progn
 748     (let* ((file-xpm (expand-file-name "gnus-pointer.xpm"
 749                                        gnus-xmas-glyph-directory))
 750            (file-xbm (expand-file-name "gnus-pointer.xbm"
 751                                        gnus-xmas-glyph-directory))
 752            (glyph (make-glyph
 753                    ;; Gag gag gag.
 754                    (cond ((featurep 'xpm)
 755                           ;; Let's try a nifty XPM
 756                           `[xpm :file ,file-xpm])
 757                          ((featurep 'xbm)
 758                           ;; Then a not-so-nifty XBM
 759                           `[xbm :file ,file-xbm])
 760                          ;; Then the simple string
 761                          (t [string :data "Gnus:"])))))
 762       (set-glyph-face glyph 'modeline-buffer-id)
 763       glyph)))
 764
 765 (defun gnus-xmas-mode-line-buffer-identification (line)
 766   (let ((line (car line))
 767         chop)
 768     (cond
 769      ;; This is some weird type of id.
 770      ((not (stringp line))
 771       (list line))
 772      ;; This is non-standard, so we just pass it through.
 773      ((not (string-match "^Gnus:" line))
 774       (list line))
 775      ;; We have a standard line, so we colorize and glyphize it a bit.
 776      (t
 777       (setq chop (match-end 0))
 778       (list
 779        (if gnus-xmas-modeline-glyph
 780            (cons gnus-xmas-modeline-left-extent gnus-xmas-modeline-glyph)
 781          (cons gnus-xmas-modeline-left-extent (substring line 0 chop)))
 782        (cons gnus-xmas-modeline-right-extent (substring line chop)))))))
 783
 784 (defun gnus-xmas-splash ()
 785   (when (eq (device-type) 'x)
 786     (gnus-splash)))
 787
 788 (defun gnus-xmas-annotation-in-region-p (b e)
 789   (or (map-extents (lambda (e u) t) nil b e nil nil 'mm t)
 790       (if (= b e)
 791           (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 792         (text-property-any b e 'gnus-undeletable t))))
 793
 794 (defun gnus-xmas-mime-button-menu (event prefix)
 795   "Construct a context-sensitive menu of MIME commands."
 796   (interactive "e\nP")
 797   (let ((response (get-popup-menu-response
 798                    `("MIME Part"
 799                      ,@(mapcar (lambda (c) `[,(caddr c) ,(car c) t])
 800                                gnus-mime-button-commands)))))
 801     (set-buffer (event-buffer event))
 802     (goto-char (event-point event))
 803     (funcall (event-function response) (event-object response))))
 804
 805 (defun gnus-group-add-icon ()
 806   "Add an icon to the current line according to `gnus-group-icon-list'."
 807   (let* ((p (point))
 808          (end (gnus-point-at-eol))
 809          ;; now find out where the line starts and leave point there.
 810          (beg (progn (beginning-of-line) (point))))
 811     (save-restriction
 812       (narrow-to-region beg end)
 813       (goto-char beg)
 814       (when (search-forward "==&&==" nil t)
 815         (let* ((group (gnus-group-group-name))
 816                (entry (gnus-group-entry group))
 817                (unread (if (numberp (car entry)) (car entry) 0))
 818                (active (gnus-active group))
 819                (total (if active (1+ (- (cdr active) (car active))) 0))
 820                (info (nth 2 entry))
 821                (method (gnus-server-get-method group (gnus-info-method info)))
 822                (marked (gnus-info-marks info))
 823                (mailp (memq 'mail (assoc (symbol-name
 824                                           (car (or method gnus-select-method)))
 825                                          gnus-valid-select-methods)))
 826                (level (or (gnus-info-level info) gnus-level-killed))
 827                (score (or (gnus-info-score info) 0))
 828                (ticked (gnus-range-length (cdr (assq 'tick marked))))
 829                (group-age (gnus-group-timestamp-delta group))
 830                (inhibit-read-only t)
 831                (list gnus-group-icon-list)
 832                (mystart (match-beginning 0))
 833                (myend (match-end 0)))
 834           (goto-char (point-min))
 835           (while (and list
 836                       (not (eval (caar list))))
 837             (setq list (cdr list)))
 838           (if list
 839               (let* ((file (cdar list))
 840                      (glyph (gnus-group-icon-create-glyph
 841                              (buffer-substring mystart myend)
 842                              file)))
 843                 (if glyph
 844                     (progn
 845                       (mapcar 'delete-annotation (annotations-at myend))
 846                       (let ((ext (make-extent mystart myend))
 847                             (ant (make-annotation glyph myend 'text)))
 848                         ;; set text extent params
 849                         (set-extent-property ext 'end-open t)
 850                         (set-extent-property ext 'start-open t)
 851                         (set-extent-property ext 'invisible t)))
 852                   (delete-region mystart myend)))
 853             (delete-region mystart myend))))
 854       (widen))
 855     (goto-char p)))
 856
 857 (defun gnus-group-icon-create-glyph (substring pixmap)
 858   "Create a glyph for insertion into a group line."
 859   (or
 860    (cdr-safe (assoc pixmap gnus-group-icon-cache))
 861    (let* ((glyph (make-glyph
 862                   (list
 863                    (cons 'x
 864                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 865                    (cons 'mswindows
 866                          (expand-file-name pixmap gnus-xmas-glyph-directory))
 867                    (cons 'tty substring)))))
 868      (setq gnus-group-icon-cache
 869            (cons (cons pixmap glyph) gnus-group-icon-cache))
 870      (set-glyph-face glyph 'default)
 871      glyph)))
 872
 873 (defun gnus-xmas-mailing-list-menu-add ()
 874   (gnus-xmas-menu-add mailing-list
 875     gnus-mailing-list-menu))
 876
 877 (defun gnus-xmas-image-type-available-p (type)
 878   (and window-system
 879        (featurep (if (eq type 'pbm) 'xbm type))))
 880
 881 (defun gnus-xmas-create-image (file &optional type data-p &rest props)
 882   (let ((type (if type
 883                   (symbol-name type)
 884                 (car (last (split-string file "[.]")))))
 885         (face (plist-get props :face))
 886         glyph)
 887     (when (equal type "pbm")
 888       (with-temp-buffer
 889         (if data-p
 890             (insert file)
 891           (insert-file-contents file))
 892         (shell-command-on-region (point-min) (point-max)
 893                                  "ppmtoxpm 2>/dev/null" t)
 894         (setq file (buffer-string)
 895               type "xpm"
 896               data-p t)))
 897     (setq glyph
 898           (if (equal type "xbm")
 899               (make-glyph (list (cons 'x file)))
 900             (with-temp-buffer
 901               (if data-p
 902                   (insert file)
 903                 (insert-file-contents file))
 904               (make-glyph
 905                (vector
 906                 (or (intern type)
 907                     (mm-image-type-from-buffer))
 908                 :data (buffer-string))))))
 909     (when face
 910       (set-glyph-face glyph face))
 911     glyph))
 912
 913 (defun gnus-xmas-put-image (glyph &optional string)
 914   "Insert STRING, but display GLYPH.
 915 Warning: Don't insert text immediately after the image."
 916   (let ((begin (point))
 917         extent)
 918     (if (and (bobp) (not string))
 919         (setq string " "))
 920     (if string
 921         (insert string)
 922       (setq begin (1- begin)))
 923     (setq extent (make-extent begin (point)))
 924     (set-extent-property extent 'gnus-image t)
 925     (set-extent-property extent 'duplicable t)
 926     (if string
 927         (set-extent-property extent 'invisible t))
 928     (set-extent-property extent 'end-glyph glyph))
 929   glyph)
 930
 931 (defun gnus-xmas-remove-image (image)
 932   (map-extents
 933    (lambda (ext unused)
 934      (when (equal (extent-end-glyph ext) image)
 935        (set-extent-property ext 'invisible nil)
 936        (set-extent-property ext 'end-glyph nil))
 937      nil)
 938    nil nil nil nil nil 'gnus-image))
 939
 940 (defun gnus-xmas-completing-read (prompt table &optional
 941                                          predicate require-match history)
 942   (when (and history
 943              (not (boundp history)))
 944     (set history nil))
 945   (completing-read
 946    (if (symbol-value history)
 947        (concat prompt " (" (car (symbol-value history)) "): ")
 948      (concat prompt ": "))
 949    table
 950    predicate
 951    require-match
 952    nil
 953    history))
 954
 955 (provide 'gnus-xmas)
 956
 957 ;;; gnus-xmas.el ends here