git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   6 ;;         Jim Radford <radford@robby.caltech.edu>
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Todo, major things:
  29 ;;
  30 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  31 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  32 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  33 ;;   o Sieve
  34 ;;   o MIME (partial article fetches)
  35 ;;   o Split to other backends, different split rules for different
  36 ;;     servers/inboxes
  37 ;;
  38 ;; Todo, minor things:
  39 ;;
  40 ;;   o Don't require half of Gnus -- backends should be standalone
  41 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  42 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  43 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  44 ;;   o What do I do with gnus-newsgroup-*?
  45 ;;   o Tell Gnus about new groups (how can we tell?)
  46 ;;   o Respooling (fix Gnus?) (unnecessary?)
  47 ;;   o Add support for the following: (if applicable)
  48 ;;       request-list-newsgroups, request-regenerate
  49 ;;       list-active-group,
  50 ;;       request-associate-buffer, request-restore-buffer,
  51 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  52 ;;   o Support RFC2221 (Login referrals)
  53 ;;   o IMAP2BIS compatibility? (RFC2061)
  54 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  55 ;;     .newsrc.eld)
  56 ;;   o What about Gnus's article editing, can we support it?  NO!
  57 ;;   o Use \Draft to support the draft group??
  58 ;;   o Duplicate suppression
  59 ;;   o Rewrite UID SEARCH UID X as UID FETCH X (UID) for those with slow servers
  60
  61 ;;; Code:
  62
  63 (require 'imap)
  64 (require 'nnoo)
  65 (require 'nnmail)
  66 (require 'nnheader)
  67 (require 'mm-util)
  68 (require 'gnus)
  69 (require 'gnus-range)
  70 (require 'gnus-start)
  71 (require 'gnus-int)
  72
  73 (eval-when-compile (require 'cl))
  74
  75 (nnoo-declare nnimap)
  76
  77 (defconst nnimap-version "nnimap 1.0")
  78
  79 (defgroup nnimap nil
  80   "Reading IMAP mail with Gnus."
  81   :group 'gnus)
  82
  83 (defvoo nnimap-address nil
  84   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  85
  86 (defvoo nnimap-server-port nil
  87   "Port number on physical IMAP server.
  88 If nil, defaults to 993 for TLS/SSL connections and 143 otherwise.")
  89
  90 ;; Splitting variables
  91
  92 (defcustom nnimap-split-crosspost t
  93   "If non-nil, do crossposting if several split methods match the mail.
  94 If nil, the first match found will be used."
  95   :group 'nnimap
  96   :type 'boolean)
  97
  98 (defcustom nnimap-split-inbox nil
  99   "Name of mailbox to split mail from.
 100
 101 Mail is read from this mailbox and split according to rules in
 102 `nnimap-split-rule'.
 103
 104 This can be a string or a list of strings."
 105   :group 'nnimap
 106   :type '(choice (string)
 107                  (repeat string)))
 108
 109 (define-widget 'nnimap-strict-function 'function
 110   "This widget only matches values that are functionp.
 111
 112 Warning: This means that a value that is the symbol of a not yet
 113 loaded function will not match.  Use with care."
 114   :match 'nnimap-strict-function-match)
 115
 116 (defun nnimap-strict-function-match (widget value)
 117   "Ignoring WIDGET, match if VALUE is a function."
 118   (functionp value))
 119
 120 (defcustom nnimap-split-rule nil
 121   "Mail will be split according to these rules.
 122
 123 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 124
 125 If you'd like, for instance, one mail group for mail from the
 126 \"gnus-imap\" mailing list, one group for junk mail and leave
 127 everything else in the incoming mailbox, you could do something like
 128 this:
 129
 130 \(setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 131                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 132
 133 As you can see, `nnimap-split-rule' is a list of lists, where the
 134 first element in each \"rule\" is the name of the IMAP mailbox (or the
 135 symbol `junk' if you want to remove the mail), and the second is a
 136 regexp that nnimap will try to match on the header to find a fit.
 137
 138 The second element can also be a function.  In that case, it will be
 139 called narrowed to the headers with the first element of the rule as
 140 the argument.  It should return a non-nil value if it thinks that the
 141 mail belongs in that group.
 142
 143 This variable can also have a function as its value, the function will
 144 be called with the headers narrowed and should return a group where it
 145 thinks the article should be splitted to.  See `nnimap-split-fancy'.
 146
 147 To allow for different split rules on different virtual servers, and
 148 even different split rules in different inboxes on the same server,
 149 the syntax of this variable have been extended along the lines of:
 150
 151 \(setq nnimap-split-rule
 152       '((\"my1server\"    (\".*\"    ((\"ding\"    \"ding@gnus.org\")
 153                                   (\"junk\"    \"From:.*Simon\")))
 154         (\"my2server\"    (\"INBOX\" nnimap-split-fancy))
 155         (\"my[34]server\" (\".*\"    ((\"private\" \"To:.*Simon\")
 156                                   (\"junk\"    my-junk-func)))))
 157
 158 The virtual server name is in fact a regexp, so that the same rules
 159 may apply to several servers.  In the example, the servers
 160 \"my3server\" and \"my4server\" both use the same rules.  Similarly,
 161 the inbox string is also a regexp.  The actual splitting rules are as
 162 before, either a function, or a list with group/regexp or
 163 group/function elements."
 164   :group 'nnimap
 165   :type '(choice :tag "Rule type"
 166                  (repeat :menu-tag "Single-server"
 167                          :tag "Single-server list"
 168                          (list (string :tag "Mailbox")
 169                                (choice :tag "Predicate"
 170                                        (regexp :tag "A regexp")
 171                                        (nnimap-strict-function :tag "A function"))))
 172                  (choice :menu-tag "A function"
 173                          :tag "A function"
 174                          (function-item nnimap-split-fancy)
 175                          (function-item nnmail-split-fancy)
 176                          (nnimap-strict-function :tag "User-defined function"))
 177                  (repeat :menu-tag "Multi-server (extended)"
 178                          :tag "Multi-server list"
 179                          (list (regexp :tag "Server regexp")
 180                                (list (regexp :tag "Incoming Mailbox regexp")
 181                                      (repeat :tag "Rules for matching server(s) and mailbox(es)"
 182                                              (list (string :tag "Destination mailbox")
 183                                                    (choice :tag "Predicate"
 184                                                            (regexp :tag "A Regexp")
 185                                                            (nnimap-strict-function :tag "A Function")))))))))
 186
 187 (defcustom nnimap-split-predicate "UNSEEN UNDELETED"
 188   "The predicate used to find articles to split.
 189 If you use another IMAP client to peek on articles but always would
 190 like nnimap to split them once it's started, you could change this to
 191 \"UNDELETED\". Other available predicates are available in
 192 RFC2060 section 6.4.4."
 193   :group 'nnimap
 194   :type 'string)
 195
 196 (defcustom nnimap-split-fancy nil
 197   "Like the variable `nnmail-split-fancy'."
 198   :group 'nnimap
 199   :type 'sexp)
 200
 201 (defvar nnimap-split-download-body-default nil
 202   "Internal variable with default value for `nnimap-split-download-body'.")
 203
 204 (defcustom nnimap-split-download-body 'default
 205   "Whether to download entire articles during splitting.
 206 This is generally not required, and will slow things down considerably.
 207 You may need it if you want to use an advanced splitting function that
 208 analyses the body before splitting the article.
 209 If this variable is nil, bodies will not be downloaded; if this
 210 variable is the symbol `default' the default behaviour is
 211 used (which currently is nil, unless you use a statistical
 212 spam.el test); if this variable is another non-nil value bodies
 213 will be downloaded."
 214   :group 'nnimap
 215   :type '(choice (const :tag "Let system decide" deault)
 216                  boolean))
 217
 218 ;; Performance / bug workaround variables
 219
 220 (defcustom nnimap-close-asynchronous t
 221   "Close mailboxes asynchronously in `nnimap-close-group'.
 222 This means that errors cought by nnimap when closing the mailbox will
 223 not prevent Gnus from updating the group status, which may be harmful.
 224 However, it increases speed."
 225   :type 'boolean
 226   :group 'nnimap)
 227
 228 (defcustom nnimap-dont-close t
 229   "Never close mailboxes.
 230 This increases the speed of closing mailboxes (quiting group) but may
 231 decrease the speed of selecting another mailbox later.  Re-selecting
 232 the same mailbox will be faster though."
 233   :type 'boolean
 234   :group 'nnimap)
 235
 236 (defcustom nnimap-retrieve-groups-asynchronous t
 237   "Send asynchronous STATUS commands for each mailbox before checking mail.
 238 If you have mailboxes that rarely receives mail, this speeds up new
 239 mail checking.  It works by first sending STATUS commands for each
 240 mailbox, and then only checking groups which has a modified UIDNEXT
 241 more carefully for new mail.
 242
 243 In summary, the default is O((1-p)*k+p*n) and changing it to nil makes
 244 it O(n).  If p is small, then the default is probably faster."
 245   :type 'boolean
 246   :group 'nnimap)
 247
 248 (defvoo nnimap-need-unselect-to-notice-new-mail nil
 249   "Unselect mailboxes before looking for new mail in them.
 250 Some servers seem to need this under some circumstances.")
 251
 252 ;; Authorization / Privacy variables
 253
 254 (defvoo nnimap-auth-method nil
 255   "Obsolete.")
 256
 257 (defvoo nnimap-stream nil
 258   "How nnimap will connect to the server.
 259
 260 The default, nil, will try to use the \"best\" method the server can
 261 handle.
 262
 263 Change this if
 264
 265 1) you want to connect with TLS/SSL.  The TLS/SSL integration
 266    with IMAP is suboptimal so you'll have to tell it
 267    specifically.
 268
 269 2) your server is more capable than your environment -- i.e. your
 270    server accept Kerberos login's but you haven't installed the
 271    `imtest' program or your machine isn't configured for Kerberos.
 272
 273 Possible choices: gssapi, kerberos4, starttls, tls, ssl, network, shell.
 274 See also `imap-streams' and `imap-stream-alist'.")
 275
 276 (defvoo nnimap-authenticator nil
 277   "How nnimap authenticate itself to the server.
 278
 279 The default, nil, will try to use the \"best\" method the server can
 280 handle.
 281
 282 There is only one reason for fiddling with this variable, and that is
 283 if your server is more capable than your environment -- i.e. you
 284 connect to a server that accept Kerberos login's but you haven't
 285 installed the `imtest' program or your machine isn't configured for
 286 Kerberos.
 287
 288 Possible choices: gssapi, kerberos4, digest-md5, cram-md5, login, anonymous.
 289 See also `imap-authenticators' and `imap-authenticator-alist'")
 290
 291 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 292   "Directory to keep NOV cache files for nnimap groups.
 293 See also `nnimap-nov-file-name'.")
 294
 295 (defvoo nnimap-nov-file-name "nnimap."
 296   "NOV cache base filename.
 297 The group name and `nnimap-nov-file-name-suffix' will be appended.  A
 298 typical complete file name would be
 299 ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 300 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 301 `nnmail-use-long-file-names' is nil")
 302
 303 (defvoo nnimap-nov-file-name-suffix ".novcache"
 304   "Suffix for NOV cache base filename.")
 305
 306 (defvoo nnimap-nov-is-evil gnus-agent
 307   "If non-nil, never generate or use a local nov database for this backend.
 308 Using nov databases should speed up header fetching considerably.
 309 However, it will invoke a UID SEARCH UID command on the server, and
 310 some servers implement this command inefficiently by opening each and
 311 every message in the group, thus making it quite slow.
 312 Unlike other backends, you do not need to take special care if you
 313 flip this variable.")
 314
 315 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 316   "Whether to expunge a group when it is closed.
 317 When a IMAP group with articles marked for deletion is closed, this
 318 variable determine if nnimap should actually remove the articles or
 319 not.
 320
 321 If always, nnimap always perform a expunge when closing the group.
 322 If never, nnimap never expunges articles marked for deletion.
 323 If ask, nnimap will ask you if you wish to expunge marked articles.
 324
 325 When setting this variable to `never', you can only expunge articles
 326 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 327
 328 (defvoo nnimap-list-pattern "*"
 329   "A string LIMIT or list of strings with mailbox wildcards used to limit available groups.
 330 See below for available wildcards.
 331
 332 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 333 REFERENCE will be passed as the first parameter to LIST/LSUB.  The
 334 semantics of this are server specific, on the University of Washington
 335 server you can specify a directory.
 336
 337 Example:
 338  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 339
 340 There are two wildcards * and %. * matches everything, % matches
 341 everything in the current hierarchy.")
 342
 343 (defvoo nnimap-news-groups nil
 344   "IMAP support a news-like mode, also known as bulletin board mode,
 345 where replies is sent via IMAP instead of SMTP.
 346
 347 This variable should contain a regexp matching groups where you wish
 348 replies to be stored to the mailbox directly.
 349
 350 Example:
 351   '(\"^[^I][^N][^B][^O][^X].*$\")
 352
 353 This will match all groups not beginning with \"INBOX\".
 354
 355 Note that there is nothing technically different between mail-like and
 356 news-like mailboxes.  If you wish to have a group with todo items or
 357 similar which you wouldn't want to set up a mailing list for, you can
 358 use this to make replies go directly to the group.")
 359
 360 (defvoo nnimap-expunge-search-string "UID %s NOT SINCE %s"
 361   "IMAP search command to use for articles that are to be expired.
 362 The first %s is replaced by a UID set of articles to search on,
 363 and the second %s is replaced by a date criterium.
 364
 365 One useful (and perhaps the only useful) value to change this to would
 366 be `UID %s NOT SENTSINCE %s' to make nnimap use the Date: header
 367 instead of the internal date of messages.  See section 6.4.4 of RFC
 368 2060 for more information on valid strings.")
 369
 370 (defvoo nnimap-importantize-dormant t
 371   "If non-nil, mark \"dormant\" articles as \"ticked\" for other IMAP clients.
 372 Note that within Gnus, dormant articles will still (only) be
 373 marked as ticked.  This is to make \"dormant\" articles stand out,
 374 just like \"ticked\" articles, in other IMAP clients.")
 375
 376 (defvoo nnimap-server-address nil
 377   "Obsolete.  Use `nnimap-address'.")
 378
 379 (defcustom nnimap-authinfo-file "~/.authinfo"
 380   "Authorization information for IMAP servers.  In .netrc format."
 381   :type
 382   '(choice file
 383            (repeat :tag "Entries"
 384                    :menu-tag "Inline"
 385                    (list :format "%v"
 386                          :value ("" ("login" . "") ("password" . ""))
 387                          (string :tag "Host")
 388                          (checklist :inline t
 389                                     (cons :format "%v"
 390                                           (const :format "" "login")
 391                                           (string :format "Login: %v"))
 392                                     (cons :format "%v"
 393                                           (const :format "" "password")
 394                                           (string :format "Password: %v")))))))
 395
 396 (defcustom nnimap-prune-cache t
 397   "If non-nil, nnimap check whether articles still exist on server before using data stored in NOV cache."
 398   :type 'boolean)
 399
 400 (defvar nnimap-request-list-method 'imap-mailbox-list
 401   "Method to use to request a list of all folders from the server.
 402 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 403 restrict visible folders.")
 404
 405 (defcustom nnimap-debug nil
 406   "If non-nil, random debug spews are placed in *nnimap-debug* buffer."
 407   :group 'nnimap
 408   :type 'boolean)
 409
 410 ;; Internal variables:
 411
 412 (defvar nnimap-debug-buffer "*nnimap-debug*")
 413 (defvar nnimap-mailbox-info (gnus-make-hashtable 997))
 414 (defvar nnimap-current-move-server nil)
 415 (defvar nnimap-current-move-group nil)
 416 (defvar nnimap-current-move-article nil)
 417 (defvar nnimap-length)
 418 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 419 (defvar nnimap-progress-how-often 20)
 420 (defvar nnimap-counter)
 421 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 422 (defvar nnimap-current-server nil) ;; Current server
 423 (defvar nnimap-server-buffer nil) ;; Current servers' buffer
 424
 425 \f
 426
 427 (nnoo-define-basics nnimap)
 428
 429 ;; Utility functions:
 430
 431 (defsubst nnimap-get-server-buffer (server)
 432   "Return buffer for SERVER, if nil use current server."
 433   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 434
 435 (defun nnimap-possibly-change-server (server)
 436   "Return buffer for SERVER, changing the current server as a side-effect.
 437 If SERVER is nil, uses the current server."
 438   (setq nnimap-current-server (or server nnimap-current-server)
 439         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 440
 441 (defun nnimap-verify-uidvalidity (group server)
 442   "Verify stored uidvalidity match current one in GROUP on SERVER."
 443   (let* ((gnusgroup (gnus-group-prefixed-name
 444                      group (gnus-server-to-method
 445                             (format "nnimap:%s" server))))
 446          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 447          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity))
 448          (dir (file-name-as-directory (expand-file-name nnimap-directory)))
 449          (nameuid (nnheader-translate-file-chars
 450                    (concat nnimap-nov-file-name
 451                            (if (equal server "")
 452                                "unnamed"
 453                              server) "." group "." old-uidvalidity
 454                            nnimap-nov-file-name-suffix) t))
 455          (file (if (or nnmail-use-long-file-names
 456                        (file-exists-p (expand-file-name nameuid dir)))
 457                    (expand-file-name nameuid dir)
 458                  (expand-file-name
 459                   (mm-encode-coding-string
 460                    (nnheader-replace-chars-in-string nameuid ?. ?/)
 461                    nnmail-pathname-coding-system)
 462                   dir))))
 463     (if old-uidvalidity
 464         (if (not (equal old-uidvalidity new-uidvalidity))
 465             ;; uidvalidity clash
 466             (gnus-delete-file file)
 467           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 468           t)
 469       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 470       t)))
 471
 472 (defun nnimap-before-find-minmax-bugworkaround ()
 473   "Function called before iterating through mailboxes with
 474 `nnimap-find-minmax-uid'."
 475   (when nnimap-need-unselect-to-notice-new-mail
 476     ;; XXX this is for UoW imapd problem, it doesn't notice new mail in
 477     ;; currently selected mailbox without a re-select/examine.
 478     (or (null (imap-current-mailbox nnimap-server-buffer))
 479         (imap-mailbox-unselect nnimap-server-buffer))))
 480
 481 (defun nnimap-find-minmax-uid (group &optional examine)
 482   "Find lowest and highest active article number in GROUP.
 483 If EXAMINE is non-nil the group is selected read-only."
 484   (with-current-buffer nnimap-server-buffer
 485     (when (or (string= group (imap-current-mailbox))
 486               (imap-mailbox-select group examine))
 487       (let (minuid maxuid)
 488         (when (> (imap-mailbox-get 'exists) 0)
 489           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 490           (imap-message-map (lambda (uid Uid)
 491                               (setq minuid (if minuid (min minuid uid) uid)
 492                                     maxuid (if maxuid (max maxuid uid) uid)))
 493                             'UID))
 494         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 495
 496 (defun nnimap-possibly-change-group (group &optional server)
 497   "Make GROUP the current group, and SERVER the current server."
 498   (when (nnimap-possibly-change-server server)
 499     (with-current-buffer nnimap-server-buffer
 500       (if (or (null group) (imap-current-mailbox-p group))
 501           imap-current-mailbox
 502         (if (imap-mailbox-select group)
 503             (if (or (nnimap-verify-uidvalidity
 504                      group (or server nnimap-current-server))
 505                     (zerop (imap-mailbox-get 'exists group))
 506                     t ;; for OGnus to see if ignoring uidvalidity
 507                     ;; changes has any bad effects.
 508                     (yes-or-no-p
 509                      (format
 510                       "nnimap: Group %s is not uidvalid.  Continue? " group)))
 511                 imap-current-mailbox
 512               (imap-mailbox-unselect)
 513               (error "nnimap: Group %s is not uid-valid" group))
 514           (nnheader-report 'nnimap (imap-error-text)))))))
 515
 516 (defun nnimap-replace-whitespace (string)
 517   "Return STRING with all whitespace replaced with space."
 518   (when string
 519     (while (string-match "[\r\n\t]+" string)
 520       (setq string (replace-match " " t t string)))
 521     string))
 522
 523 ;; Required backend functions
 524
 525 (defun nnimap-retrieve-headers-progress ()
 526   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 527   (and (numberp nnmail-large-newsgroup)
 528        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 529        (> nnimap-length nnmail-large-newsgroup)
 530        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 531                          (nth (/ (% nnimap-counter
 532                                     (* (length nnimap-progress-chars)
 533                                        nnimap-progress-how-often))
 534                                  nnimap-progress-how-often)
 535                               nnimap-progress-chars)))
 536   (with-current-buffer nntp-server-buffer
 537     (let (headers lines chars uid mbx)
 538       (with-current-buffer nnimap-server-buffer
 539         (setq uid imap-current-message
 540               mbx imap-current-mailbox
 541               headers (nnimap-demule
 542                        (if (imap-capability 'IMAP4rev1)
 543                            ;; xxx don't just use car? alist doesn't contain
 544                            ;; anything else now, but it might...
 545                            (nth 2 (car (imap-message-get uid 'BODYDETAIL)))
 546                          (imap-message-get uid 'RFC822.HEADER)))
 547               lines (imap-body-lines (imap-message-body imap-current-message))
 548               chars (imap-message-get imap-current-message 'RFC822.SIZE)))
 549       (nnheader-insert-nov
 550        (with-temp-buffer
 551          (buffer-disable-undo)
 552          (insert headers)
 553          (let ((head (nnheader-parse-naked-head)))
 554            (mail-header-set-number head uid)
 555            (mail-header-set-chars head chars)
 556            (mail-header-set-lines head lines)
 557            (mail-header-set-xref
 558             head (format "%s %s:%d" (system-name) mbx uid))
 559            head))))))
 560
 561 (defun nnimap-retrieve-which-headers (articles fetch-old)
 562   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 563   (with-current-buffer nnimap-server-buffer
 564     (if (numberp (car-safe articles))
 565         (imap-search
 566          (concat "UID "
 567                  (imap-range-to-message-set
 568                   (gnus-compress-sequence
 569                    (append (gnus-uncompress-sequence
 570                             (and fetch-old
 571                                  (cons (if (numberp fetch-old)
 572                                            (max 1 (- (car articles) fetch-old))
 573                                          1)
 574                                        (1- (car articles)))))
 575                            articles)))))
 576       (mapcar (lambda (msgid)
 577                 (imap-search
 578                  (format "HEADER Message-Id \"%s\"" msgid)))
 579               articles))))
 580
 581 (defun nnimap-group-overview-filename (group server)
 582   "Make file name for GROUP on SERVER."
 583   (let* ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 584          (uidvalidity (gnus-group-get-parameter
 585                        (gnus-group-prefixed-name
 586                         group (gnus-server-to-method
 587                                (format "nnimap:%s" server)))
 588                        'uidvalidity))
 589          (name (nnheader-translate-file-chars
 590                 (concat nnimap-nov-file-name
 591                         (if (equal server "")
 592                             "unnamed"
 593                           server) "." group nnimap-nov-file-name-suffix) t))
 594          (nameuid (nnheader-translate-file-chars
 595                    (concat nnimap-nov-file-name
 596                            (if (equal server "")
 597                                "unnamed"
 598                              server) "." group "." uidvalidity
 599                            nnimap-nov-file-name-suffix) t))
 600          (oldfile (if (or nnmail-use-long-file-names
 601                           (file-exists-p (expand-file-name name dir)))
 602                       (expand-file-name name dir)
 603                     (expand-file-name
 604                      (mm-encode-coding-string
 605                       (nnheader-replace-chars-in-string name ?. ?/)
 606                       nnmail-pathname-coding-system)
 607                      dir)))
 608          (newfile (if (or nnmail-use-long-file-names
 609                           (file-exists-p (expand-file-name nameuid dir)))
 610                       (expand-file-name nameuid dir)
 611                     (expand-file-name
 612                      (mm-encode-coding-string
 613                       (nnheader-replace-chars-in-string nameuid ?. ?/)
 614                       nnmail-pathname-coding-system)
 615                      dir))))
 616     (when (and (file-exists-p oldfile) (not (file-exists-p newfile)))
 617       (message "nnimap: Upgrading novcache filename...")
 618       (sit-for 1)
 619       (gnus-make-directory (file-name-directory newfile))
 620       (unless (ignore-errors (rename-file oldfile newfile) t)
 621         (if (ignore-errors (copy-file oldfile newfile) t)
 622             (delete-file oldfile)
 623           (error "Can't rename `%s' to `%s'" oldfile newfile))))
 624     newfile))
 625
 626 (defun nnimap-retrieve-headers-from-file (group server)
 627   (with-current-buffer nntp-server-buffer
 628     (let ((nov (nnimap-group-overview-filename group server)))
 629       (when (file-exists-p nov)
 630         (mm-insert-file-contents nov)
 631         (set-buffer-modified-p nil)
 632         (let ((min (ignore-errors (goto-char (point-min))
 633                                   (read (current-buffer))))
 634               (max (ignore-errors (goto-char (point-max))
 635                                   (forward-line -1)
 636                                   (read (current-buffer)))))
 637           (if (and (numberp min) (numberp max))
 638               (cons min max)
 639             ;; junk, remove it, it's saved later
 640             (erase-buffer)
 641             nil))))))
 642
 643 (defun nnimap-retrieve-headers-from-server (articles group server)
 644   (with-current-buffer nnimap-server-buffer
 645     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 646           (nnimap-length (gnus-range-length articles))
 647           (nnimap-counter 0))
 648       (imap-fetch (imap-range-to-message-set articles)
 649                   (concat "(UID RFC822.SIZE BODY "
 650                           (let ((headers
 651                                  (append '(Subject From Date Message-Id
 652                                                    References In-Reply-To Xref)
 653                                          (copy-sequence
 654                                           nnmail-extra-headers))))
 655                             (if (imap-capability 'IMAP4rev1)
 656                                 (format "BODY.PEEK[HEADER.FIELDS %s])" headers)
 657                               (format "RFC822.HEADER.LINES %s)" headers)))))
 658       (and (numberp nnmail-large-newsgroup)
 659            (> nnimap-length nnmail-large-newsgroup)
 660            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 661
 662 (defun nnimap-dont-use-nov-p (group server)
 663   (or gnus-nov-is-evil nnimap-nov-is-evil
 664       (unless (and (gnus-make-directory
 665                     (file-name-directory
 666                      (nnimap-group-overview-filename group server)))
 667                    (file-writable-p
 668                     (nnimap-group-overview-filename group server)))
 669         (message "nnimap: Nov cache not writable, %s"
 670                  (nnimap-group-overview-filename group server)))))
 671
 672 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 673   (when (nnimap-possibly-change-group group server)
 674     (with-current-buffer nntp-server-buffer
 675       (erase-buffer)
 676       (if (nnimap-dont-use-nov-p group server)
 677           (nnimap-retrieve-headers-from-server
 678            (gnus-compress-sequence articles) group server)
 679         (let (uids cached low high)
 680           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 681                       low (car uids)
 682                       high (car (last uids)))
 683             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 684                 (progn
 685                   ;; fetch articles with uids before cache block
 686                   (when (< low (car cached))
 687                     (goto-char (point-min))
 688                     (nnimap-retrieve-headers-from-server
 689                      (cons low (1- (car cached))) group server))
 690                   ;; fetch articles with uids after cache block
 691                   (when (> high (cdr cached))
 692                     (goto-char (point-max))
 693                     (nnimap-retrieve-headers-from-server
 694                      (cons (1+ (cdr cached)) high) group server))
 695                   (when nnimap-prune-cache
 696                     ;; remove nov's for articles which has expired on server
 697                     (goto-char (point-min))
 698                     (dolist (uid (gnus-set-difference articles uids))
 699                       (when (re-search-forward (format "^%d\t" uid) nil t)
 700                         (gnus-delete-line)))))
 701               ;; nothing cached, fetch whole range from server
 702               (nnimap-retrieve-headers-from-server
 703                (cons low high) group server))
 704             (when (buffer-modified-p)
 705               (nnmail-write-region
 706                (point-min) (point-max)
 707                (nnimap-group-overview-filename group server) nil 'nomesg))
 708             (nnheader-nov-delete-outside-range low high))))
 709       'nov)))
 710
 711 (defun nnimap-open-connection (server)
 712   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 713                       nnimap-authenticator nnimap-server-buffer))
 714       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 715     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 716                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 717       (imap-close nnimap-server-buffer)
 718       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 719     (let* ((list (gnus-parse-netrc nnimap-authinfo-file))
 720            (port (if nnimap-server-port
 721                      (int-to-string nnimap-server-port)
 722                    "imap"))
 723            (alist (or (gnus-netrc-machine list server port "imap")
 724                       (gnus-netrc-machine list
 725                                           (or nnimap-server-address
 726                                               nnimap-address)
 727                                           port "imap")))
 728            (user (gnus-netrc-get alist "login"))
 729            (passwd (gnus-netrc-get alist "password")))
 730       (if (imap-authenticate user passwd nnimap-server-buffer)
 731           (prog1
 732               (push (list server nnimap-server-buffer)
 733                     nnimap-server-buffer-alist)
 734             (nnimap-possibly-change-server server))
 735         (imap-close nnimap-server-buffer)
 736         (kill-buffer nnimap-server-buffer)
 737         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 738
 739 (deffoo nnimap-open-server (server &optional defs)
 740   (nnheader-init-server-buffer)
 741   (if (nnimap-server-opened server)
 742       t
 743     (unless (assq 'nnimap-server-buffer defs)
 744       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 745     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 746     ;; for people that configured nnimap with a very old version
 747     (unless (assq 'nnimap-address defs)
 748       (if (assq 'nnimap-server-address defs)
 749           (push (list 'nnimap-address
 750                       (cadr (assq 'nnimap-server-address defs))) defs)
 751         (push (list 'nnimap-address server) defs)))
 752     (nnoo-change-server 'nnimap server defs)
 753     (or nnimap-server-buffer
 754         (setq nnimap-server-buffer (cadr (assq 'nnimap-server-buffer defs))))
 755     (with-current-buffer (get-buffer-create nnimap-server-buffer)
 756       (nnoo-change-server 'nnimap server defs))
 757     (or (and nnimap-server-buffer
 758              (imap-opened nnimap-server-buffer)
 759              (if (with-current-buffer nnimap-server-buffer
 760                    (memq imap-state '(auth select examine)))
 761                  t
 762                (imap-close nnimap-server-buffer)
 763                (nnimap-open-connection server)))
 764         (nnimap-open-connection server))))
 765
 766 (deffoo nnimap-server-opened (&optional server)
 767   "Whether SERVER is opened.
 768 If SERVER is the current virtual server, and the connection to the
 769 physical server is alive, this function return a non-nil value.  If
 770 SERVER is nil, it is treated as the current server."
 771   ;; clean up autologouts??
 772   (and (or server nnimap-current-server)
 773        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 774        (imap-opened (nnimap-get-server-buffer server))))
 775
 776 (deffoo nnimap-close-server (&optional server)
 777   "Close connection to server and free all resources connected to it.
 778 Return nil if the server couldn't be closed for some reason."
 779   (let ((server (or server nnimap-current-server)))
 780     (when (or (nnimap-server-opened server)
 781               (imap-opened (nnimap-get-server-buffer server)))
 782       (imap-close (nnimap-get-server-buffer server))
 783       (kill-buffer (nnimap-get-server-buffer server))
 784       (setq nnimap-server-buffer nil
 785             nnimap-current-server nil
 786             nnimap-server-buffer-alist
 787             (delq server nnimap-server-buffer-alist)))
 788     (nnoo-close-server 'nnimap server)))
 789
 790 (deffoo nnimap-request-close ()
 791   "Close connection to all servers and free all resources that the backend have reserved.
 792 All buffers that have been created by that
 793 backend should be killed.  (Not the nntp-server-buffer, though.) This
 794 function is generally only called when Gnus is shutting down."
 795   (mapcar (lambda (server) (nnimap-close-server (car server)))
 796           nnimap-server-buffer-alist)
 797   (setq nnimap-server-buffer-alist nil))
 798
 799 (deffoo nnimap-status-message (&optional server)
 800   "This function returns the last error message from server."
 801   (when (nnimap-possibly-change-server server)
 802     (nnoo-status-message 'nnimap server)))
 803
 804 (defun nnimap-demule (string)
 805   (funcall (if (and (fboundp 'string-as-multibyte)
 806                     (subrp (symbol-function 'string-as-multibyte)))
 807                'string-as-multibyte
 808              'identity)
 809            (or string "")))
 810
 811 (defun nnimap-make-callback (article gnus-callback buffer)
 812   "Return a callback function."
 813   `(lambda ()
 814      (nnimap-callback ,article ,gnus-callback ,buffer)))
 815
 816 (defun nnimap-callback (article gnus-callback buffer)
 817   (when (eq article (imap-current-message))
 818     (remove-hook 'imap-fetch-data-hook
 819                  (nnimap-make-callback article gnus-callback buffer))
 820     (with-current-buffer buffer
 821       (insert
 822        (with-current-buffer nnimap-server-buffer
 823          (nnimap-demule
 824           (if (imap-capability 'IMAP4rev1)
 825               ;; xxx don't just use car? alist doesn't contain
 826               ;; anything else now, but it might...
 827               (nth 2 (car (imap-message-get article 'BODYDETAIL)))
 828             (imap-message-get article 'RFC822)))))
 829       (nnheader-ms-strip-cr)
 830       (funcall gnus-callback t))))
 831
 832 (defun nnimap-request-article-part (article part prop &optional
 833                                             group server to-buffer detail)
 834   (when (nnimap-possibly-change-group group server)
 835     (let ((article (if (stringp article)
 836                        (car-safe (imap-search
 837                                   (format "HEADER Message-Id \"%s\"" article)
 838                                   nnimap-server-buffer))
 839                      article)))
 840       (when article
 841         (gnus-message 10 "nnimap: Fetching (part of) article %d from %s..."
 842                       article (or group imap-current-mailbox
 843                                   gnus-newsgroup-name))
 844         (if (not nnheader-callback-function)
 845             (with-current-buffer (or to-buffer nntp-server-buffer)
 846               (erase-buffer)
 847               (let ((data (imap-fetch article part prop nil
 848                                       nnimap-server-buffer)))
 849                 (insert (nnimap-demule (if detail
 850                                            (nth 2 (car data))
 851                                          data))))
 852               (nnheader-ms-strip-cr)
 853               (gnus-message
 854                10 "nnimap: Fetching (part of) article %d from %s...done"
 855                article (or group imap-current-mailbox gnus-newsgroup-name))
 856               (if (bobp)
 857                   (nnheader-report 'nnimap "No such article %d in %s: %s"
 858                                    article (or group imap-current-mailbox
 859                                                gnus-newsgroup-name)
 860                                    (imap-error-text nnimap-server-buffer))
 861                 (cons group article)))
 862           (add-hook 'imap-fetch-data-hook
 863                     (nnimap-make-callback article
 864                                           nnheader-callback-function
 865                                           nntp-server-buffer))
 866           (imap-fetch-asynch article part nil nnimap-server-buffer)
 867           (cons group article))))))
 868
 869 (deffoo nnimap-asynchronous-p ()
 870   t)
 871
 872 (deffoo nnimap-request-article (article &optional group server to-buffer)
 873   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 874       (nnimap-request-article-part
 875        article "BODY.PEEK[]" 'BODYDETAIL group server to-buffer 'detail)
 876     (nnimap-request-article-part
 877      article "RFC822.PEEK" 'RFC822 group server to-buffer)))
 878
 879 (deffoo nnimap-request-head (article &optional group server to-buffer)
 880   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 881       (nnimap-request-article-part
 882        article "BODY.PEEK[HEADER]" 'BODYDETAIL group server to-buffer 'detail)
 883     (nnimap-request-article-part
 884      article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer)))
 885
 886 (deffoo nnimap-request-body (article &optional group server to-buffer)
 887   (if (imap-capability 'IMAP4rev1 nnimap-server-buffer)
 888       (nnimap-request-article-part
 889        article "BODY.PEEK[TEXT]" 'BODYDETAIL group server to-buffer 'detail)
 890     (nnimap-request-article-part
 891      article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer)))
 892
 893 (deffoo nnimap-request-group (group &optional server fast)
 894   (nnimap-request-update-info-internal
 895    group
 896    (gnus-get-info (gnus-group-prefixed-name
 897                    group (gnus-server-to-method (format "nnimap:%s" server))))
 898    server)
 899   (when (nnimap-possibly-change-group group server)
 900     (nnimap-before-find-minmax-bugworkaround)
 901     (let (info)
 902       (cond (fast group)
 903             ((null (setq info (nnimap-find-minmax-uid group t)))
 904              (nnheader-report 'nnimap "Could not get active info for %s"
 905                               group))
 906             (t
 907              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 908                               (max 1 (or (nth 1 info) 1))
 909                               (or (nth 2 info) 0) group)
 910              (nnheader-report 'nnimap "Group %s selected" group)
 911              t)))))
 912
 913 (defun nnimap-update-unseen (group &optional server)
 914   "Update the unseen count in `nnimap-mailbox-info'."
 915   (gnus-sethash
 916    (gnus-group-prefixed-name group server)
 917    (let ((old (gnus-gethash-safe (gnus-group-prefixed-name group server)
 918                                  nnimap-mailbox-info)))
 919      (list (nth 0 old) (nth 1 old)
 920            (imap-mailbox-status group 'unseen nnimap-server-buffer)
 921            (nth 3 old)))
 922    nnimap-mailbox-info))
 923
 924 (defun nnimap-close-group (group &optional server)
 925   (with-current-buffer nnimap-server-buffer
 926     (when (and (imap-opened)
 927                (nnimap-possibly-change-group group server))
 928       (nnimap-update-unseen group server)
 929       (case nnimap-expunge-on-close
 930         (always (progn
 931                   (imap-mailbox-expunge nnimap-close-asynchronous)
 932                   (unless nnimap-dont-close
 933                     (imap-mailbox-close nnimap-close-asynchronous))))
 934         (ask (if (and (imap-search "DELETED")
 935                       (gnus-y-or-n-p (format "Expunge articles in group `%s'? "
 936                                              imap-current-mailbox)))
 937                  (progn
 938                    (imap-mailbox-expunge nnimap-close-asynchronous)
 939                    (unless nnimap-dont-close
 940                      (imap-mailbox-close nnimap-close-asynchronous)))
 941                (imap-mailbox-unselect)))
 942         (t (imap-mailbox-unselect)))
 943       (not imap-current-mailbox))))
 944
 945 (defun nnimap-pattern-to-list-arguments (pattern)
 946   (mapcar (lambda (p)
 947             (cons (car-safe p) (or (cdr-safe p) p)))
 948           (if (and (listp pattern)
 949                    (listp (cdr pattern)))
 950               pattern
 951             (list pattern))))
 952
 953 (deffoo nnimap-request-list (&optional server)
 954   (when (nnimap-possibly-change-server server)
 955     (with-current-buffer nntp-server-buffer
 956       (erase-buffer))
 957     (gnus-message 5 "nnimap: Generating active list%s..."
 958                   (if (> (length server) 0) (concat " for " server) ""))
 959     (nnimap-before-find-minmax-bugworkaround)
 960     (with-current-buffer nnimap-server-buffer
 961       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 962         (dolist (mbx (funcall nnimap-request-list-method
 963                               (cdr pattern) (car pattern)))
 964           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 965               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 966                 (when info
 967                   (with-current-buffer nntp-server-buffer
 968                     (insert (format "\"%s\" %d %d y\n"
 969                                     mbx (or (nth 2 info) 0)
 970                                     (max 1 (or (nth 1 info) 1)))))))))))
 971     (gnus-message 5 "nnimap: Generating active list%s...done"
 972                   (if (> (length server) 0) (concat " for " server) ""))
 973     t))
 974
 975 (deffoo nnimap-request-post (&optional server)
 976   (let ((success t))
 977     (dolist (mbx (message-unquote-tokens
 978                   (message-tokenize-header
 979                    (message-fetch-field "Newsgroups") ", ")) success)
 980       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 981         (or (gnus-active to-newsgroup)
 982             (gnus-activate-group to-newsgroup)
 983             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 984                                        to-newsgroup))
 985                 (or (and (gnus-request-create-group
 986                           to-newsgroup gnus-command-method)
 987                          (gnus-activate-group to-newsgroup nil nil
 988                                               gnus-command-method))
 989                     (error "Couldn't create group %s" to-newsgroup)))
 990             (error "No such group: %s" to-newsgroup))
 991         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 992           (setq success nil))))))
 993
 994 ;; Optional backend functions
 995
 996 (defun nnimap-string-lessp-numerical (s1 s2)
 997   "Return t if first arg string is less than second in numerical order."
 998   (cond ((string= s1 s2)
 999          nil)
1000         ((> (length s1) (length s2))
1001          nil)
1002         ((< (length s1) (length s2))
1003          t)
1004         ((< (string-to-number (substring s1 0 1))
1005             (string-to-number (substring s2 0 1)))
1006          t)
1007         ((> (string-to-number (substring s1 0 1))
1008             (string-to-number (substring s2 0 1)))
1009          nil)
1010         (t
1011          (nnimap-string-lessp-numerical (substring s1 1) (substring s2 1)))))
1012
1013 (deffoo nnimap-retrieve-groups (groups &optional server)
1014   (when (nnimap-possibly-change-server server)
1015     (gnus-message 5 "nnimap: Checking mailboxes...")
1016     (with-current-buffer nntp-server-buffer
1017       (erase-buffer)
1018       (nnimap-before-find-minmax-bugworkaround)
1019       (let (asyncgroups slowgroups)
1020         (if (null nnimap-retrieve-groups-asynchronous)
1021             (setq slowgroups groups)
1022           (dolist (group groups)
1023             (gnus-message 9 "nnimap: Quickly checking mailbox %s" group)
1024             (add-to-list (if (gnus-gethash-safe
1025                               (gnus-group-prefixed-name group server)
1026                               nnimap-mailbox-info)
1027                              'asyncgroups
1028                            'slowgroups)
1029                          (list group (imap-mailbox-status-asynch
1030                                       group '(uidvalidity uidnext unseen)
1031                                       nnimap-server-buffer))))
1032           (dolist (asyncgroup asyncgroups)
1033             (let ((group (nth 0 asyncgroup))
1034                   (tag   (nth 1 asyncgroup))
1035                   new old)
1036               (when (imap-ok-p (imap-wait-for-tag tag nnimap-server-buffer))
1037                 (if (or (not (string=
1038                               (nth 0 (gnus-gethash (gnus-group-prefixed-name
1039                                                     group server)
1040                                                    nnimap-mailbox-info))
1041                               (imap-mailbox-get 'uidvalidity group
1042                                                 nnimap-server-buffer)))
1043                         (not (string=
1044                               (nth 1 (gnus-gethash (gnus-group-prefixed-name
1045                                                     group server)
1046                                                    nnimap-mailbox-info))
1047                               (imap-mailbox-get 'uidnext group
1048                                                 nnimap-server-buffer))))
1049                     (push (list group) slowgroups)
1050                   (insert (nth 3 (gnus-gethash (gnus-group-prefixed-name
1051                                                 group server)
1052                                                nnimap-mailbox-info))))))))
1053         (dolist (group slowgroups)
1054           (if nnimap-retrieve-groups-asynchronous
1055               (setq group (car group)))
1056           (gnus-message 7 "nnimap: Mailbox %s modified" group)
1057           (imap-mailbox-put 'uidnext nil group nnimap-server-buffer)
1058           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags group
1059                                                      nnimap-server-buffer))
1060               (let* ((info (nnimap-find-minmax-uid group 'examine))
1061                      (str (format "\"%s\" %d %d y\n" group
1062                                   (or (nth 2 info) 0)
1063                                   (max 1 (or (nth 1 info) 1)))))
1064                 (when (> (or (imap-mailbox-get 'recent group
1065                                                nnimap-server-buffer) 0)
1066                          0)
1067                   (push (list (cons group 0)) nnmail-split-history))
1068                 (insert str)
1069                 (when nnimap-retrieve-groups-asynchronous
1070                   (gnus-sethash
1071                    (gnus-group-prefixed-name group server)
1072                    (list (or (imap-mailbox-get
1073                               'uidvalidity group nnimap-server-buffer)
1074                              (imap-mailbox-status
1075                               group 'uidvalidity nnimap-server-buffer))
1076                          (or (imap-mailbox-get
1077                               'uidnext group nnimap-server-buffer)
1078                              (imap-mailbox-status
1079                               group 'uidnext nnimap-server-buffer))
1080                          (or (imap-mailbox-get
1081                               'unseen group nnimap-server-buffer)
1082                              (imap-mailbox-status
1083                               group 'unseen nnimap-server-buffer))
1084                          str)
1085                    nnimap-mailbox-info)))))))
1086     (gnus-message 5 "nnimap: Checking mailboxes...done")
1087     'active))
1088
1089 (deffoo nnimap-request-update-info-internal (group info &optional server)
1090   (when (nnimap-possibly-change-group group server)
1091     (when info ;; xxx what does this mean? should we create a info?
1092       (with-current-buffer nnimap-server-buffer
1093         (gnus-message 5 "nnimap: Updating info for %s..."
1094                       (gnus-info-group info))
1095
1096         (when (nnimap-mark-permanent-p 'read)
1097           (let (seen unseen)
1098             ;; read info could contain articles marked unread by other
1099             ;; imap clients!  we correct this
1100             (setq seen (gnus-uncompress-range (gnus-info-read info))
1101                   unseen (imap-search "UNSEEN UNDELETED")
1102                   seen (gnus-set-difference seen unseen)
1103                   ;; seen might lack articles marked as read by other
1104                   ;; imap clients! we correct this
1105                   seen (append seen (imap-search "SEEN"))
1106                   ;; remove dupes
1107                   seen (sort seen '<)
1108                   seen (gnus-compress-sequence seen t)
1109                   ;; we can't return '(1) since this isn't a "list of ranges",
1110                   ;; and we can't return '((1)) since g-list-of-unread-articles
1111                   ;; is buggy so we return '((1 . 1)).
1112                   seen (if (and (integerp (car seen))
1113                                 (null (cdr seen)))
1114                            (list (cons (car seen) (car seen)))
1115                          seen))
1116             (gnus-info-set-read info seen)))
1117
1118         (mapcar (lambda (pred)
1119                   (when (or (eq (cdr pred) 'recent)
1120                             (and (nnimap-mark-permanent-p (cdr pred))
1121                                  (member (nnimap-mark-to-flag (cdr pred))
1122                                          (imap-mailbox-get 'flags))))
1123                     (gnus-info-set-marks
1124                      info
1125                      (gnus-update-alist-soft
1126                       (cdr pred)
1127                       (gnus-compress-sequence
1128                        (imap-search (nnimap-mark-to-predicate (cdr pred))))
1129                       (gnus-info-marks info))
1130                      t)))
1131                 gnus-article-mark-lists)
1132
1133         (when nnimap-importantize-dormant
1134           ;; nnimap mark dormant article as ticked too (for other clients)
1135           ;; so we remove that mark for gnus since we support dormant
1136           (gnus-info-set-marks
1137            info
1138            (gnus-update-alist-soft
1139             'tick
1140             (gnus-remove-from-range
1141              (cdr-safe (assoc 'tick (gnus-info-marks info)))
1142              (cdr-safe (assoc 'dormant (gnus-info-marks info))))
1143             (gnus-info-marks info))
1144            t))
1145
1146         (gnus-message 5 "nnimap: Updating info for %s...done"
1147                       (gnus-info-group info))
1148
1149         info))))
1150
1151 (deffoo nnimap-request-type (group &optional article)
1152   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
1153       'news
1154     'mail))
1155
1156 (deffoo nnimap-request-set-mark (group actions &optional server)
1157   (when (nnimap-possibly-change-group group server)
1158     (with-current-buffer nnimap-server-buffer
1159       (let (action)
1160         (gnus-message 7 "nnimap: Setting marks in %s..." group)
1161         (while (setq action (pop actions))
1162           (let ((range (nth 0 action))
1163                 (what  (nth 1 action))
1164                 (cmdmarks (nth 2 action))
1165                 marks)
1166             ;; bookmark can't be stored (not list/range
1167             (setq cmdmarks (delq 'bookmark cmdmarks))
1168             ;; killed can't be stored (not list/range
1169             (setq cmdmarks (delq 'killed cmdmarks))
1170             ;; unsent are for nndraft groups only
1171             (setq cmdmarks (delq 'unsent cmdmarks))
1172             ;; cache flags are pointless on the server
1173             (setq cmdmarks (delq 'cache cmdmarks))
1174             ;; seen flags are local to each gnus
1175             (setq cmdmarks (delq 'seen cmdmarks))
1176             ;; recent marks can't be set
1177             (setq cmdmarks (delq 'recent cmdmarks))
1178             (when nnimap-importantize-dormant
1179               ;; flag dormant articles as ticked
1180               (if (memq 'dormant cmdmarks)
1181                   (setq cmdmarks (cons 'tick cmdmarks))))
1182             ;; remove stuff we are forbidden to store
1183             (mapcar (lambda (mark)
1184                       (if (imap-message-flag-permanent-p
1185                            (nnimap-mark-to-flag mark))
1186                           (setq marks (cons mark marks))))
1187                     cmdmarks)
1188             (when (and range marks)
1189               (cond ((eq what 'del)
1190                      (imap-message-flags-del
1191                       (imap-range-to-message-set range)
1192                       (nnimap-mark-to-flag marks nil t)))
1193                     ((eq what 'add)
1194                      (imap-message-flags-add
1195                       (imap-range-to-message-set range)
1196                       (nnimap-mark-to-flag marks nil t)))
1197                     ((eq what 'set)
1198                      (imap-message-flags-set
1199                       (imap-range-to-message-set range)
1200                       (nnimap-mark-to-flag marks nil t)))))))
1201         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
1202   nil)
1203
1204 (defun nnimap-split-fancy ()
1205   "Like the function `nnmail-split-fancy', but uses `nnimap-split-fancy'."
1206   (let ((nnmail-split-fancy nnimap-split-fancy))
1207     (nnmail-split-fancy)))
1208
1209 (defun nnimap-split-to-groups (rules)
1210   ;; tries to match all rules in nnimap-split-rule against content of
1211   ;; nntp-server-buffer, returns a list of groups that matched.
1212   (with-current-buffer nntp-server-buffer
1213     ;; Fold continuation lines.
1214     (goto-char (point-min))
1215     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
1216       (replace-match " " t t))
1217     (if (functionp rules)
1218         (funcall rules)
1219       (let (to-groups regrepp)
1220         (catch 'split-done
1221           (dolist (rule rules to-groups)
1222             (let ((group (car rule))
1223                   (regexp (cadr rule)))
1224               (goto-char (point-min))
1225               (when (and (if (stringp regexp)
1226                              (progn
1227                                (if (not (stringp group))
1228                                    (setq group (eval group))
1229                                  (setq regrepp
1230                                        (string-match "\\\\[0-9&]" group)))
1231                                (re-search-forward regexp nil t))
1232                            (funcall regexp group))
1233                          ;; Don't enter the article into the same group twice.
1234                          (not (assoc group to-groups)))
1235                 (push (if regrepp
1236                           (nnmail-expand-newtext group)
1237                         group)
1238                       to-groups)
1239                 (or nnimap-split-crosspost
1240                     (throw 'split-done to-groups))))))))))
1241
1242 (defun nnimap-assoc-match (key alist)
1243   (let (element)
1244     (while (and alist (not element))
1245       (if (string-match (car (car alist)) key)
1246           (setq element (car alist)))
1247       (setq alist (cdr alist)))
1248     element))
1249
1250 (defun nnimap-split-find-rule (server inbox)
1251   (if (and (listp nnimap-split-rule) (listp (car nnimap-split-rule))
1252            (list (cdar nnimap-split-rule)) (listp (cadar nnimap-split-rule)))
1253       ;; extended format
1254       (cadr (nnimap-assoc-match inbox (cdr (nnimap-assoc-match
1255                                             server nnimap-split-rule))))
1256     nnimap-split-rule))
1257
1258 (defun nnimap-split-find-inbox (server)
1259   (if (listp nnimap-split-inbox)
1260       nnimap-split-inbox
1261     (list nnimap-split-inbox)))
1262
1263 (defun nnimap-split-articles (&optional group server)
1264   (when (nnimap-possibly-change-server server)
1265     (with-current-buffer nnimap-server-buffer
1266       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
1267         ;; iterate over inboxes
1268         (while (and (setq inbox (pop inboxes))
1269                     (nnimap-possibly-change-group inbox)) ;; SELECT
1270           ;; find split rule for this server / inbox
1271           (when (setq rule (nnimap-split-find-rule server inbox))
1272             ;; iterate over articles
1273             (dolist (article (imap-search nnimap-split-predicate))
1274               (when (if (if (eq nnimap-split-download-body 'default)
1275                             nnimap-split-download-body-default
1276                           nnimap-split-download-body)
1277                         (and (nnimap-request-article article)
1278                              (with-current-buffer nntp-server-buffer (mail-narrow-to-head)))
1279                       (nnimap-request-head article))
1280                 ;; copy article to right group(s)
1281                 (setq removeorig nil)
1282                 (dolist (to-group (nnimap-split-to-groups rule))
1283                   (cond ((eq to-group 'junk)
1284                          (message "IMAP split removed %s:%s:%d" server inbox
1285                                   article)
1286                          (setq removeorig t))
1287                         ((imap-message-copy (number-to-string article)
1288                                             to-group nil 'nocopyuid)
1289                          (message "IMAP split moved %s:%s:%d to %s" server
1290                                   inbox article to-group)
1291                          (setq removeorig t)
1292                          (when nnmail-cache-accepted-message-ids
1293                            (with-current-buffer nntp-server-buffer
1294                              (let (msgid)
1295                                (and (setq msgid
1296                                           (nnmail-fetch-field "message-id"))
1297                                     (nnmail-cache-insert msgid
1298                                                          to-group
1299                                                          (nnmail-fetch-field "subject"))))))
1300                          ;; Add the group-art list to the history list.
1301                          (push (list (cons to-group 0)) nnmail-split-history))
1302                         (t
1303                          (message "IMAP split failed to move %s:%s:%d to %s"
1304                                   server inbox article to-group))))
1305                 (if (if (eq nnimap-split-download-body 'default)
1306                         nnimap-split-download-body-default
1307                       nnimap-split-download-body)
1308                     (widen))
1309                 ;; remove article if it was successfully copied somewhere
1310                 (and removeorig
1311                      (imap-message-flags-add (format "%d" article)
1312                                              "\\Seen \\Deleted")))))
1313           (when (imap-mailbox-select inbox) ;; just in case
1314             ;; todo: UID EXPUNGE (if available) to remove splitted articles
1315             (imap-mailbox-expunge)
1316             (imap-mailbox-close)))
1317         (when nnmail-cache-accepted-message-ids
1318           (nnmail-cache-close))
1319         t))))
1320
1321 (deffoo nnimap-request-scan (&optional group server)
1322   (nnimap-split-articles group server))
1323
1324 (deffoo nnimap-request-newgroups (date &optional server)
1325   (when (nnimap-possibly-change-server server)
1326     (with-current-buffer nntp-server-buffer
1327       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
1328                     (if (> (length server) 0) " on " "") server)
1329       (erase-buffer)
1330       (nnimap-before-find-minmax-bugworkaround)
1331       (dolist (pattern (nnimap-pattern-to-list-arguments
1332                         nnimap-list-pattern))
1333         (dolist (mbx (imap-mailbox-lsub (cdr pattern) (car pattern) nil
1334                                         nnimap-server-buffer))
1335           (or (catch 'found
1336                 (dolist (mailbox (imap-mailbox-get 'list-flags mbx
1337                                                    nnimap-server-buffer))
1338                   (if (string= (downcase mailbox) "\\noselect")
1339                       (throw 'found t)))
1340                 nil)
1341               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
1342                 (when info
1343                   (insert (format "\"%s\" %d %d y\n"
1344                                   mbx (or (nth 2 info) 0)
1345                                   (max 1 (or (nth 1 info) 1)))))))))
1346       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
1347                     (if (> (length server) 0) " on " "") server))
1348     t))
1349
1350 (deffoo nnimap-request-create-group (group &optional server args)
1351   (when (nnimap-possibly-change-server server)
1352     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
1353         (imap-mailbox-create group nnimap-server-buffer)
1354         (nnheader-report 'nnimap "%S"
1355                          (imap-error-text nnimap-server-buffer)))))
1356
1357 (defun nnimap-time-substract (time1 time2)
1358   "Return TIME for TIME1 - TIME2."
1359   (let* ((ms (- (car time1) (car time2)))
1360          (ls (- (nth 1 time1) (nth 1 time2))))
1361     (if (< ls 0)
1362         (list (- ms 1) (+ (expt 2 16) ls))
1363       (list ms ls))))
1364
1365 (defun nnimap-date-days-ago (daysago)
1366   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
1367   (let* ((time (nnimap-time-substract (current-time) (days-to-time daysago)))
1368          (date (format-time-string
1369                 (format "%%d-%s-%%Y"
1370                         (capitalize (car (rassoc (nth 4 (decode-time time))
1371                                                  parse-time-months))))
1372                 time)))
1373     (if (eq ?0 (string-to-char date))
1374         (substring date 1)
1375       date)))
1376
1377 (defun nnimap-request-expire-articles-progress ()
1378   (gnus-message 5 "nnimap: Marking article %d for deletion..."
1379                 imap-current-message))
1380
1381 (defun nnimap-expiry-target (arts group server)
1382   (unless (eq nnmail-expiry-target 'delete)
1383     (with-temp-buffer
1384       (dolist (art arts)
1385         (nnimap-request-article art group server (current-buffer))
1386         ;; hints for optimization in `nnimap-request-accept-article'
1387         (let ((nnimap-current-move-article art)
1388               (nnimap-current-move-group group)
1389               (nnimap-current-move-server server))
1390           (nnmail-expiry-target-group nnmail-expiry-target group))))
1391     ;; It is not clear if `nnmail-expiry-target' somehow cause the
1392     ;; current group to be changed or not, so we make sure here.
1393     (nnimap-possibly-change-group group server)))
1394
1395 ;; Notice that we don't actually delete anything, we just mark them deleted.
1396 (deffoo nnimap-request-expire-articles (articles group &optional server force)
1397   (let ((artseq (gnus-compress-sequence articles)))
1398     (when (and artseq (nnimap-possibly-change-group group server))
1399       (with-current-buffer nnimap-server-buffer
1400         (let ((days (or (and nnmail-expiry-wait-function
1401                              (funcall nnmail-expiry-wait-function group))
1402                         nnmail-expiry-wait)))
1403           (cond ((or force (eq days 'immediate))
1404                  (let ((oldarts (imap-search
1405                                  (concat "UID "
1406                                          (imap-range-to-message-set artseq)))))
1407                    (when oldarts
1408                      (nnimap-expiry-target oldarts group server)
1409                      (when (imap-message-flags-add
1410                             (imap-range-to-message-set
1411                              (gnus-compress-sequence oldarts)) "\\Deleted")
1412                        (setq articles (gnus-set-difference
1413                                        articles oldarts))))))
1414                 ((numberp days)
1415                  (let ((oldarts (imap-search
1416                                  (format nnimap-expunge-search-string
1417                                          (imap-range-to-message-set artseq)
1418                                          (nnimap-date-days-ago days))))
1419                        (imap-fetch-data-hook
1420                         '(nnimap-request-expire-articles-progress)))
1421                    (when oldarts
1422                      (nnimap-expiry-target oldarts group server)
1423                      (when (imap-message-flags-add
1424                             (imap-range-to-message-set
1425                              (gnus-compress-sequence oldarts)) "\\Deleted")
1426                        (setq articles (gnus-set-difference
1427                                        articles oldarts)))))))))))
1428   ;; return articles not deleted
1429   articles)
1430
1431 (deffoo nnimap-request-move-article (article group server
1432                                              accept-form &optional last)
1433   (when (nnimap-possibly-change-server server)
1434     (save-excursion
1435       (let ((buf (get-buffer-create " *nnimap move*"))
1436             (nnimap-current-move-article article)
1437             (nnimap-current-move-group group)
1438             (nnimap-current-move-server nnimap-current-server)
1439             result)
1440         (and (nnimap-request-article article group server)
1441              (save-excursion
1442                (set-buffer buf)
1443                (buffer-disable-undo (current-buffer))
1444                (insert-buffer-substring nntp-server-buffer)
1445                (setq result (eval accept-form))
1446                (kill-buffer buf)
1447                result)
1448              (imap-message-flags-add
1449               (imap-range-to-message-set (list article))
1450               "\\Deleted" 'silent nnimap-server-buffer))
1451         result))))
1452
1453 (deffoo nnimap-request-accept-article (group &optional server last)
1454   (when (nnimap-possibly-change-server server)
1455     (let (uid)
1456       (if (setq uid
1457                 (if (string= nnimap-current-server nnimap-current-move-server)
1458                     ;; moving article within same server, speed it up...
1459                     (and (nnimap-possibly-change-group
1460                           nnimap-current-move-group)
1461                          (imap-message-copy (number-to-string
1462                                              nnimap-current-move-article)
1463                                             group 'dontcreate nil
1464                                             nnimap-server-buffer))
1465                   (with-current-buffer (current-buffer)
1466                     (goto-char (point-min))
1467                     ;; remove any 'From blabla' lines, some IMAP servers
1468                     ;; reject the entire message otherwise.
1469                     (when (looking-at "^From[^:]")
1470                       (delete-region (point) (progn (forward-line) (point))))
1471                     ;; turn into rfc822 format (\r\n eol's)
1472                     (while (search-forward "\n" nil t)
1473                       (replace-match "\r\n"))
1474                     (when nnmail-cache-accepted-message-ids
1475                       (nnmail-cache-insert (nnmail-fetch-field "message-id")
1476                                            group
1477                                            (nnmail-fetch-field "subject"))))
1478                   (when (and last nnmail-cache-accepted-message-ids)
1479                     (nnmail-cache-close))
1480                   ;; this 'or' is for Cyrus server bug
1481                   (or (null (imap-current-mailbox nnimap-server-buffer))
1482                       (imap-mailbox-unselect nnimap-server-buffer))
1483                   (imap-message-append group (current-buffer) nil nil
1484                                        nnimap-server-buffer)))
1485           (cons group (nth 1 uid))
1486         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1487
1488 (deffoo nnimap-request-delete-group (group force &optional server)
1489   (when (nnimap-possibly-change-server server)
1490     (with-current-buffer nnimap-server-buffer
1491       (if force
1492           (or (null (imap-mailbox-status group 'uidvalidity))
1493               (imap-mailbox-delete group))
1494         ;; UNSUBSCRIBE?
1495         t))))
1496
1497 (deffoo nnimap-request-rename-group (group new-name &optional server)
1498   (when (nnimap-possibly-change-server server)
1499     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1500
1501 (defun nnimap-expunge (mailbox server)
1502   (when (nnimap-possibly-change-group mailbox server)
1503     (imap-mailbox-expunge nil nnimap-server-buffer)))
1504
1505 (defun nnimap-acl-get (mailbox server)
1506   (when (nnimap-possibly-change-server server)
1507     (and (imap-capability 'ACL nnimap-server-buffer)
1508          (imap-mailbox-acl-get mailbox nnimap-server-buffer))))
1509
1510 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1511   (when (nnimap-possibly-change-server (cadr method))
1512     (unless (imap-capability 'ACL nnimap-server-buffer)
1513       (error "Your server does not support ACL editing"))
1514     (with-current-buffer nnimap-server-buffer
1515       ;; delete all removed identifiers
1516       (mapcar (lambda (old-acl)
1517                 (unless (assoc (car old-acl) new-acls)
1518                   (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1519                       (error "Can't delete ACL for %s" (car old-acl)))))
1520               old-acls)
1521       ;; set all changed acl's
1522       (mapcar (lambda (new-acl)
1523                 (let ((new-rights (cdr new-acl))
1524                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1525                   (unless (and old-rights new-rights
1526                                (string= old-rights new-rights))
1527                     (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1528                         (error "Can't set ACL for %s to %s" (car new-acl)
1529                                new-rights)))))
1530               new-acls)
1531       t)))
1532
1533 \f
1534 ;;; Internal functions
1535
1536 ;;
1537 ;; This is confusing.
1538 ;;
1539 ;; mark      => read, tick, draft, reply etc
1540 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1541 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1542 ;;
1543 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1544 ;; world, but we cheat.  Mark == gnus-article-mark-lists + '(read . read).
1545 ;;
1546
1547 (defconst nnimap-mark-to-predicate-alist
1548   (mapcar
1549    (lambda (pair)                       ; cdr is the mark
1550      (or (assoc (cdr pair)
1551                 '((read . "SEEN")
1552                   (tick . "FLAGGED")
1553                   (draft . "DRAFT")
1554                   (recent . "RECENT")
1555                   (reply . "ANSWERED")))
1556          (cons (cdr pair)
1557                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1558    (cons '(read . read) gnus-article-mark-lists)))
1559
1560 (defun nnimap-mark-to-predicate (pred)
1561   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP predicate.
1562 This is a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD gnus-expire\",
1563 to be used within a IMAP SEARCH query."
1564   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1565
1566 (defconst nnimap-mark-to-flag-alist
1567   (mapcar
1568    (lambda (pair)
1569      (or (assoc (cdr pair)
1570                 '((read . "\\Seen")
1571                   (tick . "\\Flagged")
1572                   (draft . "\\Draft")
1573                   (recent . "\\Recent")
1574                   (reply . "\\Answered")))
1575          (cons (cdr pair)
1576                (format "gnus-%s" (symbol-name (cdr pair))))))
1577    (cons '(read . read) gnus-article-mark-lists)))
1578
1579 (defun nnimap-mark-to-flag-1 (preds)
1580   (if (and (not (null preds)) (listp preds))
1581       (cons (nnimap-mark-to-flag (car preds))
1582             (nnimap-mark-to-flag (cdr preds)))
1583     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1584
1585 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1586   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP flag.
1587 This is a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\", to
1588 be used in a STORE FLAGS command."
1589   (let ((result (nnimap-mark-to-flag-1 preds)))
1590     (setq result (if (and (or make-string always-list)
1591                           (not (listp result)))
1592                      (list result)
1593                    result))
1594     (if make-string
1595         (mapconcat (lambda (flag)
1596                      (if (listp flag)
1597                          (mapconcat 'identity flag " ")
1598                        flag))
1599                    result " ")
1600       result)))
1601
1602 (defun nnimap-mark-permanent-p (mark &optional group)
1603   "Return t iff MARK can be permanently (between IMAP sessions) saved on articles, in GROUP."
1604   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1605
1606 (when nnimap-debug
1607   (require 'trace)
1608   (buffer-disable-undo (get-buffer-create nnimap-debug-buffer))
1609   (mapcar (lambda (f) (trace-function-background f nnimap-debug-buffer))
1610           '(
1611             nnimap-possibly-change-server
1612             nnimap-verify-uidvalidity
1613             nnimap-find-minmax-uid
1614             nnimap-before-find-minmax-bugworkaround
1615             nnimap-possibly-change-group
1616             ;;nnimap-replace-whitespace
1617             nnimap-retrieve-headers-progress
1618             nnimap-retrieve-which-headers
1619             nnimap-group-overview-filename
1620             nnimap-retrieve-headers-from-file
1621             nnimap-retrieve-headers-from-server
1622             nnimap-retrieve-headers
1623             nnimap-open-connection
1624             nnimap-open-server
1625             nnimap-server-opened
1626             nnimap-close-server
1627             nnimap-request-close
1628             nnimap-status-message
1629             ;;nnimap-demule
1630             nnimap-request-article-part
1631             nnimap-request-article
1632             nnimap-request-head
1633             nnimap-request-body
1634             nnimap-request-group
1635             nnimap-close-group
1636             nnimap-pattern-to-list-arguments
1637             nnimap-request-list
1638             nnimap-request-post
1639             nnimap-retrieve-groups
1640             nnimap-request-update-info-internal
1641             nnimap-request-type
1642             nnimap-request-set-mark
1643             nnimap-split-to-groups
1644             nnimap-split-find-rule
1645             nnimap-split-find-inbox
1646             nnimap-split-articles
1647             nnimap-request-scan
1648             nnimap-request-newgroups
1649             nnimap-request-create-group
1650             nnimap-time-substract
1651             nnimap-date-days-ago
1652             nnimap-request-expire-articles-progress
1653             nnimap-request-expire-articles
1654             nnimap-request-move-article
1655             nnimap-request-accept-article
1656             nnimap-request-delete-group
1657             nnimap-request-rename-group
1658             gnus-group-nnimap-expunge
1659             gnus-group-nnimap-edit-acl
1660             gnus-group-nnimap-edit-acl-done
1661             nnimap-group-mode-hook
1662             nnimap-mark-to-predicate
1663             nnimap-mark-to-flag-1
1664             nnimap-mark-to-flag
1665             nnimap-mark-permanent-p
1666             )))
1667
1668 (provide 'nnimap)
1669
1670 ;;; nnimap.el ends here