git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-extern.el

   1 ;;; mm-extern.el --- showing message/external-body
   2 ;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   3
   4 ;; Author: Shenghuo Zhu <zsh@cs.rochester.edu>
   5 ;; Keywords: message external-body
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published
  11 ;; by the Free Software Foundation; either version 2, or (at your
  12 ;; option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful, but
  15 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 ;; General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl))
  30
  31 (require 'mm-util)
  32 (require 'mm-decode)
  33
  34 (defvar mm-extern-function-alist
  35   '((local-file . mm-extern-local-file)
  36     (url . mm-extern-url)
  37     (anon-ftp . mm-extern-anon-ftp)
  38     (ftp . mm-extern-ftp)
  39 ;;;     (tftp . mm-extern-tftp)
  40     (mail-server . mm-extern-mail-server)
  41 ;;;     (afs . mm-extern-afs))
  42     ))
  43
  44 (defvar mm-extern-anonymous "anonymous")
  45
  46 (defun mm-extern-local-file (handle)
  47   (erase-buffer)
  48   (let ((name (cdr (assq 'name (cdr (mm-handle-type handle)))))
  49         (coding-system-for-read mm-binary-coding-system))
  50     (unless name
  51       (error "The filename is not specified."))
  52     (mm-disable-multibyte-mule4)
  53     (if (file-exists-p name)
  54         (mm-insert-file-contents name nil nil nil nil t)
  55       (error (format "File %s is gone." name)))))
  56
  57 (defun mm-extern-url (handle)
  58   (erase-buffer)
  59   (require 'url)
  60   (let ((url (cdr (assq 'url (cdr (mm-handle-type handle)))))
  61         (name buffer-file-name)
  62         (coding-system-for-read mm-binary-coding-system))
  63     (unless url
  64       (error "URL is not specified."))
  65     (mm-with-unibyte-current-buffer-mule4
  66       (url-insert-file-contents url))
  67     (mm-disable-multibyte-mule4)
  68     (setq buffer-file-name name)))
  69
  70 (defun mm-extern-anon-ftp (handle)
  71   (erase-buffer)
  72   (let* ((params (cdr (mm-handle-type handle)))
  73          (name (cdr (assq 'name params)))
  74          (site (cdr (assq 'site params)))
  75          (directory (cdr (assq 'directory params)))
  76          (mode (cdr (assq 'mode params)))
  77          (path (concat "/" (or mm-extern-anonymous
  78                                (read-string (format "ID for %s: " site)))
  79                        "@" site ":" directory "/" name))
  80          (coding-system-for-read mm-binary-coding-system))
  81     (unless name
  82       (error "The filename is not specified."))
  83     (mm-disable-multibyte-mule4)
  84     (mm-insert-file-contents path nil nil nil nil t)))
  85
  86 (defun mm-extern-ftp (handle)
  87   (let (mm-extern-anonymous)
  88     (mm-extern-anon-ftp handle)))
  89
  90 (defun mm-extern-mail-server (handle)
  91   (require 'message)
  92   (let* ((params (cdr (mm-handle-type handle)))
  93          (server (cdr (assq 'server params)))
  94          (subject (or (cdr (assq 'subject params)) "none"))
  95          (buf (current-buffer))
  96          info)
  97     (if (y-or-n-p (format "Send a request message to %s?" server))
  98         (save-window-excursion
  99           (message-mail server subject)
 100           (message-goto-body)
 101           (delete-region (point) (point-max))
 102           (insert-buffer buf)
 103           (message "Requesting external body...")
 104           (message-send-and-exit)
 105           (setq info "Request is sent.")
 106           (message info))
 107       (setq info "Request is not sent."))
 108     (goto-char (point-min))
 109     (insert "[" info "]\n\n")))
 110
 111 ;;;###autoload
 112 (defun mm-inline-external-body (handle &optional no-display)
 113   "Show the external-body part of HANDLE.
 114 This function replaces the buffer of HANDLE with a buffer contains
 115 the entire message.
 116 If NO-DISPLAY is nil, display it. Otherwise, do nothing after replacing."
 117   (let* ((access-type (cdr (assq 'access-type
 118                                  (cdr (mm-handle-type handle)))))
 119          (func (cdr (assq (intern
 120                            (downcase
 121                             (or access-type
 122                                 (error "Couldn't find access type."))))
 123                           mm-extern-function-alist)))
 124          gnus-displaying-mime buf
 125          handles)
 126     (unless (mm-handle-cache handle)
 127       (unless func
 128         (error (format "Access type (%s) is not supported." access-type)))
 129       (with-temp-buffer
 130         (mm-insert-part handle)
 131         (goto-char (point-max))
 132         (insert "\n\n")
 133         (setq handles (mm-dissect-buffer t)))
 134       (unless (bufferp (car handles))
 135         (mm-destroy-parts handles)
 136         (error "Multipart external body is not supported."))
 137       (save-excursion ;; single part
 138         (set-buffer (setq buf (mm-handle-buffer handles)))
 139         (let (good)
 140           (unwind-protect
 141               (progn
 142                 (funcall func handle)
 143                 (setq good t))
 144             (unless good
 145               (mm-destroy-parts handles))))
 146         (mm-handle-set-cache handle handles))
 147       (setq gnus-article-mime-handles
 148             (mm-merge-handles gnus-article-mime-handles handles)))
 149     (unless no-display
 150       (save-excursion
 151         (save-restriction
 152           (narrow-to-region (point) (point))
 153           (gnus-display-mime (mm-handle-cache handle))
 154           (mm-handle-set-undisplayer
 155            handle
 156            `(lambda ()
 157               (let (buffer-read-only)
 158                 (condition-case nil
 159                     ;; This is only valid on XEmacs.
 160                     (mapcar (lambda (prop)
 161                             (remove-specifier
 162                              (face-property 'default prop) (current-buffer)))
 163                             '(background background-pixmap foreground))
 164                   (error nil))
 165                 (delete-region ,(point-min-marker) ,(point-max-marker))))))))))
 166
 167 ;; mm-extern.el ends here