git.chise.org Git - elisp/gnus.git-/blob - lisp/nnimap.el

   1 ;;; nnimap.el --- imap backend for Gnus
   2 ;; Copyright (C) 1998,1999 Free Software Foundation, Inc.
   3
   4 ;; Author: Simon Josefsson <jas@pdc.kth.se>
   5 ;;         Jim Radford <radford@robby.caltech.edu>
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Todo, major things:
  28 ;;
  29 ;;   o Fix Gnus to view correct number of unread/total articles in group buffer
  30 ;;   o Fix Gnus to handle leading '.' in group names (fixed?)
  31 ;;   o Finish disconnected mode (moving articles between mailboxes unplugged)
  32 ;;   o Sieve
  33 ;;   o MIME (partial article fetches)
  34 ;;   o Split to other backends, different split rules for different
  35 ;;     servers/inboxes
  36 ;;
  37 ;; Todo, minor things:
  38 ;;
  39 ;;   o Support escape characters in `message-tokenize-header'
  40 ;;   o Split-fancy.
  41 ;;   o Support NOV nnmail-extra-headers.
  42 ;;   o Verify that we don't use IMAP4rev1 specific things (RFC2060 App B)
  43 ;;   o Dont uid fetch 1,* in nnimap-retrive-groups (slow)
  44 ;;   o Split up big fetches (1,* header especially) in smaller chunks
  45 ;;   o What do I do with gnus-newsgroup-*?
  46 ;;   o Tell Gnus about new groups (how can we tell?)
  47 ;;   o Respooling (fix Gnus?) (unnecessery?)
  48 ;;   o Add support for the following: (if applicable)
  49 ;;       request-list-newsgroups, request-regenerate
  50 ;;       list-active-group,
  51 ;;       request-associate-buffer, request-restore-buffer,
  52 ;;   o Do The Right Thing when UIDVALIDITY changes (what's the right thing?)
  53 ;;   o Support RFC2221 (Login referrals)
  54 ;;   o IMAP2BIS compatibility? (RFC2061)
  55 ;;   o ACAP stuff (perhaps a different project, would be nice to ACAPify
  56 ;;     .newsrc.eld)
  57 ;;   o What about Gnus's article editing, can we support it?
  58 ;;   o Use \Draft to support the draft group??
  59
  60 ;;; Code:
  61
  62 (eval-and-compile
  63   (require 'imap))
  64
  65 (require 'nnoo)
  66 (require 'nnmail)
  67 (require 'nnheader)
  68 (require 'mm-util)
  69 (require 'gnus)
  70 (require 'gnus-async)
  71 (require 'gnus-range)
  72 (require 'gnus-start)
  73 (require 'gnus-int)
  74
  75 (nnoo-declare nnimap)
  76
  77 (defconst nnimap-version "nnimap 0.131")
  78
  79 (defvoo nnimap-address nil
  80   "Address of physical IMAP server.  If nil, use the virtual server's name.")
  81
  82 (defvoo nnimap-server-port nil
  83   "Port number on physical IMAP server.
  84 If nil, defaults to 993 for SSL connections and 143 otherwise.")
  85
  86 ;; Splitting variables
  87
  88 (defvar nnimap-split-crosspost t
  89   "If non-nil, do crossposting if several split methods match the mail.
  90 If nil, the first match found will be used.")
  91
  92 (defvar nnimap-split-inbox nil
  93   "*Name of mailbox to split mail from.
  94
  95 Mail is read from this mailbox and split according to rules in
  96 `nnimap-split-rules'.
  97
  98 This can be a string or a list of strings.")
  99
 100 (defvar nnimap-split-rule nil
 101   "*Mail will be split according to theese rules.
 102
 103 Mail is read from mailbox(es) specified in `nnimap-split-inbox'.
 104
 105 If you'd like, for instance, one mail group for mail from the
 106 \"gnus-imap\" mailing list, one group for junk mail and leave
 107 everything else in the incoming mailbox, you could do something like
 108 this:
 109
 110 (setq nnimap-split-rule '((\"INBOX.gnus-imap\"   \"From:.*gnus-imap\")
 111                           (\"INBOX.junk\"        \"Subject:.*buy\")))
 112
 113 As you can see, `nnimap-split-rule' is a list of lists, where the first
 114 element in each \"rule\" is the name of the IMAP mailbox, and the
 115 second is a regexp that nnimap will try to match on the header to find
 116 a fit.
 117
 118 The first element can also be a list. In that case, the first element
 119 is the server the second element is the group on that server in which
 120 the matching article will be stored.
 121
 122 The second element can also be a function.  In that case, it will be
 123 called narrowed to the headers with the first element of the rule as
 124 the argument.  It should return a non-nil value if it thinks that the
 125 mail belongs in that group.")
 126
 127 ;; Authorization / Privacy variables
 128
 129 (defvoo nnimap-auth-method nil
 130   "Obsolete.")
 131
 132 (defvoo nnimap-stream nil
 133   "How nnimap will connect to the server.
 134
 135 The default, nil, will try to use the \"best\" method the server can
 136 handle.
 137
 138 Change this if
 139
 140 1) you want to connect with SSL. The SSL integration with IMAP is
 141    brain-dead so you'll have to tell it specifically.
 142
 143 2) your server is more capable than your environment -- i.e. your
 144    server accept Kerberos login's but you haven't installed the
 145    `imtest' program or your machine isn't configured for Kerberos.
 146
 147 Possible choices: kerberos4, ssl, network")
 148
 149 (defvoo nnimap-authenticator nil
 150   "How nnimap authenticate itself to the server.
 151
 152 The default, nil, will try to use the \"best\" method the server can
 153 handle.
 154
 155 There is only one reason for fiddling with this variable, and that is
 156 if your server is more capable than your environment -- i.e. you
 157 connect to a server that accept Kerberos login's but you haven't
 158 installed the `imtest' program or your machine isn't configured for
 159 Kerberos.
 160
 161 Possible choices: kerberos4, cram-md5, login, anonymous.")
 162
 163 (defvoo nnimap-directory (nnheader-concat gnus-directory "overview/")
 164   "Directory to keep NOV cache files for nnimap groups. See also
 165 `nnimap-nov-file-name'.")
 166
 167 (defvoo nnimap-nov-file-name "nnimap."
 168   "NOV cache base filename. The group name and
 169 `nnimap-nov-file-name-suffix' will be appended. A typical complete
 170 file name would be ~/News/overview/nnimap.pdc.INBOX.ding.nov, or
 171 ~/News/overview/nnimap/pdc/INBOX/ding/nov if
 172 `nnmail-use-long-file-names' is nil")
 173
 174 (defvoo nnimap-nov-file-name-suffix ".novcache"
 175   "Suffix for NOV cache base filename.")
 176
 177 (defvoo nnimap-nov-is-evil nil
 178   "If non-nil, nnimap will never generate or use a local nov database
 179 for this backend.  Using nov databases will speed up header fetching
 180 considerably. Unlike other backends, you do not need to take special
 181 care if you flip this variable.")
 182
 183 (defvoo nnimap-expunge-on-close 'always ; 'ask, 'never
 184   "When a IMAP group with articles marked for deletion is closed, this
 185 variable determine if nnimap should actually remove the articles or
 186 not.
 187
 188 If always, nnimap always perform a expunge when closing the group.
 189 If never, nnimap never expunges articles marked for deletion.
 190 If ask, nnimap will ask you if you wish to expunge marked articles.
 191
 192 When setting this variable to `never', you can only expunge articles
 193 by using `G x' (gnus-group-nnimap-expunge) from the Group buffer.")
 194
 195 (defvoo nnimap-list-pattern "*"
 196   "A string LIMIT or list of strings with mailbox wildcards used to
 197 limit available groups. Se below for available wildcards.
 198
 199 The LIMIT string can be a cons cell (REFERENCE . LIMIT), where
 200 REFERENCE will be passed as the first parameter to LIST/LSUB. The
 201 semantics of this are server specific, on the University of Washington
 202 server you can specify a directory.
 203
 204 Example:
 205  '(\"INBOX\" \"mail/*\" (\"~friend/mail/\" . \"list/*\"))
 206
 207 There are two wildcards * and %. * matches everything, % matches
 208 everything in the current hierarchy.")
 209
 210 (defvoo nnimap-news-groups nil
 211   "IMAP support a news-like mode, also known as bulletin board mode,
 212 where replies is sent via IMAP instead of SMTP.
 213
 214 This variable should contain a regexp matching groups where you wish
 215 replies to be stored to the mailbox directly.
 216
 217 Example:
 218   '(\"^[^I][^N][^B][^O][^X].*$\")
 219
 220 This will match all groups not beginning with \"INBOX\".
 221
 222 Note that there is nothing technically different between mail-like and
 223 news-like mailboxes. If you wish to have a group with todo items or
 224 similar which you wouldn't want to set up a mailing list for, you can
 225 use this to make replies go directly to the group.")
 226
 227 (defvoo nnimap-server-address nil
 228   "Obsolete. Use `nnimap-address'.")
 229
 230 (defcustom nnimap-authinfo-file "~/.authinfo"
 231   "Authorization information for IMAP servers.  In .netrc format."
 232   :type
 233   '(choice file
 234            (repeat :tag "Entries"
 235                    :menu-tag "Inline"
 236                    (list :format "%v"
 237                          :value ("" ("login" . "") ("password" . ""))
 238                          (string :tag "Host")
 239                          (checklist :inline t
 240                                     (cons :format "%v"
 241                                           (const :format "" "login")
 242                                           (string :format "Login: %v"))
 243                                     (cons :format "%v"
 244                                           (const :format "" "password")
 245                                           (string :format "Password: %v")))))))
 246
 247 (defcustom nnimap-prune-cache t
 248   "If non-nil, nnimap check wheter articles still exist on server
 249 before using data stored in NOV cache."
 250   :type 'boolean)
 251
 252 (defvar nnimap-request-list-method 'imap-mailbox-list
 253   "Method to use to request a list of all folders from the server.
 254 If this is 'imap-mailbox-lsub, then use a server-side subscription list to
 255 restrict visible folders.")
 256
 257 ;; Internal variables:
 258
 259 (defvar nnimap-debug "*nnimap-debug*")
 260 (defvar nnimap-current-move-server nil)
 261 (defvar nnimap-current-move-group nil)
 262 (defvar nnimap-current-move-article nil)
 263 (defvar nnimap-length)
 264 (defvar nnimap-progress-chars '(?| ?/ ?- ?\\))
 265 (defvar nnimap-progress-how-often 20)
 266 (defvar nnimap-counter)
 267 (defvar nnimap-callback-callback-function nil
 268   "Gnus callback the nnimap asynchronous callback should call.")
 269 (defvar nnimap-callback-buffer nil
 270   "Which buffer the asynchronous article prefetch callback should work in.")
 271
 272 ;; Various server variables.
 273
 274 \f
 275 ;; Internal variables.
 276 (defvar nnimap-server-buffer-alist nil) ;; Map server name to buffers.
 277 (defvar nnimap-current-server nil)      ;; Current server
 278 (defvar nnimap-server-buffer nil)       ;; Current servers' buffer
 279
 280 (nnoo-define-basics nnimap)
 281
 282 ;; Utility functions:
 283
 284 (defun nnimap-replace-in-string (string regexp to)
 285   "Replace substrings in STRING matching REGEXP with TO."
 286   (if (string-match regexp string)
 287       (concat (substring string 0 (match-beginning 0))
 288               to
 289               (nnimap-replace-in-string (substring string (match-end 0))
 290                                  regexp to))
 291     string))
 292
 293 (defsubst nnimap-get-server-buffer (server)
 294   "Return buffer for SERVER, if nil use current server."
 295   (cadr (assoc (or server nnimap-current-server) nnimap-server-buffer-alist)))
 296
 297 (defun nnimap-possibly-change-server (server)
 298   "Return buffer for SERVER, changing the current server as a side-effect.
 299 If SERVER is nil, uses the current server."
 300   (setq nnimap-current-server (or server nnimap-current-server)
 301         nnimap-server-buffer (nnimap-get-server-buffer nnimap-current-server)))
 302
 303 (defun nnimap-verify-uidvalidity (group server)
 304   "Verify stored uidvalidity match current one in GROUP on SERVER."
 305   (let* ((gnusgroup (gnus-group-prefixed-name
 306                      group (gnus-server-to-method
 307                             (format "nnimap:%s" server))))
 308          (new-uidvalidity (imap-mailbox-get 'uidvalidity))
 309          (old-uidvalidity (gnus-group-get-parameter gnusgroup 'uidvalidity)))
 310     (if old-uidvalidity
 311         (if (not (equal old-uidvalidity new-uidvalidity))
 312             nil ;; uidvalidity clash
 313           (gnus-group-set-parameter gnusgroup 'uidvalidity new-uidvalidity)
 314           t)
 315       (gnus-group-add-parameter gnusgroup (cons 'uidvalidity new-uidvalidity))
 316       t)))
 317
 318 (defun nnimap-find-minmax-uid (group &optional examine)
 319   "Find lowest and highest active article nummber in GROUP.
 320 If EXAMINE is non-nil the group is selected read-only."
 321   (with-current-buffer nnimap-server-buffer
 322     (when (imap-mailbox-select group examine)
 323       (let (minuid maxuid)
 324         (when (> (imap-mailbox-get 'exists) 0)
 325           (imap-fetch "1,*" "UID" nil 'nouidfetch)
 326           (imap-message-map (lambda (uid Uid)
 327                               (setq minuid (if minuid (min minuid uid) uid)
 328                                     maxuid (if maxuid (max maxuid uid) uid)))
 329                             'UID))
 330         (list (imap-mailbox-get 'exists) minuid maxuid)))))
 331
 332 (defun nnimap-possibly-change-group (group &optional server)
 333   "Make GROUP the current group, and SERVER the current server."
 334   (when (nnimap-possibly-change-server server)
 335     (with-current-buffer nnimap-server-buffer
 336       (if (or (null group) (imap-current-mailbox-p group))
 337           imap-current-mailbox
 338         (if (imap-mailbox-select group)
 339             (if (or (nnimap-verify-uidvalidity
 340                      group (or server nnimap-current-server))
 341                     (zerop (imap-mailbox-get 'exists group))
 342                     (yes-or-no-p
 343                      (format
 344                       "nnimap: Group %s is not uidvalid. Continue? " group)))
 345                 imap-current-mailbox
 346               (imap-mailbox-unselect)
 347               (error "nnimap: Group %s is not uid-valid." group))
 348           (nnheader-report 'nnimap (imap-error-text)))))))
 349
 350 (defun nnimap-replace-whitespace (string)
 351   "Return STRING with all whitespace replaced with space."
 352   (when string
 353     (while (string-match "[\r\n\t]+" string)
 354       (setq string (replace-match " " t t string)))
 355     string))
 356
 357 ;; Required backend functions
 358
 359 (defun nnimap-retrieve-headers-progress ()
 360   "Hook to insert NOV line for current article into `nntp-server-buffer'."
 361   (and (numberp nnmail-large-newsgroup)
 362        (zerop (% (incf nnimap-counter) nnimap-progress-how-often))
 363        (> nnimap-length nnmail-large-newsgroup)
 364        (nnheader-message 6 "nnimap: Retrieving headers... %c"
 365                          (nth (/ (% nnimap-counter
 366                                     (* (length nnimap-progress-chars)
 367                                        nnimap-progress-how-often))
 368                                  nnimap-progress-how-often)
 369                               nnimap-progress-chars)))
 370   (with-current-buffer nntp-server-buffer
 371     (nnheader-insert-nov
 372      (with-current-buffer nnimap-server-buffer
 373        (vector imap-current-message
 374                (nnimap-replace-whitespace
 375                 (imap-message-envelope-subject imap-current-message))
 376                (nnimap-replace-whitespace
 377                 (imap-envelope-from
 378                  (car-safe (imap-message-envelope-from
 379                             imap-current-message))))
 380                (nnimap-replace-whitespace
 381                 (imap-message-envelope-date imap-current-message))
 382                (nnimap-replace-whitespace
 383                 (imap-message-envelope-message-id imap-current-message))
 384                (nnimap-replace-whitespace
 385                 (let ((str (if (imap-capability 'IMAP4rev1)
 386                                (nth 2 (assoc
 387                                        "HEADER.FIELDS REFERENCES"
 388                                        (imap-message-get
 389                                         imap-current-message 'BODYDETAIL)))
 390                              (imap-message-get imap-current-message
 391                                                'RFC822.HEADER))))
 392                   (if (> (length str) (length "References: "))
 393                       (substring str (length "References: "))
 394                     (if (and (setq str (imap-message-envelope-in-reply-to
 395                                         imap-current-message))
 396                              (string-match "<[^>]+>" str))
 397                         (substring str (match-beginning 0) (match-end 0))))))
 398                (imap-message-get imap-current-message 'RFC822.SIZE)
 399                (imap-body-lines (imap-message-body imap-current-message))
 400                nil ;; xref
 401                nil))))) ;; extra-headers
 402
 403 (defun nnimap-retrieve-which-headers (articles fetch-old)
 404   "Get a range of articles to fetch based on ARTICLES and FETCH-OLD."
 405   (with-current-buffer nnimap-server-buffer
 406     (if (numberp (car-safe articles))
 407         (imap-search
 408          (concat "UID "
 409                  (nnimap-range-to-string
 410                   (gnus-compress-sequence
 411                    (append (gnus-uncompress-sequence
 412                             (and fetch-old
 413                                  (cons (if (numberp fetch-old)
 414                                            (max 1 (- (car articles) fetch-old))
 415                                          1)
 416                                        (1- (car articles)))))
 417                            articles)))))
 418       (mapcar (lambda (msgid)
 419                 (imap-search
 420                  (format "HEADER Message-Id %s" msgid)))
 421               articles))))
 422
 423 (defun nnimap-group-overview-filename (group server)
 424   "Make pathname for GROUP on SERVER."
 425   (let ((dir (file-name-as-directory (expand-file-name nnimap-directory)))
 426         (file (nnheader-translate-file-chars
 427                (concat nnimap-nov-file-name
 428                        (if (equal server "")
 429                            "unnamed"
 430                          server) "." group nnimap-nov-file-name-suffix) t)))
 431     (if (or nnmail-use-long-file-names
 432             (file-exists-p (concat dir file)))
 433         (concat dir file)
 434       (concat dir (mm-encode-coding-string
 435                    (nnheader-replace-chars-in-string file ?. ?/)
 436                    nnmail-pathname-coding-system)))))
 437
 438 (defun nnimap-retrieve-headers-from-file (group server)
 439   (with-current-buffer nntp-server-buffer
 440     (let ((nov (nnimap-group-overview-filename group server)))
 441       (when (file-exists-p nov)
 442         (mm-insert-file-contents nov)
 443         (set-buffer-modified-p nil)
 444         (let ((min (progn (goto-char (point-min))
 445                           (when (not (eobp))
 446                             (read (current-buffer)))))
 447               (max (progn (goto-char (point-max))
 448                           (forward-line -1)
 449                           (when (not (bobp))
 450                             (read (current-buffer))))))
 451           (if (and (numberp min) (numberp max))
 452               (cons min max)
 453             ;; junk, remove it, it's saved later
 454             (erase-buffer)
 455             nil))))))
 456
 457 (defun nnimap-retrieve-headers-from-server (articles group server)
 458   (with-current-buffer nnimap-server-buffer
 459     (let ((imap-fetch-data-hook '(nnimap-retrieve-headers-progress))
 460           (nnimap-length (gnus-range-length articles))
 461           (nnimap-counter 0))
 462       (imap-fetch (nnimap-range-to-string articles)
 463                   (concat "(UID RFC822.SIZE ENVELOPE BODY "
 464                           (if (imap-capability 'IMAP4rev1)
 465                               "BODY.PEEK[HEADER.FIELDS (References)])"
 466                             "RFC822.HEADER.LINES (References))")))
 467       (and (numberp nnmail-large-newsgroup)
 468            (> nnimap-length nnmail-large-newsgroup)
 469            (nnheader-message 6 "nnimap: Retrieving headers...done")))))
 470
 471 (defun nnimap-use-nov-p (group server)
 472   (or gnus-nov-is-evil nnimap-nov-is-evil
 473       (unless (and (gnus-make-directory
 474                     (file-name-directory
 475                      (nnimap-group-overview-filename group server)))
 476                    (file-writable-p
 477                     (nnimap-group-overview-filename group server)))
 478         (message "nnimap: Nov cache not writable, %s"
 479                  (nnimap-group-overview-filename group server)))))
 480
 481 (deffoo nnimap-retrieve-headers (articles &optional group server fetch-old)
 482   (when (nnimap-possibly-change-group group server)
 483     (with-current-buffer nntp-server-buffer
 484       (erase-buffer)
 485       (if (nnimap-use-nov-p group server)
 486           (nnimap-retrieve-headers-from-server
 487            (gnus-compress-sequence articles) group server)
 488         (let (uids cached low high)
 489           (when (setq uids (nnimap-retrieve-which-headers articles fetch-old)
 490                       low (car uids)
 491                       high (car (last uids)))
 492             (if (setq cached (nnimap-retrieve-headers-from-file group server))
 493                 (progn
 494                   ;; fetch articles with uids before cache block
 495                   (when (< low (car cached))
 496                     (goto-char (point-min))
 497                     (nnimap-retrieve-headers-from-server
 498                      (cons low (1- (car cached))) group server))
 499                   ;; fetch articles with uids after cache block
 500                   (when (> high (cdr cached))
 501                     (goto-char (point-max))
 502                     (nnimap-retrieve-headers-from-server
 503                      (cons (1+ (cdr cached)) high) group server))
 504                   (when nnimap-prune-cache
 505                     ;; remove nov's for articles which has expired on server
 506                     (goto-char (point-min))
 507                     (dolist (uid (gnus-set-difference articles uids))
 508                       (when (re-search-forward (format "^%d\t" uid) nil t)
 509                         (gnus-delete-line)))))
 510               ;; nothing cached, fetch whole range from server
 511               (nnimap-retrieve-headers-from-server
 512                (cons low high) group server))
 513             (when (buffer-modified-p)
 514               (nnmail-write-region
 515                1 (point-max) (nnimap-group-overview-filename group server)
 516                nil 'nomesg))
 517             (nnheader-nov-delete-outside-range low high))))
 518       'nov)))
 519
 520 (defun nnimap-open-connection (server)
 521   (if (not (imap-open nnimap-address nnimap-server-port nnimap-stream
 522                       nnimap-authenticator nnimap-server-buffer))
 523       (nnheader-report 'nnimap "Can't open connection to server %s" server)
 524     (unless (or (imap-capability 'IMAP4 nnimap-server-buffer)
 525                 (imap-capability 'IMAP4rev1 nnimap-server-buffer))
 526       (imap-close nnimap-server-buffer)
 527       (nnheader-report 'nnimap "Server %s is not IMAP4 compliant" server))
 528     (let (list alist user passwd)
 529       (and (fboundp 'gnus-parse-netrc)
 530            (setq list (gnus-parse-netrc nnimap-authinfo-file)
 531                  alist (or (and (gnus-netrc-get
 532                                  (gnus-netrc-machine list server) "machine")
 533                                 (gnus-netrc-machine list server))
 534                            (gnus-netrc-machine list nnimap-address))
 535                  user (gnus-netrc-get alist "login")
 536                  passwd (gnus-netrc-get alist "password")))
 537       (if (imap-authenticate user passwd nnimap-server-buffer)
 538           (prog1
 539               (push (list server nnimap-server-buffer)
 540                     nnimap-server-buffer-alist)
 541             (nnimap-possibly-change-server server))
 542         (imap-close nnimap-server-buffer)
 543         (kill-buffer nnimap-server-buffer)
 544         (nnheader-report 'nnimap "Could not authenticate to %s" server)))))
 545
 546 (deffoo nnimap-open-server (server &optional defs)
 547   (nnheader-init-server-buffer)
 548   (if (nnimap-server-opened server)
 549       t
 550     (unless (assq 'nnimap-server-buffer defs)
 551       (push (list 'nnimap-server-buffer (concat " *nnimap* " server)) defs))
 552     ;; translate `nnimap-server-address' to `nnimap-address' in defs
 553     ;; for people that configured nnimap with a very old version
 554     (unless (assq 'nnimap-address defs)
 555       (if (assq 'nnimap-server-address defs)
 556           (push (list 'nnimap-address
 557                       (cadr (assq 'nnimap-server-address defs))) defs)
 558         (push (list 'nnimap-address server) defs)))
 559     (nnoo-change-server 'nnimap server defs)
 560     (if (null nnimap-server-buffer)
 561         (error "this shouldn't happen"))
 562     (or (imap-opened nnimap-server-buffer)
 563         (nnimap-open-connection server))))
 564
 565 (deffoo nnimap-server-opened (&optional server)
 566   "If SERVER is the current virtual server, and the connection to the
 567 physical server is alive, this function return a non-nil value. If
 568 SERVER is nil, it is treated as the current server."
 569   ;; clean up autologouts??
 570   (and (or server nnimap-current-server)
 571        (nnoo-server-opened 'nnimap (or server nnimap-current-server))
 572        (imap-opened (nnimap-get-server-buffer server))))
 573
 574 (deffoo nnimap-close-server (&optional server)
 575   "Close connection to server and free all resources connected to
 576 it. Return nil if the server couldn't be closed for some reason."
 577   (let ((server (or server nnimap-current-server)))
 578     (when (or (nnimap-server-opened server)
 579               (imap-opened (nnimap-get-server-buffer server)))
 580       (imap-close (nnimap-get-server-buffer server))
 581       (kill-buffer (nnimap-get-server-buffer server))
 582       (setq nnimap-server-buffer nil
 583             nnimap-current-server nil
 584             nnimap-server-buffer-alist
 585             (delq server nnimap-server-buffer-alist)))
 586     (nnoo-close-server 'nnimap server)))
 587
 588 (deffoo nnimap-request-close ()
 589   "Close connection to all servers and free all resources that the
 590 backend have reserved. All buffers that have been created by that
 591 backend should be killed. (Not the nntp-server-buffer, though.) This
 592 function is generally only called when Gnus is shutting down."
 593   (mapcar (lambda (server) (nnimap-close-server (car server)))
 594           nnimap-server-buffer-alist)
 595   (setq nnimap-server-buffer-alist nil))
 596
 597 (deffoo nnimap-status-message (&optional server)
 598   "This function returns the last error message from server."
 599   (when (nnimap-possibly-change-server server)
 600     (nnoo-status-message 'nnimap server)))
 601
 602 (defun nnimap-demule (string)
 603   (funcall (if (and (fboundp 'string-as-multibyte)
 604                     (subrp (symbol-function 'string-as-multibyte)))
 605                'string-as-multibyte
 606              'identity)
 607            (or string "")))
 608
 609 (defun nnimap-callback ()
 610   (remove-hook 'imap-fetch-data-hook 'nnimap-callback)
 611   (with-current-buffer nnimap-callback-buffer
 612     (insert
 613      (with-current-buffer nnimap-server-buffer
 614        (nnimap-demule (imap-message-get (imap-current-message) 'RFC822)))) ;xxx
 615     (nnheader-ms-strip-cr)
 616     (funcall nnimap-callback-callback-function t)))
 617
 618 (defun nnimap-request-article-part (article part prop
 619                                             &optional group server to-buffer)
 620   (when (nnimap-possibly-change-group group server)
 621     (let ((article (if (stringp article)
 622                        (car-safe (imap-search
 623                                   (format "HEADER Message-Id %s" article)
 624                                   nnimap-server-buffer))
 625                      article)))
 626       (when article
 627         (gnus-message 9 "nnimap: Fetching (part of) article %d..." article)
 628         (if (not nnheader-callback-function)
 629             (with-current-buffer (or to-buffer nntp-server-buffer)
 630               (erase-buffer)
 631               (insert (nnimap-demule (imap-fetch article part prop nil
 632                                                  nnimap-server-buffer)))
 633               (nnheader-ms-strip-cr)
 634               (gnus-message 9 "nnimap: Fetching (part of) article %d...done"
 635                             article)
 636               (if (bobp)
 637                   (nnheader-report 'nnimap "No such article: %s"
 638                                    (imap-error-text nnimap-server-buffer))
 639                 (cons group article)))
 640           (add-hook 'imap-fetch-data-hook 'nnimap-callback)
 641           (setq nnimap-callback-callback-function nnheader-callback-function
 642                 nnimap-callback-buffer nntp-server-buffer)
 643           (imap-fetch-asynch article part nil nnimap-server-buffer)
 644           (cons group article))))))
 645
 646 (deffoo nnimap-asynchronous-p ()
 647   t)
 648
 649 (deffoo nnimap-request-article (article &optional group server to-buffer)
 650   (nnimap-request-article-part
 651    article "RFC822.PEEK" 'RFC822 group server to-buffer))
 652
 653 (deffoo nnimap-request-head (article &optional group server to-buffer)
 654   (nnimap-request-article-part
 655    article "RFC822.HEADER" 'RFC822.HEADER group server to-buffer))
 656
 657 (deffoo nnimap-request-body (article &optional group server to-buffer)
 658   (nnimap-request-article-part
 659    article "RFC822.TEXT.PEEK" 'RFC822.TEXT group server to-buffer))
 660
 661 (deffoo nnimap-request-group (group &optional server fast)
 662   (nnimap-request-update-info-internal
 663    group
 664    (gnus-get-info (gnus-group-prefixed-name
 665                    group (gnus-server-to-method (format "nnimap:%s" server))))
 666    server)
 667   (when (nnimap-possibly-change-group group server)
 668     (let (info)
 669       (cond (fast group)
 670             ((null (setq info (nnimap-find-minmax-uid group t)))
 671              (nnheader-report 'nnimap "Could not get active info for %s"
 672                               group))
 673             (t
 674              (nnheader-insert "211 %d %d %d %s\n" (or (nth 0 info) 0)
 675                               (max 1 (or (nth 1 info) 1))
 676                               (or (nth 2 info) 0) group)
 677              (nnheader-report 'nnimap "Group %s selected" group)
 678              t)))))
 679
 680 (defun nnimap-close-group (group &optional server)
 681   (with-current-buffer nnimap-server-buffer
 682     (when (and (imap-opened)
 683                (nnimap-possibly-change-group group server))
 684       (case nnimap-expunge-on-close
 685         ('always (imap-mailbox-expunge)
 686                  (imap-mailbox-close))
 687         ('ask (if (and (imap-search "DELETED")
 688                        (gnus-y-or-n-p (format
 689                                        "Expunge articles in group `%s'? "
 690                                        imap-current-mailbox)))
 691                   (progn (imap-mailbox-expunge)
 692                          (imap-mailbox-close))
 693                 (imap-mailbox-unselect)))
 694         (t (imap-mailbox-unselect)))
 695       (not imap-current-mailbox))))
 696
 697 (defun nnimap-pattern-to-list-arguments (pattern)
 698   (mapcar (lambda (p)
 699             (cons (car-safe p) (or (cdr-safe p) p)))
 700           (if (and (listp pattern)
 701                    (listp (cdr pattern)))
 702               pattern
 703             (list pattern))))
 704
 705 (deffoo nnimap-request-list (&optional server)
 706   (when (nnimap-possibly-change-server server)
 707     (with-current-buffer nntp-server-buffer
 708       (erase-buffer))
 709     (gnus-message 5 "nnimap: Generating active list%s..."
 710                   (if (> (length server) 0) (concat " for " server) ""))
 711     (with-current-buffer nnimap-server-buffer
 712       (dolist (pattern (nnimap-pattern-to-list-arguments nnimap-list-pattern))
 713         (dolist (mbx (funcall nnimap-request-list-method
 714                               (cdr pattern) (car pattern)))
 715           (or (member "\\NoSelect" (imap-mailbox-get 'list-flags mbx))
 716               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 717                 (when info
 718                   ;; Escape SPC in mailboxes xxx relies on gnus internals
 719                   (with-current-buffer nntp-server-buffer
 720                     (insert (format "%s %d %d y\n"
 721                                     (nnimap-replace-in-string mbx " " "\\ ")
 722                                     (or (nth 2 info) 0)
 723                                     (max 1 (or (nth 1 info) 1)))))))))))
 724     (gnus-message 5 "nnimap: Generating active list%s...done"
 725                   (if (> (length server) 0) (concat " for " server) ""))
 726     t))
 727
 728 (deffoo nnimap-request-post (&optional server)
 729   (let ((success t))
 730     (dolist  (mbx (message-tokenize-header
 731                    (message-fetch-field "Newsgroups")) success)
 732       (let ((to-newsgroup (gnus-group-prefixed-name mbx gnus-command-method)))
 733         (or (gnus-active to-newsgroup)
 734             (gnus-activate-group to-newsgroup)
 735             (if (gnus-y-or-n-p (format "No such group: %s.  Create it? "
 736                                        to-newsgroup))
 737                 (or (and (gnus-request-create-group
 738                           to-newsgroup gnus-command-method)
 739                          (gnus-activate-group to-newsgroup nil nil
 740                                               gnus-command-method))
 741                     (error "Couldn't create group %s" to-newsgroup)))
 742             (error "No such group: %s" to-newsgroup))
 743         (unless (nnimap-request-accept-article mbx (nth 1 gnus-command-method))
 744           (setq success nil))))))
 745
 746 ;; Optional backend functions
 747
 748 (deffoo nnimap-retrieve-groups (groups &optional server)
 749   (when (nnimap-possibly-change-server server)
 750     (gnus-message 5 "nnimap: Checking mailboxes...")
 751     (with-current-buffer nntp-server-buffer
 752       (erase-buffer)
 753       (dolist (group groups)
 754         (gnus-message 7 "nnimap: Checking mailbox %s" group)
 755         (or (member "\\NoSelect"
 756                     (imap-mailbox-get 'list-flags group nnimap-server-buffer))
 757             (let ((info (nnimap-find-minmax-uid group 'examine)))
 758               ;; Escape SPC in mailboxes xxx relies on gnus internals
 759               (insert (format "211 %d %d %d %s\n" (or (nth 0 info) 0)
 760                               (max 1 (or (nth 1 info) 1))
 761                               (or (nth 2 info) 0)
 762                               (nnimap-replace-in-string group " " "\\ ")))))))
 763     (gnus-message 5 "nnimap: Checking mailboxes...done")
 764     'groups))
 765
 766 (deffoo nnimap-request-update-info-internal (group info &optional server)
 767   (when (nnimap-possibly-change-group group server)
 768     (when info ;; xxx what does this mean? should we create a info?
 769       (with-current-buffer nnimap-server-buffer
 770         (gnus-message 5 "nnimap: Updating info for %s..."
 771                       (gnus-info-group info))
 772
 773         (when (nnimap-mark-permanent-p 'read)
 774           (let (seen unseen)
 775             ;; read info could contain articles marked unread by other
 776             ;; imap clients!  we correct this
 777             (setq seen (gnus-uncompress-range (gnus-info-read info))
 778                   unseen (imap-search "UNSEEN UNDELETED")
 779                   seen (gnus-set-difference seen unseen)
 780                   ;; seen might lack articles marked as read by other
 781                   ;; imap clients! we correct this
 782                   seen (append seen (imap-search "SEEN"))
 783                   ;; remove dupes
 784                   seen (sort seen '<)
 785                   seen (gnus-compress-sequence seen t)
 786                   ;; we can't return '(1) since this isn't a "list of ranges",
 787                   ;; and we can't return '((1)) since g-list-of-unread-articles
 788                   ;; is buggy so we return '((1 . 1)).
 789                   seen (if (and (integerp (car seen))
 790                                 (null (cdr seen)))
 791                            (list (cons (car seen) (car seen)))
 792                          seen))
 793             (gnus-info-set-read info seen)))
 794
 795         (mapc (lambda (pred)
 796                 (when (and (nnimap-mark-permanent-p (cdr pred))
 797                            (member (nnimap-mark-to-flag (cdr pred))
 798                                    (imap-mailbox-get 'flags)))
 799                   (gnus-info-set-marks
 800                    info
 801                    (nnimap-update-alist-soft
 802                     (cdr pred)
 803                     (gnus-compress-sequence
 804                      (imap-search (nnimap-mark-to-predicate (cdr pred))))
 805                     (gnus-info-marks info))
 806                    t)))
 807               gnus-article-mark-lists)
 808
 809         (gnus-message 5 "nnimap: Updating info for %s...done"
 810                       (gnus-info-group info))
 811
 812         info))))
 813
 814 (deffoo nnimap-request-type (group &optional article)
 815   (if (and nnimap-news-groups (string-match nnimap-news-groups group))
 816       'news
 817     'mail))
 818
 819 (deffoo nnimap-request-set-mark (group actions &optional server)
 820   (when (nnimap-possibly-change-group group server)
 821     (with-current-buffer nnimap-server-buffer
 822       (let (action)
 823         (gnus-message 7 "nnimap: Setting marks in %s..." group)
 824         (while (setq action (pop actions))
 825           (let ((range (nth 0 action))
 826                 (what  (nth 1 action))
 827                 (cmdmarks (nth 2 action))
 828                 marks)
 829             ;; cache flags are pointless on the server
 830             (setq cmdmarks (delq 'cache cmdmarks))
 831             ;; flag dormant articles as ticked
 832             (if (memq 'dormant cmdmarks)
 833                 (setq cmdmarks (cons 'tick cmdmarks)))
 834             ;; remove stuff we are forbidden to store
 835             (mapcar (lambda (mark)
 836                       (if (imap-message-flag-permanent-p
 837                            (nnimap-mark-to-flag mark))
 838                           (setq marks (cons mark marks))))
 839                     cmdmarks)
 840             (when (and range marks)
 841               (cond ((eq what 'del)
 842                      (imap-message-flags-del
 843                       (nnimap-range-to-string range)
 844                       (nnimap-mark-to-flag marks nil t)))
 845                     ((eq what 'add)
 846                      (imap-message-flags-add
 847                       (nnimap-range-to-string range)
 848                       (nnimap-mark-to-flag marks nil t)))
 849                     ((eq what 'set)
 850                      (imap-message-flags-set
 851                       (nnimap-range-to-string range)
 852                       (nnimap-mark-to-flag marks nil t)))))))
 853         (gnus-message 7 "nnimap: Setting marks in %s...done" group))))
 854   nil)
 855
 856 (defun nnimap-split-to-groups (rules)
 857   ;; tries to match all rules in nnimap-split-rule against content of
 858   ;; nntp-server-buffer, returns a list of groups that matched.
 859   (with-current-buffer nntp-server-buffer
 860     ;; Fold continuation lines.
 861     (goto-char (point-min))
 862     (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 863       (replace-match " " t t))
 864     (if (functionp rules)
 865         (funcall rules)
 866       (let (to-groups regrepp)
 867         (catch 'split-done
 868           (dolist (rule rules to-groups)
 869             (let ((group (car rule))
 870                   (regexp (cadr rule)))
 871               (goto-char (point-min))
 872               (when (and (if (stringp regexp)
 873                              (progn
 874                                (setq regrepp (string-match "\\\\[0-9&]" group))
 875                                (re-search-forward regexp nil t))
 876                            (funcall regexp group))
 877                          ;; Don't enter the article into the same group twice.
 878                          (not (assoc group to-groups)))
 879                 (push (if regrepp
 880                           (nnmail-expand-newtext group)
 881                         group)
 882                       to-groups)
 883                 (or nnimap-split-crosspost
 884                     (throw 'split-done to-groups))))))))))
 885
 886 (defun nnimap-split-find-rule (server inbox)
 887   nnimap-split-rule)
 888
 889 (defun nnimap-split-find-inbox (server)
 890   (if (listp nnimap-split-inbox)
 891       nnimap-split-inbox
 892     (list nnimap-split-inbox)))
 893
 894 (defun nnimap-split-articles (&optional group server)
 895   (when (nnimap-possibly-change-server server)
 896     (with-current-buffer nnimap-server-buffer
 897       (let (rule inbox removeorig (inboxes (nnimap-split-find-inbox server)))
 898         ;; iterate over inboxes
 899         (while (and (setq inbox (pop inboxes))
 900                     (nnimap-possibly-change-group inbox)) ;; SELECT
 901           ;; find split rule for this server / inbox
 902           (when (setq rule (nnimap-split-find-rule server inbox))
 903             ;; iterate over articles
 904             (dolist (article (imap-search "UNSEEN UNDELETED"))
 905               (when (nnimap-request-head article)
 906                 ;; copy article to right group(s)
 907                 (setq removeorig nil)
 908                 (dolist (to-group (nnimap-split-to-groups rule))
 909                   (if (imap-message-copy (number-to-string article)
 910                                          to-group nil 'nocopyuid)
 911                       (progn
 912                         (message "IMAP split moved %s:%s:%d to %s" server inbox
 913                                  article to-group)
 914                         (setq removeorig t)
 915                         ;; Add the group-art list to the history list.
 916                         (push (list (cons to-group 0)) nnmail-split-history))
 917                     (message "IMAP split failed to move %s:%s:%d to %s" server
 918                              inbox article to-group)))
 919                 ;; remove article if it was successfully copied somewhere
 920                 (and removeorig
 921                      (imap-message-flags-add (format "%d" article)
 922                                              "\\Seen \\Deleted")))))
 923           (when (imap-mailbox-select inbox) ;; just in case
 924             ;; todo: UID EXPUNGE (if available) to remove splitted articles
 925             (imap-mailbox-expunge)
 926             (imap-mailbox-close)))
 927         t))))
 928
 929 (deffoo nnimap-request-scan (&optional group server)
 930   (nnimap-split-articles group server))
 931
 932 (deffoo nnimap-request-newgroups (date &optional server)
 933   (when (nnimap-possibly-change-server server)
 934     (with-current-buffer nntp-server-buffer
 935       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s..."
 936                     (if (> (length server) 0) " on " "") server)
 937       (erase-buffer)
 938       (dolist (pattern (nnimap-pattern-to-list-arguments
 939                         nnimap-list-pattern))
 940         (dolist (mbx (imap-mailbox-lsub "*" (car pattern) nil
 941                                         nnimap-server-buffer))
 942           (or (member-if (lambda (mailbox)
 943                            (string= (downcase mailbox) "\\noselect"))
 944                          (imap-mailbox-get 'list-flags mbx
 945                                            nnimap-server-buffer))
 946               ;; Escape SPC in mailboxes xxx relies on gnus internals
 947               (let ((info (nnimap-find-minmax-uid mbx 'examine)))
 948                 (when info
 949                   (insert (format "%s %d %d y\n"
 950                                   (nnimap-replace-in-string mbx " " "\\ ")
 951                                   (or (nth 2 info) 0)
 952                                   (max 1 (or (nth 1 info) 1)))))))))
 953       (gnus-message 5 "nnimap: Listing subscribed mailboxes%s%s...done"
 954                     (if (> (length server) 0) " on " "") server))
 955     t))
 956
 957 (deffoo nnimap-request-create-group (group &optional server args)
 958   (when (nnimap-possibly-change-server server)
 959     (or (imap-mailbox-status group 'uidvalidity nnimap-server-buffer)
 960         (imap-mailbox-create group nnimap-server-buffer))))
 961
 962 (defun nnimap-time-substract (time1 time2)
 963   "Return TIME for TIME1 - TIME2."
 964   (let* ((ms (- (car time1) (car time2)))
 965          (ls (- (nth 1 time1) (nth 1 time2))))
 966     (if (< ls 0)
 967         (list (- ms 1) (+ (expt 2 16) ls))
 968       (list ms ls))))
 969
 970 (defun nnimap-date-days-ago (daysago)
 971   "Return date, in format \"3-Aug-1998\", for DAYSAGO days ago."
 972   (let ((date (format-time-string "%d-%b-%Y"
 973                                   (nnimap-time-substract
 974                                    (current-time)
 975                                    (days-to-time daysago)))))
 976     (if (eq ?0 (string-to-char date))
 977         (substring date 1)
 978       date)))
 979
 980 (defun nnimap-request-expire-articles-progress ()
 981   (gnus-message 5 "nnimap: Marking article %d for deletion..."
 982                 imap-current-message))
 983
 984 ;; Notice that we don't actually delete anything, we just mark them deleted.
 985 (deffoo nnimap-request-expire-articles (articles group &optional server force)
 986   (let ((artseq (gnus-compress-sequence articles)))
 987     (when (and artseq (nnimap-possibly-change-group group server))
 988       (with-current-buffer nnimap-server-buffer
 989         (if force
 990             (and (imap-message-flags-add
 991                   (nnimap-range-to-string artseq) "\\Deleted")
 992                  (setq articles nil))
 993           (let ((days (or (and nnmail-expiry-wait-function
 994                                (funcall nnmail-expiry-wait-function group))
 995                           nnmail-expiry-wait)))
 996             (cond ((eq days 'immediate)
 997                    (and (imap-message-flags-add
 998                          (nnimap-range-to-string artseq) "\\Deleted")
 999                         (setq articles nil)))
1000                   ((numberp days)
1001                    (let ((oldarts (imap-search
1002                                    (format "UID %s NOT SINCE %s"
1003                                            (nnimap-range-to-string artseq)
1004                                            (nnimap-date-days-ago days))))
1005                          (imap-fetch-data-hook
1006                           '(nnimap-request-expire-articles-progress)))
1007                      (and oldarts
1008                           (imap-message-flags-add
1009                            (nnimap-range-to-string
1010                             (gnus-compress-sequence oldarts))
1011                            "\\Deleted")
1012                           (setq articles (gnus-set-difference
1013                                           articles oldarts)))))))))))
1014   ;; return articles not deleted
1015   articles)
1016
1017 (deffoo nnimap-request-move-article (article group server
1018                                              accept-form &optional last)
1019   (when (nnimap-possibly-change-server server)
1020     (save-excursion
1021       (let ((buf (get-buffer-create " *nnimap move*"))
1022             (nnimap-current-move-article article)
1023             (nnimap-current-move-group group)
1024             (nnimap-current-move-server nnimap-current-server)
1025             result)
1026         (and (nnimap-request-article article group server)
1027              (save-excursion
1028                (set-buffer buf)
1029                (buffer-disable-undo (current-buffer))
1030                (insert-buffer-substring nntp-server-buffer)
1031                (setq result (eval accept-form))
1032                (kill-buffer buf)
1033                result)
1034              (nnimap-request-expire-articles (list article) group server t))
1035         result))))
1036
1037 (deffoo nnimap-request-accept-article (group &optional server last)
1038   (when (nnimap-possibly-change-server server)
1039     (let (uid)
1040       (if (setq uid
1041                 (if (string= nnimap-current-server nnimap-current-move-server)
1042                     ;; moving article within same server, speed it up...
1043                     (and (nnimap-possibly-change-group
1044                           nnimap-current-move-group)
1045                          (imap-message-copy (number-to-string
1046                                              nnimap-current-move-article)
1047                                             group 'dontcreate nil
1048                                             nnimap-server-buffer))
1049                   ;; turn into rfc822 format (\r\n eol's)
1050                   (with-current-buffer (current-buffer)
1051                     (goto-char (point-min))
1052                     (while (search-forward "\n" nil t)
1053                       (replace-match "\r\n")))
1054                   ;; next line for Cyrus server bug
1055                   (imap-mailbox-unselect nnimap-server-buffer)
1056                   (imap-message-append group (current-buffer) nil nil
1057                                        nnimap-server-buffer)))
1058           (cons group (nth 1 uid))
1059         (nnheader-report 'nnimap (imap-error-text nnimap-server-buffer))))))
1060
1061 (deffoo nnimap-request-delete-group (group force &optional server)
1062   (when (nnimap-possibly-change-server server)
1063     (with-current-buffer nnimap-server-buffer
1064       (if force
1065           (or (null (imap-mailbox-status group 'uidvalidity))
1066               (imap-mailbox-delete group))
1067         ;; UNSUBSCRIBE?
1068         t))))
1069
1070 (deffoo nnimap-request-rename-group (group new-name &optional server)
1071   (when (nnimap-possibly-change-server server)
1072     (imap-mailbox-rename group new-name nnimap-server-buffer)))
1073
1074 (defun nnimap-expunge (mailbox server)
1075   (when (nnimap-possibly-change-group mailbox server)
1076     (imap-mailbox-expunge nnimap-server-buffer)))
1077
1078 (defun nnimap-acl-get (mailbox server)
1079   (when (nnimap-possibly-change-server server)
1080     (imap-mailbox-acl-get mailbox nnimap-server-buffer)))
1081
1082 (defun nnimap-acl-edit (mailbox method old-acls new-acls)
1083   (when (nnimap-possibly-change-server (cadr method))
1084     (unless (imap-capability 'ACL nnimap-server-buffer)
1085       (error "Your server does not support ACL editing"))
1086     (with-current-buffer nnimap-server-buffer
1087       ;; delete all removed identifiers
1088       (mapcar (lambda (old-acl)
1089                 (unless (assoc (car old-acl) new-acls)
1090                     (or (imap-mailbox-acl-delete (car old-acl) mailbox)
1091                         (error "Can't delete ACL for %s" (car old-acl)))))
1092               old-acls)
1093       ;; set all changed acl's
1094       (mapcar (lambda (new-acl)
1095                 (let ((new-rights (cdr new-acl))
1096                       (old-rights (cdr (assoc (car new-acl) old-acls))))
1097                 (unless (and old-rights new-rights
1098                              (string= old-rights new-rights))
1099                   (or (imap-mailbox-acl-set (car new-acl) new-rights mailbox)
1100                       (error "Can't set ACL for %s to %s" (car new-acl)
1101                              new-rights)))))
1102               new-acls)
1103       t)))
1104
1105 \f
1106 ;;; Internal functions
1107
1108 ;;
1109 ;; This is confusing.
1110 ;;
1111 ;; mark      => read, tick, draft, reply etc
1112 ;; flag      => "\\Seen", "\\Flagged", "\\Draft", "gnus-expire" etc
1113 ;; predicate => "SEEN", "FLAGGED", "DRAFT", "KEYWORD gnus-expire" etc
1114 ;;
1115 ;; Mark should not really contain 'read since it's not a "mark" in the Gnus
1116 ;; world, but we cheat. Mark == gnus-article-mark-lists + '(read . read).
1117 ;;
1118
1119 (defconst nnimap-mark-to-predicate-alist
1120   (mapcar
1121    (lambda (pair) ; cdr is the mark
1122      (or (assoc (cdr pair)
1123                 '((read . "SEEN")
1124                   (tick . "FLAGGED")
1125                   (draft . "DRAFT")
1126                   (reply . "ANSWERED")))
1127          (cons (cdr pair)
1128                (format "KEYWORD gnus-%s" (symbol-name (cdr pair))))))
1129    (cons '(read . read) gnus-article-mark-lists)))
1130
1131 (defun nnimap-mark-to-predicate (pred)
1132   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP
1133 predicate (a string such as \"SEEN\", \"FLAGGED\", \"KEYWORD
1134 gnus-expire\") to be used within a IMAP SEARCH query."
1135   (cdr (assq pred nnimap-mark-to-predicate-alist)))
1136
1137 (defconst nnimap-mark-to-flag-alist
1138   (mapcar
1139    (lambda (pair)
1140      (or (assoc (cdr pair)
1141                 '((read . "\\Seen")
1142                   (tick . "\\Flagged")
1143                   (draft . "\\Draft")
1144                   (reply . "\\Answered")))
1145          (cons (cdr pair)
1146                (format "gnus-%s" (symbol-name (cdr pair))))))
1147    (cons '(read . read) gnus-article-mark-lists)))
1148
1149 (defun nnimap-mark-to-flag-1 (preds)
1150   (if (and (not (null preds)) (listp preds))
1151       (cons (nnimap-mark-to-flag (car preds))
1152             (nnimap-mark-to-flag (cdr preds)))
1153     (cdr (assoc preds nnimap-mark-to-flag-alist))))
1154
1155 (defun nnimap-mark-to-flag (preds &optional always-list make-string)
1156   "Convert a Gnus mark (a symbol such as read, tick, expire) to a IMAP
1157 flag (a string such as \"\\Seen\", \"\\Flagged\", \"gnus-expire\") to
1158 be used in a STORE FLAGS command."
1159   (let ((result (nnimap-mark-to-flag-1 preds)))
1160     (setq result (if (and (or make-string always-list)
1161                           (not (listp result)))
1162                      (list result)
1163                    result))
1164     (if make-string
1165         (mapconcat (lambda (flag)
1166                      (if (listp flag)
1167                          (mapconcat 'identity flag " ")
1168                        flag))
1169                    result " ")
1170       result)))
1171
1172 (defun nnimap-mark-permanent-p (mark &optional group)
1173   "Return t iff MARK can be permanently (between IMAP sessions) saved
1174 on articles, in GROUP."
1175   (imap-message-flag-permanent-p (nnimap-mark-to-flag mark)))
1176
1177 (defun nnimap-remassoc (key alist)
1178   "Delete by side effect any elements of LIST whose car is
1179 `equal' to KEY.  The modified LIST is returned.  If the first member
1180 of LIST has a car that is `equal' to KEY, there is no way to remove it
1181 by side effect; therefore, write `(setq foo (remassoc key foo))' to be
1182 sure of changing the value of `foo'."
1183   (when alist
1184     (if (equal key (caar alist))
1185         (cdr alist)
1186       (setcdr alist (nnimap-remassoc key (cdr alist)))
1187       alist)))
1188
1189 (defun nnimap-update-alist-soft (key value alist)
1190   (if value
1191       (cons (cons key value) (nnimap-remassoc key alist))
1192     (nnimap-remassoc key alist)))
1193
1194 (defun nnimap-range-to-string (range)
1195   (mapconcat
1196    (lambda (item)
1197      (if (consp item)
1198          (format "%d:%d"
1199                  (car item) (cdr item))
1200        (format "%d" item)))
1201    (if (and (listp range) (not (listp (cdr range))))
1202        (list range) ;; make (1 . 2) into ((1 . 2))
1203      range)
1204    ","))
1205
1206 (when nnimap-debug
1207   (require 'trace)
1208   (buffer-disable-undo (get-buffer-create nnimap-debug))
1209   (mapc (lambda (f) (trace-function-background f nnimap-debug))
1210         '(
1211 nnimap-replace-in-string
1212 nnimap-possibly-change-server
1213 nnimap-verify-uidvalidity
1214 nnimap-find-minmax-uid
1215 nnimap-possibly-change-group
1216 ;nnimap-replace-whitespace
1217 nnimap-retrieve-headers-progress
1218 nnimap-retrieve-which-headers
1219 nnimap-group-overview-filename
1220 nnimap-retrieve-headers-from-file
1221 nnimap-retrieve-headers-from-server
1222 nnimap-retrieve-headers
1223 nnimap-open-connection
1224 nnimap-open-server
1225 nnimap-server-opened
1226 nnimap-close-server
1227 nnimap-request-close
1228 nnimap-status-message
1229 ;nnimap-demule
1230 nnimap-request-article-part
1231 nnimap-request-article
1232 nnimap-request-head
1233 nnimap-request-body
1234 nnimap-request-group
1235 nnimap-close-group
1236 nnimap-pattern-to-list-arguments
1237 nnimap-request-list
1238 nnimap-request-post
1239 nnimap-retrieve-groups
1240 nnimap-request-update-info-internal
1241 nnimap-request-type
1242 nnimap-request-set-mark
1243 nnimap-split-to-groups
1244 nnimap-split-find-rule
1245 nnimap-split-find-inbox
1246 nnimap-split-articles
1247 nnimap-request-scan
1248 nnimap-request-newgroups
1249 nnimap-request-create-group
1250 nnimap-time-substract
1251 nnimap-date-days-ago
1252 nnimap-request-expire-articles-progress
1253 nnimap-request-expire-articles
1254 nnimap-request-move-article
1255 nnimap-request-accept-article
1256 nnimap-request-delete-group
1257 nnimap-request-rename-group
1258 gnus-group-nnimap-expunge
1259 gnus-group-nnimap-edit-acl
1260 gnus-group-nnimap-edit-acl-done
1261 nnimap-group-mode-hook
1262 nnimap-mark-to-predicate
1263 nnimap-mark-to-flag-1
1264 nnimap-mark-to-flag
1265 nnimap-mark-permanent-p
1266 nnimap-remassoc
1267 nnimap-update-alist-soft
1268 nnimap-range-to-string
1269           )))
1270
1271 (provide 'nnimap)
1272
1273 ;;; nnimap.el ends here