git.chise.org Git - elisp/gnus.git-/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'nnmail)
  32 (require 'gnus-start)
  33 (require 'nnmh)
  34 (require 'nnoo)
  35 (require 'mm-util)
  36 (eval-when-compile (require 'cl))
  37
  38 (nnoo-declare nndraft
  39   nnmh)
  40
  41 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  42   "Where nndraft will store its files."
  43   nnmh-directory)
  44
  45 \f
  46
  47 (defvoo nndraft-current-group "" nil nnmh-current-group)
  48 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  49 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  50
  51 (defconst nndraft-version "nndraft 1.0")
  52 (defvoo nndraft-status-string "" nil nnmh-status-string)
  53
  54 \f
  55
  56 ;;; Interface functions.
  57
  58 (nnoo-define-basics nndraft)
  59
  60 (deffoo nndraft-open-server (server &optional defs)
  61   (nnoo-change-server 'nndraft server defs)
  62   (cond
  63    ((not (file-exists-p nndraft-directory))
  64     (nndraft-close-server)
  65     (nnheader-report 'nndraft "No such file or directory: %s"
  66                      nndraft-directory))
  67    ((not (file-directory-p (file-truename nndraft-directory)))
  68     (nndraft-close-server)
  69     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  70    (t
  71     (nnheader-report 'nndraft "Opened server %s using directory %s"
  72                      server nndraft-directory)
  73     t)))
  74
  75 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  76   (nndraft-possibly-change-group group)
  77   (save-excursion
  78     (set-buffer nntp-server-buffer)
  79     (erase-buffer)
  80     (let* (article)
  81       ;; We don't support fetching by Message-ID.
  82       (if (stringp (car articles))
  83           'headers
  84         (while articles
  85           (narrow-to-region (point) (point))
  86           (when (nndraft-request-article
  87                  (setq article (pop articles)) group server (current-buffer))
  88             (goto-char (point-min))
  89             (if (search-forward "\n\n" nil t)
  90                 (forward-line -1)
  91               (goto-char (point-max)))
  92             (delete-region (point) (point-max))
  93             (goto-char (point-min))
  94             (insert (format "221 %d Article retrieved.\n" article))
  95             (widen)
  96             (goto-char (point-max))
  97             (insert ".\n")))
  98
  99         (nnheader-fold-continuation-lines)
 100         'headers))))
 101
 102 (deffoo nndraft-request-article (id &optional group server buffer)
 103   (nndraft-possibly-change-group group)
 104   (when (numberp id)
 105     ;; We get the newest file of the auto-saved file and the
 106     ;; "real" file.
 107     (let* ((file (nndraft-article-filename id))
 108            (auto (nndraft-auto-save-file-name file))
 109            (newest (if (file-newer-than-file-p file auto) file auto))
 110            (nntp-server-buffer (or buffer nntp-server-buffer)))
 111       (when (and (file-exists-p newest)
 112                  (let ((nnmail-file-coding-system
 113                         (if (file-newer-than-file-p file auto)
 114                             (if (member group '("drafts" "delayed"))
 115                                 message-draft-coding-system
 116                               mm-text-coding-system)
 117                           mm-auto-save-coding-system)))
 118                    (nnmail-find-file newest)))
 119         (save-excursion
 120           (set-buffer nntp-server-buffer)
 121           (goto-char (point-min))
 122           ;; If there's a mail header separator in this file,
 123           ;; we remove it.
 124           (when (re-search-forward
 125                  (concat "^" (regexp-quote mail-header-separator) "$") nil t)
 126             (replace-match "" t t)))
 127         t))))
 128
 129 (deffoo nndraft-request-restore-buffer (article &optional group server)
 130   "Request a new buffer that is restored to the state of ARTICLE."
 131   (nndraft-possibly-change-group group)
 132   (when (nndraft-request-article article group server (current-buffer))
 133     (message-remove-header "xref")
 134     (message-remove-header "lines")
 135     ;; Articles in nndraft:queue are considered as sent messages.  The
 136     ;; Date field should be the time when they are sent.
 137     ;;(message-remove-header "date")
 138     t))
 139
 140 (deffoo nndraft-request-update-info (group info &optional server)
 141   (nndraft-possibly-change-group group)
 142   (gnus-info-set-read
 143    info
 144    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 145                               (nndraft-articles) t))
 146   (let ((marks (nth 3 info)))
 147     (when marks
 148       ;; Nix out all marks except the `unsend'-able article marks.
 149       (setcar (nthcdr 3 info)
 150               (if (assq 'unsend marks)
 151                   (list (assq 'unsend marks))
 152                 nil))))
 153   t)
 154
 155 (defun nndraft-generate-headers ()
 156   (save-excursion
 157     (message-generate-headers
 158      (message-headers-to-generate
 159       message-required-headers message-draft-headers nil))))
 160
 161 (deffoo nndraft-request-associate-buffer (group)
 162   "Associate the current buffer with some article in the draft group."
 163   (nndraft-open-server "")
 164   (nndraft-request-group group)
 165   (nndraft-possibly-change-group group)
 166   (let ((gnus-verbose-backends nil)
 167         (buf (current-buffer))
 168         article file)
 169     (with-temp-buffer
 170       (insert-buffer-substring buf)
 171       (setq article (nndraft-request-accept-article
 172                      group (nnoo-current-server 'nndraft) t 'noinsert)
 173             file (nndraft-article-filename article)))
 174     (setq buffer-file-name (expand-file-name file)
 175           buffer-auto-save-file-name (make-auto-save-file-name))
 176     (clear-visited-file-modtime)
 177     (make-local-variable 'write-contents-hooks)
 178     (push 'nndraft-generate-headers write-contents-hooks)
 179     article))
 180
 181 (deffoo nndraft-request-group (group &optional server dont-check)
 182   (nndraft-possibly-change-group group)
 183   (unless dont-check
 184     (let* ((pathname (nnmail-group-pathname group nndraft-directory))
 185            (file-name-coding-system nnmail-pathname-coding-system)
 186            dir file)
 187       (nnheader-re-read-dir pathname)
 188       (setq dir (mapcar (lambda (name) (string-to-int (substring name 1)))
 189                         (directory-files pathname nil "^#[0-9]+#$" t)))
 190       (dolist (n dir)
 191         (unless (file-exists-p
 192                  (setq file (expand-file-name (int-to-string n) pathname)))
 193           (rename-file (nndraft-auto-save-file-name file) file)))))
 194   (nnoo-parent-function 'nndraft
 195                         'nnmh-request-group
 196                         (list group server dont-check)))
 197
 198 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 199   (nndraft-possibly-change-group group)
 200   (let* ((nnmh-allow-delete-final t)
 201          (res (nnoo-parent-function 'nndraft
 202                                     'nnmh-request-expire-articles
 203                                     (list articles group server force)))
 204          article)
 205     ;; Delete all the "state" files of articles that have been expired.
 206     (while articles
 207       (unless (memq (setq article (pop articles)) res)
 208         (let ((auto (nndraft-auto-save-file-name
 209                      (nndraft-article-filename article))))
 210           (when (file-exists-p auto)
 211             (funcall nnmail-delete-file-function auto)))
 212         (dolist (backup
 213                  (let ((kept-new-versions 1)
 214                        (kept-old-versions 0))
 215                    (find-backup-file-name
 216                     (nndraft-article-filename article))))
 217           (when (file-exists-p backup)
 218             (funcall nnmail-delete-file-function backup)))))
 219     res))
 220
 221 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 222   (nndraft-possibly-change-group group)
 223   (let ((gnus-verbose-backends nil))
 224     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 225                           (list group server last noinsert))))
 226
 227 (deffoo nndraft-request-replace-article (article group buffer)
 228   (nndraft-possibly-change-group group)
 229   (let ((nnmail-file-coding-system
 230          (if (member group '("drafts" "delayed"))
 231              message-draft-coding-system
 232            mm-text-coding-system)))
 233     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 234                           (list article group buffer))))
 235
 236 (deffoo nndraft-request-create-group (group &optional server args)
 237   (nndraft-possibly-change-group group)
 238   (if (file-exists-p nndraft-current-directory)
 239       (if (file-directory-p nndraft-current-directory)
 240           t
 241         nil)
 242     (condition-case ()
 243         (progn
 244           (gnus-make-directory nndraft-current-directory)
 245           t)
 246       (file-error nil))))
 247
 248 \f
 249 ;;; Low-Level Interface
 250
 251 (defun nndraft-possibly-change-group (group)
 252   (when (and group
 253              (not (equal group nndraft-current-group)))
 254     (nndraft-open-server "")
 255     (setq nndraft-current-group group)
 256     (setq nndraft-current-directory
 257           (nnheader-concat nndraft-directory group))))
 258
 259 (defun nndraft-article-filename (article &rest args)
 260   (apply 'concat
 261          (file-name-as-directory nndraft-current-directory)
 262          (int-to-string article)
 263          args))
 264
 265 (defun nndraft-auto-save-file-name (file)
 266   (save-excursion
 267     (prog1
 268         (progn
 269           (set-buffer (get-buffer-create " *draft tmp*"))
 270           (setq buffer-file-name file)
 271           (make-auto-save-file-name))
 272       (kill-buffer (current-buffer)))))
 273
 274 (defun nndraft-articles ()
 275   "Return the list of messages in the group."
 276   (gnus-make-directory nndraft-current-directory)
 277   (sort
 278    (mapcar 'string-to-int
 279            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 280    '<))
 281
 282 (nnoo-import nndraft
 283   (nnmh
 284    nnmh-retrieve-headers
 285    nnmh-request-group
 286    nnmh-close-group
 287    nnmh-request-list
 288    nnmh-request-newsgroups
 289    nnmh-request-move-article))
 290
 291 (provide 'nndraft)
 292
 293 ;;; nndraft.el ends here