git.chise.org Git - elisp/gnus.git-/blob - lisp/mail-source.el

   1 ;;; mail-source.el --- functions for fetching mail
   2 ;; Copyright (C) 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news, mail
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl)
  30   (require 'imap)
  31   (eval-when-compile (defvar display-time-mail-function)))
  32 (eval-and-compile
  33   (autoload 'pop3-movemail "pop3")
  34   (autoload 'pop3-get-message-count "pop3")
  35   (autoload 'nnheader-cancel-timer "nnheader")
  36   (autoload 'nnheader-run-at-time "nnheader"))
  37 (require 'format-spec)
  38 (require 'mm-util)
  39 (require 'message) ;; for `message-directory'
  40
  41 (defgroup mail-source nil
  42   "The mail-fetching library."
  43   :version "21.1"
  44   :group 'gnus)
  45
  46 ;; Define these at compile time to avoid dragging in imap always.
  47 (defconst mail-source-imap-authenticators
  48   (eval-when-compile
  49     (mapcar (lambda (a)
  50               (list 'const (car a)))
  51      imap-authenticator-alist)))
  52 (defconst mail-source-imap-streams
  53   (eval-when-compile
  54     (mapcar (lambda (a)
  55               (list 'const (car a)))
  56      imap-stream-alist)))
  57
  58 (defcustom mail-sources nil
  59   "*Where the mail backends will look for incoming mail.
  60 This variable is a list of mail source specifiers.
  61 See Info node `(gnus)Mail Source Specifiers'."
  62   :group 'mail-source
  63   :type `(repeat
  64           (choice :format "%[Value Menu%] %v"
  65                   :value (file)
  66                   (cons :tag "Spool file"
  67                         (const :format "" file)
  68                         (checklist :tag "Options" :greedy t
  69                                    (group :inline t
  70                                           (const :format "" :value :path)
  71                                           file)))
  72                   (cons :tag "Several files in a directory"
  73                         (const :format "" directory)
  74                         (checklist :tag "Options" :greedy t
  75                                    (group :inline t
  76                                           (const :format "" :value :path)
  77                                           (directory :tag "Path"))
  78                                    (group :inline t
  79                                           (const :format "" :value :suffix)
  80                                           (string :tag "Suffix"))
  81                                    (group :inline t
  82                                           (const :format "" :value :predicate)
  83                                           (function :tag "Predicate"))
  84                                    (group :inline t
  85                                           (const :format "" :value :prescript)
  86                                           (string :tag "Prescript"))
  87                                    (group :inline t
  88                                           (const :format "" :value :postscript)
  89                                           (string :tag "Postscript"))
  90                                    (group :inline t
  91                                           (const :format "" :value :plugged)
  92                                           (boolean :tag "Plugged"))))
  93                   (cons :tag "POP3 server"
  94                         (const :format "" pop)
  95                         (checklist :tag "Options" :greedy t
  96                                    (group :inline t
  97                                           (const :format "" :value :server)
  98                                           (string :tag "Server"))
  99                                    (group :inline t
 100                                           (const :format "" :value :port)
 101                                           (choice :tag "Port"
 102                                                   :value "pop3"
 103                                                   (number :format "%v")
 104                                                   (string :format "%v")))
 105                                    (group :inline t
 106                                           (const :format "" :value :user)
 107                                           (string :tag "User"))
 108                                    (group :inline t
 109                                           (const :format "" :value :password)
 110                                           (string :tag "Password"))
 111                                    (group :inline t
 112                                           (const :format "" :value :program)
 113                                           (string :tag "Program"))
 114                                    (group :inline t
 115                                           (const :format "" :value :prescript)
 116                                           (string :tag "Prescript"))
 117                                    (group :inline t
 118                                           (const :format "" :value :postscript)
 119                                           (string :tag "Postscript"))
 120                                    (group :inline t
 121                                           (const :format "" :value :function)
 122                                           (function :tag "Function"))
 123                                    (group :inline t
 124                                           (const :format ""
 125                                                  :value :authentication)
 126                                           (choice :tag "Authentication"
 127                                                   :value apop
 128                                                   (const password)
 129                                                   (const apop)))
 130                                    (group :inline t
 131                                           (const :format "" :value :plugged)
 132                                           (boolean :tag "Plugged"))))
 133                   (cons :tag "Maildir (qmail, postfix...)"
 134                         (const :format "" maildir)
 135                         (checklist :tag "Options" :greedy t
 136                                    (group :inline t
 137                                           (const :format "" :value :path)
 138                                           (directory :tag "Path"))
 139                                    (group :inline t
 140                                           (const :format "" :value :plugged)
 141                                           (boolean :tag "Plugged"))))
 142                   (cons :tag "IMAP server"
 143                         (const :format "" imap)
 144                         (checklist :tag "Options" :greedy t
 145                                    (group :inline t
 146                                           (const :format "" :value :server)
 147                                           (string :tag "Server"))
 148                                    (group :inline t
 149                                           (const :format "" :value :port)
 150                                           (choice :tag "Port"
 151                                                   :value 143
 152                                                   number string))
 153                                    (group :inline t
 154                                           (const :format "" :value :user)
 155                                           (string :tag "User"))
 156                                    (group :inline t
 157                                           (const :format "" :value :password)
 158                                           (string :tag "Password"))
 159                                    (group :inline t
 160                                           (const :format "" :value :stream)
 161                                           (choice :tag "Stream"
 162                                                   :value network
 163                                                   ,@mail-source-imap-streams))
 164                                    (group :inline t
 165                                           (const :format "" :value :program)
 166                                           (string :tag "Program"))
 167                                    (group :inline t
 168                                           (const :format ""
 169                                                  :value :authenticator)
 170                                           (choice :tag "Authenticator"
 171                                                   :value login
 172                                                   ,@mail-source-imap-authenticators))
 173                                    (group :inline t
 174                                           (const :format "" :value :mailbox)
 175                                           (string :tag "Mailbox"
 176                                                   :value "INBOX"))
 177                                    (group :inline t
 178                                           (const :format "" :value :predicate)
 179                                           (string :tag "Predicate"
 180                                                   :value "UNSEEN UNDELETED"))
 181                                    (group :inline t
 182                                           (const :format "" :value :fetchflag)
 183                                           (string :tag "Fetchflag"
 184                                                   :value  "\\Deleted"))
 185                                    (group :inline t
 186                                           (const :format ""
 187                                                  :value :dontexpunge)
 188                                           (boolean :tag "Dontexpunge"))
 189                                    (group :inline t
 190                                           (const :format "" :value :plugged)
 191                                           (boolean :tag "Plugged"))))
 192                   (cons :tag "Webmail server"
 193                         (const :format "" webmail)
 194                         (checklist :tag "Options" :greedy t
 195                                    (group :inline t
 196                                          (const :format "" :value :subtype)
 197                                          ;; Should be generated from
 198                                          ;; `webmail-type-definition', but we
 199                                          ;; can't require webmail without W3.
 200                                          (choice :tag "Subtype"
 201                                                  :value hotmail
 202                                                  (const hotmail)
 203                                                  (const yahoo)
 204                                                  (const netaddress)
 205                                                  (const netscape)
 206                                                  (const my-deja)))
 207                                    (group :inline t
 208                                           (const :format "" :value :user)
 209                                           (string :tag "User"))
 210                                    (group :inline t
 211                                           (const :format "" :value :password)
 212                                           (string :tag "Password"))
 213                                    (group :inline t
 214                                           (const :format ""
 215                                                  :value :dontexpunge)
 216                                           (boolean :tag "Dontexpunge"))
 217                                    (group :inline t
 218                                           (const :format "" :value :plugged)
 219                                           (boolean :tag "Plugged")))))))
 220
 221 (defcustom mail-source-primary-source nil
 222   "*Primary source for incoming mail.
 223 If non-nil, this maildrop will be checked periodically for new mail."
 224   :group 'mail-source
 225   :type 'sexp)
 226
 227 (defcustom mail-source-flash t
 228   "*If non-nil, flash periodically when mail is available."
 229   :group 'mail-source
 230   :type 'boolean)
 231
 232 (defcustom mail-source-crash-box "~/.emacs-mail-crash-box"
 233   "File where mail will be stored while processing it."
 234   :group 'mail-source
 235   :type 'file)
 236
 237 (defcustom mail-source-directory message-directory
 238   "Directory where files (if any) will be stored."
 239   :group 'mail-source
 240   :type 'directory)
 241
 242 (defcustom mail-source-default-file-modes 384
 243   "Set the mode bits of all new mail files to this integer."
 244   :group 'mail-source
 245   :type 'integer)
 246
 247 (defcustom mail-source-delete-incoming nil
 248   "*If non-nil, delete incoming files after handling."
 249   :group 'mail-source
 250   :type 'boolean)
 251
 252 (defcustom mail-source-incoming-file-prefix "Incoming"
 253   "Prefix for file name for storing incoming mail"
 254   :group 'mail-source
 255   :type 'string)
 256
 257 (defcustom mail-source-report-new-mail-interval 5
 258   "Interval in minutes between checks for new mail."
 259   :group 'mail-source
 260   :type 'number)
 261
 262 (defcustom mail-source-idle-time-delay 5
 263   "Number of idle seconds to wait before checking for new mail."
 264   :group 'mail-source
 265   :type 'number)
 266
 267 (defcustom mail-source-movemail-program nil
 268   "If non-nil, name of program for fetching new mail."
 269   :group 'mail-source
 270   :type '(choice (const nil) string))
 271
 272 ;;; Internal variables.
 273
 274 (defvar mail-source-string ""
 275   "A dynamically bound string that says what the current mail source is.")
 276
 277 (defvar mail-source-new-mail-available nil
 278   "Flag indicating when new mail is available.")
 279
 280 (eval-and-compile
 281   (defvar mail-source-common-keyword-map
 282     '((:plugged))
 283     "Mapping from keywords to default values.
 284 Common keywords should be listed here.")
 285
 286   (defvar mail-source-keyword-map
 287     '((file
 288        (:prescript)
 289        (:prescript-delay)
 290        (:postscript)
 291        (:path (or (getenv "MAIL")
 292                   (expand-file-name (user-login-name) rmail-spool-directory))))
 293       (directory
 294        (:prescript)
 295        (:prescript-delay)
 296        (:postscript)
 297        (:path)
 298        (:suffix ".spool")
 299        (:predicate identity))
 300       (pop
 301        (:prescript)
 302        (:prescript-delay)
 303        (:postscript)
 304        (:server (getenv "MAILHOST"))
 305        (:port 110)
 306        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 307        (:program)
 308        (:function)
 309        (:password)
 310        (:authentication password))
 311       (maildir
 312        (:path (or (getenv "MAILDIR") "~/Maildir/"))
 313        (:subdirs ("new" "cur"))
 314        (:function))
 315       (imap
 316        (:server (getenv "MAILHOST"))
 317        (:port)
 318        (:stream)
 319        (:program)
 320        (:authentication)
 321        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 322        (:password)
 323        (:mailbox "INBOX")
 324        (:predicate "UNSEEN UNDELETED")
 325        (:fetchflag "\\Deleted")
 326        (:dontexpunge))
 327       (webmail
 328        (:subtype hotmail)
 329        (:user (or (user-login-name) (getenv "LOGNAME") (getenv "USER")))
 330        (:password)
 331        (:dontexpunge)
 332        (:authentication password)))
 333     "Mapping from keywords to default values.
 334 All keywords that can be used must be listed here."))
 335
 336 (defvar mail-source-fetcher-alist
 337   '((file mail-source-fetch-file)
 338     (directory mail-source-fetch-directory)
 339     (pop mail-source-fetch-pop)
 340     (maildir mail-source-fetch-maildir)
 341     (imap mail-source-fetch-imap)
 342     (webmail mail-source-fetch-webmail))
 343   "A mapping from source type to fetcher function.")
 344
 345 (defvar mail-source-password-cache nil)
 346
 347 (defvar mail-source-plugged t)
 348
 349 ;;; Functions
 350
 351 (eval-and-compile
 352   (defun mail-source-strip-keyword (keyword)
 353     "Strip the leading colon off the KEYWORD."
 354     (intern (substring (symbol-name keyword) 1))))
 355
 356 (eval-and-compile
 357   (defun mail-source-bind-1 (type)
 358     (let* ((defaults (cdr (assq type mail-source-keyword-map)))
 359            default bind)
 360       (while (setq default (pop defaults))
 361         (push (list (mail-source-strip-keyword (car default))
 362                     nil)
 363               bind))
 364       bind)))
 365
 366 (defmacro mail-source-bind (type-source &rest body)
 367   "Return a `let' form that binds all variables in source TYPE.
 368 TYPE-SOURCE is a list where the first element is the TYPE, and
 369 the second variable is the SOURCE.
 370 At run time, the mail source specifier SOURCE will be inspected,
 371 and the variables will be set according to it.  Variables not
 372 specified will be given default values.
 373
 374 After this is done, BODY will be executed in the scope
 375 of the `let' form.
 376
 377 The variables bound and their default values are described by
 378 the `mail-source-keyword-map' variable."
 379   `(let ,(mail-source-bind-1 (car type-source))
 380      (mail-source-set-1 ,(cadr type-source))
 381      ,@body))
 382
 383 (put 'mail-source-bind 'lisp-indent-function 1)
 384 (put 'mail-source-bind 'edebug-form-spec '(sexp body))
 385
 386 (defun mail-source-set-1 (source)
 387   (let* ((type (pop source))
 388          (defaults (cdr (assq type mail-source-keyword-map)))
 389          default value keyword)
 390     (while (setq default (pop defaults))
 391       (set (mail-source-strip-keyword (setq keyword (car default)))
 392            (if (setq value (plist-get source keyword))
 393                (mail-source-value value)
 394              (mail-source-value (cadr default)))))))
 395
 396 (eval-and-compile
 397   (defun mail-source-bind-common-1 ()
 398     (let* ((defaults mail-source-common-keyword-map)
 399            default bind)
 400       (while (setq default (pop defaults))
 401         (push (list (mail-source-strip-keyword (car default))
 402                     nil)
 403               bind))
 404       bind)))
 405
 406 (defun mail-source-set-common-1 (source)
 407   (let* ((type (pop source))
 408          (defaults mail-source-common-keyword-map)
 409          (defaults-1 (cdr (assq type mail-source-keyword-map)))
 410          default value keyword)
 411     (while (setq default (pop defaults))
 412       (set (mail-source-strip-keyword (setq keyword (car default)))
 413            (if (setq value (plist-get source keyword))
 414                (mail-source-value value)
 415              (if (setq value (assq  keyword defaults-1))
 416                  (mail-source-value (cadr value))
 417                (mail-source-value (cadr default))))))))
 418
 419 (defmacro mail-source-bind-common (source &rest body)
 420   "Return a `let' form that binds all common variables.
 421 See `mail-source-bind'."
 422   `(let ,(mail-source-bind-common-1)
 423      (mail-source-set-common-1 source)
 424      ,@body))
 425
 426 (put 'mail-source-bind-common 'lisp-indent-function 1)
 427 (put 'mail-source-bind-common 'edebug-form-spec '(sexp body))
 428
 429 (defun mail-source-value (value)
 430   "Return the value of VALUE."
 431   (cond
 432    ;; String
 433    ((stringp value)
 434     value)
 435    ;; Function
 436    ((and (listp value)
 437          (functionp (car value)))
 438     (eval value))
 439    ;; Just return the value.
 440    (t
 441     value)))
 442
 443 (defun mail-source-fetch (source callback)
 444   "Fetch mail from SOURCE and call CALLBACK zero or more times.
 445 CALLBACK will be called with the name of the file where (some of)
 446 the mail from SOURCE is put.
 447 Return the number of files that were found."
 448   (mail-source-bind-common source
 449     (if (or mail-source-plugged plugged)
 450         (save-excursion
 451           (let ((function (cadr (assq (car source) mail-source-fetcher-alist)))
 452                 (found 0))
 453             (unless function
 454               (error "%S is an invalid mail source specification" source))
 455             ;; If there's anything in the crash box, we do it first.
 456             (when (file-exists-p mail-source-crash-box)
 457               (message "Processing mail from %s..." mail-source-crash-box)
 458               (setq found (mail-source-callback
 459                            callback mail-source-crash-box)))
 460             (+ found
 461                (if (or debug-on-quit debug-on-error)
 462                    (funcall function source callback)
 463                  (condition-case err
 464                      (funcall function source callback)
 465                    (error
 466                     (unless (yes-or-no-p
 467                              (format "Mail source %s error (%s).  Continue? "
 468                                      source
 469                                      (cadr err)))
 470                       (error "Cannot get new mail"))
 471                     0)))))))))
 472
 473 (eval-and-compile
 474   (if (fboundp 'make-temp-file)
 475       (defalias 'mail-source-make-complex-temp-name 'make-temp-file)
 476     (defun mail-source-make-complex-temp-name (prefix)
 477       (let ((newname (make-temp-name prefix))
 478             (newprefix prefix))
 479         (while (file-exists-p newname)
 480           (setq newprefix (concat newprefix "x"))
 481           (setq newname (make-temp-name newprefix)))
 482         newname))))
 483
 484 (defun mail-source-callback (callback info)
 485   "Call CALLBACK on the mail file, and then remove the mail file.
 486 Pass INFO on to CALLBACK."
 487   (if (or (not (file-exists-p mail-source-crash-box))
 488           (zerop (nth 7 (file-attributes mail-source-crash-box))))
 489       (progn
 490         (when (file-exists-p mail-source-crash-box)
 491           (delete-file mail-source-crash-box))
 492         0)
 493     (prog1
 494         (funcall callback mail-source-crash-box info)
 495       (when (file-exists-p mail-source-crash-box)
 496         ;; Delete or move the incoming mail out of the way.
 497         (if mail-source-delete-incoming
 498             (delete-file mail-source-crash-box)
 499           (let ((incoming
 500                  (mail-source-make-complex-temp-name
 501                   (expand-file-name
 502                    mail-source-incoming-file-prefix
 503                    mail-source-directory))))
 504             (unless (file-exists-p (file-name-directory incoming))
 505               (make-directory (file-name-directory incoming) t))
 506             (rename-file mail-source-crash-box incoming t)))))))
 507
 508 (defun mail-source-movemail (from to)
 509   "Move FROM to TO using movemail."
 510   (if (not (file-writable-p to))
 511       (error "Can't write to crash box %s.  Not moving mail" to)
 512     (let ((to (file-truename (expand-file-name to)))
 513           errors result)
 514       (setq to (file-truename to)
 515             from (file-truename from))
 516       ;; Set TO if have not already done so, and rename or copy
 517       ;; the file FROM to TO if and as appropriate.
 518       (cond
 519        ((file-exists-p to)
 520         ;; The crash box exists already.
 521         t)
 522        ((not (file-exists-p from))
 523         ;; There is no inbox.
 524         (setq to nil))
 525        ((zerop (nth 7 (file-attributes from)))
 526         ;; Empty file.
 527         (setq to nil))
 528        (t
 529         ;; If getting from mail spool directory, use movemail to move
 530         ;; rather than just renaming, so as to interlock with the
 531         ;; mailer.
 532         (unwind-protect
 533             (save-excursion
 534               (setq errors (generate-new-buffer " *mail source loss*"))
 535               (let ((default-directory "/"))
 536                 (setq result
 537                       (apply
 538                        'call-process
 539                        (append
 540                         (list
 541                          (or mail-source-movemail-program
 542                              (expand-file-name "movemail" exec-directory))
 543                          nil errors nil from to)))))
 544               (when (file-exists-p to)
 545                 (set-file-modes to mail-source-default-file-modes))
 546               (if (and (or (not (buffer-modified-p errors))
 547                            (zerop (buffer-size errors)))
 548                        (zerop result))
 549                   ;; No output => movemail won.
 550                   t
 551                 (set-buffer errors)
 552                 ;; There may be a warning about older revisions.  We
 553                 ;; ignore that.
 554                 (goto-char (point-min))
 555                 (if (search-forward "older revision" nil t)
 556                     t
 557                   ;; Probably a real error.
 558                   (subst-char-in-region (point-min) (point-max) ?\n ?\  )
 559                   (goto-char (point-max))
 560                   (skip-chars-backward " \t")
 561                   (delete-region (point) (point-max))
 562                   (goto-char (point-min))
 563                   (when (looking-at "movemail: ")
 564                     (delete-region (point-min) (match-end 0)))
 565                   ;; Result may be a signal description string.
 566                   (unless (yes-or-no-p
 567                            (format "movemail: %s (%s return).  Continue? "
 568                                    (buffer-string) result))
 569                     (error "%s" (buffer-string)))
 570                   (setq to nil)))))))
 571       (when (and errors
 572                  (buffer-name errors))
 573         (kill-buffer errors))
 574       ;; Return whether we moved successfully or not.
 575       to)))
 576
 577 (defun mail-source-movemail-and-remove (from to)
 578   "Move FROM to TO using movemail, then remove FROM if empty."
 579   (or (not (mail-source-movemail from to))
 580       (not (zerop (nth 7 (file-attributes from))))
 581       (delete-file from)))
 582
 583 (defvar mail-source-read-passwd nil)
 584 (defun mail-source-read-passwd (prompt &rest args)
 585   "Read a password using PROMPT.
 586 If ARGS, PROMPT is used as an argument to `format'."
 587   (let ((prompt
 588          (if args
 589              (apply 'format prompt args)
 590            prompt)))
 591     (unless mail-source-read-passwd
 592       (if (or (fboundp 'read-passwd) (load "passwd" t))
 593           (setq mail-source-read-passwd 'read-passwd)
 594         (unless (fboundp 'ange-ftp-read-passwd)
 595           (autoload 'ange-ftp-read-passwd "ange-ftp"))
 596         (setq mail-source-read-passwd 'ange-ftp-read-passwd)))
 597     (funcall mail-source-read-passwd prompt)))
 598
 599 (defun mail-source-fetch-with-program (program)
 600   (zerop (call-process shell-file-name nil nil nil
 601                        shell-command-switch program)))
 602
 603 (defun mail-source-run-script (script spec &optional delay)
 604   (when script
 605     (if (and (symbolp script) (fboundp script))
 606         (funcall script)
 607       (mail-source-call-script
 608        (format-spec script spec))))
 609   (when delay
 610     (sleep-for delay)))
 611
 612 (defun mail-source-call-script (script)
 613   (let ((background nil))
 614     (when (string-match "& *$" script)
 615       (setq script (substring script 0 (match-beginning 0))
 616             background 0))
 617     (call-process shell-file-name nil background nil
 618                   shell-command-switch script)))
 619
 620 ;;;
 621 ;;; Different fetchers
 622 ;;;
 623
 624 (defun mail-source-fetch-file (source callback)
 625   "Fetcher for single-file sources."
 626   (mail-source-bind (file source)
 627     (mail-source-run-script
 628      prescript (format-spec-make ?t mail-source-crash-box)
 629      prescript-delay)
 630     (let ((mail-source-string (format "file:%s" path)))
 631       (if (mail-source-movemail path mail-source-crash-box)
 632           (prog1
 633               (mail-source-callback callback path)
 634             (mail-source-run-script
 635              postscript (format-spec-make ?t mail-source-crash-box)))
 636         0))))
 637
 638 (defun mail-source-fetch-directory (source callback)
 639   "Fetcher for directory sources."
 640   (mail-source-bind (directory source)
 641     (mail-source-run-script
 642      prescript (format-spec-make ?t path)
 643      prescript-delay)
 644     (let ((found 0)
 645           (mail-source-string (format "directory:%s" path)))
 646       (dolist (file (directory-files
 647                      path t (concat (regexp-quote suffix) "$")))
 648         (when (and (file-regular-p file)
 649                    (funcall predicate file)
 650                    (mail-source-movemail file mail-source-crash-box))
 651           (incf found (mail-source-callback callback file))))
 652       (mail-source-run-script
 653        postscript (format-spec-make ?t path))
 654       found)))
 655
 656 (defun mail-source-fetch-pop (source callback)
 657   "Fetcher for single-file sources."
 658   (mail-source-bind (pop source)
 659     (mail-source-run-script
 660      prescript
 661      (format-spec-make ?p password ?t mail-source-crash-box
 662                        ?s server ?P port ?u user)
 663      prescript-delay)
 664     (let ((from (format "%s:%s:%s" server user port))
 665           (mail-source-string (format "pop:%s@%s" user server))
 666           result)
 667       (when (eq authentication 'password)
 668         (setq password
 669               (or password
 670                   (cdr (assoc from mail-source-password-cache))
 671                   (mail-source-read-passwd
 672                    (format "Password for %s at %s: " user server)))))
 673       (when server
 674         (setenv "MAILHOST" server))
 675       (setq result
 676             (cond
 677              (program
 678               (mail-source-fetch-with-program
 679                (format-spec
 680                 program
 681                 (format-spec-make ?p password ?t mail-source-crash-box
 682                                   ?s server ?P port ?u user))))
 683              (function
 684               (funcall function mail-source-crash-box))
 685              ;; The default is to use pop3.el.
 686              (t
 687               (let ((pop3-password password)
 688                     (pop3-maildrop user)
 689                     (pop3-mailhost server)
 690                     (pop3-port port)
 691                     (pop3-authentication-scheme
 692                      (if (eq authentication 'apop) 'apop 'pass)))
 693                 (if (or debug-on-quit debug-on-error)
 694                     (save-excursion (pop3-movemail mail-source-crash-box))
 695                   (condition-case err
 696                       (save-excursion (pop3-movemail mail-source-crash-box))
 697                     (error
 698                      ;; We nix out the password in case the error
 699                      ;; was because of a wrong password being given.
 700                      (setq mail-source-password-cache
 701                            (delq (assoc from mail-source-password-cache)
 702                                  mail-source-password-cache))
 703                      (signal (car err) (cdr err)))))))))
 704       (if result
 705           (progn
 706             (when (eq authentication 'password)
 707               (unless (assoc from mail-source-password-cache)
 708                 (push (cons from password) mail-source-password-cache)))
 709             (prog1
 710                 (mail-source-callback callback server)
 711               ;; Update display-time's mail flag, if relevant.
 712               (if (equal source mail-source-primary-source)
 713                   (setq mail-source-new-mail-available nil))
 714               (mail-source-run-script
 715                postscript
 716                (format-spec-make ?p password ?t mail-source-crash-box
 717                                  ?s server ?P port ?u user))))
 718         ;; We nix out the password in case the error
 719         ;; was because of a wrong password being given.
 720         (setq mail-source-password-cache
 721               (delq (assoc from mail-source-password-cache)
 722                     mail-source-password-cache))
 723         0))))
 724
 725 (defun mail-source-check-pop (source)
 726   "Check whether there is new mail."
 727   (mail-source-bind (pop source)
 728     (let ((from (format "%s:%s:%s" server user port))
 729           (mail-source-string (format "pop:%s@%s" user server))
 730           result)
 731       (when (eq authentication 'password)
 732         (setq password
 733               (or password
 734                   (cdr (assoc from mail-source-password-cache))
 735                   (mail-source-read-passwd
 736                    (format "Password for %s at %s: " user server))))
 737         (unless (assoc from mail-source-password-cache)
 738           (push (cons from password) mail-source-password-cache)))
 739       (when server
 740         (setenv "MAILHOST" server))
 741       (setq result
 742             (cond
 743              ;; No easy way to check whether mail is waiting for these.
 744              (program)
 745              (function)
 746              ;; The default is to use pop3.el.
 747              (t
 748               (let ((pop3-password password)
 749                     (pop3-maildrop user)
 750                     (pop3-mailhost server)
 751                     (pop3-port port)
 752                     (pop3-authentication-scheme
 753                      (if (eq authentication 'apop) 'apop 'pass)))
 754                 (if (or debug-on-quit debug-on-error)
 755                     (save-excursion (pop3-get-message-count))
 756                   (condition-case err
 757                       (save-excursion (pop3-get-message-count))
 758                     (error
 759                      ;; We nix out the password in case the error
 760                      ;; was because of a wrong password being given.
 761                      (setq mail-source-password-cache
 762                            (delq (assoc from mail-source-password-cache)
 763                                  mail-source-password-cache))
 764                      (signal (car err) (cdr err)))))))))
 765       (if result
 766           ;; Inform display-time that we have new mail.
 767           (setq mail-source-new-mail-available (> result 0))
 768         ;; We nix out the password in case the error
 769         ;; was because of a wrong password being given.
 770         (setq mail-source-password-cache
 771               (delq (assoc from mail-source-password-cache)
 772                     mail-source-password-cache)))
 773       result)))
 774
 775 (defun mail-source-new-mail-p ()
 776   "Handler for `display-time' to indicate when new mail is available."
 777   ;; Flash (ie. ring the visible bell) if mail is available.
 778   (if (and mail-source-flash mail-source-new-mail-available)
 779       (let ((visible-bell t))
 780         (ding)))
 781   ;; Only report flag setting; flag is updated on a different schedule.
 782   mail-source-new-mail-available)
 783
 784
 785 (defvar mail-source-report-new-mail nil)
 786 (defvar mail-source-report-new-mail-timer nil)
 787 (defvar mail-source-report-new-mail-idle-timer nil)
 788
 789 (eval-when-compile
 790   (if (featurep 'xemacs)
 791       (require 'itimer)
 792     (require 'timer)))
 793
 794 (defun mail-source-start-idle-timer ()
 795   ;; Start our idle timer if necessary, so we delay the check until the
 796   ;; user isn't typing.
 797   (unless mail-source-report-new-mail-idle-timer
 798     (setq mail-source-report-new-mail-idle-timer
 799           (run-with-idle-timer
 800            mail-source-idle-time-delay
 801            nil
 802            (lambda ()
 803              (unwind-protect
 804                  (mail-source-check-pop mail-source-primary-source)
 805                (setq mail-source-report-new-mail-idle-timer nil)))))
 806     ;; Since idle timers created when Emacs is already in the idle
 807     ;; state don't get activated until Emacs _next_ becomes idle, we
 808     ;; need to force our timer to be considered active now.  We do
 809     ;; this by being naughty and poking the timer internals directly
 810     ;; (element 0 of the vector is nil if the timer is active).
 811     (aset mail-source-report-new-mail-idle-timer 0 nil)))
 812
 813 (defun mail-source-report-new-mail (arg)
 814   "Toggle whether to report when new mail is available.
 815 This only works when `display-time' is enabled."
 816   (interactive "P")
 817   (if (not mail-source-primary-source)
 818       (error "Need to set `mail-source-primary-source' to check for new mail"))
 819   (let ((on (if (null arg)
 820                 (not mail-source-report-new-mail)
 821               (> (prefix-numeric-value arg) 0))))
 822     (setq mail-source-report-new-mail on)
 823     (and mail-source-report-new-mail-timer
 824          (nnheader-cancel-timer mail-source-report-new-mail-timer))
 825     (and mail-source-report-new-mail-idle-timer
 826          (nnheader-cancel-timer mail-source-report-new-mail-idle-timer))
 827     (setq mail-source-report-new-mail-timer nil)
 828     (setq mail-source-report-new-mail-idle-timer nil)
 829     (if on
 830         (progn
 831           (require 'time)
 832           ;; display-time-mail-function is an Emacs 21 feature.
 833           (setq display-time-mail-function #'mail-source-new-mail-p)
 834           ;; Set up the main timer.
 835           (setq mail-source-report-new-mail-timer
 836                 (nnheader-run-at-time
 837                  (* 60 mail-source-report-new-mail-interval)
 838                  (* 60 mail-source-report-new-mail-interval)
 839                  #'mail-source-start-idle-timer))
 840           ;; When you get new mail, clear "Mail" from the mode line.
 841           (add-hook 'nnmail-post-get-new-mail-hook
 842                     'display-time-event-handler)
 843           (message "Mail check enabled"))
 844       (setq display-time-mail-function nil)
 845       (remove-hook 'nnmail-post-get-new-mail-hook
 846                    'display-time-event-handler)
 847       (message "Mail check disabled"))))
 848
 849 (defun mail-source-fetch-maildir (source callback)
 850   "Fetcher for maildir sources."
 851   (mail-source-bind (maildir source)
 852     (let ((found 0)
 853           mail-source-string)
 854       (unless (string-match "/$" path)
 855         (setq path (concat path "/")))
 856       (dolist (subdir subdirs)
 857         (when (file-directory-p (concat path subdir))
 858           (setq mail-source-string (format "maildir:%s%s" path subdir))
 859           (dolist (file (directory-files (concat path subdir) t))
 860             (when (and (not (file-directory-p file))
 861                        (not (if function
 862                                 (funcall function file mail-source-crash-box)
 863                               (let ((coding-system-for-write
 864                                      mm-text-coding-system)
 865                                     (coding-system-for-read
 866                                      mm-text-coding-system))
 867                                 (with-temp-file mail-source-crash-box
 868                                   (insert-file-contents file)
 869                                   (goto-char (point-min))
 870 ;;;                               ;; Unix mail format
 871 ;;;                               (unless (looking-at "\n*From ")
 872 ;;;                                 (insert "From maildir "
 873 ;;;                                         (current-time-string) "\n"))
 874 ;;;                               (while (re-search-forward "^From " nil t)
 875 ;;;                                 (replace-match ">From "))
 876 ;;;                               (goto-char (point-max))
 877 ;;;                               (insert "\n\n")
 878                                   ;; MMDF mail format
 879                                   (insert "\001\001\001\001\n"))
 880                                 (delete-file file)))))
 881               (incf found (mail-source-callback callback file))))))
 882       found)))
 883
 884 (eval-and-compile
 885   (autoload 'imap-open "imap")
 886   (autoload 'imap-authenticate "imap")
 887   (autoload 'imap-mailbox-select "imap")
 888   (autoload 'imap-mailbox-unselect "imap")
 889   (autoload 'imap-mailbox-close "imap")
 890   (autoload 'imap-search "imap")
 891   (autoload 'imap-fetch "imap")
 892   (autoload 'imap-close "imap")
 893   (autoload 'imap-error-text "imap")
 894   (autoload 'imap-message-flags-add "imap")
 895   (autoload 'imap-list-to-message-set "imap")
 896   (autoload 'imap-range-to-message-set "imap")
 897   (autoload 'nnheader-ms-strip-cr "nnheader"))
 898
 899 (defvar mail-source-imap-file-coding-system 'binary
 900   "Coding system for the crashbox made by `mail-source-fetch-imap'.")
 901
 902 (defun mail-source-fetch-imap (source callback)
 903   "Fetcher for imap sources."
 904   (mail-source-bind (imap source)
 905     (let ((from (format "%s:%s:%s" server user port))
 906           (found 0)
 907           (buf (get-buffer-create (generate-new-buffer-name " *imap source*")))
 908           (mail-source-string (format "imap:%s:%s" server mailbox))
 909           (imap-shell-program (or (list program) imap-shell-program))
 910           remove)
 911       (if (and (imap-open server port stream authentication buf)
 912                (imap-authenticate
 913                 user (or (cdr (assoc from mail-source-password-cache))
 914                          password) buf)
 915                (imap-mailbox-select mailbox nil buf))
 916           (let ((coding-system-for-write mail-source-imap-file-coding-system)
 917                 str)
 918             (with-temp-file mail-source-crash-box
 919               ;; Avoid converting 8-bit chars from inserted strings to
 920               ;; multibyte.
 921               (mm-disable-multibyte)
 922               ;; remember password
 923               (with-current-buffer buf
 924                 (when (or imap-password
 925                           (assoc from mail-source-password-cache))
 926                   (push (cons from imap-password) mail-source-password-cache)))
 927               ;; if predicate is nil, use all uids
 928               (dolist (uid (imap-search (or predicate "1:*") buf))
 929                 (when (setq str
 930                             (if (imap-capability 'IMAP4rev1 buf)
 931                                 (caddar (imap-fetch uid "BODY.PEEK[]"
 932                                                     'BODYDETAIL nil buf))
 933                               (imap-fetch uid "RFC822.PEEK" 'RFC822 nil buf)))
 934                   (push uid remove)
 935                   (insert "From imap " (current-time-string) "\n")
 936                   (save-excursion
 937                     (insert str "\n\n"))
 938                   (while (re-search-forward "^From " nil t)
 939                     (replace-match ">From "))
 940                   (goto-char (point-max))))
 941               (nnheader-ms-strip-cr))
 942             (incf found (mail-source-callback callback server))
 943             (when (and remove fetchflag)
 944               (imap-message-flags-add
 945                (imap-range-to-message-set (gnus-compress-sequence remove))
 946                fetchflag nil buf))
 947             (if dontexpunge
 948                 (imap-mailbox-unselect buf)
 949               (imap-mailbox-close nil buf))
 950             (imap-close buf))
 951         (imap-close buf)
 952         ;; We nix out the password in case the error
 953         ;; was because of a wrong password being given.
 954         (setq mail-source-password-cache
 955               (delq (assoc from mail-source-password-cache)
 956                     mail-source-password-cache))
 957         (error (imap-error-text buf)))
 958       (kill-buffer buf)
 959       found)))
 960
 961 (eval-and-compile
 962   (autoload 'webmail-fetch "webmail"))
 963
 964 (defun mail-source-fetch-webmail (source callback)
 965   "Fetch for webmail source."
 966   (mail-source-bind (webmail source)
 967     (let ((mail-source-string (format "webmail:%s:%s" subtype user))
 968           (webmail-newmail-only dontexpunge)
 969           (webmail-move-to-trash-can (not dontexpunge)))
 970       (when (eq authentication 'password)
 971         (setq password
 972               (or password
 973                   (cdr (assoc (format "webmail:%s:%s" subtype user)
 974                               mail-source-password-cache))
 975                   (mail-source-read-passwd
 976                    (format "Password for %s at %s: " user subtype))))
 977         (when (and password
 978                    (not (assoc (format "webmail:%s:%s" subtype user)
 979                                mail-source-password-cache)))
 980           (push (cons (format "webmail:%s:%s" subtype user) password)
 981                 mail-source-password-cache)))
 982       (webmail-fetch mail-source-crash-box subtype user password)
 983       (mail-source-callback callback (symbol-name subtype)))))
 984
 985 (provide 'mail-source)
 986
 987 ;;; mail-source.el ends here