git.chise.org Git - elisp/gnus.git-/blob - lisp/nnbabyl.el

   1 ;;; nnbabyl.el --- rmail mbox access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1099, 2000, 2001
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; For an overview of what the interface functions do, please see the
  30 ;; Gnus sources.
  31
  32 ;;; Code:
  33
  34 (eval-when-compile (require 'cl))
  35
  36 (require 'nnheader)
  37 (condition-case nil
  38     (require 'rmail)
  39   (t (nnheader-message
  40       5 "Ignore rmail errors from this file, you don't have rmail")))
  41 (require 'nnmail)
  42 (require 'nnoo)
  43
  44 (nnoo-declare nnbabyl)
  45
  46 (defvoo nnbabyl-mbox-file (expand-file-name "~/RMAIL")
  47   "The name of the rmail box file in the users home directory.")
  48
  49 (defvoo nnbabyl-active-file (expand-file-name "~/.rmail-active")
  50   "The name of the active file for the rmail box.")
  51
  52 (defvoo nnbabyl-get-new-mail t
  53   "If non-nil, nnbabyl will check the incoming mail file and split the mail.")
  54
  55
  56 (defvoo nnbabyl-prepare-save-mail-hook nil
  57   "Hook run narrowed to an article before saving.")
  58
  59 \f
  60
  61 (defvar nnbabyl-mail-delimiter "\^_")
  62
  63 (defconst nnbabyl-version "nnbabyl 1.0"
  64   "nnbabyl version.")
  65
  66 (defvoo nnbabyl-mbox-buffer nil)
  67 (defvoo nnbabyl-current-group nil)
  68 (defvoo nnbabyl-status-string "")
  69 (defvoo nnbabyl-group-alist nil)
  70 (defvoo nnbabyl-active-timestamp nil)
  71
  72 (defvoo nnbabyl-previous-buffer-mode nil)
  73
  74 (eval-and-compile
  75   (autoload 'gnus-set-text-properties "gnus-ems"))
  76
  77 \f
  78
  79 ;;; Interface functions
  80
  81 (nnoo-define-basics nnbabyl)
  82
  83 (deffoo nnbabyl-retrieve-headers (articles &optional group server fetch-old)
  84   (save-excursion
  85     (set-buffer nntp-server-buffer)
  86     (erase-buffer)
  87     (let ((number (length articles))
  88           (count 0)
  89           (delim (concat "^" nnbabyl-mail-delimiter))
  90           article art-string start stop)
  91       (nnbabyl-possibly-change-newsgroup group server)
  92       (while (setq article (pop articles))
  93         (setq art-string (nnbabyl-article-string article))
  94         (set-buffer nnbabyl-mbox-buffer)
  95         (end-of-line)
  96         (when (or (search-forward art-string nil t)
  97                   (search-backward art-string nil t))
  98           (unless (re-search-backward delim nil t)
  99             (goto-char (point-min)))
 100           (while (and (not (looking-at ".+:"))
 101                       (zerop (forward-line 1))))
 102           (setq start (point))
 103           (search-forward "\n\n" nil t)
 104           (setq stop (1- (point)))
 105           (set-buffer nntp-server-buffer)
 106           (insert "221 ")
 107           (princ article (current-buffer))
 108           (insert " Article retrieved.\n")
 109           (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 110           (goto-char (point-max))
 111           (insert ".\n"))
 112         (and (numberp nnmail-large-newsgroup)
 113              (> number nnmail-large-newsgroup)
 114              (zerop (% (incf count) 20))
 115              (nnheader-message 5 "nnbabyl: Receiving headers... %d%%"
 116                                (/ (* count 100) number))))
 117
 118       (and (numberp nnmail-large-newsgroup)
 119            (> number nnmail-large-newsgroup)
 120            (nnheader-message 5 "nnbabyl: Receiving headers...done"))
 121
 122       (set-buffer nntp-server-buffer)
 123       (nnheader-fold-continuation-lines)
 124       'headers)))
 125
 126 (deffoo nnbabyl-open-server (server &optional defs)
 127   (nnoo-change-server 'nnbabyl server defs)
 128   (nnbabyl-create-mbox)
 129   (cond
 130    ((not (file-exists-p nnbabyl-mbox-file))
 131     (nnbabyl-close-server)
 132     (nnheader-report 'nnbabyl "No such file: %s" nnbabyl-mbox-file))
 133    ((file-directory-p nnbabyl-mbox-file)
 134     (nnbabyl-close-server)
 135     (nnheader-report 'nnbabyl "Not a regular file: %s" nnbabyl-mbox-file))
 136    (t
 137     (nnheader-report 'nnbabyl "Opened server %s using mbox %s" server
 138                      nnbabyl-mbox-file)
 139     t)))
 140
 141 (deffoo nnbabyl-close-server (&optional server)
 142   ;; Restore buffer mode.
 143   (when (and (nnbabyl-server-opened)
 144              nnbabyl-previous-buffer-mode)
 145     (save-excursion
 146       (set-buffer nnbabyl-mbox-buffer)
 147       (narrow-to-region
 148        (caar nnbabyl-previous-buffer-mode)
 149        (cdar nnbabyl-previous-buffer-mode))
 150       (funcall (cdr nnbabyl-previous-buffer-mode))))
 151   (nnoo-close-server 'nnbabyl server)
 152   (setq nnbabyl-mbox-buffer nil)
 153   t)
 154
 155 (deffoo nnbabyl-server-opened (&optional server)
 156   (and (nnoo-current-server-p 'nnbabyl server)
 157        nnbabyl-mbox-buffer
 158        (buffer-name nnbabyl-mbox-buffer)
 159        nntp-server-buffer
 160        (buffer-name nntp-server-buffer)))
 161
 162 (deffoo nnbabyl-request-article (article &optional newsgroup server buffer)
 163   (nnbabyl-possibly-change-newsgroup newsgroup server)
 164   (save-excursion
 165     (set-buffer nnbabyl-mbox-buffer)
 166     (goto-char (point-min))
 167     (when (search-forward (nnbabyl-article-string article) nil t)
 168       (let (start stop summary-line)
 169         (unless (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 170           (goto-char (point-min))
 171           (end-of-line))
 172         (while (and (not (looking-at ".+:"))
 173                     (zerop (forward-line 1))))
 174         (setq start (point))
 175         (or (when (re-search-forward
 176                    (concat "^" nnbabyl-mail-delimiter) nil t)
 177               (beginning-of-line)
 178               t)
 179             (goto-char (point-max)))
 180         (setq stop (point))
 181         (let ((nntp-server-buffer (or buffer nntp-server-buffer)))
 182           (set-buffer nntp-server-buffer)
 183           (erase-buffer)
 184           (insert-buffer-substring nnbabyl-mbox-buffer start stop)
 185           (goto-char (point-min))
 186           ;; If there is an EOOH header, then we have to remove some
 187           ;; duplicated headers.
 188           (setq summary-line (looking-at "Summary-line:"))
 189           (when (search-forward "\n*** EOOH ***" nil t)
 190             (if summary-line
 191                 ;; The headers to be deleted are located before the
 192                 ;; EOOH line...
 193                 (delete-region (point-min) (progn (forward-line 1)
 194                                                   (point)))
 195               ;; ...or after.
 196               (delete-region (progn (beginning-of-line) (point))
 197                              (or (search-forward "\n\n" nil t)
 198                                  (point)))))
 199           (if (numberp article)
 200               (cons nnbabyl-current-group article)
 201             (nnbabyl-article-group-number)))))))
 202
 203 (deffoo nnbabyl-request-group (group &optional server dont-check)
 204   (let ((active (cadr (assoc group nnbabyl-group-alist))))
 205     (save-excursion
 206       (cond
 207        ((or (null active)
 208             (null (nnbabyl-possibly-change-newsgroup group server)))
 209         (nnheader-report 'nnbabyl "No such group: %s" group))
 210        (dont-check
 211         (nnheader-report 'nnbabyl "Selected group %s" group)
 212         (nnheader-insert ""))
 213        (t
 214         (nnheader-report 'nnbabyl "Selected group %s" group)
 215         (nnheader-insert "211 %d %d %d %s\n"
 216                          (1+ (- (cdr active) (car active)))
 217                          (car active) (cdr active) group))))))
 218
 219 (deffoo nnbabyl-request-scan (&optional group server)
 220   (nnbabyl-possibly-change-newsgroup group server)
 221   (nnbabyl-read-mbox)
 222   (nnmail-get-new-mail
 223    'nnbabyl
 224    (lambda ()
 225      (save-excursion
 226        (set-buffer nnbabyl-mbox-buffer)
 227        (save-buffer)))
 228    (file-name-directory nnbabyl-mbox-file)
 229    group
 230    (lambda ()
 231      (save-excursion
 232        (let ((in-buf (current-buffer)))
 233          (goto-char (point-min))
 234          (while (search-forward "\n\^_\n" nil t)
 235            (delete-char -1))
 236          (set-buffer nnbabyl-mbox-buffer)
 237          (goto-char (point-max))
 238          (search-backward "\n\^_" nil t)
 239          (goto-char (match-end 0))
 240          (insert-buffer-substring in-buf)))
 241      (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))))
 242
 243 (deffoo nnbabyl-close-group (group &optional server)
 244   t)
 245
 246 (deffoo nnbabyl-request-create-group (group &optional server args)
 247   (nnmail-activate 'nnbabyl)
 248   (unless (assoc group nnbabyl-group-alist)
 249     (push (list group (cons 1 0))
 250           nnbabyl-group-alist)
 251     (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))
 252   t)
 253
 254 (deffoo nnbabyl-request-list (&optional server)
 255   (save-excursion
 256     (nnmail-find-file nnbabyl-active-file)
 257     (setq nnbabyl-group-alist (nnmail-get-active))
 258     t))
 259
 260 (deffoo nnbabyl-request-newgroups (date &optional server)
 261   (nnbabyl-request-list server))
 262
 263 (deffoo nnbabyl-request-list-newsgroups (&optional server)
 264   (nnheader-report 'nnbabyl "nnbabyl: LIST NEWSGROUPS is not implemented."))
 265
 266 (deffoo nnbabyl-request-expire-articles
 267     (articles newsgroup &optional server force)
 268   (nnbabyl-possibly-change-newsgroup newsgroup server)
 269   (let* ((is-old t)
 270          rest)
 271     (nnmail-activate 'nnbabyl)
 272
 273     (save-excursion
 274       (set-buffer nnbabyl-mbox-buffer)
 275       (gnus-set-text-properties (point-min) (point-max) nil)
 276       (while (and articles is-old)
 277         (goto-char (point-min))
 278         (when (search-forward (nnbabyl-article-string (car articles)) nil t)
 279           (if (setq is-old
 280                     (nnmail-expired-article-p
 281                      newsgroup
 282                      (buffer-substring
 283                       (point) (progn (end-of-line) (point))) force))
 284               (progn
 285                 (unless (eq nnmail-expiry-target 'delete)
 286                   (with-temp-buffer
 287                     (nnbabyl-request-article (car articles)
 288                                              newsgroup server
 289                                              (current-buffer))
 290                     (let ((nnml-current-directory nil))
 291                       (nnmail-expiry-target-group
 292                        nnmail-expiry-target newsgroup)))
 293                   (nnbabyl-possibly-change-newsgroup newsgroup server))
 294                 (nnheader-message 5 "Deleting article %d in %s..."
 295                                   (car articles) newsgroup)
 296                 (nnbabyl-delete-mail))
 297             (push (car articles) rest)))
 298         (setq articles (cdr articles)))
 299       (save-buffer)
 300       ;; Find the lowest active article in this group.
 301       (let ((active (nth 1 (assoc newsgroup nnbabyl-group-alist))))
 302         (goto-char (point-min))
 303         (while (and (not (search-forward
 304                           (nnbabyl-article-string (car active)) nil t))
 305                     (<= (car active) (cdr active)))
 306           (setcar active (1+ (car active)))
 307           (goto-char (point-min))))
 308       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 309       (nconc rest articles))))
 310
 311 (deffoo nnbabyl-request-move-article
 312     (article group server accept-form &optional last)
 313   (let ((buf (get-buffer-create " *nnbabyl move*"))
 314         result)
 315     (and
 316      (nnbabyl-request-article article group server)
 317      (save-excursion
 318        (set-buffer buf)
 319        (insert-buffer-substring nntp-server-buffer)
 320        (goto-char (point-min))
 321        (while (re-search-forward
 322                "^X-Gnus-Newsgroup:"
 323                (save-excursion (search-forward "\n\n" nil t) (point)) t)
 324          (delete-region (progn (beginning-of-line) (point))
 325                         (progn (forward-line 1) (point))))
 326        (setq result (eval accept-form))
 327        (kill-buffer (current-buffer))
 328        result)
 329      (save-excursion
 330        (nnbabyl-possibly-change-newsgroup group server)
 331        (set-buffer nnbabyl-mbox-buffer)
 332        (goto-char (point-min))
 333        (if (search-forward (nnbabyl-article-string article) nil t)
 334            (nnbabyl-delete-mail))
 335        (and last (save-buffer))))
 336     result))
 337
 338 (deffoo nnbabyl-request-accept-article (group &optional server last)
 339   (nnbabyl-possibly-change-newsgroup group server)
 340   (nnmail-check-syntax)
 341   (let ((buf (current-buffer))
 342         result beg)
 343     (and
 344      (nnmail-activate 'nnbabyl)
 345      (save-excursion
 346        (goto-char (point-min))
 347        (search-forward "\n\n" nil t)
 348        (forward-line -1)
 349        (save-excursion
 350          (while (re-search-backward "^X-Gnus-Newsgroup: " beg t)
 351            (delete-region (point) (progn (forward-line 1) (point)))))
 352        (when nnmail-cache-accepted-message-ids
 353          (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 354        (setq result
 355              (if (stringp group)
 356                  (list (cons group (nnbabyl-active-number group)))
 357                (nnmail-article-group 'nnbabyl-active-number)))
 358        (if (and (null result)
 359                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 360            (setq result 'junk)
 361          (setq result (car (nnbabyl-save-mail result))))
 362        (set-buffer nnbabyl-mbox-buffer)
 363        (goto-char (point-max))
 364        (search-backward "\n\^_")
 365        (goto-char (match-end 0))
 366        (insert-buffer-substring buf)
 367        (when last
 368          (when nnmail-cache-accepted-message-ids
 369            (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 370          (save-buffer)
 371          (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file))
 372        result))))
 373
 374 (deffoo nnbabyl-request-replace-article (article group buffer)
 375   (nnbabyl-possibly-change-newsgroup group)
 376   (save-excursion
 377     (set-buffer nnbabyl-mbox-buffer)
 378     (goto-char (point-min))
 379     (if (not (search-forward (nnbabyl-article-string article) nil t))
 380         nil
 381       (nnbabyl-delete-mail t t)
 382       (insert-buffer-substring buffer)
 383       (save-buffer)
 384       t)))
 385
 386 (deffoo nnbabyl-request-delete-group (group &optional force server)
 387   (nnbabyl-possibly-change-newsgroup group server)
 388   ;; Delete all articles in GROUP.
 389   (if (not force)
 390       ()                                ; Don't delete the articles.
 391     (save-excursion
 392       (set-buffer nnbabyl-mbox-buffer)
 393       (goto-char (point-min))
 394       ;; Delete all articles in this group.
 395       (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 396             found)
 397         (while (search-forward ident nil t)
 398           (setq found t)
 399           (nnbabyl-delete-mail))
 400         (when found
 401           (save-buffer)))))
 402   ;; Remove the group from all structures.
 403   (setq nnbabyl-group-alist
 404         (delq (assoc group nnbabyl-group-alist) nnbabyl-group-alist)
 405         nnbabyl-current-group nil)
 406   ;; Save the active file.
 407   (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 408   t)
 409
 410 (deffoo nnbabyl-request-rename-group (group new-name &optional server)
 411   (nnbabyl-possibly-change-newsgroup group server)
 412   (save-excursion
 413     (set-buffer nnbabyl-mbox-buffer)
 414     (goto-char (point-min))
 415     (let ((ident (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"))
 416           (new-ident (concat "\nX-Gnus-Newsgroup: " new-name ":"))
 417           found)
 418       (while (search-forward ident nil t)
 419         (replace-match new-ident t t)
 420         (setq found t))
 421       (when found
 422         (save-buffer))))
 423   (let ((entry (assoc group nnbabyl-group-alist)))
 424     (and entry (setcar entry new-name))
 425     (setq nnbabyl-current-group nil)
 426     ;; Save the new group alist.
 427     (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 428     t))
 429
 430 \f
 431 ;;; Internal functions.
 432
 433 ;; If FORCE, delete article no matter how many X-Gnus-Newsgroup
 434 ;; headers there are.  If LEAVE-DELIM, don't delete the Unix mbox
 435 ;; delimiter line.
 436 (defun nnbabyl-delete-mail (&optional force leave-delim)
 437   ;; Delete the current X-Gnus-Newsgroup line.
 438   (unless force
 439     (delete-region
 440      (progn (beginning-of-line) (point))
 441      (progn (forward-line 1) (point))))
 442   ;; Beginning of the article.
 443   (save-excursion
 444     (save-restriction
 445       (widen)
 446       (narrow-to-region
 447        (save-excursion
 448          (unless (re-search-backward (concat "^" nnbabyl-mail-delimiter) nil t)
 449            (goto-char (point-min))
 450            (end-of-line))
 451          (if leave-delim (progn (forward-line 1) (point))
 452            (match-beginning 0)))
 453        (progn
 454          (forward-line 1)
 455          (or (and (re-search-forward (concat "^" nnbabyl-mail-delimiter)
 456                                      nil t)
 457                   (match-beginning 0))
 458              (point-max))))
 459       (goto-char (point-min))
 460       ;; Only delete the article if no other groups owns it as well.
 461       (when (or force (not (re-search-forward "^X-Gnus-Newsgroup: " nil t)))
 462         (delete-region (point-min) (point-max))))))
 463
 464 (defun nnbabyl-possibly-change-newsgroup (newsgroup &optional server)
 465   (when (and server
 466              (not (nnbabyl-server-opened server)))
 467     (nnbabyl-open-server server))
 468   (when (or (not nnbabyl-mbox-buffer)
 469             (not (buffer-name nnbabyl-mbox-buffer)))
 470     (save-excursion (nnbabyl-read-mbox)))
 471   (unless nnbabyl-group-alist
 472     (nnmail-activate 'nnbabyl))
 473   (if newsgroup
 474       (if (assoc newsgroup nnbabyl-group-alist)
 475           (setq nnbabyl-current-group newsgroup)
 476         (nnheader-report 'nnbabyl "No such group in file"))
 477     t))
 478
 479 (defun nnbabyl-article-string (article)
 480   (if (numberp article)
 481       (concat "\nX-Gnus-Newsgroup: " nnbabyl-current-group ":"
 482               (int-to-string article) " ")
 483     (concat "\nMessage-ID: " article)))
 484
 485 (defun nnbabyl-article-group-number ()
 486   (save-excursion
 487     (goto-char (point-min))
 488     (when (re-search-forward "^X-Gnus-Newsgroup: +\\([^:]+\\):\\([0-9]+\\) "
 489                              nil t)
 490       (cons (buffer-substring (match-beginning 1) (match-end 1))
 491             (string-to-int
 492              (buffer-substring (match-beginning 2) (match-end 2)))))))
 493
 494 (defun nnbabyl-insert-lines ()
 495   "Insert how many lines and chars there are in the body of the mail."
 496   (let (lines chars)
 497     (save-excursion
 498       (goto-char (point-min))
 499       (when (search-forward "\n\n" nil t)
 500         ;; There may be an EOOH line here...
 501         (when (looking-at "\\*\\*\\* EOOH \\*\\*\\*")
 502           (search-forward "\n\n" nil t))
 503         (setq chars (- (point-max) (point))
 504               lines (max (- (count-lines (point) (point-max)) 1) 0))
 505         ;; Move back to the end of the headers.
 506         (goto-char (point-min))
 507         (search-forward "\n\n" nil t)
 508         (forward-char -1)
 509         (save-excursion
 510           (when (re-search-backward "^Lines: " nil t)
 511             (delete-region (point) (progn (forward-line 1) (point)))))
 512         (insert (format "Lines: %d\n" lines))
 513         chars))))
 514
 515 (defun nnbabyl-save-mail (group-art)
 516   ;; Called narrowed to an article.
 517   (nnbabyl-insert-lines)
 518   (nnmail-insert-xref group-art)
 519   (nnbabyl-insert-newsgroup-line group-art)
 520   (run-hooks 'nnbabyl-prepare-save-mail-hook)
 521   group-art)
 522
 523 (defun nnbabyl-insert-newsgroup-line (group-art)
 524   (save-excursion
 525     (goto-char (point-min))
 526     (while (looking-at "From ")
 527       (replace-match "Mail-from: From " t t)
 528       (forward-line 1))
 529     ;; If there is a C-l at the beginning of the narrowed region, this
 530     ;; isn't really a "save", but rather a "scan".
 531     (goto-char (point-min))
 532     (unless (looking-at "\^L")
 533       (save-excursion
 534         (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 535         (goto-char (point-max))
 536         (insert "\^_\n")))
 537     (when (search-forward "\n\n" nil t)
 538       (forward-char -1)
 539       (while group-art
 540         (insert (format "X-Gnus-Newsgroup: %s:%d   %s\n"
 541                         (caar group-art) (cdar group-art)
 542                         (current-time-string)))
 543         (setq group-art (cdr group-art))))
 544     t))
 545
 546 (defun nnbabyl-active-number (group)
 547   ;; Find the next article number in GROUP.
 548   (let ((active (cadr (assoc group nnbabyl-group-alist))))
 549     (if active
 550         (setcdr active (1+ (cdr active)))
 551       ;; This group is new, so we create a new entry for it.
 552       ;; This might be a bit naughty... creating groups on the drop of
 553       ;; a hat, but I don't know...
 554       (push (list group (setq active (cons 1 1)))
 555             nnbabyl-group-alist))
 556     (cdr active)))
 557
 558 (defun nnbabyl-create-mbox ()
 559   (unless (file-exists-p nnbabyl-mbox-file)
 560     ;; Create a new, empty RMAIL mbox file.
 561     (save-excursion
 562       (set-buffer (setq nnbabyl-mbox-buffer
 563                         (create-file-buffer nnbabyl-mbox-file)))
 564       (setq buffer-file-name nnbabyl-mbox-file)
 565       (insert "BABYL OPTIONS:\n\n\^_")
 566       (nnmail-write-region
 567        (point-min) (point-max) nnbabyl-mbox-file t 'nomesg))))
 568
 569 (defun nnbabyl-read-mbox ()
 570   (nnmail-activate 'nnbabyl)
 571   (nnbabyl-create-mbox)
 572
 573   (unless (and nnbabyl-mbox-buffer
 574                (buffer-name nnbabyl-mbox-buffer)
 575                (save-excursion
 576                  (set-buffer nnbabyl-mbox-buffer)
 577                  (= (buffer-size) (nnheader-file-size nnbabyl-mbox-file))))
 578     ;; This buffer has changed since we read it last.  Possibly.
 579     (save-excursion
 580       (let ((delim (concat "^" nnbabyl-mail-delimiter))
 581             (alist nnbabyl-group-alist)
 582             start end number)
 583         (set-buffer (setq nnbabyl-mbox-buffer
 584                           (nnheader-find-file-noselect
 585                            nnbabyl-mbox-file nil t)))
 586         ;; Save previous buffer mode.
 587         (setq nnbabyl-previous-buffer-mode
 588               (cons (cons (point-min) (point-max))
 589                     major-mode))
 590
 591         (buffer-disable-undo)
 592         (widen)
 593         (setq buffer-read-only nil)
 594         (fundamental-mode)
 595
 596         ;; Go through the group alist and compare against
 597         ;; the rmail file.
 598         (while alist
 599           (goto-char (point-max))
 600           (when (and (re-search-backward
 601                       (format "^X-Gnus-Newsgroup: %s:\\([0-9]+\\) "
 602                               (caar alist))
 603                       nil t)
 604                      (> (setq number
 605                               (string-to-number
 606                                (buffer-substring
 607                                 (match-beginning 1) (match-end 1))))
 608                         (cdadar alist)))
 609             (setcdr (cadar alist) number))
 610           (setq alist (cdr alist)))
 611
 612         ;; We go through the mbox and make sure that each and
 613         ;; every mail belongs to some group or other.
 614         (goto-char (point-min))
 615         (if (looking-at "\^L")
 616             (setq start (point))
 617           (re-search-forward delim nil t)
 618           (setq start (match-end 0)))
 619         (while (re-search-forward delim nil t)
 620           (setq end (match-end 0))
 621           (unless (search-backward "\nX-Gnus-Newsgroup: " start t)
 622             (goto-char end)
 623             (save-excursion
 624               (save-restriction
 625                 (narrow-to-region (goto-char start) end)
 626                 (nnbabyl-save-mail
 627                  (nnmail-article-group 'nnbabyl-active-number))
 628                 (setq end (point-max)))))
 629           (goto-char (setq start end)))
 630         (when (buffer-modified-p (current-buffer))
 631           (save-buffer))
 632         (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)))))
 633
 634 (defun nnbabyl-remove-incoming-delims ()
 635   (goto-char (point-min))
 636   (while (search-forward "\^_" nil t)
 637     (replace-match "?" t t)))
 638
 639 (defun nnbabyl-check-mbox ()
 640   "Go through the nnbabyl mbox and make sure that no article numbers are reused."
 641   (interactive)
 642   (let ((idents (make-vector 1000 0))
 643         id)
 644     (save-excursion
 645       (when (or (not nnbabyl-mbox-buffer)
 646                 (not (buffer-name nnbabyl-mbox-buffer)))
 647         (nnbabyl-read-mbox))
 648       (set-buffer nnbabyl-mbox-buffer)
 649       (goto-char (point-min))
 650       (while (re-search-forward "^X-Gnus-Newsgroup: \\([^ ]+\\) "  nil t)
 651         (if (intern-soft (setq id (match-string 1)) idents)
 652             (progn
 653               (delete-region (progn (beginning-of-line) (point))
 654                              (progn (forward-line 1) (point)))
 655               (nnheader-message 7 "Moving %s..." id)
 656               (nnbabyl-save-mail
 657                (nnmail-article-group 'nnbabyl-active-number)))
 658           (intern id idents)))
 659       (when (buffer-modified-p (current-buffer))
 660         (save-buffer))
 661       (nnmail-save-active nnbabyl-group-alist nnbabyl-active-file)
 662       (nnheader-message 5 ""))))
 663
 664 (provide 'nnbabyl)
 665
 666 ;;; nnbabyl.el ends here