git.chise.org Git - elisp/gnus.git-/blob - lisp/nnagent.el

   1 ;;; nnagent.el --- offline backend for Gnus
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'nnoo)
  32 (eval-when-compile (require 'cl))
  33 (require 'gnus-agent)
  34 (require 'nnml)
  35
  36 (nnoo-declare nnagent
  37   nnml)
  38
  39 \f
  40
  41 (defconst nnagent-version "nnagent 1.0")
  42
  43 (defvoo nnagent-directory nil
  44   "Internal variable."
  45   nnml-directory)
  46
  47 (defvoo nnagent-active-file nil
  48   "Internal variable."
  49   nnml-active-file)
  50
  51 (defvoo nnagent-newsgroups-file nil
  52   "Internal variable."
  53   nnml-newsgroups-file)
  54
  55 (defvoo nnagent-get-new-mail nil
  56   "Internal variable."
  57   nnml-get-new-mail)
  58
  59 ;;; Interface functions.
  60
  61 (nnoo-define-basics nnagent)
  62
  63 (defun nnagent-server (server)
  64   (and server (format "%s+%s" (car gnus-command-method) server)))
  65
  66 (deffoo nnagent-open-server (server &optional defs)
  67   (setq defs
  68         `((nnagent-directory ,(gnus-agent-directory))
  69           (nnagent-active-file ,(gnus-agent-lib-file "active"))
  70           (nnagent-newsgroups-file ,(gnus-agent-lib-file "newsgroups"))
  71           (nnagent-get-new-mail nil)))
  72   (nnoo-change-server 'nnagent
  73                       (nnagent-server server)
  74                       defs)
  75   (let ((dir (gnus-agent-directory))
  76         err)
  77     (cond
  78      ((not (condition-case arg
  79                (file-exists-p dir)
  80              (ftp-error (setq err (format "%s" arg)))))
  81       (nnagent-close-server)
  82       (nnheader-report
  83        'nnagent (or err
  84                     (format "No such file or directory: %s" dir))))
  85      ((not (file-directory-p (file-truename dir)))
  86       (nnagent-close-server)
  87       (nnheader-report 'nnagent "Not a directory: %s" dir))
  88      (t
  89       (nnheader-report 'nnagent "Opened server %s using directory %s"
  90                        server dir)
  91       t))))
  92
  93 (deffoo nnagent-retrieve-groups (groups &optional server)
  94   (save-excursion
  95     (cond
  96      ((file-exists-p (gnus-agent-lib-file "groups"))
  97       (nnmail-find-file (gnus-agent-lib-file "groups"))
  98       'groups)
  99      ((file-exists-p (gnus-agent-lib-file "active"))
 100       (nnmail-find-file (gnus-agent-lib-file "active"))
 101       'active)
 102      (t nil))))
 103
 104 (defun nnagent-request-type (group article)
 105   (unless (stringp article)
 106     (let ((gnus-plugged t))
 107       (if (not (gnus-check-backend-function
 108                 'request-type (car gnus-command-method)))
 109           'unknown
 110         (funcall (gnus-get-function gnus-command-method 'request-type)
 111                  (gnus-group-real-name group) article)))))
 112
 113 (deffoo nnagent-request-newgroups (date server)
 114   nil)
 115
 116 (deffoo nnagent-request-update-info (group info &optional server)
 117   nil)
 118
 119 (deffoo nnagent-request-post (&optional server)
 120   (gnus-agent-insert-meta-information 'news gnus-command-method)
 121   (gnus-request-accept-article "nndraft:queue" nil t t))
 122
 123 (deffoo nnagent-request-set-mark (group action server)
 124   (with-temp-buffer
 125     (insert (format "(%s-request-set-mark \"%s\" '%s \"%s\")\n"
 126                     (nth 0 gnus-command-method) group action
 127                     (or server (nth 1 gnus-command-method))))
 128     (append-to-file (point-min) (point-max) (gnus-agent-lib-file "flags")))
 129   nil)
 130
 131 (deffoo nnagent-retrieve-headers (articles &optional group server fetch-old)
 132   (let ((file (gnus-agent-article-name ".overview" group))
 133         arts n)
 134     (save-excursion
 135       (gnus-agent-load-alist group)
 136       (setq arts (gnus-set-difference articles
 137                                       (mapcar 'car gnus-agent-article-alist)))
 138       (set-buffer nntp-server-buffer)
 139       (erase-buffer)
 140       (nnheader-insert-file-contents file)
 141       (goto-char (point-min))
 142       (while (and arts (not (eobp)))
 143         (cond
 144          ((looking-at "[0-9]")
 145           (setq n (read (current-buffer)))
 146           (if (> n (car arts))
 147               (beginning-of-line))
 148           (while (and arts (> n (car arts)))
 149             (insert (format
 150                      "%d\t[Undownloaded article %d]\tGnus Agent\t\t\t\n"
 151                      (car arts) (car arts)))
 152             (pop arts))
 153           (if (and arts (= n (car arts)))
 154             (pop arts))))
 155         (forward-line 1))
 156       (while (and arts)
 157         (insert (format
 158                  "%d\t[Undownloaded article %d]\tGnus Agent\t\t\t\n"
 159                  (car arts) (car arts)))
 160         (pop arts))
 161       (if (and fetch-old
 162                (not (numberp fetch-old)))
 163           t                             ; Don't remove anything.
 164         (nnheader-nov-delete-outside-range
 165          (if fetch-old (max 1 (- (car articles) fetch-old))
 166            (car articles))
 167          (car (last articles)))
 168         t)
 169       'nov)))
 170
 171 (deffoo nnagent-request-group (group &optional server dont-check)
 172   (nnoo-parent-function 'nnagent 'nnml-request-group
 173                         (list group (nnagent-server server) dont-check)))
 174
 175 (deffoo nnagent-close-group (group &optional server)
 176   (nnoo-parent-function 'nnagent 'nnml-close-group
 177                         (list group (nnagent-server server))))
 178
 179 (deffoo nnagent-request-accept-article (group &optional server last)
 180   (nnoo-parent-function 'nnagent 'nnml-request-accept-article
 181                         (list group (nnagent-server server) last)))
 182
 183 (deffoo nnagent-request-article (id &optional group server buffer)
 184   (nnoo-parent-function 'nnagent 'nnml-request-article
 185                         (list id group (nnagent-server server) buffer)))
 186
 187 (deffoo nnagent-request-create-group (group &optional server args)
 188   (nnoo-parent-function 'nnagent 'nnml-request-create-group
 189                         (list group (nnagent-server server) args)))
 190
 191 (deffoo nnagent-request-delete-group (group &optional force server)
 192   (nnoo-parent-function 'nnagent 'nnml-request-delete-group
 193                         (list group force (nnagent-server server))))
 194
 195 (deffoo nnagent-request-expire-articles (articles group &optional server force)
 196   (nnoo-parent-function 'nnagent 'nnml-request-expire-articles
 197                         (list articles group (nnagent-server server) force)))
 198
 199 (deffoo nnagent-request-list (&optional server)
 200   (nnoo-parent-function 'nnagent 'nnml-request-list
 201                         (list (nnagent-server server))))
 202
 203 (deffoo nnagent-request-list-newsgroups (&optional server)
 204   (nnoo-parent-function 'nnagent 'nnml-request-list-newsgroups
 205                         (list (nnagent-server server))))
 206
 207 (deffoo nnagent-request-move-article
 208     (article group server accept-form &optional last)
 209   (nnoo-parent-function 'nnagent 'nnml-request-move-article
 210                         (list article group (nnagent-server server)
 211                               accept-form last)))
 212
 213 (deffoo nnagent-request-rename-group (group new-name &optional server)
 214   (nnoo-parent-function 'nnagent 'nnml-request-rename-group
 215                         (list group new-name (nnagent-server server))))
 216
 217 (deffoo nnagent-request-scan (&optional group server)
 218   (nnoo-parent-function 'nnagent 'nnml-request-scan
 219                         (list group (nnagent-server server))))
 220
 221 (deffoo nnagent-set-status (article name value &optional group server)
 222   (nnoo-parent-function 'nnagent 'nnml-set-status
 223                         (list article name value group (nnagent-server server))))
 224
 225 (deffoo nnagent-server-opened (&optional server)
 226   (nnoo-parent-function 'nnagent 'nnml-server-opened
 227                         (list (nnagent-server server))))
 228
 229 (deffoo nnagent-status-message (&optional server)
 230   (nnoo-parent-function 'nnagent 'nnml-status-message
 231                         (list (nnagent-server server))))
 232
 233 (deffoo nnagent-request-regenerate (server)
 234   (nnoo-parent-function 'nnagent 'nnml-request-regenerate
 235                         (list (nnagent-server server))))
 236
 237 ;; Use nnml functions for just about everything.
 238 (nnoo-import nnagent
 239   (nnml))
 240
 241 \f
 242 ;;; Internal functions.
 243
 244 (provide 'nnagent)
 245
 246 ;;; nnagent.el ends here