git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-encode.el

   1 ;;; mm-encode.el --- Functions for encoding MIME things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-parse)
  29 (require 'mailcap)
  30 (eval-and-compile
  31   (autoload 'mm-body-7-or-8 "mm-bodies"))
  32
  33 (defvar mm-content-transfer-encoding-defaults
  34   '(("text/x-patch" 8bit)
  35     ("text/.*" qp-or-base64)
  36     ("message/rfc822" 8bit)
  37     ("application/emacs-lisp" 8bit)
  38     ("application/x-emacs-lisp" 8bit)
  39     ("application/x-patch" 8bit)
  40     (".*" base64))
  41   "Alist of regexps that match MIME types and their encodings.
  42 If the encoding is `qp-or-base64', then either quoted-printable
  43 or base64 will be used, depending on what is more efficient.")
  44
  45 (defvar mm-use-ultra-safe-encoding nil
  46   "If non-nil, use encodings aimed at Procrustean bed survival.
  47
  48 This means that textual parts are encoded as quoted-printable if they
  49 contain lines longer than 76 characters or starting with \"From \" in
  50 the body.  Non-7bit encodings (8bit, binary) are generally disallowed.
  51 This is to reduce the probability that a broken MTA or MDA changes the
  52 message.
  53
  54 This variable should never be set directly, but bound before a call to
  55 `mml-generate-mime' or similar functions.")
  56
  57 (defun mm-insert-rfc822-headers (charset encoding)
  58   "Insert text/plain headers with CHARSET and ENCODING."
  59   (insert "MIME-Version: 1.0\n")
  60   (insert "Content-Type: text/plain; charset="
  61           (mail-quote-string (downcase (symbol-name charset))) "\n")
  62   (insert "Content-Transfer-Encoding: "
  63           (downcase (symbol-name encoding)) "\n"))
  64
  65 (defun mm-insert-multipart-headers ()
  66   "Insert multipart/mixed headers."
  67   (let ((boundary "=-=-="))
  68     (insert "MIME-Version: 1.0\n")
  69     (insert "Content-Type: multipart/mixed; boundary=\"" boundary "\"\n")
  70     boundary))
  71
  72 (defun mm-default-file-encoding (file)
  73   "Return a default encoding for FILE."
  74   (if (not (string-match "\\.[^.]+$" file))
  75       "application/octet-stream"
  76     (mailcap-extension-to-mime (match-string 0 file))))
  77
  78 (defun mm-safer-encoding (encoding)
  79   "Return a safer but similar encoding."
  80   (cond
  81    ((memq encoding '(7bit 8bit quoted-printable)) 'quoted-printable)
  82    ;; The remaing encodings are binary and base64 (and perhaps some
  83    ;; non-standard ones), which are both turned into base64.
  84    (t 'base64)))
  85
  86 (defun mm-encode-content-transfer-encoding (encoding &optional type)
  87   (cond
  88    ((eq encoding 'quoted-printable)
  89     (mm-with-unibyte-current-buffer-mule4
  90       (quoted-printable-encode-region (point-min) (point-max) t)))
  91    ((eq encoding 'base64)
  92     (when (equal type "text/plain")
  93       (goto-char (point-min))
  94       (while (search-forward "\n" nil t)
  95         (replace-match "\r\n" t t)))
  96     (condition-case error
  97         (base64-encode-region (point-min) (point-max))
  98       (error
  99        (message "Error while decoding: %s" error)
 100        nil)))
 101    ((memq encoding '(7bit 8bit binary))
 102     ;; Do nothing.
 103     )
 104    ((null encoding)
 105     ;; Do nothing.
 106     )
 107    ((functionp encoding)
 108     (ignore-errors (funcall encoding (point-min) (point-max))))
 109    (t
 110     (message "Unknown encoding %s; treating it as 8bit" encoding))))
 111
 112 (defun mm-encode-buffer (type)
 113   "Encode the buffer which contains data of TYPE.
 114 The encoding used is returned."
 115   (let* ((mime-type (if (stringp type) type (car type)))
 116          (encoding
 117           (or (and (listp type)
 118                    (cadr (assq 'encoding type)))
 119               (mm-content-transfer-encoding mime-type)))
 120          (bits (mm-body-7-or-8)))
 121     ;; We force buffers that are 7bit to be unencoded, no matter
 122     ;; what the preferred encoding is.
 123     ;; Only if the buffers don't contain lone lines.
 124     (when (and (eq bits '7bit) (not (mm-long-lines-p 76)))
 125       (setq encoding bits))
 126     (mm-encode-content-transfer-encoding encoding mime-type)
 127     encoding))
 128
 129 (defun mm-insert-headers (type encoding &optional file)
 130   "Insert headers for TYPE."
 131   (insert "Content-Type: " type)
 132   (when file
 133     (insert ";\n\tname=\"" (file-name-nondirectory file) "\""))
 134   (insert "\n")
 135   (insert (format "Content-Transfer-Encoding: %s\n" encoding))
 136   (insert "Content-Disposition: inline")
 137   (when file
 138     (insert ";\n\tfilename=\"" (file-name-nondirectory file) "\""))
 139   (insert "\n")
 140   (insert "\n"))
 141
 142 (defun mm-content-transfer-encoding (type)
 143   "Return a CTE suitable for TYPE to encode the current buffer."
 144   (let ((rules mm-content-transfer-encoding-defaults))
 145     (catch 'found
 146       (while rules
 147         (when (string-match (caar rules) type)
 148           (throw 'found
 149                  (let ((encoding
 150                         (if (eq (cadr (car rules)) 'qp-or-base64)
 151                             (mm-qp-or-base64)
 152                           (cadr (car rules)))))
 153                    (if mm-use-ultra-safe-encoding
 154                        (mm-safer-encoding encoding)
 155                      encoding))))
 156         (pop rules)))))
 157
 158 (defun mm-qp-or-base64 ()
 159   (save-excursion
 160     (let ((limit (min (point-max) (+ 2000 (point-min))))
 161           (n8bit 0))
 162       (goto-char (point-min))
 163       (skip-chars-forward "\x20-\x7f\r\n\t" limit)
 164       (while (< (point) limit)
 165         (incf n8bit)
 166         (forward-char 1)
 167         (skip-chars-forward "\x20-\x7f\r\n\t" limit))
 168       (if (or (< (* 6 n8bit) (- limit (point-min)))
 169               ;; Don't base64, say, a short line with a single
 170               ;; non-ASCII char when splitting parts by charset.
 171               (= n8bit 1))
 172           'quoted-printable
 173         'base64))))
 174
 175 (provide 'mm-encode)
 176
 177 ;;; mm-encode.el ends here