git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;   Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl))
  29 (require 'mail-prsvr)
  30
  31 (eval-and-compile
  32   (mapcar
  33    (lambda (elem)
  34      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  35        (if (fboundp (car elem))
  36            (defalias nfunc (car elem))
  37          (defalias nfunc (cdr elem)))))
  38    '((decode-coding-string . (lambda (s a) s))
  39      (encode-coding-string . (lambda (s a) s))
  40      (encode-coding-region . ignore)
  41      (coding-system-list . ignore)
  42      (decode-coding-region . ignore)
  43      (char-int . identity)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-make-unibyte . identity)
  73      (string-as-multibyte . identity)
  74      (multibyte-string-p . ignore))))
  75
  76 (eval-and-compile
  77   (defalias 'mm-char-or-char-int-p
  78     (cond
  79      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  80      ((fboundp 'char-valid-p) 'char-valid-p)
  81      (t 'identity))))
  82
  83 (eval-and-compile
  84   (defalias 'mm-read-coding-system
  85     (cond
  86      ((fboundp 'read-coding-system)
  87       (if (and (featurep 'xemacs)
  88                (<= (string-to-number emacs-version) 21.1))
  89           (lambda (prompt &optional default-coding-system)
  90             (read-coding-system prompt))
  91         'read-coding-system))
  92      (t (lambda (prompt &optional default-coding-system)
  93           "Prompt the user for a coding system."
  94           (completing-read
  95            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  96                           mm-mime-mule-charset-alist)))))))
  97
  98 (defvar mm-coding-system-list nil)
  99 (defun mm-get-coding-system-list ()
 100   "Get the coding system list."
 101   (or mm-coding-system-list
 102       (setq mm-coding-system-list (mm-coding-system-list))))
 103
 104 (defun mm-coding-system-p (sym)
 105   "Return non-nil if SYM is a coding system."
 106   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 107       (memq sym (mm-get-coding-system-list))))
 108
 109 (defvar mm-charset-synonym-alist
 110   `(
 111     ;; Perfectly fine?  A valid MIME name, anyhow.
 112     ,@(unless (mm-coding-system-p 'big5)
 113        '((big5 . cn-big5)))
 114     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 115     ,@(unless (mm-coding-system-p 'x-ctext)
 116        '((x-ctext . ctext)))
 117     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 118     ,@(unless (mm-coding-system-p 'gb2312)
 119        '((gb2312 . cn-gb-2312)))
 120     ;; ISO-8859-15 is very similar to ISO-8859-1.
 121     ,@(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 122        '((iso-8859-15 . iso-8859-1)))
 123     ;; Windows-1252 is actually a superset of Latin-1.  See also
 124     ;; `gnus-article-dumbquotes-map'.
 125     ,@(unless (mm-coding-system-p 'windows-1252)
 126        (if (mm-coding-system-p 'cp1252)
 127            '((windows-1252 . cp1252))
 128          '((windows-1252 . iso-8859-1))))
 129     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 130     ;; Outlook users in Czech republic. Use this to allow reading of their
 131     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 132     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 133                (mm-coding-system-p 'cp1250))
 134           '((windows-1250 . cp1250)))
 135     )
 136   "A mapping from invalid charset names to the real charset names.")
 137
 138 (defvar mm-binary-coding-system
 139   (cond
 140    ((mm-coding-system-p 'binary) 'binary)
 141    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 142    (t nil))
 143   "100% binary coding system.")
 144
 145 (defvar mm-text-coding-system
 146   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 147           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 148         (and (mm-coding-system-p 'raw-text) 'raw-text))
 149       mm-binary-coding-system)
 150   "Text-safe coding system (For removing ^M).")
 151
 152 (defvar mm-text-coding-system-for-write nil
 153   "Text coding system for write.")
 154
 155 (defvar mm-auto-save-coding-system
 156   (cond
 157    ((mm-coding-system-p 'emacs-mule)
 158     (if (memq system-type '(windows-nt ms-dos ms-windows))
 159         (if (mm-coding-system-p 'emacs-mule-dos)
 160             'emacs-mule-dos mm-binary-coding-system)
 161       'emacs-mule))
 162    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 163    (t mm-binary-coding-system))
 164   "Coding system of auto save file.")
 165
 166 (defvar mm-universal-coding-system mm-auto-save-coding-system
 167   "The universal coding system.")
 168
 169 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 170 ;; should only matter with XEmacs, though.
 171 (defvar mm-mime-mule-charset-alist
 172   `((us-ascii ascii)
 173     (iso-8859-1 latin-iso8859-1)
 174     (iso-8859-2 latin-iso8859-2)
 175     (iso-8859-3 latin-iso8859-3)
 176     (iso-8859-4 latin-iso8859-4)
 177     (iso-8859-5 cyrillic-iso8859-5)
 178     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 179     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 180     ;; charset is koi8-r, not iso-8859-5.
 181     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 182     (iso-8859-6 arabic-iso8859-6)
 183     (iso-8859-7 greek-iso8859-7)
 184     (iso-8859-8 hebrew-iso8859-8)
 185     (iso-8859-9 latin-iso8859-9)
 186     (iso-8859-14 latin-iso8859-14)
 187     (iso-8859-15 latin-iso8859-15)
 188     (viscii vietnamese-viscii-lower)
 189     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 190     (euc-kr korean-ksc5601)
 191     (gb2312 chinese-gb2312)
 192     (big5 chinese-big5-1 chinese-big5-2)
 193     (tibetan tibetan)
 194     (thai-tis620 thai-tis620)
 195     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 196     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 197                    latin-jisx0201 japanese-jisx0208-1978
 198                    chinese-gb2312 japanese-jisx0208
 199                    korean-ksc5601 japanese-jisx0212
 200                    katakana-jisx0201)
 201     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 202                     latin-jisx0201 japanese-jisx0208-1978
 203                     chinese-gb2312 japanese-jisx0208
 204                     korean-ksc5601 japanese-jisx0212
 205                     chinese-cns11643-1 chinese-cns11643-2)
 206     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 207                     cyrillic-iso8859-5 greek-iso8859-7
 208                     latin-jisx0201 japanese-jisx0208-1978
 209                     chinese-gb2312 japanese-jisx0208
 210                     korean-ksc5601 japanese-jisx0212
 211                     chinese-cns11643-1 chinese-cns11643-2
 212                     chinese-cns11643-3 chinese-cns11643-4
 213                     chinese-cns11643-5 chinese-cns11643-6
 214                     chinese-cns11643-7)
 215     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 216              (charsetp 'unicode-a)
 217              (not (mm-coding-system-p 'mule-utf-8)))
 218          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 219        ;; If we have utf-8 we're in Mule 5+.
 220        (append '(utf-8)
 221                (delete 'ascii
 222                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 223   "Alist of MIME-charset/MULE-charsets.")
 224
 225 ;; Correct by construction, but should be unnecessary:
 226 ;; XEmacs hates it.
 227 (when (and (not (featurep 'xemacs))
 228            (fboundp 'coding-system-list)
 229            (fboundp 'sort-coding-systems))
 230   (setq mm-mime-mule-charset-alist
 231         (apply
 232          'nconc
 233          (mapcar
 234           (lambda (cs)
 235             (when (and (coding-system-get cs 'mime-charset)
 236                        (not (eq t (coding-system-get cs 'safe-charsets))))
 237               (list (cons (coding-system-get cs 'mime-charset)
 238                           (delq 'ascii
 239                                 (coding-system-get cs 'safe-charsets))))))
 240           (sort-coding-systems (coding-system-list 'base-only))))))
 241
 242 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 243   "A list of special charsets.
 244 Valid elements include:
 245 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 246 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 247 )
 248
 249 (defvar mm-iso-8859-15-compatible
 250   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 251     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 252   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 253
 254 (defvar mm-iso-8859-x-to-15-table
 255   (and (fboundp 'coding-system-p)
 256        (mm-coding-system-p 'iso-8859-15)
 257        (mapcar
 258         (lambda (cs)
 259           (if (mm-coding-system-p (car cs))
 260               (let ((c (string-to-char
 261                         (decode-coding-string "\341" (car cs)))))
 262                 (cons (char-charset c)
 263                       (cons
 264                        (- (string-to-char
 265                            (decode-coding-string "\341" 'iso-8859-15)) c)
 266                        (string-to-list (decode-coding-string (car (cdr cs))
 267                                                              (car cs))))))
 268             '(gnus-charset 0)))
 269         mm-iso-8859-15-compatible))
 270   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 271
 272 (defcustom mm-coding-system-priorities
 273   (if (boundp 'current-language-environment)
 274       (let ((lang (symbol-value 'current-language-environment)))
 275         (cond ((string= lang "Japanese")
 276                ;; Japanese users may prefer iso-2022-jp to shift-jis.
 277                '(iso-2022-jp iso-2022-jp-2 japanese-shift-jis
 278                              iso-latin-1 utf-8)))))
 279   "Preferred coding systems for encoding outgoing mails.
 280
 281 More than one suitable coding systems may be found for some texts.  By
 282 default, a coding system with the highest priority is used to encode
 283 outgoing mails (see `sort-coding-systems').  If this variable is set,
 284 it overrides the default priority."
 285   :type '(repeat (symbol :tag "Coding system"))
 286   :group 'mime)
 287
 288 (defvar mm-use-find-coding-systems-region
 289   (fboundp 'find-coding-systems-region)
 290   "Use `find-coding-systems-region' to find proper coding systems.
 291
 292 Setting it to nil is useful on Emacsen supporting Unicode if sending
 293 mail with multiple parts is preferred to sending a Unicode one.")
 294
 295 ;;; Internal variables:
 296
 297 ;;; Functions:
 298
 299 (defun mm-mule-charset-to-mime-charset (charset)
 300   "Return the MIME charset corresponding to the given Mule CHARSET."
 301   (if (fboundp 'find-coding-systems-for-charsets)
 302       (let (mime)
 303         (dolist (cs (find-coding-systems-for-charsets (list charset)))
 304           (unless mime
 305             (when cs
 306               (setq mime (coding-system-get cs 'mime-charset)))))
 307         mime)
 308     (let ((alist mm-mime-mule-charset-alist)
 309           out)
 310       (while alist
 311         (when (memq charset (cdar alist))
 312           (setq out (caar alist)
 313                 alist nil))
 314         (pop alist))
 315       out)))
 316
 317 (defun mm-charset-to-coding-system (charset &optional lbt)
 318   "Return coding-system corresponding to CHARSET.
 319 CHARSET is a symbol naming a MIME charset.
 320 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 321 used as the line break code type of the coding system."
 322   (when (stringp charset)
 323     (setq charset (intern (downcase charset))))
 324   (when lbt
 325     (setq charset (intern (format "%s-%s" charset lbt))))
 326   (cond
 327    ((null charset)
 328     charset)
 329    ;; Running in a non-MULE environment.
 330    ((null (mm-get-coding-system-list))
 331     charset)
 332    ;; ascii
 333    ((eq charset 'us-ascii)
 334     'ascii)
 335    ;; Check to see whether we can handle this charset.  (This depends
 336    ;; on there being some coding system matching each `mime-charset'
 337    ;; property defined, as there should be.)
 338    ((and (mm-coding-system-p charset)
 339 ;;; Doing this would potentially weed out incorrect charsets.
 340 ;;;      charset
 341 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 342          )
 343     charset)
 344    ;; Translate invalid charsets.
 345    ((let ((cs (cdr (assq charset mm-charset-synonym-alist))))
 346       (and cs (mm-coding-system-p cs) cs)))
 347    ;; Last resort: search the coding system list for entries which
 348    ;; have the right mime-charset in case the canonical name isn't
 349    ;; defined (though it should be).
 350    ((let (cs)
 351       ;; mm-get-coding-system-list returns a list of cs without lbt.
 352       ;; Do we need -lbt?
 353       (dolist (c (mm-get-coding-system-list))
 354         (if (and (null cs)
 355                  (eq charset (coding-system-get c 'mime-charset)))
 356             (setq cs c)))
 357       cs))))
 358
 359 (defsubst mm-replace-chars-in-string (string from to)
 360   (mm-subst-char-in-string from to string))
 361
 362 (eval-and-compile
 363   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 364                              (boundp 'default-enable-multibyte-characters)
 365                              default-enable-multibyte-characters
 366                              (fboundp 'set-buffer-multibyte))
 367     "Emacs mule.")
 368
 369   (defvar mm-mule4-p (and mm-emacs-mule
 370                           (fboundp 'charsetp)
 371                           (not (charsetp 'eight-bit-control)))
 372     "Mule version 4.")
 373
 374   (if mm-emacs-mule
 375       (defun mm-enable-multibyte ()
 376         "Set the multibyte flag of the current buffer.
 377 Only do this if the default value of `enable-multibyte-characters' is
 378 non-nil.  This is a no-op in XEmacs."
 379         (set-buffer-multibyte t))
 380     (defalias 'mm-enable-multibyte 'ignore))
 381
 382   (if mm-emacs-mule
 383       (defun mm-disable-multibyte ()
 384         "Unset the multibyte flag of in the current buffer.
 385 This is a no-op in XEmacs."
 386         (set-buffer-multibyte nil))
 387     (defalias 'mm-disable-multibyte 'ignore))
 388
 389   (if mm-mule4-p
 390       (defun mm-enable-multibyte-mule4  ()
 391         "Enable multibyte in the current buffer.
 392 Only used in Emacs Mule 4."
 393         (set-buffer-multibyte t))
 394     (defalias 'mm-enable-multibyte-mule4 'ignore))
 395
 396   (if mm-mule4-p
 397       (defun mm-disable-multibyte-mule4 ()
 398         "Disable multibyte in the current buffer.
 399 Only used in Emacs Mule 4."
 400         (set-buffer-multibyte nil))
 401     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 402
 403 (defun mm-preferred-coding-system (charset)
 404   ;; A typo in some Emacs versions.
 405   (or (get-charset-property charset 'preferred-coding-system)
 406       (get-charset-property charset 'prefered-coding-system)))
 407
 408 (defsubst mm-guess-charset ()
 409   "Guess Mule charset from the language environment."
 410   (or
 411    mail-parse-mule-charset ;; cached mule-charset
 412    (progn
 413      (setq mail-parse-mule-charset
 414            (and (boundp 'current-language-environment)
 415                 (car (last
 416                       (assq 'charset
 417                             (assoc current-language-environment
 418                                    language-info-alist))))))
 419      (if (or (not mail-parse-mule-charset)
 420              (eq mail-parse-mule-charset 'ascii))
 421          (setq mail-parse-mule-charset
 422                (or (car (last (assq mail-parse-charset
 423                                     mm-mime-mule-charset-alist)))
 424                    ;; default
 425                    'latin-iso8859-1)))
 426      mail-parse-mule-charset)))
 427
 428 (defun mm-charset-after (&optional pos)
 429   "Return charset of a character in current buffer at position POS.
 430 If POS is nil, it defauls to the current point.
 431 If POS is out of range, the value is nil.
 432 If the charset is `composition', return the actual one."
 433   (let ((char (char-after pos)) charset)
 434     (if (< (mm-char-int char) 128)
 435         (setq charset 'ascii)
 436       ;; charset-after is fake in some Emacsen.
 437       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 438       (if (eq charset 'composition)
 439           (let ((p (or pos (point))))
 440             (cadr (find-charset-region p (1+ p))))
 441         (if (and charset (not (memq charset '(ascii eight-bit-control
 442                                                     eight-bit-graphic))))
 443             charset
 444           (mm-guess-charset))))))
 445
 446 (defun mm-mime-charset (charset)
 447   "Return the MIME charset corresponding to the given Mule CHARSET."
 448   (if (eq charset 'unknown)
 449       (error "The message contains non-printable characters, please use attachment"))
 450   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 451       ;; This exists in Emacs 20.
 452       (or
 453        (and (mm-preferred-coding-system charset)
 454             (coding-system-get
 455              (mm-preferred-coding-system charset) 'mime-charset))
 456        (and (eq charset 'ascii)
 457             'us-ascii)
 458        (mm-preferred-coding-system charset)
 459        (mm-mule-charset-to-mime-charset charset))
 460     ;; This is for XEmacs.
 461     (mm-mule-charset-to-mime-charset charset)))
 462
 463 (defun mm-delete-duplicates (list)
 464   "Simple substitute for CL `delete-duplicates', testing with `equal'."
 465   (let (result head)
 466     (while list
 467       (setq head (car list))
 468       (setq list (delete head list))
 469       (setq result (cons head result)))
 470     (nreverse result)))
 471
 472 (if (and (not (featurep 'xemacs))
 473          (boundp 'enable-multibyte-characters))
 474     (defalias 'mm-multibyte-p
 475       (lambda ()
 476         "Say whether multibyte is enabled in the current buffer."
 477         enable-multibyte-characters))
 478   (defalias 'mm-multibyte-p (lambda () (featurep 'mule))))
 479
 480 (defun mm-iso-8859-x-to-15-region (&optional b e)
 481   (if (fboundp 'char-charset)
 482       (let (charset item c inconvertible)
 483         (save-restriction
 484           (if e (narrow-to-region b e))
 485           (goto-char (point-min))
 486           (skip-chars-forward "\0-\177")
 487           (while (not (eobp))
 488             (cond
 489              ((not (setq item (assq (char-charset (setq c (char-after)))
 490                                     mm-iso-8859-x-to-15-table)))
 491               (forward-char))
 492              ((memq c (cdr (cdr item)))
 493               (setq inconvertible t)
 494               (forward-char))
 495              (t
 496               (insert-before-markers (prog1 (+ c (car (cdr item)))
 497                                        (delete-char 1)))))
 498             (skip-chars-forward "\0-\177")))
 499         (not inconvertible))))
 500
 501 (defun mm-sort-coding-systems-predicate (a b)
 502   (> (length (memq a mm-coding-system-priorities))
 503      (length (memq b mm-coding-system-priorities))))
 504
 505 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 506   "Return the MIME charsets needed to encode the region between B and E.
 507 nil means ASCII, a single-element list represents an appropriate MIME
 508 charset, and a longer list means no appropriate charset."
 509   (let (charsets)
 510     ;; The return possibilities of this function are a mess...
 511     (or (and (mm-multibyte-p)
 512              mm-use-find-coding-systems-region
 513              ;; Find the mime-charset of the most preferred coding
 514              ;; system that has one.
 515              (let ((systems (find-coding-systems-region b e)))
 516                (when mm-coding-system-priorities
 517                  (setq systems
 518                        (sort systems 'mm-sort-coding-systems-predicate)))
 519                ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 520                ;; is not in the IANA list.
 521                (setq systems (delq 'compound-text systems))
 522                (unless (equal systems '(undecided))
 523                  (while systems
 524                    (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 525                      (if cs
 526                          (setq systems nil
 527                                charsets (list cs))))))
 528                charsets))
 529         ;; Otherwise we're not multibyte, XEmacs or a single coding
 530         ;; system won't cover it.
 531         (setq charsets
 532               (mm-delete-duplicates
 533                (mapcar 'mm-mime-charset
 534                        (delq 'ascii
 535                              (mm-find-charset-region b e))))))
 536     (if (and (> (length charsets) 1)
 537              (memq 'iso-8859-15 charsets)
 538              (memq 'iso-8859-15 hack-charsets)
 539              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 540         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 541                 mm-iso-8859-15-compatible))
 542     (if (and (memq 'iso-2022-jp-2 charsets)
 543              (memq 'iso-2022-jp-2 hack-charsets))
 544         (setq charsets (delq 'iso-2022-jp charsets)))
 545     charsets))
 546
 547 (defmacro mm-with-unibyte-buffer (&rest forms)
 548   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 549 Use unibyte mode for this."
 550   `(let (default-enable-multibyte-characters)
 551      (with-temp-buffer ,@forms)))
 552 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 553 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 554
 555 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 556   "Evaluate FORMS with current current buffer temporarily made unibyte.
 557 Also bind `default-enable-multibyte-characters' to nil.
 558 Equivalent to `progn' in XEmacs"
 559   (let ((multibyte (make-symbol "multibyte"))
 560         (buffer (make-symbol "buffer")))
 561     `(if mm-emacs-mule
 562          (let ((,multibyte enable-multibyte-characters)
 563                (,buffer (current-buffer)))
 564            (unwind-protect
 565                (let (default-enable-multibyte-characters)
 566                  (set-buffer-multibyte nil)
 567                  ,@forms)
 568              (set-buffer ,buffer)
 569              (set-buffer-multibyte ,multibyte)))
 570        (let (default-enable-multibyte-characters)
 571          ,@forms))))
 572 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 573 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 574
 575 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 576   "Evaluate FORMS there like `progn' in current buffer.
 577 Mule4 only."
 578   (let ((multibyte (make-symbol "multibyte"))
 579         (buffer (make-symbol "buffer")))
 580     `(if mm-mule4-p
 581          (let ((,multibyte enable-multibyte-characters)
 582                (,buffer (current-buffer)))
 583            (unwind-protect
 584                (let (default-enable-multibyte-characters)
 585                  (set-buffer-multibyte nil)
 586                  ,@forms)
 587              (set-buffer ,buffer)
 588              (set-buffer-multibyte ,multibyte)))
 589        (let (default-enable-multibyte-characters)
 590          ,@forms))))
 591 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 592 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 593
 594 (defmacro mm-with-unibyte (&rest forms)
 595   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 596   `(let (default-enable-multibyte-characters)
 597      ,@forms))
 598 (put 'mm-with-unibyte 'lisp-indent-function 0)
 599 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 600
 601 (defun mm-find-charset-region (b e)
 602   "Return a list of Emacs charsets in the region B to E."
 603   (cond
 604    ((and (mm-multibyte-p)
 605          (fboundp 'find-charset-region))
 606     ;; Remove composition since the base charsets have been included.
 607     ;; Remove eight-bit-*, treat them as ascii.
 608     (let ((css (find-charset-region b e)))
 609       (mapcar (lambda (cs) (setq css (delq cs css)))
 610               '(composition eight-bit-control eight-bit-graphic
 611                             control-1))
 612       css))
 613    (t
 614     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 615     (save-excursion
 616       (save-restriction
 617         (narrow-to-region b e)
 618         (goto-char (point-min))
 619         (skip-chars-forward "\0-\177")
 620         (if (eobp)
 621             '(ascii)
 622           (let (charset)
 623             (setq charset
 624                   (and (boundp 'current-language-environment)
 625                        (car (last (assq 'charset
 626                                         (assoc current-language-environment
 627                                                language-info-alist))))))
 628             (if (eq charset 'ascii) (setq charset nil))
 629             (or charset
 630                 (setq charset
 631                       (car (last (assq mail-parse-charset
 632                                        mm-mime-mule-charset-alist)))))
 633             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 634
 635 (if (fboundp 'shell-quote-argument)
 636     (defalias 'mm-quote-arg 'shell-quote-argument)
 637   (defun mm-quote-arg (arg)
 638     "Return a version of ARG that is safe to evaluate in a shell."
 639     (let ((pos 0) new-pos accum)
 640       ;; *** bug: we don't handle newline characters properly
 641       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 642         (push (substring arg pos new-pos) accum)
 643         (push "\\" accum)
 644         (push (list (aref arg new-pos)) accum)
 645         (setq pos (1+ new-pos)))
 646       (if (= pos 0)
 647           arg
 648         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 649
 650 (defun mm-auto-mode-alist ()
 651   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 652   (let ((alist auto-mode-alist)
 653         out)
 654     (while alist
 655       (when (listp (cdar alist))
 656         (push (car alist) out))
 657       (pop alist))
 658     (nreverse out)))
 659
 660 (defvar mm-inhibit-file-name-handlers
 661   '(jka-compr-handler image-file-handler)
 662   "A list of handlers doing (un)compression (etc) thingies.")
 663
 664 (defun mm-insert-file-contents (filename &optional visit beg end replace
 665                                          inhibit)
 666   "Like `insert-file-contents', q.v., but only reads in the file.
 667 A buffer may be modified in several ways after reading into the buffer due
 668 to advanced Emacs features, such as file-name-handlers, format decoding,
 669 find-file-hooks, etc.
 670 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 671   This function ensures that none of these modifications will take place."
 672   (let ((format-alist nil)
 673         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 674         (default-major-mode 'fundamental-mode)
 675         (enable-local-variables nil)
 676         (after-insert-file-functions nil)
 677         (enable-local-eval nil)
 678         (find-file-hooks nil)
 679         (inhibit-file-name-operation (if inhibit
 680                                          'insert-file-contents
 681                                        inhibit-file-name-operation))
 682         (inhibit-file-name-handlers
 683          (if inhibit
 684              (append mm-inhibit-file-name-handlers
 685                      inhibit-file-name-handlers)
 686            inhibit-file-name-handlers)))
 687     (insert-file-contents filename visit beg end replace)))
 688
 689 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 690   "Append the contents of the region to the end of file FILENAME.
 691 When called from a function, expects three arguments,
 692 START, END and FILENAME.  START and END are buffer positions
 693 saying what text to write.
 694 Optional fourth argument specifies the coding system to use when
 695 encoding the file.
 696 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 697   (let ((coding-system-for-write
 698          (or codesys mm-text-coding-system-for-write
 699              mm-text-coding-system))
 700         (inhibit-file-name-operation (if inhibit
 701                                          'append-to-file
 702                                        inhibit-file-name-operation))
 703         (inhibit-file-name-handlers
 704          (if inhibit
 705              (append mm-inhibit-file-name-handlers
 706                      inhibit-file-name-handlers)
 707            inhibit-file-name-handlers)))
 708     (append-to-file start end filename)))
 709
 710 (defun mm-write-region (start end filename &optional append visit lockname
 711                               coding-system inhibit)
 712
 713   "Like `write-region'.
 714 If INHIBIT is non-nil, inhibit `mm-inhibit-file-name-handlers'."
 715   (let ((coding-system-for-write
 716          (or coding-system mm-text-coding-system-for-write
 717              mm-text-coding-system))
 718         (inhibit-file-name-operation (if inhibit
 719                                          'write-region
 720                                        inhibit-file-name-operation))
 721         (inhibit-file-name-handlers
 722          (if inhibit
 723              (append mm-inhibit-file-name-handlers
 724                      inhibit-file-name-handlers)
 725            inhibit-file-name-handlers)))
 726     (write-region start end filename append visit lockname)))
 727
 728 (defun mm-image-load-path (&optional package)
 729   (let (dir result)
 730     (dolist (path load-path (nreverse result))
 731       (if (file-directory-p
 732            (setq dir (concat (file-name-directory
 733                               (directory-file-name path))
 734                              "etc/" (or package "gnus/"))))
 735           (push dir result))
 736       (push path result))))
 737
 738 (if (fboundp 'detect-coding-region)
 739     (defun mm-detect-coding-region (start end)
 740       "Like `detect-coding-region' except returning the best one."
 741       (let ((coding-systems
 742              (detect-coding-region (point) (point-max))))
 743         (or (car-safe coding-systems)
 744             coding-systems)))
 745   (defun mm-detect-coding-region (start end)
 746     (let ((point (point)))
 747       (goto-char start)
 748       (skip-chars-forward "\0-\177" end)
 749       (prog1
 750           (if (eq (point) end) 'ascii (mm-guess-charset))
 751         (goto-char point)))))
 752
 753 (if (fboundp 'coding-system-get)
 754     (defun mm-detect-mime-charset-region (start end)
 755       "Detect MIME charset of the text in the region between START and END."
 756       (let ((cs (mm-detect-coding-region start end)))
 757         (coding-system-get cs 'mime-charset)))
 758   (defun mm-detect-mime-charset-region (start end)
 759     "Detect MIME charset of the text in the region between START and END."
 760     (let ((cs (mm-detect-coding-region start end)))
 761       cs)))
 762
 763 (defun mm-guess-mime-charset ()
 764   "Guess the default MIME charset from the language environment."
 765   (let ((language-info
 766          (and (boundp 'current-language-environment)
 767               (assoc current-language-environment
 768                      language-info-alist)))
 769         item)
 770     (cond
 771      ((null language-info)
 772       'iso-8859-1)
 773      ((setq item
 774             (cadr
 775              (or (assq 'coding-priority language-info)
 776                  (assq 'coding-system language-info))))
 777       (if (fboundp 'coding-system-get)
 778           (or (coding-system-get item 'mime-charset)
 779               item)
 780         item))
 781      ((setq item (car (last (assq 'charset language-info))))
 782       (if (eq item 'ascii)
 783           'iso-8859-1
 784         (mm-mime-charset item)))
 785      (t
 786       'iso-8859-1))))
 787
 788 ;; It is not a MIME function, but some MIME functions use it.
 789 (defalias 'mm-make-temp-file
 790   (if (fboundp 'make-temp-file)
 791       'make-temp-file
 792     (lambda (prefix &optional dir-flag)
 793       (let ((file (expand-file-name
 794                    (make-temp-name prefix)
 795                    (if (fboundp 'temp-directory)
 796                        (temp-directory)
 797                      temporary-file-directory))))
 798         (if dir-flag
 799             (make-directory file))
 800         file))))
 801
 802 (provide 'mm-util)
 803
 804 ;;; mm-util.el ends here