git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for MIME things
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (defvar mm-mime-mule-charset-alist
  28   '((us-ascii ascii)
  29     (iso-8859-1 latin-iso8859-1)
  30     (iso-8859-2 latin-iso8859-2)
  31     (iso-8859-3 latin-iso8859-3)
  32     (iso-8859-4 latin-iso8859-4)
  33     (iso-8859-5 cyrillic-iso8859-5)
  34     (koi8-r cyrillic-iso8859-5)
  35     (iso-8859-6 arabic-iso8859-6)
  36     (iso-8859-7 greek-iso8859-7)
  37     (iso-8859-8 hebrew-iso8859-8)
  38     (iso-8859-9 latin-iso8859-9)
  39     (viscii vietnamese-viscii-lower)
  40     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
  41     (euc-kr korean-ksc5601)
  42     (cn-gb-2312 chinese-gb2312)
  43     (cn-big5 chinese-big5-1 chinese-big5-2)
  44     (tibetan tibetan)
  45     (thai-tis620 thai-tis620)
  46     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
  47     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
  48                    latin-jisx0201 japanese-jisx0208-1978
  49                    chinese-gb2312 japanese-jisx0208
  50                    korean-ksc5601 japanese-jisx0212
  51                    katakana-jisx0201)
  52     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
  53                     latin-jisx0201 japanese-jisx0208-1978
  54                     chinese-gb2312 japanese-jisx0208
  55                     korean-ksc5601 japanese-jisx0212
  56                     chinese-cns11643-1 chinese-cns11643-2)
  57     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
  58                     cyrillic-iso8859-5 greek-iso8859-7
  59                     latin-jisx0201 japanese-jisx0208-1978
  60                     chinese-gb2312 japanese-jisx0208
  61                     korean-ksc5601 japanese-jisx0212
  62                     chinese-cns11643-1 chinese-cns11643-2
  63                     chinese-cns11643-3 chinese-cns11643-4
  64                     chinese-cns11643-5 chinese-cns11643-6
  65                     chinese-cns11643-7))
  66   "Alist of MIME-charset/MULE-charsets.")
  67
  68
  69 (eval-and-compile
  70   (mapcar
  71    (lambda (elem)
  72      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  73        (if (fboundp (car elem))
  74            (defalias nfunc (car elem))
  75          (defalias nfunc (cdr elem)))))
  76    '((decode-coding-string . (lambda (s a) s))
  77      (encode-coding-string . (lambda (s a) s))
  78      (encode-coding-region . ignore)
  79      (coding-system-list . ignore)
  80      (decode-coding-region . ignore)
  81      (char-int . identity)
  82      (device-type . ignore)
  83      (coding-system-equal . equal)
  84      (annotationp . ignore)
  85      (set-buffer-file-coding-system . ignore)
  86      (make-char
  87       . (lambda (charset int)
  88           (int-to-char int)))
  89      (read-coding-system
  90       . (lambda (prompt)
  91           "Prompt the user for a coding system."
  92           (completing-read
  93            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  94                           mm-mime-mule-charset-alist)))))))
  95
  96 (defvar mm-coding-system-list nil)
  97 (defun mm-get-coding-system-list ()
  98   "Get the coding system list."
  99   (or mm-coding-system-list
 100       (setq mm-coding-system-list (mm-coding-system-list))))
 101
 102 (defvar mm-charset-synonym-alist
 103   '((big5 . cn-big5)
 104     (gb2312 . cn-gb-2312)
 105     (x-ctext . ctext))
 106   "A mapping from invalid charset names to the real charset names.")
 107
 108 (defun mm-coding-system-p (sym)
 109   "Return non-nil if SYM is a coding system."
 110   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 111       (memq sym (mm-get-coding-system-list))))
 112
 113 (defvar mm-binary-coding-system
 114   (cond
 115    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 116    ((mm-coding-system-p 'binary) 'binary)
 117    (t nil))
 118   "100% binary coding system.")
 119
 120 (defvar mm-text-coding-system
 121   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 122           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 123         (and (mm-coding-system-p 'raw-text) 'raw-text))
 124       mm-binary-coding-system)
 125   "Text-safe coding system (For removing ^M).")
 126
 127 (defvar mm-text-coding-system-for-write nil
 128   "Text coding system for write.")
 129
 130 (defvar mm-auto-save-coding-system
 131   (cond
 132    ((mm-coding-system-p 'emacs-mule)
 133     (if (memq system-type '(windows-nt ms-dos ms-windows))
 134         (if (mm-coding-system-p 'emacs-mule-dos)
 135             'emacs-mule-dos mm-binary-coding-system)
 136       'emacs-mule))
 137    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 138    (t mm-binary-coding-system))
 139   "Coding system of auto save file.")
 140
 141 ;;; Internal variables:
 142
 143 ;;; Functions:
 144
 145 (defun mm-mule-charset-to-mime-charset (charset)
 146   "Return the MIME charset corresponding to MULE CHARSET."
 147   (let ((alist mm-mime-mule-charset-alist)
 148         out)
 149     (while alist
 150       (when (memq charset (cdar alist))
 151         (setq out (caar alist)
 152               alist nil))
 153       (pop alist))
 154     out))
 155
 156 (defun mm-charset-to-coding-system (charset &optional lbt)
 157   "Return coding-system corresponding to CHARSET.
 158 CHARSET is a symbol naming a MIME charset.
 159 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 160 used as the line break code type of the coding system."
 161   (when (stringp charset)
 162     (setq charset (intern (downcase charset))))
 163   (setq charset
 164         (or (cdr (assq charset mm-charset-synonym-alist))
 165             charset))
 166   (when lbt
 167     (setq charset (intern (format "%s-%s" charset lbt))))
 168   (cond
 169    ;; Running in a non-MULE environment.
 170    ((null (mm-get-coding-system-list))
 171     charset)
 172    ;; ascii
 173    ((eq charset 'us-ascii)
 174     'ascii)
 175    ;; Check to see whether we can handle this charset.
 176    ((memq charset (mm-get-coding-system-list))
 177     charset)
 178    ;; Nope.
 179    (t
 180     nil)))
 181
 182 (defun mm-replace-chars-in-string (string from to)
 183   "Replace characters in STRING from FROM to TO."
 184   (let ((string (substring string 0))   ;Copy string.
 185         (len (length string))
 186         (idx 0))
 187     ;; Replace all occurrences of FROM with TO.
 188     (while (< idx len)
 189       (when (= (aref string idx) from)
 190         (aset string idx to))
 191       (setq idx (1+ idx)))
 192     string))
 193
 194 (defsubst mm-enable-multibyte ()
 195   "Enable multibyte in the current buffer."
 196   (when (and (fboundp 'set-buffer-multibyte)
 197              (boundp 'enable-multibyte-characters)
 198              (default-value 'enable-multibyte-characters))
 199     (set-buffer-multibyte t)))
 200
 201 (defsubst mm-disable-multibyte ()
 202   "Disable multibyte in the current buffer."
 203   (when (fboundp 'set-buffer-multibyte)
 204     (set-buffer-multibyte nil)))
 205
 206 (defun mm-preferred-coding-system (charset)
 207   ;; A typo in some Emacs versions.
 208   (or (get-charset-property charset 'prefered-coding-system)
 209       (get-charset-property charset 'preffered-coding-system)))
 210
 211 (defun mm-mime-charset (charset)
 212   "Return the MIME charset corresponding to the MULE CHARSET."
 213   (if (fboundp 'coding-system-get)
 214       ;; This exists in Emacs 20.
 215       (or
 216        (and (mm-preferred-coding-system charset)
 217             (coding-system-get
 218              (mm-preferred-coding-system charset) 'mime-charset))
 219        (and (eq charset 'ascii)
 220             'us-ascii)
 221        (mm-preferred-coding-system charset)
 222        (mm-mule-charset-to-mime-charset charset))
 223     ;; This is for XEmacs.
 224     (mm-mule-charset-to-mime-charset charset)))
 225
 226 (defun mm-find-mime-charset-region (b e)
 227   "Return the MIME charsets needed to encode the region between B and E."
 228   (let ((charsets
 229          (mapcar 'mm-mime-charset
 230                  (delq 'ascii
 231                        (mm-find-charset-region b e)))))
 232     (when (memq 'iso-2022-jp-2 charsets)
 233       (setq charsets (delq 'iso-2022-jp charsets)))
 234     (delete-duplicates charsets)))
 235
 236 (defsubst mm-multibyte-p ()
 237   "Say whether multibyte is enabled."
 238   (and (boundp 'enable-multibyte-characters)
 239        enable-multibyte-characters))
 240
 241 (defmacro mm-with-unibyte-buffer (&rest forms)
 242   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 243 See also `with-temp-file' and `with-output-to-string'."
 244   (let ((temp-buffer (make-symbol "temp-buffer"))
 245         (multibyte (make-symbol "multibyte")))
 246     `(if (not (boundp 'enable-multibyte-characters))
 247          (with-temp-buffer ,@forms)
 248        (let ((,multibyte (default-value 'enable-multibyte-characters))
 249              ,temp-buffer)
 250          (unwind-protect
 251              (progn
 252                (setq-default enable-multibyte-characters nil)
 253                (setq ,temp-buffer
 254                      (get-buffer-create (generate-new-buffer-name " *temp*")))
 255                (unwind-protect
 256                    (with-current-buffer ,temp-buffer
 257                      (let ((buffer-file-coding-system mm-binary-coding-system)
 258                            (coding-system-for-read mm-binary-coding-system)
 259                            (coding-system-for-write mm-binary-coding-system))
 260                        ,@forms))
 261                  (and (buffer-name ,temp-buffer)
 262                       (kill-buffer ,temp-buffer))))
 263            (setq-default enable-multibyte-characters ,multibyte))))))
 264 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 265 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 266
 267 (defun mm-find-charset-region (b e)
 268   "Return a list of charsets in the region."
 269   (cond
 270    ((and (boundp 'enable-multibyte-characters)
 271          enable-multibyte-characters
 272          (fboundp 'find-charset-region))
 273     (find-charset-region b e))
 274    ((not (boundp 'current-language-environment))
 275     (save-excursion
 276       (save-restriction
 277         (narrow-to-region b e)
 278         (goto-char (point-min))
 279         (skip-chars-forward "\0-\177")
 280         (if (eobp)
 281             '(ascii)
 282           (delq nil (list 'ascii mail-parse-charset))))))
 283    (t
 284     ;; We are in a unibyte buffer, so we futz around a bit.
 285     (save-excursion
 286       (save-restriction
 287         (narrow-to-region b e)
 288         (goto-char (point-min))
 289         (let ((entry (assoc (capitalize current-language-environment)
 290                             language-info-alist)))
 291           (skip-chars-forward "\0-\177")
 292           (if (eobp)
 293               '(ascii)
 294             (list 'ascii (car (last (assq 'charset entry)))))))))))
 295
 296 (defun mm-read-charset (prompt)
 297   "Return a charset."
 298   (intern
 299    (completing-read
 300     prompt
 301     (mapcar (lambda (e) (list (symbol-name (car e))))
 302             mm-mime-mule-charset-alist)
 303     nil t)))
 304
 305 (defun mm-quote-arg (arg)
 306   "Return a version of ARG that is safe to evaluate in a shell."
 307   (let ((pos 0) new-pos accum)
 308     ;; *** bug: we don't handle newline characters properly
 309     (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 310       (push (substring arg pos new-pos) accum)
 311       (push "\\" accum)
 312       (push (list (aref arg new-pos)) accum)
 313       (setq pos (1+ new-pos)))
 314     (if (= pos 0)
 315         arg
 316       (apply 'concat (nconc (nreverse accum) (list (substring arg pos)))))))
 317
 318 (defun mm-auto-mode-alist ()
 319   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 320   (let ((alist auto-mode-alist)
 321         out)
 322     (while alist
 323       (when (listp (cdar alist))
 324         (push (car alist) out))
 325       (pop alist))
 326     (nreverse out)))
 327
 328 (defvar mm-inhibit-file-name-handlers
 329   '(jka-compr-handler)
 330   "A list of handlers doing (un)compression (etc) thingies.")
 331
 332 (defun mm-insert-file-contents (filename &optional visit beg end replace
 333                                          inhibit)
 334   "Like `insert-file-contents', q.v., but only reads in the file.
 335 A buffer may be modified in several ways after reading into the buffer due
 336 to advanced Emacs features, such as file-name-handlers, format decoding,
 337 find-file-hooks, etc.
 338 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 339   This function ensures that none of these modifications will take place."
 340   (let ((format-alist nil)
 341         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 342         (default-major-mode 'fundamental-mode)
 343         (enable-local-variables nil)
 344         (after-insert-file-functions nil)
 345         (enable-local-eval nil)
 346         (find-file-hooks nil)
 347         (inhibit-file-name-operation (if inhibit
 348                                          'insert-file-contents
 349                                        inhibit-file-name-operation))
 350         (inhibit-file-name-handlers
 351          (if inhibit
 352              (append mm-inhibit-file-name-handlers
 353                      inhibit-file-name-handlers)
 354            inhibit-file-name-handlers)))
 355     (insert-file-contents filename visit beg end replace)))
 356
 357 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 358   "Append the contents of the region to the end of file FILENAME.
 359 When called from a function, expects three arguments,
 360 START, END and FILENAME.  START and END are buffer positions
 361 saying what text to write.
 362 Optional fourth argument specifies the coding system to use when
 363 encoding the file.
 364 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 365   (let ((coding-system-for-write
 366          (or codesys mm-text-coding-system-for-write
 367              mm-text-coding-system))
 368         (inhibit-file-name-operation (if inhibit
 369                                          'append-to-file
 370                                        inhibit-file-name-operation))
 371         (inhibit-file-name-handlers
 372          (if inhibit
 373              (append mm-inhibit-file-name-handlers
 374                      inhibit-file-name-handlers)
 375            inhibit-file-name-handlers)))
 376     (append-to-file start end filename)))
 377
 378 (defun mm-write-region (start end filename &optional append visit lockname
 379                               coding-system inhibit)
 380
 381   "Like `write-region'.
 382 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 383   (let ((coding-system-for-write
 384          (or coding-system mm-text-coding-system-for-write
 385              mm-text-coding-system))
 386         (inhibit-file-name-operation (if inhibit
 387                                          'write-region
 388                                        inhibit-file-name-operation))
 389         (inhibit-file-name-handlers
 390          (if inhibit
 391              (append mm-inhibit-file-name-handlers
 392                      inhibit-file-name-handlers)
 393            inhibit-file-name-handlers)))
 394     (write-region start end filename append visit lockname)))
 395
 396 (provide 'mm-util)
 397
 398 ;;; mm-util.el ends here