git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'mail-parse)
  28 (require 'mailcap)
  29 (require 'mm-bodies)
  30
  31 ;;; Convenience macros.
  32
  33 (defmacro mm-handle-buffer (handle)
  34   `(nth 0 ,handle))
  35 (defmacro mm-handle-type (handle)
  36   `(nth 1 ,handle))
  37 (defmacro mm-handle-encoding (handle)
  38   `(nth 2 ,handle))
  39 (defmacro mm-handle-undisplayer (handle)
  40   `(nth 3 ,handle))
  41 (defmacro mm-handle-set-undisplayer (handle function)
  42   `(setcar (nthcdr 3 ,handle) ,function))
  43 (defmacro mm-handle-disposition (handle)
  44   `(nth 4 ,handle))
  45 (defmacro mm-handle-description (handle)
  46   `(nth 5 ,handle))
  47 (defmacro mm-handle-cache (handle)
  48   `(nth 6 ,handle))
  49 (defmacro mm-handle-set-cache (handle contents)
  50   `(setcar (nthcdr 6 ,handle) ,contents))
  51 (defmacro mm-handle-id (handle)
  52   `(nth 7 ,handle))
  53 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
  54                                     disposition description cache
  55                                     id)
  56   `(list ,buffer ,type ,encoding ,undisplayer
  57          ,disposition ,description ,cache ,id))
  58
  59 (defvar mm-inline-media-tests
  60   '(("image/jpeg" mm-inline-image
  61      (and window-system (featurep 'jpeg) (mm-image-fit-p handle)))
  62     ("image/png" mm-inline-image
  63      (and window-system (featurep 'png) (mm-image-fit-p handle)))
  64     ("image/gif" mm-inline-image
  65      (and window-system (featurep 'gif) (mm-image-fit-p handle)))
  66     ("image/tiff" mm-inline-image
  67      (and window-system (featurep 'tiff) (mm-image-fit-p handle)))
  68     ("image/xbm" mm-inline-image
  69      (and window-system (fboundp 'device-type)
  70           (eq (device-type) 'x)))
  71     ("image/x-xbitmap" mm-inline-image
  72      (and window-system (fboundp 'device-type)
  73           (eq (device-type) 'x)))
  74     ("image/xpm" mm-inline-image
  75      (and window-system (featurep 'xpm)))
  76     ("image/x-pixmap" mm-inline-image
  77      (and window-system (featurep 'xpm)))
  78     ("image/bmp" mm-inline-image
  79      (and window-system (featurep 'bmp)))
  80     ("text/plain" mm-inline-text t)
  81     ("text/enriched" mm-inline-text t)
  82     ("text/richtext" mm-inline-text t)
  83     ("text/html" mm-inline-text (locate-library "w3"))
  84     ("message/delivery-status" mm-inline-text t)
  85     ("text/.*" mm-inline-text t)
  86     ("audio/wav" mm-inline-audio
  87      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  88           (device-sound-enabled-p)))
  89     ("audio/au" mm-inline-audio
  90      (and (or (featurep 'nas-sound) (featurep 'native-sound))
  91           (device-sound-enabled-p)))
  92     ("multipart/alternative" ignore t)
  93     ("multipart/mixed" ignore t)
  94     ("multipart/related" ignore t))
  95   "Alist of media types/test that say whether the media types can be displayed inline.")
  96
  97 (defvar mm-user-display-methods
  98   '(("image/.*" . inline)
  99     ("text/.*" . inline)
 100     ("message/delivery-status" . inline)))
 101
 102 (defvar mm-user-automatic-display
 103   '("text/plain" "text/enriched" "text/richtext" "text/html"
 104     "image/.*" "message/delivery-status" "multipart/.*"))
 105
 106 (defvar mm-user-automatic-external-display nil
 107   "List of MIME type regexps that will be displayed externally automatically.")
 108
 109 (defvar mm-alternative-precedence
 110   '("multipart/related" "multipart/mixed" "multipart/alternative"
 111     "image/jpeg" "image/gif" "text/html" "text/enriched"
 112     "text/richtext" "text/plain")
 113   "List that describes the precedence of alternative parts.")
 114
 115 (defvar mm-tmp-directory
 116   (cond ((fboundp 'temp-directory) (temp-directory))
 117         ((boundp 'temporary-file-directory) temporary-file-directory)
 118         ("/tmp/"))
 119   "Where mm will store its temporary files.")
 120
 121 (defvar mm-all-images-fit nil
 122   "If non-nil, then all images fit in the buffer.")
 123
 124 ;;; Internal variables.
 125
 126 (defvar mm-dissection-list nil)
 127 (defvar mm-last-shell-command "")
 128 (defvar mm-content-id-alist nil)
 129
 130 ;;; The functions.
 131
 132 (defun mm-dissect-buffer (&optional no-strict-mime)
 133   "Dissect the current buffer and return a list of MIME handles."
 134   (save-excursion
 135     (let (ct ctl type subtype cte cd description id result)
 136       (save-restriction
 137         (mail-narrow-to-head)
 138         (when (or no-strict-mime
 139                   (mail-fetch-field "mime-version"))
 140           (setq ct (mail-fetch-field "content-type")
 141                 ctl (condition-case () (mail-header-parse-content-type ct)
 142                       (error nil))
 143                 cte (mail-fetch-field "content-transfer-encoding")
 144                 cd (mail-fetch-field "content-disposition")
 145                 description (mail-fetch-field "content-description")
 146                 id (mail-fetch-field "content-id"))))
 147       (if (or (not ctl)
 148               (not (string-match "/" (car ctl))))
 149           (mm-dissect-singlepart
 150            '("text/plain") nil no-strict-mime
 151            (and cd (condition-case ()
 152                        (mail-header-parse-content-disposition cd)
 153                      (error nil)))
 154            description)
 155         (setq type (split-string (car ctl) "/"))
 156         (setq subtype (cadr type)
 157               type (pop type))
 158         (setq
 159          result
 160          (cond
 161           ((equal type "multipart")
 162            (cons (car ctl) (mm-dissect-multipart ctl)))
 163           (t
 164            (mm-dissect-singlepart
 165             ctl
 166             (and cte (intern (downcase (mail-header-remove-whitespace
 167                                         (mail-header-remove-comments
 168                                          cte)))))
 169             no-strict-mime
 170             (and cd (condition-case ()
 171                         (mail-header-parse-content-disposition cd)
 172                       (error nil)))
 173             description id))))
 174         (when id
 175           (when (string-match " *<\\(.*\\)> *" id)
 176             (setq id (match-string 1 id)))
 177           (push (cons id result) mm-content-id-alist))
 178         result))))
 179
 180 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 181   (when (or force
 182             (not (equal "text/plain" (car ctl))))
 183     (let ((res (mm-make-handle
 184                 (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 185       (push (car res) mm-dissection-list)
 186       res)))
 187
 188 (defun mm-remove-all-parts ()
 189   "Remove all MIME handles."
 190   (interactive)
 191   (mapcar 'mm-remove-part mm-dissection-list)
 192   (setq mm-dissection-list nil))
 193
 194 (defun mm-dissect-multipart (ctl)
 195   (goto-char (point-min))
 196   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 197         (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 198         start parts
 199         (end (save-excursion
 200                (goto-char (point-max))
 201                (if (re-search-backward close-delimiter nil t)
 202                    (match-beginning 0)
 203                  (point-max)))))
 204     (while (search-forward boundary end t)
 205       (goto-char (match-beginning 0))
 206       (when start
 207         (save-excursion
 208           (save-restriction
 209             (narrow-to-region start (point))
 210             (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 211       (forward-line 2)
 212       (setq start (point)))
 213     (when start
 214       (save-excursion
 215         (save-restriction
 216           (narrow-to-region start end)
 217           (setq parts (nconc (list (mm-dissect-buffer t)) parts)))))
 218     (nreverse parts)))
 219
 220 (defun mm-copy-to-buffer ()
 221   "Copy the contents of the current buffer to a fresh buffer."
 222   (save-excursion
 223     (let ((obuf (current-buffer))
 224           beg)
 225       (goto-char (point-min))
 226       (search-forward-regexp "^\n" nil t)
 227       (setq beg (point))
 228       (set-buffer (generate-new-buffer " *mm*"))
 229       (insert-buffer-substring obuf beg)
 230       (current-buffer))))
 231
 232 (defun mm-inlinable-part-p (type)
 233   "Say whether TYPE can be displayed inline."
 234   (eq (mm-user-method type) 'inline))
 235
 236 (defun mm-display-part (handle &optional no-default)
 237   "Display the MIME part represented by HANDLE.
 238 Returns nil if the part is removed; inline if displayed inline;
 239 external if displayed external."
 240   (save-excursion
 241     (mailcap-parse-mailcaps)
 242     (if (mm-handle-displayed-p handle)
 243         (mm-remove-part handle)
 244       (let* ((type (car (mm-handle-type handle)))
 245              (method (mailcap-mime-info type))
 246              (user-method (mm-user-method type)))
 247         (if (eq user-method 'inline)
 248             (progn
 249               (forward-line 1)
 250               (mm-display-inline handle)
 251               'inline)
 252           (when (or user-method
 253                     method
 254                     (not no-default))
 255             (if (and (not user-method)
 256                      (not method)
 257                      (equal "text" (car (split-string type))))
 258                 (progn
 259                   (forward-line 1)
 260                   (mm-insert-inline handle (mm-get-part handle))
 261                   'inline)
 262               (mm-display-external
 263                handle (or user-method method
 264                           'mailcap-save-binary-file))
 265               'external)))))))
 266
 267 (defun mm-display-external (handle method)
 268   "Display HANDLE using METHOD."
 269   (mm-with-unibyte-buffer
 270     (if (functionp method)
 271         (let ((cur (current-buffer)))
 272           (if (eq method 'mailcap-save-binary-file)
 273               (progn
 274                 (set-buffer (generate-new-buffer "*mm*"))
 275                 (setq method nil))
 276             (mm-insert-part handle)
 277             (let ((win (get-buffer-window cur t)))
 278               (when win
 279                 (select-window win)))
 280             (switch-to-buffer (generate-new-buffer "*mm*")))
 281           (buffer-disable-undo)
 282           (mm-set-buffer-file-coding-system mm-binary-coding-system)
 283           (insert-buffer-substring cur)
 284           (message "Viewing with %s" method)
 285           (let ((mm (current-buffer))
 286                 (non-viewer (assoc "non-viewer"
 287                                    (mailcap-mime-info
 288                                     (car (mm-handle-type handle)) t))))
 289             (unwind-protect
 290                 (if method
 291                     (funcall method)
 292                   (mm-save-part handle))
 293               (when (and (not non-viewer)
 294                          method)
 295                 (mm-handle-set-undisplayer handle mm)))))
 296       ;; The function is a string to be executed.
 297       (mm-insert-part handle)
 298       (let* ((dir (make-temp-name (expand-file-name "emm." mm-tmp-directory)))
 299              (filename (mail-content-type-get
 300                         (mm-handle-disposition handle) 'filename))
 301              (needsterm (assoc "needsterm"
 302                                (mailcap-mime-info
 303                                 (car (mm-handle-type handle)) t)))
 304              process file buffer)
 305         ;; We create a private sub-directory where we store our files.
 306         (make-directory dir)
 307         (set-file-modes dir 448)
 308         (if filename
 309             (setq file (expand-file-name (file-name-nondirectory filename)
 310                                          dir))
 311           (setq file (make-temp-name (expand-file-name "mm." dir))))
 312         (write-region (point-min) (point-max) file nil 'nomesg)
 313         (message "Viewing with %s" method)
 314         (unwind-protect
 315             (setq process
 316                   (if needsterm
 317                       (start-process "*display*" nil
 318                                      "xterm"
 319                                      "-e" shell-file-name "-c"
 320                                      (format method
 321                                              (mm-quote-arg file)))
 322                     (start-process "*display*"
 323                                    (setq buffer (generate-new-buffer "*mm*"))
 324                                    shell-file-name
 325                                    "-c" (format method
 326                                                 (mm-quote-arg file)))))
 327           (mm-handle-set-undisplayer handle (cons file buffer)))
 328         (message "Displaying %s..." (format method file))))))
 329
 330 (defun mm-remove-parts (handles)
 331   "Remove the displayed MIME parts represented by HANDLE."
 332   (if (and (listp handles)
 333            (bufferp (car handles)))
 334       (mm-remove-part handles)
 335     (let (handle)
 336       (while (setq handle (pop handles))
 337         (cond
 338          ((stringp handle)
 339           )
 340          ((and (listp handle)
 341                (stringp (car handle)))
 342           (mm-remove-parts (cdr handle)))
 343          (t
 344           (mm-remove-part handle)))))))
 345
 346 (defun mm-destroy-parts (handles)
 347   "Remove the displayed MIME parts represented by HANDLE."
 348   (if (and (listp handles)
 349            (bufferp (car handles)))
 350       (mm-destroy-part handles)
 351     (let (handle)
 352       (while (setq handle (pop handles))
 353         (cond
 354          ((stringp handle)
 355           )
 356          ((and (listp handle)
 357                (stringp (car handle)))
 358           (mm-destroy-parts (cdr handle)))
 359          (t
 360           (mm-destroy-part handle)))))))
 361
 362 (defun mm-remove-part (handle)
 363   "Remove the displayed MIME part represented by HANDLE."
 364   (when (listp handle)
 365     (let ((object (mm-handle-undisplayer handle)))
 366       (condition-case ()
 367           (cond
 368            ;; Internally displayed part.
 369            ((mm-annotationp object)
 370             (delete-annotation object))
 371            ((or (functionp object)
 372                 (and (listp object)
 373                      (eq (car object) 'lambda)))
 374             (funcall object))
 375            ;; Externally displayed part.
 376            ((consp object)
 377             (condition-case ()
 378                 (delete-file (car object))
 379               (error nil))
 380             (condition-case ()
 381                 (delete-directory (file-name-directory (car object)))
 382               (error nil))
 383             (condition-case ()
 384                 (kill-buffer (cdr object))
 385               (error nil)))
 386            ((bufferp object)
 387             (when (buffer-live-p object)
 388               (kill-buffer object))))
 389         (error nil))
 390       (mm-handle-set-undisplayer handle nil))))
 391
 392 (defun mm-display-inline (handle)
 393   (let* ((type (car (mm-handle-type handle)))
 394          (function (cadr (assoc type mm-inline-media-tests))))
 395     (funcall function handle)
 396     (goto-char (point-min))))
 397
 398 (defun mm-inlinable-p (type)
 399   "Say whether TYPE can be displayed inline."
 400   (let ((alist mm-inline-media-tests)
 401         test)
 402     (while alist
 403       (when (equal type (caar alist))
 404         (setq test (caddar alist)
 405               alist nil)
 406         (setq test (eval test)))
 407       (pop alist))
 408     test))
 409
 410 (defun mm-user-method (type)
 411   "Return the user-defined method for TYPE."
 412   (let ((methods mm-user-display-methods)
 413         method result)
 414     (while (setq method (pop methods))
 415       (when (string-match (car method) type)
 416         (when (or (not (eq (cdr method) 'inline))
 417                   (mm-inlinable-p type))
 418           (setq result (cdr method)
 419                 methods nil))))
 420     result))
 421
 422 (defun mm-automatic-display-p (type)
 423   "Return the user-defined method for TYPE."
 424   (let ((methods mm-user-automatic-display)
 425         method result)
 426     (while (setq method (pop methods))
 427       (when (and (string-match method type)
 428                  (mm-inlinable-p type))
 429         (setq result t
 430               methods nil)))
 431     result))
 432
 433 (defun mm-automatic-external-display-p (type)
 434   "Return the user-defined method for TYPE."
 435   (let ((methods mm-user-automatic-external-display)
 436         method result)
 437     (while (setq method (pop methods))
 438       (when (string-match method type)
 439         (setq result t
 440               methods nil)))
 441     result))
 442
 443 (defun add-mime-display-method (type method)
 444   "Make parts of TYPE be displayed with METHOD.
 445 This overrides entries in the mailcap file."
 446   (push (cons type method) mm-user-display-methods))
 447
 448 (defun mm-destroy-part (handle)
 449   "Destroy the data structures connected to HANDLE."
 450   (when (listp handle)
 451     (mm-remove-part handle)
 452     (when (buffer-live-p (mm-handle-buffer handle))
 453       (kill-buffer (mm-handle-buffer handle)))))
 454
 455 (defun mm-handle-displayed-p (handle)
 456   "Say whether HANDLE is displayed or not."
 457   (mm-handle-undisplayer handle))
 458
 459 (defun mm-quote-arg (arg)
 460   "Return a version of ARG that is safe to evaluate in a shell."
 461   (let ((pos 0) new-pos accum)
 462     ;; *** bug: we don't handle newline characters properly
 463     (while (setq new-pos (string-match "[;!`\"$\\& \t{} |()<>]" arg pos))
 464       (push (substring arg pos new-pos) accum)
 465       (push "\\" accum)
 466       (push (list (aref arg new-pos)) accum)
 467       (setq pos (1+ new-pos)))
 468     (if (= pos 0)
 469         arg
 470       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 471
 472 ;;;
 473 ;;; Functions for outputting parts
 474 ;;;
 475
 476 (defun mm-get-part (handle)
 477   "Return the contents of HANDLE as a string."
 478   (mm-with-unibyte-buffer
 479     (mm-insert-part handle)
 480     (buffer-string)))
 481
 482 (defun mm-insert-part (handle)
 483   "Insert the contents of HANDLE in the current buffer."
 484   (let ((cur (current-buffer)))
 485     (save-excursion
 486       (mm-with-unibyte-buffer
 487         (insert-buffer-substring (mm-handle-buffer handle))
 488         (mm-decode-content-transfer-encoding
 489          (mm-handle-encoding handle)
 490          (car (mm-handle-type handle)))
 491         (let ((temp (current-buffer)))
 492           (set-buffer cur)
 493           (insert-buffer-substring temp))))))
 494
 495 (defvar mm-default-directory nil)
 496
 497 (defun mm-save-part (handle)
 498   "Write HANDLE to a file."
 499   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 500          (filename (mail-content-type-get
 501                     (mm-handle-disposition handle) 'filename))
 502          file)
 503     (when filename
 504       (setq filename (file-name-nondirectory filename)))
 505     (setq file
 506           (read-file-name "Save MIME part to: "
 507                           (expand-file-name
 508                            (or filename name "")
 509                            (or mm-default-directory default-directory))))
 510     (setq mm-default-directory (file-name-directory file))
 511     (mm-with-unibyte-buffer
 512       (mm-insert-part handle)
 513       (when (or (not (file-exists-p file))
 514                 (yes-or-no-p (format "File %s already exists; overwrite? "
 515                                      file)))
 516         ;; Now every coding system is 100% binary within mm-with-unibyte-buffer
 517         ;; Is text still special?
 518       (let ((coding-system-for-write
 519              (if (equal "text" (car (split-string
 520                                      (car (mm-handle-type handle)) "/")))
 521                  buffer-file-coding-system
 522                'binary))
 523             ;; Don't re-compress .gz & al.  Arguably we should make
 524             ;; `file-name-handler-alist' nil, but that would chop
 525             ;; ange-ftp which it's reasonable to use here.
 526             (inhibit-file-name-operation 'write-region)
 527             (inhibit-file-name-handlers
 528              (if (equal (car (mm-handle-type handle))
 529                         "application/octet-stream")
 530                  (cons 'jka-compr-handler inhibit-file-name-handlers)
 531                inhibit-file-name-handlers)))
 532         (write-region (point-min) (point-max) file))))))
 533
 534 (defun mm-pipe-part (handle)
 535   "Pipe HANDLE to a process."
 536   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
 537          (command
 538           (read-string "Shell command on MIME part: " mm-last-shell-command)))
 539     (mm-with-unibyte-buffer
 540       (mm-insert-part handle)
 541       (shell-command-on-region (point-min) (point-max) command nil))))
 542
 543 (defun mm-interactively-view-part (handle)
 544   "Display HANDLE using METHOD."
 545   (let* ((type (car (mm-handle-type handle)))
 546          (methods
 547           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
 548                   (mailcap-mime-info type 'all)))
 549          (method (completing-read "Viewer: " methods)))
 550     (mm-display-external (copy-sequence handle) method)))
 551
 552 (defun mm-preferred-alternative (handles &optional preferred)
 553   "Say which of HANDLES are preferred."
 554   (let ((prec (if preferred (list preferred) mm-alternative-precedence))
 555         p h result type handle)
 556     (while (setq p (pop prec))
 557       (setq h handles)
 558       (while h
 559         (setq type
 560               (if (stringp (caar h))
 561                   (caar h)
 562                 (car (mm-handle-type (car h)))))
 563         (setq handle (car h))
 564         (when (and (equal p type)
 565                    (mm-automatic-display-p type)
 566                    (or (stringp (caar h))
 567                        (not (mm-handle-disposition (car h)))
 568                        (equal (car (mm-handle-disposition (car h)))
 569                               "inline")))
 570           (setq result (car h)
 571                 h nil
 572                 prec nil))
 573         (pop h)))
 574     result))
 575
 576 (defun mm-get-content-id (id)
 577   "Return the handle(s) referred to by ID."
 578   (cdr (assoc id mm-content-id-alist)))
 579
 580 (defun mm-get-image (handle)
 581   "Return an image instance based on HANDLE."
 582   (let ((type (cadr (split-string (car (mm-handle-type handle)) "/")))
 583         spec)
 584     ;; Allow some common translations.
 585     (setq type
 586           (cond
 587            ((equal type "x-pixmap")
 588             "xpm")
 589            ((equal type "x-xbitmap")
 590             "xbm")
 591            (t type)))
 592     (or (mm-handle-cache handle)
 593         (mm-with-unibyte-buffer
 594           (mm-insert-part handle)
 595           (prog1
 596               (setq spec
 597                     (make-glyph `[,(intern type) :data ,(buffer-string)]))
 598             (mm-handle-set-cache handle spec))))))
 599
 600 (defun mm-image-fit-p (handle)
 601   "Say whether the image in HANDLE will fit the current window."
 602   (let ((image (mm-get-image handle)))
 603     (or mm-all-images-fit
 604         (and (< (glyph-width image) (window-pixel-width))
 605              (< (glyph-height image) (window-pixel-height))))))
 606
 607 (provide 'mm-decode)
 608
 609 ;; mm-decode.el ends here