git.chise.org Git - elisp/gnus.git-/blob - lisp/mm-util.el

   1 ;;; mm-util.el --- Utility functions for Mule and low level things
   2 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mail-prsvr)
  29
  30 (eval-and-compile
  31   (mapcar
  32    (lambda (elem)
  33      (let ((nfunc (intern (format "mm-%s" (car elem)))))
  34        (if (fboundp (car elem))
  35            (defalias nfunc (car elem))
  36          (defalias nfunc (cdr elem)))))
  37    '((decode-coding-string . (lambda (s a) s))
  38      (encode-coding-string . (lambda (s a) s))
  39      (encode-coding-region . ignore)
  40      (coding-system-list . ignore)
  41      (decode-coding-region . ignore)
  42      (char-int . identity)
  43      (device-type . ignore)
  44      (coding-system-equal . equal)
  45      (annotationp . ignore)
  46      (set-buffer-file-coding-system . ignore)
  47      (make-char
  48       . (lambda (charset int)
  49           (int-to-char int)))
  50      (read-charset
  51       . (lambda (prompt)
  52           "Return a charset."
  53           (intern
  54            (completing-read
  55             prompt
  56             (mapcar (lambda (e) (list (symbol-name (car e))))
  57                     mm-mime-mule-charset-alist)
  58             nil t))))
  59      (subst-char-in-string
  60       . (lambda (from to string) ;; stolen (and renamed) from nnheader.el
  61           "Replace characters in STRING from FROM to TO."
  62           (let ((string (substring string 0)) ;Copy string.
  63                 (len (length string))
  64                 (idx 0))
  65             ;; Replace all occurrences of FROM with TO.
  66             (while (< idx len)
  67               (when (= (aref string idx) from)
  68                 (aset string idx to))
  69               (setq idx (1+ idx)))
  70             string)))
  71      (string-as-unibyte . identity)
  72      (string-as-multibyte . identity)
  73      (multibyte-string-p . ignore))))
  74
  75 (eval-and-compile
  76   (defalias 'mm-char-or-char-int-p
  77     (cond
  78      ((fboundp 'char-or-char-int-p) 'char-or-char-int-p)
  79      ((fboundp 'char-valid-p) 'char-valid-p)
  80      (t 'identity))))
  81
  82 (eval-and-compile
  83   (defalias 'mm-read-coding-system
  84     (cond
  85      ((fboundp 'read-coding-system)
  86       (if (and (featurep 'xemacs)
  87                (<= (string-to-number emacs-version) 21.1))
  88           (lambda (prompt &optional default-coding-system)
  89             (read-coding-system prompt))
  90         'read-coding-system))
  91      (t (lambda (prompt &optional default-coding-system)
  92           "Prompt the user for a coding system."
  93           (completing-read
  94            prompt (mapcar (lambda (s) (list (symbol-name (car s))))
  95                           mm-mime-mule-charset-alist)))))))
  96
  97 (defvar mm-coding-system-list nil)
  98 (defun mm-get-coding-system-list ()
  99   "Get the coding system list."
 100   (or mm-coding-system-list
 101       (setq mm-coding-system-list (mm-coding-system-list))))
 102
 103 (defun mm-coding-system-p (sym)
 104   "Return non-nil if SYM is a coding system."
 105   (or (and (fboundp 'coding-system-p) (coding-system-p sym))
 106       (memq sym (mm-get-coding-system-list))))
 107
 108 (defvar mm-charset-synonym-alist
 109   `(
 110     ;; Perfectly fine?  A valid MIME name, anyhow.
 111     ,@(unless (mm-coding-system-p 'big5)
 112        '((big5 . cn-big5)))
 113     ;; Not in XEmacs, but it's not a proper MIME charset anyhow.
 114     ,@(unless (mm-coding-system-p 'x-ctext)
 115        '((x-ctext . ctext)))
 116     ;; Apparently not defined in Emacs 20, but is a valid MIME name.
 117     ,@(unless (mm-coding-system-p 'gb2312)
 118        '((gb2312 . cn-gb-2312)))
 119     ;; ISO-8859-15 is very similar to ISO-8859-1.
 120     ,@(unless (mm-coding-system-p 'iso-8859-15) ; Emacs 21 defines it.
 121        '((iso-8859-15 . iso-8859-1)))
 122     ;; Windows-1252 is actually a superset of Latin-1.  See also
 123     ;; `gnus-article-dumbquotes-map'.
 124     ,@(unless (mm-coding-system-p 'windows-1252)
 125        (if (mm-coding-system-p 'cp1252)
 126            '((windows-1252 . cp1252))
 127          '((windows-1252 . iso-8859-1))))
 128     ;; Windows-1250 is a variant of Latin-2 heavily used by Microsoft
 129     ;; Outlook users in Czech republic. Use this to allow reading of their
 130     ;; e-mails. cp1250 should be defined by M-x codepage-setup.
 131     ,@(if (and (not (mm-coding-system-p 'windows-1250))
 132                (mm-coding-system-p 'cp1250))
 133           '((windows-1250 . cp1250)))
 134     )
 135   "A mapping from invalid charset names to the real charset names.")
 136
 137 (defvar mm-binary-coding-system
 138   (cond
 139    ((mm-coding-system-p 'binary) 'binary)
 140    ((mm-coding-system-p 'no-conversion) 'no-conversion)
 141    (t nil))
 142   "100% binary coding system.")
 143
 144 (defvar mm-text-coding-system
 145   (or (if (memq system-type '(windows-nt ms-dos ms-windows))
 146           (and (mm-coding-system-p 'raw-text-dos) 'raw-text-dos)
 147         (and (mm-coding-system-p 'raw-text) 'raw-text))
 148       mm-binary-coding-system)
 149   "Text-safe coding system (For removing ^M).")
 150
 151 (defvar mm-text-coding-system-for-write nil
 152   "Text coding system for write.")
 153
 154 (defvar mm-auto-save-coding-system
 155   (cond
 156    ((mm-coding-system-p 'emacs-mule)
 157     (if (memq system-type '(windows-nt ms-dos ms-windows))
 158         (if (mm-coding-system-p 'emacs-mule-dos)
 159             'emacs-mule-dos mm-binary-coding-system)
 160       'emacs-mule))
 161    ((mm-coding-system-p 'escape-quoted) 'escape-quoted)
 162    (t mm-binary-coding-system))
 163   "Coding system of auto save file.")
 164
 165 (defvar mm-universal-coding-system mm-auto-save-coding-system
 166   "The universal coding system.")
 167
 168 ;; Fixme: some of the cars here aren't valid MIME charsets.  That
 169 ;; should only matter with XEmacs, though.
 170 (defvar mm-mime-mule-charset-alist
 171   `((us-ascii ascii)
 172     (iso-8859-1 latin-iso8859-1)
 173     (iso-8859-2 latin-iso8859-2)
 174     (iso-8859-3 latin-iso8859-3)
 175     (iso-8859-4 latin-iso8859-4)
 176     (iso-8859-5 cyrillic-iso8859-5)
 177     ;; Non-mule (X)Emacs uses the last mule-charset for 8bit characters.
 178     ;; The fake mule-charset, gnus-koi8-r, tells Gnus that the default
 179     ;; charset is koi8-r, not iso-8859-5.
 180     (koi8-r cyrillic-iso8859-5 gnus-koi8-r)
 181     (iso-8859-6 arabic-iso8859-6)
 182     (iso-8859-7 greek-iso8859-7)
 183     (iso-8859-8 hebrew-iso8859-8)
 184     (iso-8859-9 latin-iso8859-9)
 185     (iso-8859-14 latin-iso8859-14)
 186     (iso-8859-15 latin-iso8859-15)
 187     (viscii vietnamese-viscii-lower)
 188     (iso-2022-jp latin-jisx0201 japanese-jisx0208 japanese-jisx0208-1978)
 189     (euc-kr korean-ksc5601)
 190     (gb2312 chinese-gb2312)
 191     (big5 chinese-big5-1 chinese-big5-2)
 192     (tibetan tibetan)
 193     (thai-tis620 thai-tis620)
 194     (iso-2022-7bit ethiopic arabic-1-column arabic-2-column)
 195     (iso-2022-jp-2 latin-iso8859-1 greek-iso8859-7
 196                    latin-jisx0201 japanese-jisx0208-1978
 197                    chinese-gb2312 japanese-jisx0208
 198                    korean-ksc5601 japanese-jisx0212
 199                    katakana-jisx0201)
 200     (iso-2022-int-1 latin-iso8859-1 greek-iso8859-7
 201                     latin-jisx0201 japanese-jisx0208-1978
 202                     chinese-gb2312 japanese-jisx0208
 203                     korean-ksc5601 japanese-jisx0212
 204                     chinese-cns11643-1 chinese-cns11643-2)
 205     (iso-2022-int-1 latin-iso8859-1 latin-iso8859-2
 206                     cyrillic-iso8859-5 greek-iso8859-7
 207                     latin-jisx0201 japanese-jisx0208-1978
 208                     chinese-gb2312 japanese-jisx0208
 209                     korean-ksc5601 japanese-jisx0212
 210                     chinese-cns11643-1 chinese-cns11643-2
 211                     chinese-cns11643-3 chinese-cns11643-4
 212                     chinese-cns11643-5 chinese-cns11643-6
 213                     chinese-cns11643-7)
 214     ,(if (or (not (fboundp 'charsetp)) ;; non-Mule case
 215              (charsetp 'unicode-a)
 216              (not (mm-coding-system-p 'mule-utf-8)))
 217          '(utf-8 unicode-a unicode-b unicode-c unicode-d unicode-e)
 218        ;; If we have utf-8 we're in Mule 5+.
 219        (append '(utf-8)
 220                (delete 'ascii
 221                        (coding-system-get 'mule-utf-8 'safe-charsets)))))
 222   "Alist of MIME-charset/MULE-charsets.")
 223
 224 ;; Correct by construction, but should be unnecessary:
 225 ;; XEmacs hates it.
 226 (when (and (not (featurep 'xemacs))
 227            (fboundp 'coding-system-list)
 228            (fboundp 'sort-coding-systems))
 229   (setq mm-mime-mule-charset-alist
 230         (apply
 231          'nconc
 232          (mapcar
 233           (lambda (cs)
 234             (when (and (coding-system-get cs 'mime-charset)
 235                        (not (eq t (coding-system-get cs 'safe-charsets))))
 236               (list (cons (coding-system-get cs 'mime-charset)
 237                           (delq 'ascii
 238                                 (coding-system-get cs 'safe-charsets))))))
 239           (sort-coding-systems (coding-system-list 'base-only))))))
 240
 241 (defvar mm-hack-charsets '(iso-8859-15 iso-2022-jp-2)
 242   "A list of special charsets.
 243 Valid elements include:
 244 `iso-8859-15'    convert ISO-8859-1, -9 to ISO-8859-15 if ISO-8859-15 exists.
 245 `iso-2022-jp-2'  convert ISO-2022-jp to ISO-2022-jp-2 if ISO-2022-jp-2 exists."
 246 )
 247
 248 (defvar mm-iso-8859-15-compatible
 249   '((iso-8859-1 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE")
 250     (iso-8859-9 "\xA4\xA6\xA8\xB4\xB8\xBC\xBD\xBE\xD0\xDD\xDE\xF0\xFD\xFE"))
 251   "ISO-8859-15 exchangeable coding systems and inconvertible characters.")
 252
 253 (defvar mm-iso-8859-x-to-15-table
 254   (and (fboundp 'coding-system-p)
 255        (mm-coding-system-p 'iso-8859-15)
 256        (mapcar
 257         (lambda (cs)
 258           (if (mm-coding-system-p (car cs))
 259               (let ((c (string-to-char
 260                         (decode-coding-string "\341" (car cs)))))
 261                 (cons (char-charset c)
 262                       (cons
 263                        (- (string-to-char
 264                            (decode-coding-string "\341" 'iso-8859-15)) c)
 265                        (string-to-list (decode-coding-string (car (cdr cs))
 266                                                              (car cs))))))
 267             '(gnus-charset 0)))
 268         mm-iso-8859-15-compatible))
 269   "A table of the difference character between ISO-8859-X and ISO-8859-15.")
 270
 271 (defvar mm-coding-system-priorities nil
 272   "Preferred coding systems for encoding outgoing mails.
 273
 274 More than one suitable coding systems may be found for some texts.  By
 275 default, a coding system with the highest priority is used to encode
 276 outgoing mails (see `sort-coding-systems').  If this variable is set,
 277 it overrides the default priority.  For example, Japanese users may
 278 prefer iso-2022-jp to japanese-shift-jis:
 279
 280 \(setq mm-coding-system-priorities
 281   '(iso-2022-jp iso-2022-jp-2 japanese-shift-jis utf-8))
 282 ")
 283
 284 ;;; Internal variables:
 285
 286 ;;; Functions:
 287
 288 (defun mm-mule-charset-to-mime-charset (charset)
 289   "Return the MIME charset corresponding to the given Mule CHARSET."
 290   (if (fboundp 'find-coding-systems-for-charsets)
 291       (let (mime)
 292         (dolist (cs (find-coding-systems-for-charsets (list charset)))
 293           (unless mime
 294             (when cs
 295               (setq mime (coding-system-get cs 'mime-charset)))))
 296         mime)
 297     (let ((alist mm-mime-mule-charset-alist)
 298           out)
 299       (while alist
 300         (when (memq charset (cdar alist))
 301           (setq out (caar alist)
 302                 alist nil))
 303         (pop alist))
 304       out)))
 305
 306 (defun mm-charset-to-coding-system (charset &optional lbt)
 307   "Return coding-system corresponding to CHARSET.
 308 CHARSET is a symbol naming a MIME charset.
 309 If optional argument LBT (`unix', `dos' or `mac') is specified, it is
 310 used as the line break code type of the coding system."
 311   (when (stringp charset)
 312     (setq charset (intern (downcase charset))))
 313   (when lbt
 314     (setq charset (intern (format "%s-%s" charset lbt))))
 315   (cond
 316    ((null charset)
 317     charset)
 318    ;; Running in a non-MULE environment.
 319    ((null (mm-get-coding-system-list))
 320     charset)
 321    ;; ascii
 322    ((eq charset 'us-ascii)
 323     'ascii)
 324    ;; Check to see whether we can handle this charset.  (This depends
 325    ;; on there being some coding system matching each `mime-charset'
 326    ;; property defined, as there should be.)
 327    ((and (mm-coding-system-p charset)
 328 ;;; Doing this would potentially weed out incorrect charsets.
 329 ;;;      charset
 330 ;;;      (eq charset (coding-system-get charset 'mime-charset))
 331          )
 332     charset)
 333    ;; Translate invalid charsets.
 334    ((mm-coding-system-p (setq charset
 335                            (cdr (assq charset
 336                                       mm-charset-synonym-alist))))
 337     charset)
 338    ;; Last resort: search the coding system list for entries which
 339    ;; have the right mime-charset in case the canonical name isn't
 340    ;; defined (though it should be).
 341    ((let (cs)
 342       ;; mm-get-coding-system-list returns a list of cs without lbt.
 343       ;; Do we need -lbt?
 344       (dolist (c (mm-get-coding-system-list))
 345         (if (and (null cs)
 346                  (eq charset (coding-system-get c 'mime-charset)))
 347             (setq cs c)))
 348       cs))))
 349
 350 (defsubst mm-replace-chars-in-string (string from to)
 351   (mm-subst-char-in-string from to string))
 352
 353 (eval-and-compile
 354   (defvar mm-emacs-mule (and (not (featurep 'xemacs))
 355                              (boundp 'default-enable-multibyte-characters)
 356                              default-enable-multibyte-characters
 357                              (fboundp 'set-buffer-multibyte))
 358     "Emacs mule.")
 359
 360   (defvar mm-mule4-p (and mm-emacs-mule
 361                           (fboundp 'charsetp)
 362                           (not (charsetp 'eight-bit-control)))
 363     "Mule version 4.")
 364
 365   (if mm-emacs-mule
 366       (defun mm-enable-multibyte ()
 367         "Set the multibyte flag of the current buffer.
 368 Only do this if the default value of `enable-multibyte-characters' is
 369 non-nil.  This is a no-op in XEmacs."
 370         (set-buffer-multibyte t))
 371     (defalias 'mm-enable-multibyte 'ignore))
 372
 373   (if mm-emacs-mule
 374       (defun mm-disable-multibyte ()
 375         "Unset the multibyte flag of in the current buffer.
 376 This is a no-op in XEmacs."
 377         (set-buffer-multibyte nil))
 378     (defalias 'mm-disable-multibyte 'ignore))
 379
 380   (if mm-mule4-p
 381       (defun mm-enable-multibyte-mule4  ()
 382         "Enable multibyte in the current buffer.
 383 Only used in Emacs Mule 4."
 384         (set-buffer-multibyte t))
 385     (defalias 'mm-enable-multibyte-mule4 'ignore))
 386
 387   (if mm-mule4-p
 388       (defun mm-disable-multibyte-mule4 ()
 389         "Disable multibyte in the current buffer.
 390 Only used in Emacs Mule 4."
 391         (set-buffer-multibyte nil))
 392     (defalias 'mm-disable-multibyte-mule4 'ignore)))
 393
 394 (defun mm-preferred-coding-system (charset)
 395   ;; A typo in some Emacs versions.
 396   (or (get-charset-property charset 'preferred-coding-system)
 397       (get-charset-property charset 'prefered-coding-system)))
 398
 399 (defun mm-charset-after (&optional pos)
 400   "Return charset of a character in current buffer at position POS.
 401 If POS is nil, it defauls to the current point.
 402 If POS is out of range, the value is nil.
 403 If the charset is `composition', return the actual one."
 404   (let ((char (char-after pos)) charset)
 405     (if (< (mm-char-int char) 128)
 406         (setq charset 'ascii)
 407       ;; charset-after is fake in some Emacsen.
 408       (setq charset (and (fboundp 'char-charset) (char-charset char)))
 409       (if (eq charset 'composition)
 410           (let ((p (or pos (point))))
 411             (cadr (find-charset-region p (1+ p))))
 412         (if (and charset (not (memq charset '(ascii eight-bit-control
 413                                                     eight-bit-graphic))))
 414             charset
 415           (or
 416            mail-parse-mule-charset ;; cached mule-charset
 417            (progn
 418              (setq mail-parse-mule-charset
 419                    (and (boundp 'current-language-environment)
 420                         (car (last
 421                               (assq 'charset
 422                                     (assoc current-language-environment
 423                                            language-info-alist))))))
 424              (if (or (not mail-parse-mule-charset)
 425                      (eq mail-parse-mule-charset 'ascii))
 426                  (setq mail-parse-mule-charset
 427                        (or (car (last (assq mail-parse-charset
 428                                             mm-mime-mule-charset-alist)))
 429                            ;; Fixme: don't fix that!
 430                            'latin-iso8859-1)))
 431              mail-parse-mule-charset)))))))
 432
 433 (defun mm-mime-charset (charset)
 434   "Return the MIME charset corresponding to the given Mule CHARSET."
 435   (if (eq charset 'unknown)
 436       (error "The message contains non-printable characters, please use attachment"))
 437   (if (and (fboundp 'coding-system-get) (fboundp 'get-charset-property))
 438       ;; This exists in Emacs 20.
 439       (or
 440        (and (mm-preferred-coding-system charset)
 441             (coding-system-get
 442              (mm-preferred-coding-system charset) 'mime-charset))
 443        (and (eq charset 'ascii)
 444             'us-ascii)
 445        (mm-preferred-coding-system charset)
 446        (mm-mule-charset-to-mime-charset charset))
 447     ;; This is for XEmacs.
 448     (mm-mule-charset-to-mime-charset charset)))
 449
 450 (defun mm-delete-duplicates (list)
 451   "Simple  substitute for CL `delete-duplicates', testing with `equal'."
 452   (let (result head)
 453     (while list
 454       (setq head (car list))
 455       (setq list (delete head list))
 456       (setq result (cons head result)))
 457     (nreverse result)))
 458
 459 ;; It's not clear whether this is supposed to mean the global or local
 460 ;; setting.  I think it's used inconsistently.  -- fx
 461 (defsubst mm-multibyte-p ()
 462   "Say whether multibyte is enabled."
 463   (if (and (not (featurep 'xemacs))
 464            (boundp 'enable-multibyte-characters))
 465       enable-multibyte-characters
 466     (featurep 'mule)))
 467
 468 (defun mm-iso-8859-x-to-15-region (&optional b e)
 469   (if (fboundp 'char-charset)
 470       (let (charset item c inconvertible)
 471         (save-restriction
 472           (if e (narrow-to-region b e))
 473           (goto-char (point-min))
 474           (skip-chars-forward "\0-\177")
 475           (while (not (eobp))
 476             (cond
 477              ((not (setq item (assq (char-charset (setq c (char-after)))
 478                                     mm-iso-8859-x-to-15-table)))
 479               (forward-char))
 480              ((memq c (cdr (cdr item)))
 481               (setq inconvertible t)
 482               (forward-char))
 483              (t
 484               (insert-before-markers (prog1 (+ c (car (cdr item)))
 485                                        (delete-char 1))))
 486             (skip-chars-forward "\0-\177"))))
 487         (not inconvertible))))
 488
 489 (defun mm-sort-coding-systems-predicate (a b)
 490   (> (length (memq a mm-coding-system-priorities))
 491      (length (memq b mm-coding-system-priorities))))
 492
 493 (defun mm-find-mime-charset-region (b e &optional hack-charsets)
 494   "Return the MIME charsets needed to encode the region between B and E.
 495 nil means ASCII, a single-element list represents an appropriate MIME
 496 charset, and a longer list means no appropriate charset."
 497   (let (charsets)
 498     ;; The return possibilities of this function are a mess...
 499     (or (and (mm-multibyte-p)
 500              (fboundp 'find-coding-systems-region)
 501              ;; Find the mime-charset of the most preferred coding
 502              ;; system that has one.
 503              (let ((systems (find-coding-systems-region b e)))
 504                (when mm-coding-system-priorities
 505                  (setq systems
 506                        (sort systems 'mm-sort-coding-systems-predicate)))
 507                ;; Fixme: The `mime-charset' (`x-ctext') of `compound-text'
 508                ;; is not in the IANA list.
 509                (setq systems (delq 'compound-text systems))
 510                (unless (equal systems '(undecided))
 511                  (while systems
 512                    (let ((cs (coding-system-get (pop systems) 'mime-charset)))
 513                      (if cs
 514                          (setq systems nil
 515                                charsets (list cs))))))
 516                charsets))
 517         ;; Otherwise we're not multibyte, XEmacs or a single coding
 518         ;; system won't cover it.
 519         (setq charsets
 520               (mm-delete-duplicates
 521                (mapcar 'mm-mime-charset
 522                        (delq 'ascii
 523                              (mm-find-charset-region b e))))))
 524     (if (and (memq 'iso-8859-15 charsets)
 525              (memq 'iso-8859-15 hack-charsets)
 526              (save-excursion (mm-iso-8859-x-to-15-region b e)))
 527         (mapcar (lambda (x) (setq charsets (delq (car x) charsets)))
 528                 mm-iso-8859-15-compatible))
 529     (if (and (memq 'iso-2022-jp-2 charsets)
 530              (memq 'iso-2022-jp-2 hack-charsets))
 531         (setq charsets (delq 'iso-2022-jp charsets)))
 532     charsets))
 533
 534 (defmacro mm-with-unibyte-buffer (&rest forms)
 535   "Create a temporary buffer, and evaluate FORMS there like `progn'.
 536 Use unibyte mode for this."
 537   `(let (default-enable-multibyte-characters)
 538      (with-temp-buffer ,@forms)))
 539 (put 'mm-with-unibyte-buffer 'lisp-indent-function 0)
 540 (put 'mm-with-unibyte-buffer 'edebug-form-spec '(body))
 541
 542 (defmacro mm-with-unibyte-current-buffer (&rest forms)
 543   "Evaluate FORMS with current current buffer temporarily made unibyte.
 544 Also bind `default-enable-multibyte-characters' to nil.
 545 Equivalent to `progn' in XEmacs"
 546   (let ((multibyte (make-symbol "multibyte"))
 547         (buffer (make-symbol "buffer")))
 548     `(if mm-emacs-mule
 549          (let ((,multibyte enable-multibyte-characters)
 550                (,buffer (current-buffer)))
 551            (unwind-protect
 552                (let (default-enable-multibyte-characters)
 553                  (set-buffer-multibyte nil)
 554                  ,@forms)
 555              (set-buffer ,buffer)
 556              (set-buffer-multibyte ,multibyte)))
 557        (let (default-enable-multibyte-characters)
 558          ,@forms))))
 559 (put 'mm-with-unibyte-current-buffer 'lisp-indent-function 0)
 560 (put 'mm-with-unibyte-current-buffer 'edebug-form-spec '(body))
 561
 562 (defmacro mm-with-unibyte-current-buffer-mule4 (&rest forms)
 563   "Evaluate FORMS there like `progn' in current buffer.
 564 Mule4 only."
 565   (let ((multibyte (make-symbol "multibyte"))
 566         (buffer (make-symbol "buffer")))
 567     `(if mm-mule4-p
 568          (let ((,multibyte enable-multibyte-characters)
 569                (,buffer (current-buffer)))
 570            (unwind-protect
 571                (let (default-enable-multibyte-characters)
 572                  (set-buffer-multibyte nil)
 573                  ,@forms)
 574              (set-buffer ,buffer)
 575              (set-buffer-multibyte ,multibyte)))
 576        (let (default-enable-multibyte-characters)
 577          ,@forms))))
 578 (put 'mm-with-unibyte-current-buffer-mule4 'lisp-indent-function 0)
 579 (put 'mm-with-unibyte-current-buffer-mule4 'edebug-form-spec '(body))
 580
 581 (defmacro mm-with-unibyte (&rest forms)
 582   "Eval the FORMS with the default value of `enable-multibyte-characters' nil, ."
 583   `(let (default-enable-multibyte-characters)
 584      ,@forms))
 585 (put 'mm-with-unibyte 'lisp-indent-function 0)
 586 (put 'mm-with-unibyte 'edebug-form-spec '(body))
 587
 588 (defun mm-find-charset-region (b e)
 589   "Return a list of Emacs charsets in the region B to E."
 590   (cond
 591    ((and (mm-multibyte-p)
 592          (fboundp 'find-charset-region))
 593     ;; Remove composition since the base charsets have been included.
 594     ;; Remove eight-bit-*, treat them as ascii.
 595     (let ((css (find-charset-region b e)))
 596       (mapcar (lambda (cs) (setq css (delq cs css)))
 597               '(composition eight-bit-control eight-bit-graphic
 598                             control-1))
 599       css))
 600    (t
 601     ;; We are in a unibyte buffer or XEmacs non-mule, so we futz around a bit.
 602     (save-excursion
 603       (save-restriction
 604         (narrow-to-region b e)
 605         (goto-char (point-min))
 606         (skip-chars-forward "\0-\177")
 607         (if (eobp)
 608             '(ascii)
 609           (let (charset)
 610             (setq charset
 611                   (and (boundp 'current-language-environment)
 612                        (car (last (assq 'charset
 613                                         (assoc current-language-environment
 614                                                language-info-alist))))))
 615             (if (eq charset 'ascii) (setq charset nil))
 616             (or charset
 617                 (setq charset
 618                       (car (last (assq mail-parse-charset
 619                                        mm-mime-mule-charset-alist)))))
 620             (list 'ascii (or charset 'latin-iso8859-1)))))))))
 621
 622 (if (fboundp 'shell-quote-argument)
 623     (defalias 'mm-quote-arg 'shell-quote-argument)
 624   (defun mm-quote-arg (arg)
 625     "Return a version of ARG that is safe to evaluate in a shell."
 626     (let ((pos 0) new-pos accum)
 627       ;; *** bug: we don't handle newline characters properly
 628       (while (setq new-pos (string-match "[]*[;!'`\"$\\& \t{} |()<>]" arg pos))
 629         (push (substring arg pos new-pos) accum)
 630         (push "\\" accum)
 631         (push (list (aref arg new-pos)) accum)
 632         (setq pos (1+ new-pos)))
 633       (if (= pos 0)
 634           arg
 635         (apply 'concat (nconc (nreverse accum) (list (substring arg pos))))))))
 636
 637 (defun mm-auto-mode-alist ()
 638   "Return an `auto-mode-alist' with only the .gz (etc) thingies."
 639   (let ((alist auto-mode-alist)
 640         out)
 641     (while alist
 642       (when (listp (cdar alist))
 643         (push (car alist) out))
 644       (pop alist))
 645     (nreverse out)))
 646
 647 (defvar mm-inhibit-file-name-handlers
 648   '(jka-compr-handler image-file-handler)
 649   "A list of handlers doing (un)compression (etc) thingies.")
 650
 651 (defun mm-insert-file-contents (filename &optional visit beg end replace
 652                                          inhibit)
 653   "Like `insert-file-contents', q.v., but only reads in the file.
 654 A buffer may be modified in several ways after reading into the buffer due
 655 to advanced Emacs features, such as file-name-handlers, format decoding,
 656 find-file-hooks, etc.
 657 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers.
 658   This function ensures that none of these modifications will take place."
 659   (let ((format-alist nil)
 660         (auto-mode-alist (if inhibit nil (mm-auto-mode-alist)))
 661         (default-major-mode 'fundamental-mode)
 662         (enable-local-variables nil)
 663         (after-insert-file-functions nil)
 664         (enable-local-eval nil)
 665         (find-file-hooks nil)
 666         (inhibit-file-name-operation (if inhibit
 667                                          'insert-file-contents
 668                                        inhibit-file-name-operation))
 669         (inhibit-file-name-handlers
 670          (if inhibit
 671              (append mm-inhibit-file-name-handlers
 672                      inhibit-file-name-handlers)
 673            inhibit-file-name-handlers)))
 674     (insert-file-contents filename visit beg end replace)))
 675
 676 (defun mm-append-to-file (start end filename &optional codesys inhibit)
 677   "Append the contents of the region to the end of file FILENAME.
 678 When called from a function, expects three arguments,
 679 START, END and FILENAME.  START and END are buffer positions
 680 saying what text to write.
 681 Optional fourth argument specifies the coding system to use when
 682 encoding the file.
 683 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 684   (let ((coding-system-for-write
 685          (or codesys mm-text-coding-system-for-write
 686              mm-text-coding-system))
 687         (inhibit-file-name-operation (if inhibit
 688                                          'append-to-file
 689                                        inhibit-file-name-operation))
 690         (inhibit-file-name-handlers
 691          (if inhibit
 692              (append mm-inhibit-file-name-handlers
 693                      inhibit-file-name-handlers)
 694            inhibit-file-name-handlers)))
 695     (append-to-file start end filename)))
 696
 697 (defun mm-write-region (start end filename &optional append visit lockname
 698                               coding-system inhibit)
 699
 700   "Like `write-region'.
 701 If INHIBIT is non-nil, inhibit mm-inhibit-file-name-handlers."
 702   (let ((coding-system-for-write
 703          (or coding-system mm-text-coding-system-for-write
 704              mm-text-coding-system))
 705         (inhibit-file-name-operation (if inhibit
 706                                          'write-region
 707                                        inhibit-file-name-operation))
 708         (inhibit-file-name-handlers
 709          (if inhibit
 710              (append mm-inhibit-file-name-handlers
 711                      inhibit-file-name-handlers)
 712            inhibit-file-name-handlers)))
 713     (write-region start end filename append visit lockname)))
 714
 715 (defun mm-image-load-path (&optional package)
 716   (let (dir result)
 717     (dolist (path load-path (nreverse result))
 718       (if (file-directory-p
 719            (setq dir (concat (file-name-directory
 720                               (directory-file-name path))
 721                              "etc/" (or package "gnus/"))))
 722           (push dir result))
 723       (push path result))))
 724
 725 (provide 'mm-util)
 726
 727 ;;; mm-util.el ends here