git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998,1999 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   5 ;;         Jim Radford <radford@robby.caltech.edu>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Don't require half of Gnus -- backends should be standalone
  40 ;;   o Support escape characters in `message-tokenize-header'
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessery?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58
  59 ;;; Code:
  60
  61 (eval-and-compile
  62   (require 'imap))
  63
  64 (require 'nnoo)
  65 (require 'nnmail)
  66 (require 'nnheader)
  67 (require 'mm-util)
  68 (require 'gnus)
  69 (require 'gnus-range)
  70 (require 'gnus-start)
  71 (require 'gnus-int)
  72
  73 (nnoo-declare nnimap)
  74
  75 (defconst nnimap-version "nnimap 0.131")
  76
  77 (defvoo nnimap-address nil
  78   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  79
  80 (defvoo nnimap-server-port nil
  81   "Port number on physical IMAP server.
  82 If nil, defaults to 993 for SSL connections and 143 otherwise.")
  83
  84 ;; Splitting variables
  85
  86 (defvar nnimap-split-crosspost t
  87   "If non-nil, do crossposting if several split methods match the mail.
  88 If nil, the first match found will be used.")
  89
  90 (defvar nnimap-split-inbox nil
  91   "*Name of mailbox to split mail from.
  92
  93 Mail is read from this mailbox and split according to rules in
  94 `nnimap-split-rules'.
  95
  96 This can be a string or a list of strings.")
  97
  98 (defvar nnimap-split-rule nil
  99   "*Mail will be split according to theese rules.
 100
 101 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 102
 103 If you'd like, for instance, one mail group for mail from the
 104 \"gnus-imap\" mailing list, one group for junk mail and leave
 105 everything else in the incoming mailbox, you could do something like
 106 this:
 107
 108 (setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 109                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 110
 111 As you can see, `nnimap-split-rule' is a list of lists, where the first
 112 element in each \"rule\" is the name of the IMAP mailbox, and the
 113 second is a regexp that nnimap will try to match on the header to find
 114 a fit.
 115
 116 The first element can also be a list.  In that case, the first element
 117 is the server the second element is the group on that server in which
 118 the matching article will be stored.
 119
 120 The second element can also be a function.  In that case, it will be
 121 called narrowed to the headers with the first element of the rule as
 122 the argument.  It should return a non-nil value if it thinks that the
 123 mail belongs in that group.
 124
 125 This variable can also have a function as its value, the function will
 126 be called with the headers narrowed and should return a group where it
 127 thinks the article should be splitted to.")
 128
 129 (defvar nnimap-split-fancy nil
 130   "Like `nnmail-split-fancy', which see.")
 131
 132 ;; Authorization / Privacy variables
 133
 134 (defvoo nnimap-auth-method nil
 135   "Obsolete.")
 136
 137 (defvoo nnimap-stream nil
 138   "How nnimap will connect to the server.
 139
 140 The default, nil, will try to use the \"best\" method the server can
 141 handle.
 142
 143 Change this if
 144
 145 1) you want to connect with SSL.  The SSL integration with IMAP is
 146    brain-dead so you'll have to tell it specifically.
 147
 148 2) your server is more capable than your environment -- i.e. your
 149    server accept Kerberos login's but you haven't installed the
 150    `imtest' program or your machine isn't configured for Kerberos.
 151
 152 Possible choices: kerberos4, ssl, network")
 153
 154 (defvoo nnimap-authenticator nil
 155   "How nnimap authenticate itself to the server.
 156
 157 The default, nil, will try to use the \"best\" method the server can
 158 handle.
 159
 160 There is only one reason for fiddling with this variable, and that is
 161 if your server is more capable than your environment -- i.e. you
 162 connect to a server that accept Kerberos login's but you haven't
 163 installed the `imtest' program or your machine isn't configured for
 164 Kerberos.
 165
 166 Possible choices: kerberos4, cram-md5, login, anonymous.")
 167
 168 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 169   "Directory to keep NOV cache files for nnimap groups.
 170 See also `nnimap-nov-file-name'.")
 171
 172 (defvoo nnimap-nov-file-name "nnimap."
 173   "NOV cache base filename.
 174 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 175 typical complete file name would be
 176 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 177 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 178 `nnmail-use-long-file-names' is nil")
 179
 180 (defvoo nnimap-nov-file-name-suffix ".novcache"
 181   "Suffix for NOV cache base filename.")
 182
 183 (defvoo nnimap-nov-is-evil nil
 184   "If non-nil, nnimap will never generate or use a local nov database for this backend.
 185 Using nov databases will speed up header fetching considerably.
 186 Unlike other backends, you do not need to take special care if you
 187 flip this variable.")
 188
 189 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 190   "Whether to expunge a group when it is closed.
 191 When a IMAP group with articles marked for deletion is closed, this
 192 variable determine if nnimap should actually remove the articles or
 193 not.
 194
 195 If always, nnimap always perform a expunge when closing the group.
 196 If never, nnimap never expunges articles marked for deletion.
 197 If ask, nnimap will ask you if you wish to expunge marked articles.
 198
 199 When setting this variable to `never', you can only expunge articles
 200 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 201
 202 (defvoo nnimap-list-pattern "*"
 203   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 204 See below for available wildcards.
 205
 206 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 207 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 208 semantics of this are server specific, on the University of Washington
 209 server you can specify a directory.
 210
 211 Example:
 212  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 213
 214 There are two wildcards * and %. * matches everything, % matches
 215 everything in the current hierarchy.")
 216
 217 (defvoo nnimap-news-groups nil
 218   "IMAP support a news-like mode, also known as bulletin board mode, where replies is sent via IMAP instead of SMTP.
 219
 220 This variable should contain a regexp matching groups where you wish
 221 replies to be stored to the mailbox directly.
 222
 223 Example:
 224   '(\"^[^I][^N][^B][^O][^X].*$\")
 225
 226 This will match all groups not beginning with \"INBOX\".
 227
 228 Note that there is nothing technically different between mail-like and
 229 news-like mailboxes.  If you wish to have a group with todo items or
 230 similar which you wouldn't want to set up a mailing list for, you can
 231 use this to make replies go directly to the group.")
 232
 233 (defvoo nnimap-server-address nil
 234   "Obsolete.  Use `nnimap-address'.")
 235
 236 (defcustom nnimap-authinfo-file "~/.authinfo"
 237   "Authorization information for IMAP servers.  In .netrc format."
 238   :type
 239   '(choice file
 240            (repeat :tag "Entries"
 241                    :menu-tag "Inline"
 242                    (list :format "%v"
 243                          :value ("" ("login" . "") ("password" . ""))
 244                          (string :tag "Host")
 245                          (checklist :inline t
 246                                     (cons :format "%v"
 247                                           (const :format "" "login")
 248                                           (string :format "Login: %v"))
 249                                     (cons :format "%v"
 250                                           (const :format "" "password")
 251                                           (string :format "Password: %v")))))))
 252
 253 (defcustom nnimap-prune-cache t
 254   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 255   :type 'boolean)
 256
 257 (defvar nnimap-request-list-method 'imap-mailbox-list
 258   "Method to use to request a list of all folders from the server.
 259 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 260 restrict visible folders.")
 261
 262 ;; Internal variables:
 263
 264 (defvar nnimap-debug nil);; "*nnimap-debug*")
 265 (defvar nnimap-current-move-server nil)
 266 (defvar nnimap-current-move-group nil)
 267 (defvar nnimap-current-move-article nil)
 268 (defvar nnimap-length)
 269 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 270 (defvar nnimap-progress-how-often 20)
 271 (defvar nnimap-counter)
 272 (defvar nnimap-callback-callback-function nil
 273   "Gnus callback the nnimap asynchronous callback should call.")
 274 (defvar nnimap-callback-buffer nil
 275   "Which buffer the asynchronous article prefetch callback should work in.")
 276 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 277 (defvar nnimap-current-server nil)      ;; Current server
 278 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 279
 280 \f
 281
 282 (nnoo-define-basics nnimap)
 283
 284 ;; Utility functions:
 285
 286 (defsubst nnimap-get-server-buffer (server)
 287   "Return buffer for SERVER, if nil use current server."
 288   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 289
 290 (defun nnimap-possibly-change-server (server)
 291   "Return buffer for SERVER, changing the current server as a side-effect.
 292 If SERVER is nil, uses the current server."
 293   (setq nnimap-current-server (or server nnimap-current-server)
 294         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 295
 296 (defun nnimap-verify-uidvalidity (group server)
 297   "Verify stored uidvalidity match current one in GROUP on SERVER."
 298   (let* ((gnusgroup (gnus-group-prefixed-name
 299                      group (gnus-server-to-method
 300                             (format "nnimap:%s" server))))
 301          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 302          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity)))
 303     (if old-uidvalidity
 304         (if (not (equal old-uidvalidity new-uidvalidity))
 305             nil ;; uidvalidity clash
 306           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 307           t)
 308       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 309       t)))
 310
 311 (defun nnimap-find-minmax-uid (group &optional examine)
 312   "Find lowest and highest active article nummber in GROUP.
 313 If EXAMINE is non-nil the group is selected read-only."
 314   (with-current-buffer nnimap-server-buffer
 315     (when (imap-mailbox-select group examine)
 316       (let (minuid maxuid)
 317         (when (> (imap-mailbox-get 'exists) 0)
 318           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 319           (imap-message-map (lambda (uid Uid)
 320                               (setq minuid (if minuid (min minuid uid) uid)
 321                                     maxuid (if maxuid (max maxuid uid) uid)))
 322                             'UID))
 323         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 324
 325 (defun nnimap-possibly-change-group (group &optional server)
 326   "Make GROUP the current group, and SERVER the current server."
 327   (when (nnimap-possibly-change-server server)
 328     (with-current-buffer nnimap-server-buffer
 329       (if (or (null group) (imap-current-mailbox-p group))
 330           imap-current-mailbox
 331         (if (imap-mailbox-select group)
 332             (if (or (nnimap-verify-uidvalidity
 333                      group (or server nnimap-current-server))
 334                     (zerop (imap-mailbox-get 'exists group))
 335                     (yes-or-no-p
 336                      (format
 337                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 338                 imap-current-mailbox
 339               (imap-mailbox-unselect)
 340               (error "nnimap: Group %s is not uid-valid." group))
 341           (nnheader-report 'nnimap (imap-error-text)))))))
 342
 343 (defun nnimap-replace-whitespace (string)
 344   "Return STRING with all whitespace replaced with space."
 345   (when string
 346     (while (string-match "[\r\n\t]+" string)
 347       (setq string (replace-match " " t t string)))
 348     string))
 349
 350 ;; Required backend functions
 351
 352 (defun nnimap-retrieve-headers-progress ()
 353   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 354   (and (numberp nnmail-large-newsgroup)
 355        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 356        (> nnimap-length nnmail-large-newsgroup)
 357        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 358                          (nth (/ (% nnimap-counter
 359                                     (* (length nnimap-progress-chars)
 360                                        nnimap-progress-how-often))
 361                                  nnimap-progress-how-often)
 362                               nnimap-progress-chars)))
 363   (with-current-buffer nntp-server-buffer
 364     (let (headers lines chars uid)
 365       (with-current-buffer nnimap-server-buffer
 366         (setq uid imap-current-message
 367               headers (if (imap-capability 'IMAP4rev1)
 368                           ;; xxx don't just use car? alist doesn't contain
 369                           ;; anything else now, but it might...
 370                           (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 371                         (imap-message-get uid 'RFC822.HEADER))
 372               lines (imap-body-lines (imap-message-body imap-current-message))
 373               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 374       (nnheader-insert-nov
 375        (with-temp-buffer
 376          (buffer-disable-undo)
 377          (insert headers)
 378          (nnheader-ms-strip-cr)
 379          (let ((head (nnheader-parse-head 'naked)))
 380            (mail-header-set-number head uid)
 381            (mail-header-set-chars head chars)
 382            (mail-header-set-lines head lines)
 383            head))))))
 384
 385 (defun nnimap-retrieve-which-headers (articles fetch-old)
 386   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 387   (with-current-buffer nnimap-server-buffer
 388     (if (numberp (car-safe articles))
 389         (imap-search
 390          (concat "UID "
 391                  (nnimap-range-to-string
 392                   (gnus-compress-sequence
 393                    (append (gnus-uncompress-sequence
 394                             (and fetch-old
 395                                  (cons (if (numberp fetch-old)
 396                                            (max 1 (- (car articles) fetch-old))
 397                                          1)
 398                                        (1- (car articles)))))
 399                            articles)))))
 400       (mapcar (lambda (msgid)
 401                 (imap-search
 402                  (format "HEADER Message-Id %s" msgid)))
 403               articles))))
 404
 405 (defun nnimap-group-overview-filename (group server)
 406   "Make pathname for GROUP on SERVER."
 407   (let ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 408         (file (nnheader-translate-file-chars
 409                (concat nnimap-nov-file-name
 410                        (if (equal server "")
 411                            "unnamed"
 412                          server) "." group nnimap-nov-file-name-suffix) t)))
 413     (if (or nnmail-use-long-file-names
 414             (file-exists-p (concat dir file)))
 415         (concat dir file)
 416       (concat dir (mm-encode-coding-string
 417                    (nnheader-replace-chars-in-string file ?. ?/)
 418                    nnmail-pathname-coding-system)))))
 419
 420 (defun nnimap-retrieve-headers-from-file (group server)
 421   (with-current-buffer nntp-server-buffer
 422     (let ((nov (nnimap-group-overview-filename group server)))
 423       (when (file-exists-p nov)
 424         (mm-insert-file-contents nov)
 425         (set-buffer-modified-p nil)
 426         (let ((min (progn (goto-char (point-min))
 427                           (when (not (eobp))
 428                             (read (current-buffer)))))
 429               (max (progn (goto-char (point-max))
 430                           (forward-line -1)
 431                           (when (not (bobp))
 432                             (read (current-buffer))))))
 433           (if (and (numberp min) (numberp max))
 434               (cons min max)
 435             ;; junk, remove it, it's saved later
 436             (erase-buffer)
 437             nil))))))
 438
 439 (defun nnimap-retrieve-headers-from-server (articles group server)
 440   (with-current-buffer nnimap-server-buffer
 441     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 442           (nnimap-length (gnus-range-length articles))
 443           (nnimap-counter 0))
 444       (imap-fetch (nnimap-range-to-string articles)
 445                   (concat "(UID RFC822.SIZE BODY "
 446                           (let ((headers
 447                                  (append '(Subject From Date Message-Id
 448                                                    References In-Reply-To Xref)
 449                                          (copy-sequence
 450                                           nnmail-extra-headers))))
 451                             (if (imap-capability 'IMAP4rev1)
 452                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 453                               (format "RFC822.HEADER.LINES %s)" headers)))))
 454       (and (numberp nnmail-large-newsgroup)
 455            (> nnimap-length nnmail-large-newsgroup)
 456            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 457
 458 (defun nnimap-use-nov-p (group server)
 459   (or gnus-nov-is-evil nnimap-nov-is-evil
 460       (unless (and (gnus-make-directory
 461                     (file-name-directory
 462                      (nnimap-group-overview-filename group server)))
 463                    (file-writable-p
 464                     (nnimap-group-overview-filename group server)))
 465         (message "nnimap: Nov cache not writable, %s"
 466                  (nnimap-group-overview-filename group server)))))
 467
 468 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 469   (when (nnimap-possibly-change-group group server)
 470     (with-current-buffer nntp-server-buffer
 471       (erase-buffer)
 472       (if (nnimap-use-nov-p group server)
 473           (nnimap-retrieve-headers-from-server
 474            (gnus-compress-sequence articles) group server)
 475         (let (uids cached low high)
 476           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 477                       low (car uids)
 478                       high (car (last uids)))
 479             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 480                 (progn
 481                   ;; fetch articles with uids before cache block
 482                   (when (< low (car cached))
 483                     (goto-char (point-min))
 484                     (nnimap-retrieve-headers-from-server
 485                      (cons low (1- (car cached))) group server))
 486                   ;; fetch articles with uids after cache block
 487                   (when (> high (cdr cached))
 488                     (goto-char (point-max))
 489                     (nnimap-retrieve-headers-from-server
 490                      (cons (1+ (cdr cached)) high) group server))
 491                   (when nnimap-prune-cache
 492                     ;; remove nov's for articles which has expired on server
 493                     (goto-char (point-min))
 494                     (dolist (uid (gnus-set-difference articles uids))
 495                       (when (re-search-forward (format "^%d\t" uid) nil t)
 496                         (gnus-delete-line)))))
 497               ;; nothing cached, fetch whole range from server
 498               (nnimap-retrieve-headers-from-server
 499                (cons low high) group server))
 500             (when (buffer-modified-p)
 501               (nnmail-write-region
 502                1 (point-max) (nnimap-group-overview-filename group server)
 503                nil 'nomesg))
 504             (nnheader-nov-delete-outside-range low high))))
 505       'nov)))
 506
 507 (defun nnimap-open-connection (server)
 508   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 509                       nnimap-authenticator nnimap-server-buffer))
 510       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 511     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 512                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 513       (imap-close nnimap-server-buffer)
 514       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 515     (let (list alist user passwd)
 516       (and (fboundp 'gnus-parse-netrc)
 517            (setq list (gnus-parse-netrc nnimap-authinfo-file)
 518                  alist (or (and (gnus-netrc-get
 519                                  (gnus-netrc-machine list server) "machine")
 520                                 (gnus-netrc-machine list server))
 521                            (gnus-netrc-machine list nnimap-address))
 522                  user (gnus-netrc-get alist "login")
 523                  passwd (gnus-netrc-get alist "password")))
 524       (if (imap-authenticate user passwd nnimap-server-buffer)
 525           (prog1
 526               (push (list server nnimap-server-buffer)
 527                     nnimap-server-buffer-alist)
 528             (nnimap-possibly-change-server server))
 529         (imap-close nnimap-server-buffer)
 530         (kill-buffer nnimap-server-buffer)
 531         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 532
 533 (deffoo nnimap-open-server (server &optional defs)
 534   (nnheader-init-server-buffer)
 535   (if (nnimap-server-opened server)
 536       t
 537     (unless (assq 'nnimap-server-buffer defs)
 538       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 539     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 540     ;; for people that configured nnimap with a very old version
 541     (unless (assq 'nnimap-address defs)
 542       (if (assq 'nnimap-server-address defs)
 543           (push (list 'nnimap-address
 544                       (cadr (assq 'nnimap-server-address defs))) defs)
 545         (push (list 'nnimap-address server) defs)))
 546     (nnoo-change-server 'nnimap server defs)
 547     (or (and nnimap-server-buffer
 548              (imap-opened nnimap-server-buffer))
 549         (nnimap-open-connection server))))
 550
 551 (deffoo nnimap-server-opened (&optional server)
 552   "Whether SERVER is opened.
 553 If SERVER is the current virtual server, and the connection to the
 554 physical server is alive, this function return a non-nil value.  If
 555 SERVER is nil, it is treated as the current server."
 556   ;; clean up autologouts??
 557   (and (or server nnimap-current-server)
 558        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 559        (imap-opened (nnimap-get-server-buffer server))))
 560
 561 (deffoo nnimap-close-server (&optional server)
 562   "Close connection to server and free all resources connected to it.
 563 Return nil if the server couldn't be closed for some reason."
 564   (let ((server (or server nnimap-current-server)))
 565     (when (or (nnimap-server-opened server)
 566               (imap-opened (nnimap-get-server-buffer server)))
 567       (imap-close (nnimap-get-server-buffer server))
 568       (kill-buffer (nnimap-get-server-buffer server))
 569       (setq nnimap-server-buffer nil
 570             nnimap-current-server nil
 571             nnimap-server-buffer-alist
 572             (delq server nnimap-server-buffer-alist)))
 573     (nnoo-close-server 'nnimap server)))
 574
 575 (deffoo nnimap-request-close ()
 576   "Close connection to all servers and free all resources that the backend have reserved.
 577 All buffers that have been created by that
 578 backend should be killed.  (Not the nntp-server-buffer, though.) This
 579 function is generally only called when Gnus is shutting down."
 580   (mapcar (lambda (server) (nnimap-close-server (car server)))
 581           nnimap-server-buffer-alist)
 582   (setq nnimap-server-buffer-alist nil))
 583
 584 (deffoo nnimap-status-message (&optional server)
 585   "This function returns the last error message from server."
 586   (when (nnimap-possibly-change-server server)
 587     (nnoo-status-message 'nnimap server)))
 588
 589 (defun nnimap-demule (string)
 590   (funcall (if (and (fboundp 'string-as-multibyte)
 591                     (subrp (symbol-function 'string-as-multibyte)))
 592                'string-as-multibyte
 593              'identity)
 594            (or string "")))
 595
 596 (defun nnimap-callback ()
 597   (remove-hook 'imap-fetch-data-hook 'nnimap-callback)
 598   (with-current-buffer nnimap-callback-buffer
 599     (insert
 600      (with-current-buffer nnimap-server-buffer
 601        (nnimap-demule (imap-message-get (imap-current-message) 'RFC822)))) ;xxx
 602     (nnheader-ms-strip-cr)
 603     (funcall nnimap-callback-callback-function t)))
 604
 605 (defun nnimap-request-article-part (article part prop
 606                                             &optional group server to-buffer)
 607   (when (nnimap-possibly-change-group group server)
 608     (let ((article (if (stringp article)
 609                        (car-safe (imap-search
 610                                   (format "HEADER Message-Id %s" article)
 611                                   nnimap-server-buffer))
 612                      article)))
 613       (when article
 614         (gnus-message 9 "nnimap: Fetching (part of) article %d..." article)
 615         (if (not nnheader-callback-function)
 616             (with-current-buffer (or to-buffer nntp-server-buffer)
 617               (erase-buffer)
 618               (insert (nnimap-demule (imap-fetch article part prop nil
 619                                                  nnimap-server-buffer)))
 620               (nnheader-ms-strip-cr)
 621               (gnus-message 9 "nnimap: Fetching (part of) article %d...done"
 622                             article)
 623               (if (bobp)
 624                   (nnheader-report 'nnimap "No such article: %s"
 625                                    (imap-error-text nnimap-server-buffer))
 626                 (cons group article)))
 627           (add-hook 'imap-fetch-data-hook 'nnimap-callback)
 628           (setq nnimap-callback-callback-function nnheader-callback-function
 629                 nnimap-callback-buffer nntp-server-buffer)
 630           (imap-fetch-asynch article part nil nnimap-server-buffer)
 631           (cons group article))))))
 632
 633 (deffoo nnimap-asynchronous-p ()
 634   t)
 635
 636 (deffoo nnimap-request-article (article &optional group server to-buffer)
 637   (nnimap-request-article-part
 638    article "RFC822.PEEK" 'RFC822 group server to-buffer))
 639
 640 (deffoo nnimap-request-head (article &optional group server to-buffer)
 641   (nnimap-request-article-part
 642    article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer))
 643
 644 (deffoo nnimap-request-body (article &optional group server to-buffer)
 645   (nnimap-request-article-part
 646    article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer))
 647
 648 (deffoo nnimap-request-group (group &optional server fast)
 649   (nnimap-request-update-info-internal
 650    group
 651    (gnus-get-info (gnus-group-prefixed-name
 652                    group (gnus-server-to-method (format "nnimap:%s" server))))
 653    server)
 654   (when (nnimap-possibly-change-group group server)
 655     (let (info)
 656       (cond (fast group)
 657             ((null (setq info (nnimap-find-minmax-uid group t)))
 658              (nnheader-report 'nnimap "Could not get active info for %s"
 659                               group))
 660             (t
 661              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 662                               (max 1 (or (nth 1 info) 1))
 663                               (or (nth 2 info) 0) group)
 664              (nnheader-report 'nnimap "Group %s selected" group)
 665              t)))))
 666
 667 (defun nnimap-close-group (group &optional server)
 668   (with-current-buffer nnimap-server-buffer
 669     (when (and (imap-opened)
 670                (nnimap-possibly-change-group group server))
 671       (case nnimap-expunge-on-close
 672         ('always (imap-mailbox-expunge)
 673                  (imap-mailbox-close))
 674         ('ask (if (and (imap-search "DELETED")
 675                        (gnus-y-or-n-p (format
 676                                        "Expunge articles in group `%s'? "
 677                                        imap-current-mailbox)))
 678                   (progn (imap-mailbox-expunge)
 679                          (imap-mailbox-close))
 680                 (imap-mailbox-unselect)))
 681         (t (imap-mailbox-unselect)))
 682       (not imap-current-mailbox))))
 683
 684 (defun nnimap-pattern-to-list-arguments (pattern)
 685   (mapcar (lambda (p)
 686             (cons (car-safe p) (or (cdr-safe p) p)))
 687           (if (and (listp pattern)
 688                    (listp (cdr pattern)))
 689               pattern
 690             (list pattern))))
 691
 692 (deffoo nnimap-request-list (&optional server)
 693   (when (nnimap-possibly-change-server server)
 694     (with-current-buffer nntp-server-buffer
 695       (erase-buffer))
 696     (gnus-message 5 "nnimap: Generating active list%s..."
 697                   (if (> (length server) 0) (concat " for " server) ""))
 698     (with-current-buffer nnimap-server-buffer
 699       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 700         (dolist (mbx (funcall nnimap-request-list-method
 701                               (cdr pattern) (car pattern)))
 702           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 703               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 704                 (when info
 705                   (with-current-buffer nntp-server-buffer
 706                    (insert (format "\"%s\" %d %d y\n"
 707                                    mbx (or (nth 2 info) 0)
 708                                    (max 1 (or (nth 1 info) 1)))))))))))
 709     (gnus-message 5 "nnimap: Generating active list%s...done"
 710                   (if (> (length server) 0) (concat " for " server) ""))
 711     t))
 712
 713 (deffoo nnimap-request-post (&optional server)
 714   (let ((success t))
 715     (dolist  (mbx (message-tokenize-header
 716                    (message-fetch-field "Newsgroups")) success)
 717       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 718         (or (gnus-active to-newsgroup)
 719             (gnus-activate-group to-newsgroup)
 720             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 721                                        to-newsgroup))
 722                 (or (and (gnus-request-create-group
 723                           to-newsgroup gnus-command-method)
 724                          (gnus-activate-group to-newsgroup nil nil
 725                                               gnus-command-method))
 726                     (error "Couldn't create group %s" to-newsgroup)))
 727             (error "No such group: %s" to-newsgroup))
 728         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 729           (setq success nil))))))
 730
 731 ;; Optional backend functions
 732
 733 (deffoo nnimap-retrieve-groups (groups &optional server)
 734   (when (nnimap-possibly-change-server server)
 735     (gnus-message 5 "nnimap: Checking mailboxes...")
 736     (with-current-buffer nntp-server-buffer
 737       (erase-buffer)
 738       (dolist (group groups)
 739         (gnus-message 7 "nnimap: Checking mailbox %s" group)
 740         (or (member "\\NoSelect"
 741                     (imap-mailbox-get 'list-flags group nnimap-server-buffer))
 742             (let ((info (nnimap-find-minmax-uid group 'examine)))
 743               (insert (format "\"%s\" %d %d y\n" group
 744                               (or (nth 2 info) 0)
 745                               (max 1 (or (nth 1 info) 1))))))))
 746     (gnus-message 5 "nnimap: Checking mailboxes...done")
 747     'active))
 748
 749 (deffoo nnimap-request-update-info-internal (group info &optional server)
 750   (when (nnimap-possibly-change-group group server)
 751     (when info;; xxx what does this mean? should we create a info?
 752       (with-current-buffer nnimap-server-buffer
 753         (gnus-message 5 "nnimap: Updating info for %s..."
 754                       (gnus-info-group info))
 755
 756         (when (nnimap-mark-permanent-p 'read)
 757           (let (seen unseen)
 758             ;; read info could contain articles marked unread by other
 759             ;; imap clients!  we correct this
 760             (setq seen (gnus-uncompress-range (gnus-info-read info))
 761                   unseen (imap-search "UNSEEN UNDELETED")
 762                   seen (gnus-set-difference seen unseen)
 763                   ;; seen might lack articles marked as read by other
 764                   ;; imap clients! we correct this
 765                   seen (append seen (imap-search "SEEN"))
 766                   ;; remove dupes
 767                   seen (sort seen '<)
 768                   seen (gnus-compress-sequence seen t)
 769                   ;; we can't return '(1) since this isn't a "list of ranges",
 770                   ;; and we can't return '((1)) since g-list-of-unread-articles
 771                   ;; is buggy so we return '((1 . 1)).
 772                   seen (if (and (integerp (car seen))
 773                                 (null (cdr seen)))
 774                            (list (cons (car seen) (car seen)))
 775                          seen))
 776             (gnus-info-set-read info seen)))
 777
 778         (mapcar (lambda (pred)
 779                   (when (and (nnimap-mark-permanent-p (cdr pred))
 780                              (member (nnimap-mark-to-flag (cdr pred))
 781                                      (imap-mailbox-get 'flags)))
 782                     (gnus-info-set-marks
 783                      info
 784                      (nnimap-update-alist-soft
 785                       (cdr pred)
 786                       (gnus-compress-sequence
 787                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
 788                       (gnus-info-marks info))
 789                      t)))
 790                 gnus-article-mark-lists)
 791
 792         (gnus-message 5 "nnimap: Updating info for %s...done"
 793                       (gnus-info-group info))
 794
 795         info))))
 796
 797 (deffoo nnimap-request-type (group &optional article)
 798   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
 799       'news
 800     'mail))
 801
 802 (deffoo nnimap-request-set-mark (group actions &optional server)
 803   (when (nnimap-possibly-change-group group server)
 804     (with-current-buffer nnimap-server-buffer
 805       (let (action)
 806         (gnus-message 7 "nnimap: Setting marks in %s..." group)
 807         (while (setq action (pop actions))
 808           (let ((range (nth 0 action))
 809                 (what  (nth 1 action))
 810                 (cmdmarks (nth 2 action))
 811                 marks)
 812             ;; cache flags are pointless on the server
 813             (setq cmdmarks (delq 'cache cmdmarks))
 814             ;; flag dormant articles as ticked
 815             (if (memq 'dormant cmdmarks)
 816                 (setq cmdmarks (cons 'tick cmdmarks)))
 817             ;; remove stuff we are forbidden to store
 818             (mapcar (lambda (mark)
 819                       (if (imap-message-flag-permanent-p
 820                            (nnimap-mark-to-flag mark))
 821                           (setq marks (cons mark marks))))
 822                     cmdmarks)
 823             (when (and range marks)
 824               (cond ((eq what 'del)
 825                      (imap-message-flags-del
 826                       (nnimap-range-to-string range)
 827                       (nnimap-mark-to-flag marks nil t)))
 828                     ((eq what 'add)
 829                      (imap-message-flags-add
 830                       (nnimap-range-to-string range)
 831                       (nnimap-mark-to-flag marks nil t)))
 832                     ((eq what 'set)
 833                      (imap-message-flags-set
 834                       (nnimap-range-to-string range)
 835                       (nnimap-mark-to-flag marks nil t)))))))
 836         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
 837   nil)
 838
 839 (defun nnimap-split-fancy ()
 840   "Like nnmail-split-fancy, but uses nnimap-split-fancy."
 841   (let ((nnmail-split-fancy nnimap-split-fancy))
 842     (nnmail-split-fancy)))
 843
 844 (defun nnimap-split-to-groups (rules)
 845   ;; tries to match all rules in nnimap-split-rule against content of
 846   ;; nntp-server-buffer, returns a list of groups that matched.
 847   (with-current-buffer nntp-server-buffer
 848     ;; Fold continuation lines.
 849     (goto-char (point-min))
 850     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 851       (replace-match " " t t))
 852     (if (functionp rules)
 853         (funcall rules)
 854       (let (to-groups regrepp)
 855         (catch 'split-done
 856           (dolist (rule rules to-groups)
 857             (let ((group (car rule))
 858                   (regexp (cadr rule)))
 859               (goto-char (point-min))
 860               (when (and (if (stringp regexp)
 861                              (progn
 862                                (setq regrepp (string-match "\\\\[0-9&]" group))
 863                                (re-search-forward regexp nil t))
 864                            (funcall regexp group))
 865                          ;; Don't enter the article into the same group twice.
 866                          (not (assoc group to-groups)))
 867                 (push (if regrepp
 868                           (nnmail-expand-newtext group)
 869                         group)
 870                       to-groups)
 871                 (or nnimap-split-crosspost
 872                     (throw 'split-done to-groups))))))))))
 873
 874 (defun nnimap-split-find-rule (server inbox)
 875   nnimap-split-rule)
 876
 877 (defun nnimap-split-find-inbox (server)
 878   (if (listp nnimap-split-inbox)
 879       nnimap-split-inbox
 880     (list nnimap-split-inbox)))
 881
 882 (defun nnimap-split-articles (&optional group server)
 883   (when (nnimap-possibly-change-server server)
 884     (with-current-buffer nnimap-server-buffer
 885       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
 886         ;; iterate over inboxes
 887         (while (and (setq inbox (pop inboxes))
 888                     (nnimap-possibly-change-group inbox));; SELECT
 889           ;; find split rule for this server / inbox
 890           (when (setq rule (nnimap-split-find-rule server inbox))
 891             ;; iterate over articles
 892             (dolist (article (imap-search "UNSEEN UNDELETED"))
 893               (when (nnimap-request-head article)
 894                 ;; copy article to right group(s)
 895                 (setq removeorig nil)
 896                 (dolist (to-group (nnimap-split-to-groups rule))
 897                   (if (imap-message-copy (number-to-string article)
 898                                          to-group nil 'nocopyuid)
 899                       (progn
 900                         (message "IMAP split moved %s:%s:%d to %s" server inbox
 901                                  article to-group)
 902                         (setq removeorig t)
 903                         ;; Add the group-art list to the history list.
 904                         (push (list (cons to-group 0)) nnmail-split-history))
 905                     (message "IMAP split failed to move %s:%s:%d to %s" server
 906                              inbox article to-group)))
 907                 ;; remove article if it was successfully copied somewhere
 908                 (and removeorig
 909                      (imap-message-flags-add (format "%d" article)
 910                                              "\\Seen \\Deleted")))))
 911           (when (imap-mailbox-select inbox);; just in case
 912             ;; todo: UID EXPUNGE (if available) to remove splitted articles
 913             (imap-mailbox-expunge)
 914             (imap-mailbox-close)))
 915         t))))
 916
 917 (deffoo nnimap-request-scan (&optional group server)
 918   (nnimap-split-articles group server))
 919
 920 (deffoo nnimap-request-newgroups (date &optional server)
 921   (when (nnimap-possibly-change-server server)
 922     (with-current-buffer nntp-server-buffer
 923       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
 924                     (if (> (length server) 0) " on " "") server)
 925       (erase-buffer)
 926       (dolist (pattern (nnimap-pattern-to-list-arguments
 927                         nnimap-list-pattern))
 928         (dolist (mbx (imap-mailbox-lsub "*" (car pattern) nil
 929                                         nnimap-server-buffer))
 930           (or (member-if (lambda (mailbox)
 931                            (string= (downcase mailbox) "\\noselect"))
 932                          (imap-mailbox-get 'list-flags mbx
 933                                            nnimap-server-buffer))
 934               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 935                 (when info
 936                  (insert (format "\"%s\" %d %d y\n"
 937                                  mbx (or (nth 2 info) 0)
 938                                  (max 1 (or (nth 1 info) 1)))))))))
 939       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
 940                     (if (> (length server) 0) " on " "") server))
 941     t))
 942
 943 (deffoo nnimap-request-create-group (group &optional server args)
 944   (when (nnimap-possibly-change-server server)
 945     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
 946         (imap-mailbox-create group nnimap-server-buffer))))
 947
 948 (defun nnimap-time-substract (time1 time2)
 949   "Return TIME for TIME1 - TIME2."
 950   (let* ((ms (- (car time1) (car time2)))
 951          (ls (- (nth 1 time1) (nth 1 time2))))
 952     (if (< ls 0)
 953         (list (- ms 1) (+ (expt 2 16) ls))
 954       (list ms ls))))
 955
 956 (defun nnimap-date-days-ago (daysago)
 957   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
 958   (let ((date (format-time-string "%d-%b-%Y"
 959                                   (nnimap-time-substract
 960                                    (current-time)
 961                                    (days-to-time daysago)))))
 962     (if (eq ?0 (string-to-char date))
 963         (substring date 1)
 964       date)))
 965
 966 (defun nnimap-request-expire-articles-progress ()
 967   (gnus-message 5 "nnimap: Marking article %d for deletion..."
 968                 imap-current-message))
 969
 970 ;; Notice that we don't actually delete anything, we just mark them deleted.
 971 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 972   (let ((artseq (gnus-compress-sequence articles)))
 973     (when (and artseq (nnimap-possibly-change-group group server))
 974       (with-current-buffer nnimap-server-buffer
 975         (if force
 976             (and (imap-message-flags-add
 977                   (nnimap-range-to-string artseq) "\\Deleted")
 978                  (setq articles nil))
 979           (let ((days (or (and nnmail-expiry-wait-function
 980                                (funcall nnmail-expiry-wait-function group))
 981                           nnmail-expiry-wait)))
 982             (cond ((eq days 'immediate)
 983                    (and (imap-message-flags-add
 984                          (nnimap-range-to-string artseq) "\\Deleted")
 985                         (setq articles nil)))
 986                   ((numberp days)
 987                    (let ((oldarts (imap-search
 988                                    (format "UID %s NOT SINCE %s"
 989                                            (nnimap-range-to-string artseq)
 990                                            (nnimap-date-days-ago days))))
 991                          (imap-fetch-data-hook
 992                           '(nnimap-request-expire-articles-progress)))
 993                      (and oldarts
 994                           (imap-message-flags-add
 995                            (nnimap-range-to-string
 996                             (gnus-compress-sequence oldarts))
 997                            "\\Deleted")
 998                           (setq articles (gnus-set-difference
 999                                           articles oldarts)))))))))))
1000   ;; return articles not deleted
1001   articles)
1002
1003 (deffoo nnimap-request-move-article (article group server
1004                                              accept-form &optional last)
1005   (when (nnimap-possibly-change-server server)
1006     (save-excursion
1007       (let ((buf (get-buffer-create " *nnimap move*"))
1008             (nnimap-current-move-article article)
1009             (nnimap-current-move-group group)
1010             (nnimap-current-move-server nnimap-current-server)
1011             result)
1012         (and (nnimap-request-article article group server)
1013              (save-excursion
1014                (set-buffer buf)
1015                (buffer-disable-undo (current-buffer))
1016                (insert-buffer-substring nntp-server-buffer)
1017                (setq result (eval accept-form))
1018                (kill-buffer buf)
1019                result)
1020              (nnimap-request-expire-articles (list article) group server t))
1021         result))))
1022
1023 (deffoo nnimap-request-accept-article (group &optional server last)
1024   (when (nnimap-possibly-change-server server)
1025     (let (uid)
1026       (if (setq uid
1027                 (if (string= nnimap-current-server nnimap-current-move-server)
1028                     ;; moving article within same server, speed it up...
1029                     (and (nnimap-possibly-change-group
1030                           nnimap-current-move-group)
1031                          (imap-message-copy (number-to-string
1032                                              nnimap-current-move-article)
1033                                             group 'dontcreate nil
1034                                             nnimap-server-buffer))
1035                   ;; turn into rfc822 format (\r\n eol's)
1036                   (with-current-buffer (current-buffer)
1037                     (goto-char (point-min))
1038                     (while (search-forward "\n" nil t)
1039                       (replace-match "\r\n")))
1040                   ;; next line for Cyrus server bug
1041                   (imap-mailbox-unselect nnimap-server-buffer)
1042                   (imap-message-append group (current-buffer) nil nil
1043                                        nnimap-server-buffer)))
1044           (cons group (nth 1 uid))
1045         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1046
1047 (deffoo nnimap-request-delete-group (group force &optional server)
1048   (when (nnimap-possibly-change-server server)
1049     (with-current-buffer nnimap-server-buffer
1050       (if force
1051           (or (null (imap-mailbox-status group 'uidvalidity))
1052               (imap-mailbox-delete group))
1053         ;; UNSUBSCRIBE?
1054         t))))
1055
1056 (deffoo nnimap-request-rename-group (group new-name &optional server)
1057   (when (nnimap-possibly-change-server server)
1058     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1059
1060 (defun nnimap-expunge (mailbox server)
1061   (when (nnimap-possibly-change-group mailbox server)
1062     (imap-mailbox-expunge nnimap-server-buffer)))
1063
1064 (defun nnimap-acl-get (mailbox server)
1065   (when (nnimap-possibly-change-server server)
1066     (imap-mailbox-acl-get mailbox nnimap-server-buffer)))
1067
1068 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1069   (when (nnimap-possibly-change-server (cadr method))
1070     (unless (imap-capability 'ACL nnimap-server-buffer)
1071       (error "Your server does not support ACL editing"))
1072     (with-current-buffer nnimap-server-buffer
1073       ;; delete all removed identifiers
1074       (mapcar (lambda (old-acl)
1075                 (unless (assoc (car old-acl) new-acls)
1076                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1077                       (error "Can't delete ACL for %s" (car old-acl)))))
1078               old-acls)
1079       ;; set all changed acl's
1080       (mapcar (lambda (new-acl)
1081                 (let ((new-rights (cdr new-acl))
1082                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1083                   (unless (and old-rights new-rights
1084                                (string= old-rights new-rights))
1085                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1086                         (error "Can't set ACL for %s to %s" (car new-acl)
1087                                new-rights)))))
1088               new-acls)
1089       t)))
1090
1091 \f
1092 ;;; Internal functions
1093
1094 ;;
1095 ;; This is confusing.
1096 ;;
1097 ;; mark      => read, tick, draft, reply etc
1098 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1099 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1100 ;;
1101 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1102 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1103 ;;
1104
1105 (defconst nnimap-mark-to-predicate-alist
1106   (mapcar
1107    (lambda (pair)                       ; cdr is the mark
1108      (or (assoc (cdr pair)
1109                 '((read . "SEEN")
1110                   (tick . "FLAGGED")
1111                   (draft . "DRAFT")
1112                   (reply . "ANSWERED")))
1113          (cons (cdr pair)
1114                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1115    (cons '(read . read) gnus-article-mark-lists)))
1116
1117 (defun nnimap-mark-to-predicate (pred)
1118   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1119 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1120 to be used within a IMAP SEARCH query."
1121   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1122
1123 (defconst nnimap-mark-to-flag-alist
1124   (mapcar
1125    (lambda (pair)
1126      (or (assoc (cdr pair)
1127                 '((read . "\\Seen")
1128                   (tick . "\\Flagged")
1129                   (draft . "\\Draft")
1130                   (reply . "\\Answered")))
1131          (cons (cdr pair)
1132                (format "gnus-%s" (symbol-name (cdr pair))))))
1133    (cons '(read . read) gnus-article-mark-lists)))
1134
1135 (defun nnimap-mark-to-flag-1 (preds)
1136   (if (and (not (null preds)) (listp preds))
1137       (cons (nnimap-mark-to-flag (car preds))
1138             (nnimap-mark-to-flag (cdr preds)))
1139     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1140
1141 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1142   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1143 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1144 be used in a STORE FLAGS command."
1145   (let ((result (nnimap-mark-to-flag-1 preds)))
1146     (setq result (if (and (or make-string always-list)
1147                           (not (listp result)))
1148                      (list result)
1149                    result))
1150     (if make-string
1151         (mapconcat (lambda (flag)
1152                      (if (listp flag)
1153                          (mapconcat 'identity flag " ")
1154                        flag))
1155                    result " ")
1156       result)))
1157
1158 (defun nnimap-mark-permanent-p (mark &optional group)
1159   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1160   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1161
1162 (defun nnimap-remassoc (key alist)
1163   "Delete by side effect any elements of LIST whose car is `equal' to KEY.
1164 The modified LIST is returned.  If the first member
1165 of LIST has a car that is `equal' to KEY, there is no way to remove it
1166 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1167 sure of changing the value of `foo'."
1168   (when alist
1169     (if (equal key (caar alist))
1170         (cdr alist)
1171       (setcdr alist (nnimap-remassoc key (cdr alist)))
1172       alist)))
1173
1174 (defun nnimap-update-alist-soft (key value alist)
1175   (if value
1176       (cons (cons key value) (nnimap-remassoc key alist))
1177     (nnimap-remassoc key alist)))
1178
1179 (defun nnimap-range-to-string (range)
1180   (mapconcat
1181    (lambda (item)
1182      (if (consp item)
1183          (format "%d:%d"
1184                  (car item) (cdr item))
1185        (format "%d" item)))
1186    (if (and (listp range) (not (listp (cdr range))))
1187        (list range);; make (1 . 2) into ((1 . 2))
1188      range)
1189    ","))
1190
1191 (when nnimap-debug
1192   (require 'trace)
1193   (buffer-disable-undo (get-buffer-create nnimap-debug))
1194   (mapcar (lambda (f) (trace-function-background f nnimap-debug))
1195         '(
1196           nnimap-possibly-change-server
1197           nnimap-verify-uidvalidity
1198           nnimap-find-minmax-uid
1199           nnimap-possibly-change-group
1200           ;;nnimap-replace-whitespace
1201           nnimap-retrieve-headers-progress
1202           nnimap-retrieve-which-headers
1203           nnimap-group-overview-filename
1204           nnimap-retrieve-headers-from-file
1205           nnimap-retrieve-headers-from-server
1206           nnimap-retrieve-headers
1207           nnimap-open-connection
1208           nnimap-open-server
1209           nnimap-server-opened
1210           nnimap-close-server
1211           nnimap-request-close
1212           nnimap-status-message
1213           ;;nnimap-demule
1214           nnimap-request-article-part
1215           nnimap-request-article
1216           nnimap-request-head
1217           nnimap-request-body
1218           nnimap-request-group
1219           nnimap-close-group
1220           nnimap-pattern-to-list-arguments
1221           nnimap-request-list
1222           nnimap-request-post
1223           nnimap-retrieve-groups
1224           nnimap-request-update-info-internal
1225           nnimap-request-type
1226           nnimap-request-set-mark
1227           nnimap-split-to-groups
1228           nnimap-split-find-rule
1229           nnimap-split-find-inbox
1230           nnimap-split-articles
1231           nnimap-request-scan
1232           nnimap-request-newgroups
1233           nnimap-request-create-group
1234           nnimap-time-substract
1235           nnimap-date-days-ago
1236           nnimap-request-expire-articles-progress
1237           nnimap-request-expire-articles
1238           nnimap-request-move-article
1239           nnimap-request-accept-article
1240           nnimap-request-delete-group
1241           nnimap-request-rename-group
1242           gnus-group-nnimap-expunge
1243           gnus-group-nnimap-edit-acl
1244           gnus-group-nnimap-edit-acl-done
1245           nnimap-group-mode-hook
1246           nnimap-mark-to-predicate
1247           nnimap-mark-to-flag-1
1248           nnimap-mark-to-flag
1249           nnimap-mark-permanent-p
1250           nnimap-remassoc
1251           nnimap-update-alist-soft
1252           nnimap-range-to-string
1253           )))
1254
1255 (provide 'nnimap)
1256
1257 ;;; nnimap.el ends here