git.chise.org Git - elisp/gnus.git-/blob - lisp/nndraft.el

   1 ;;; nndraft.el --- draft article access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'nnheader)
  32 (require 'nnmail)
  33 (require 'gnus-start)
  34 (require 'nnmh)
  35 (require 'nnoo)
  36
  37 (nnoo-declare nndraft
  38   nnmh)
  39
  40 (defvoo nndraft-directory (nnheader-concat gnus-directory "drafts/")
  41   "Where nndraft will store its files."
  42   nnmh-directory)
  43
  44 \f
  45
  46 (defvoo nndraft-current-group "" nil nnmh-current-group)
  47 (defvoo nndraft-get-new-mail nil nil nnmh-get-new-mail)
  48 (defvoo nndraft-current-directory nil nil nnmh-current-directory)
  49
  50 (defconst nndraft-version "nndraft 1.0")
  51 (defvoo nndraft-status-string "" nil nnmh-status-string)
  52
  53 \f
  54
  55 ;;; Interface functions.
  56
  57 (nnoo-define-basics nndraft)
  58
  59 (deffoo nndraft-open-server (server &optional defs)
  60   (nnoo-change-server 'nndraft server defs)
  61   (cond
  62    ((not (file-exists-p nndraft-directory))
  63     (nndraft-close-server)
  64     (nnheader-report 'nndraft "No such file or directory: %s"
  65                      nndraft-directory))
  66    ((not (file-directory-p (file-truename nndraft-directory)))
  67     (nndraft-close-server)
  68     (nnheader-report 'nndraft "Not a directory: %s" nndraft-directory))
  69    (t
  70     (nnheader-report 'nndraft "Opened server %s using directory %s"
  71                      server nndraft-directory)
  72     t)))
  73
  74 (deffoo nndraft-retrieve-headers (articles &optional group server fetch-old)
  75   (nndraft-possibly-change-group group)
  76   (save-excursion
  77     (set-buffer nntp-server-buffer)
  78     (erase-buffer)
  79     (let* (article)
  80       ;; We don't support fetching by Message-ID.
  81       (if (stringp (car articles))
  82           'headers
  83         (while articles
  84           (narrow-to-region (point) (point))
  85           (when (nndraft-request-article
  86                  (setq article (pop articles)) group server (current-buffer))
  87             (goto-char (point-min))
  88             (if (search-forward "\n\n" nil t)
  89                 (forward-line -1)
  90               (goto-char (point-max)))
  91             (delete-region (point) (point-max))
  92             (goto-char (point-min))
  93             (insert (format "221 %d Article retrieved.\n" article))
  94             (widen)
  95             (goto-char (point-max))
  96             (insert ".\n")))
  97
  98         (nnheader-fold-continuation-lines)
  99         'headers))))
 100
 101 (deffoo nndraft-request-article (id &optional group server buffer)
 102   (nndraft-possibly-change-group group)
 103   (when (numberp id)
 104     ;; We get the newest file of the auto-saved file and the
 105     ;; "real" file.
 106     (let* ((file (nndraft-article-filename id))
 107            (auto (nndraft-auto-save-file-name file))
 108            (newest (if (file-newer-than-file-p file auto) file auto))
 109            (nntp-server-buffer (or buffer nntp-server-buffer)))
 110       (when (and (file-exists-p newest)
 111                  (let ((nnmail-file-coding-system nnheader-text-coding-system))
 112                    (nnmail-find-file newest)))
 113         (save-excursion
 114           (set-buffer nntp-server-buffer)
 115           (goto-char (point-min))
 116           ;; If there's a mail header separator in this file,
 117           ;; we remove it.
 118           (when (re-search-forward
 119                  (concat "^" mail-header-separator "$") nil t)
 120             (replace-match "" t t)))
 121         t))))
 122
 123 (deffoo nndraft-request-restore-buffer (article &optional group server)
 124   "Request a new buffer that is restored to the state of ARTICLE."
 125   (nndraft-possibly-change-group group)
 126   (when (nndraft-request-article article group server (current-buffer))
 127     (message-remove-header "xref")
 128     (message-remove-header "lines")
 129     ;; Articles in nndraft:queue are considered as sent messages.  The
 130     ;; Date field should be the time when they are sent.
 131     ;;(message-remove-header "date")
 132     t))
 133
 134 (deffoo nndraft-request-update-info (group info &optional server)
 135   (nndraft-possibly-change-group group)
 136   (gnus-info-set-read
 137    info
 138    (gnus-update-read-articles (gnus-group-prefixed-name group '(nndraft ""))
 139                               (nndraft-articles) t))
 140   (let ((marks (nth 3 info)))
 141     (when marks
 142       ;; Nix out all marks except the `unsend'-able article marks.
 143       (setcar (nthcdr 3 info)
 144               (if (assq 'unsend marks)
 145                   (list (assq 'unsend marks))
 146                 nil))))
 147   t)
 148
 149 (deffoo nndraft-request-associate-buffer (group)
 150   "Associate the current buffer with some article in the draft group."
 151   (nndraft-open-server "")
 152   (nndraft-request-group group)
 153   (nndraft-possibly-change-group group)
 154   (let ((gnus-verbose-backends nil)
 155         (buf (current-buffer))
 156         article file)
 157     (with-temp-buffer
 158       (insert-buffer-substring buf)
 159       (setq article (nndraft-request-accept-article
 160                      group (nnoo-current-server 'nndraft) t 'noinsert)
 161             file (nndraft-article-filename article)))
 162     (setq buffer-file-name (expand-file-name file)
 163           buffer-auto-save-file-name (make-auto-save-file-name))
 164     (clear-visited-file-modtime)
 165     article))
 166
 167 (deffoo nndraft-request-group (group &optional server dont-check)
 168   (nndraft-possibly-change-group group)
 169   (unless dont-check
 170     (let* ((pathname (nnmail-group-pathname group nndraft-directory))
 171            (file-name-coding-system nnmail-pathname-coding-system)
 172            dir file)
 173       (nnheader-re-read-dir pathname)
 174       (setq dir (mapcar (lambda (name) (string-to-int (substring name 1)))
 175                         (directory-files pathname nil "^#[0-9]+#$" t)))
 176       (dolist (n dir)
 177         (unless (file-exists-p
 178                  (setq file (expand-file-name (int-to-string n) pathname)))
 179           (rename-file (let ((buffer-file-name file))
 180                          (make-auto-save-file-name)) file)))))
 181   (nnoo-parent-function 'nndraft
 182                         'nnmh-request-group
 183                         (list group server dont-check)))
 184
 185 (deffoo nndraft-request-expire-articles (articles group &optional server force)
 186   (nndraft-possibly-change-group group)
 187   (let* ((nnmh-allow-delete-final t)
 188          (res (nnoo-parent-function 'nndraft
 189                                     'nnmh-request-expire-articles
 190                                     (list articles group server force)))
 191          article)
 192     ;; Delete all the "state" files of articles that have been expired.
 193     (while articles
 194       (unless (memq (setq article (pop articles)) res)
 195         (let ((auto (nndraft-auto-save-file-name
 196                      (nndraft-article-filename article))))
 197           (when (file-exists-p auto)
 198             (funcall nnmail-delete-file-function auto)))
 199         (dolist (backup
 200                  (let ((kept-new-versions 1)
 201                        (kept-old-versions 0))
 202                    (find-backup-file-name
 203                     (nndraft-article-filename article))))
 204           (when (file-exists-p backup)
 205             (funcall nnmail-delete-file-function backup)))))
 206     res))
 207
 208 (deffoo nndraft-request-accept-article (group &optional server last noinsert)
 209   (nndraft-possibly-change-group group)
 210   (let ((gnus-verbose-backends nil))
 211     (nnoo-parent-function 'nndraft 'nnmh-request-accept-article
 212                           (list group server last noinsert))))
 213
 214 (deffoo nndraft-request-replace-article (article group buffer)
 215   (nndraft-possibly-change-group group)
 216   (let ((nnmail-file-coding-system nnheader-text-coding-system))
 217     (nnoo-parent-function 'nndraft 'nnmh-request-replace-article
 218                           (list article group buffer))))
 219
 220 (deffoo nndraft-request-create-group (group &optional server args)
 221   (nndraft-possibly-change-group group)
 222   (if (file-exists-p nndraft-current-directory)
 223       (if (file-directory-p nndraft-current-directory)
 224           t
 225         nil)
 226     (condition-case ()
 227         (progn
 228           (gnus-make-directory nndraft-current-directory)
 229           t)
 230       (file-error nil))))
 231
 232 \f
 233 ;;; Low-Level Interface
 234
 235 (defun nndraft-possibly-change-group (group)
 236   (when (and group
 237              (not (equal group nndraft-current-group)))
 238     (nndraft-open-server "")
 239     (setq nndraft-current-group group)
 240     (setq nndraft-current-directory
 241           (nnheader-concat nndraft-directory group))))
 242
 243 (defun nndraft-article-filename (article &rest args)
 244   (apply 'concat
 245          (file-name-as-directory nndraft-current-directory)
 246          (int-to-string article)
 247          args))
 248
 249 (defun nndraft-auto-save-file-name (file)
 250   (save-excursion
 251     (prog1
 252         (progn
 253           (set-buffer (get-buffer-create " *draft tmp*"))
 254           (setq buffer-file-name file)
 255           (make-auto-save-file-name))
 256       (kill-buffer (current-buffer)))))
 257
 258 (defun nndraft-articles ()
 259   "Return the list of messages in the group."
 260   (gnus-make-directory nndraft-current-directory)
 261   (sort
 262    (mapcar 'string-to-int
 263            (directory-files nndraft-current-directory nil "\\`[0-9]+\\'" t))
 264    '<))
 265
 266 (nnoo-import nndraft
 267   (nnmh
 268    nnmh-retrieve-headers
 269    nnmh-request-group
 270    nnmh-close-group
 271    nnmh-request-list
 272    nnmh-request-newsgroups
 273    nnmh-request-move-article))
 274
 275 (provide 'nndraft)
 276
 277 ;;; nndraft.el ends here