git.chise.org Git - elisp/gnus.git-/blob - lisp/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   4 ;;      Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;         Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;         MORIOKA Tomohiko <morioka@jaist.ac.jp>
   9 ;; Keywords: news, mail
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  31 ;; For an overview of what the interface functions do, please see the
  32 ;; Gnus sources.
  33
  34 ;;; Code:
  35
  36 (eval-when-compile (require 'cl))
  37 (eval-when-compile (require 'gnus-clfns))
  38
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'gnus-start)
  42 (require 'nnoo)
  43
  44 (nnoo-declare nnmh)
  45
  46 (defvoo nnmh-directory message-directory
  47   "Mail spool directory.")
  48
  49 (defvoo nnmh-get-new-mail t
  50   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  51
  52 (defvoo nnmh-prepare-save-mail-hook nil
  53   "Hook run narrowed to an article before saving.")
  54
  55 (defvoo nnmh-be-safe nil
  56   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  57 Go through the .nnmh-articles file and compare with the actual
  58 articles in this folder.  The articles that are \"new\" will be marked
  59 as unread by Gnus.")
  60
  61 \f
  62
  63 (defconst nnmh-version "nnmh 1.0"
  64   "nnmh version.")
  65
  66 (defvoo nnmh-current-directory nil
  67   "Current news group directory.")
  68
  69 (defvoo nnmh-status-string "")
  70 (defvoo nnmh-group-alist nil)
  71 ;; Don't even think about setting this variable.  It does not exist.
  72 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  73 ;; dynamically by certain functions in nndraft.
  74 (defvar nnmh-allow-delete-final nil)
  75
  76 \f
  77
  78 ;;; Interface functions.
  79
  80 (nnoo-define-basics nnmh)
  81
  82 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  83   (save-excursion
  84     (set-buffer nntp-server-buffer)
  85     (erase-buffer)
  86     (let* ((file nil)
  87            (number (length articles))
  88            (large (and (numberp nnmail-large-newsgroup)
  89                        (> number nnmail-large-newsgroup)))
  90            (count 0)
  91            (file-name-coding-system nnmail-pathname-coding-system)
  92            (pathname-coding-system nnmail-pathname-coding-system)
  93            beg article)
  94       (nnmh-possibly-change-directory newsgroup server)
  95       ;; We don't support fetching by Message-ID.
  96       (if (stringp (car articles))
  97           'headers
  98         (while articles
  99           (when (and (file-exists-p
 100                       (setq file (concat (file-name-as-directory
 101                                           nnmh-current-directory)
 102                                          (int-to-string
 103                                           (setq article (pop articles))))))
 104                      (not (file-directory-p file)))
 105             (insert (format "221 %d Article retrieved.\n" article))
 106             (setq beg (point))
 107             (nnheader-insert-head file)
 108             (goto-char beg)
 109             (if (search-forward "\n\n" nil t)
 110                 (forward-char -1)
 111               (goto-char (point-max))
 112               (insert "\n\n"))
 113             (insert ".\n")
 114             (delete-region (point) (point-max)))
 115           (setq count (1+ count))
 116
 117           (and large
 118                (zerop (% count 20))
 119                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 120                                  (/ (* count 100) number))))
 121
 122         (when large
 123           (nnheader-message 5 "nnmh: Receiving headers...done"))
 124
 125         ;; (nnheader-fold-continuation-lines)
 126         'headers))))
 127
 128 (deffoo nnmh-open-server (server &optional defs)
 129   (nnoo-change-server 'nnmh server defs)
 130   (when (not (file-exists-p nnmh-directory))
 131     (condition-case ()
 132         (make-directory nnmh-directory t)
 133       (error t)))
 134   (cond
 135    ((not (file-exists-p nnmh-directory))
 136     (nnmh-close-server)
 137     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 138    ((not (file-directory-p (file-truename nnmh-directory)))
 139     (nnmh-close-server)
 140     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 141    (t
 142     (nnheader-report 'nnmh "Opened server %s using directory %s"
 143                      server nnmh-directory)
 144     t)))
 145
 146 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 147   (nnmh-possibly-change-directory newsgroup server)
 148   (let ((file (if (stringp id)
 149                   nil
 150                 (concat nnmh-current-directory (int-to-string id))))
 151         (file-name-coding-system nnmail-pathname-coding-system)
 152         (pathname-coding-system nnmail-pathname-coding-system)
 153         (nntp-server-buffer (or buffer nntp-server-buffer)))
 154     (and (stringp file)
 155          (file-exists-p file)
 156          (not (file-directory-p file))
 157          (save-excursion (nnmail-find-file file))
 158          (string-to-int (file-name-nondirectory file)))))
 159
 160 (deffoo nnmh-request-group (group &optional server dont-check)
 161   (nnheader-init-server-buffer)
 162   (nnmh-possibly-change-directory group server)
 163   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 164         (file-name-coding-system nnmail-pathname-coding-system)
 165         (pathname-coding-system nnmail-pathname-coding-system)
 166         dir)
 167     (cond
 168      ((not (file-directory-p pathname))
 169       (nnheader-report
 170        'nnmh "Can't select group (no such directory): %s" group))
 171      (t
 172       (setq nnmh-current-directory pathname)
 173       (and nnmh-get-new-mail
 174            nnmh-be-safe
 175            (nnmh-update-gnus-unreads group))
 176       (cond
 177        (dont-check
 178         (nnheader-report 'nnmh "Selected group %s" group)
 179         t)
 180        (t
 181         ;; Re-scan the directory if it's on a foreign system.
 182         (nnheader-re-read-dir pathname)
 183         (setq dir
 184               (sort
 185                (mapcar (lambda (name) (string-to-int name))
 186                        (directory-files pathname nil "^[0-9]+$" t))
 187                '<))
 188         (cond
 189          (dir
 190           (setq nnmh-group-alist
 191                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 192           (push (list group (cons (car dir) (car (last dir))))
 193                 nnmh-group-alist)
 194           (nnheader-report 'nnmh "Selected group %s" group)
 195           (nnheader-insert
 196            "211 %d %d %d %s\n" (length dir) (car dir)
 197            (car (last dir)) group))
 198          (t
 199           (nnheader-report 'nnmh "Empty group %s" group)
 200           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 201
 202 (deffoo nnmh-request-scan (&optional group server)
 203   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 204
 205 (deffoo nnmh-request-list (&optional server dir)
 206   (nnheader-insert "")
 207   (nnmh-possibly-change-directory nil server)
 208   (let ((file-name-coding-system nnmail-pathname-coding-system)
 209         (pathname-coding-system nnmail-pathname-coding-system)
 210         (nnmh-toplev
 211          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 212     (nnmh-request-list-1 nnmh-toplev))
 213   (setq nnmh-group-alist (nnmail-get-active))
 214   t)
 215
 216 (defvar nnmh-toplev)
 217 (defun nnmh-request-list-1 (dir)
 218   (setq dir (expand-file-name dir))
 219   ;; Recurse down all directories.
 220   (let ((dirs (and (file-readable-p dir)
 221                    (> (nth 1 (file-attributes (file-chase-links dir))) 2)
 222                    (nnheader-directory-files dir t nil t)))
 223         rdir)
 224     ;; Recurse down directories.
 225     (while (setq rdir (pop dirs))
 226       (when (and (file-directory-p rdir)
 227                  (file-readable-p rdir)
 228                  (not (equal (file-truename rdir)
 229                              (file-truename dir))))
 230         (nnmh-request-list-1 rdir))))
 231   ;; For each directory, generate an active file line.
 232   (unless (string= (expand-file-name nnmh-toplev) dir)
 233     (let ((files (mapcar
 234                   (lambda (name) (string-to-int name))
 235                   (directory-files dir nil "^[0-9]+$" t))))
 236       (when files
 237         (save-excursion
 238           (set-buffer nntp-server-buffer)
 239           (goto-char (point-max))
 240           (insert
 241            (format
 242             "%s %d %d y\n"
 243             (progn
 244               (string-match
 245                (regexp-quote
 246                 (file-truename (file-name-as-directory
 247                                 (expand-file-name nnmh-toplev))))
 248                dir)
 249               (string-as-multibyte
 250                (encode-coding-string
 251                 (nnheader-replace-chars-in-string
 252                  (substring dir (match-end 0))
 253                  ?/ ?.)
 254                 nnmail-pathname-coding-system)))
 255             (apply 'max files)
 256             (apply 'min files)))))))
 257   t)
 258
 259 (deffoo nnmh-request-newgroups (date &optional server)
 260   (nnmh-request-list server))
 261
 262 (deffoo nnmh-request-expire-articles (articles newsgroup
 263                                                &optional server force)
 264   (nnmh-possibly-change-directory newsgroup server)
 265   (let* ((is-old t)
 266          article rest mod-time)
 267     (nnheader-init-server-buffer)
 268
 269     (while (and articles is-old)
 270       (setq article (concat nnmh-current-directory
 271                             (int-to-string (car articles))))
 272       (when (setq mod-time (nth 5 (file-attributes article)))
 273         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 274                  (setq is-old
 275                        (nnmail-expired-article-p newsgroup mod-time force)))
 276             (progn
 277               ;; Allow a special target group. -- jcn
 278               (unless (eq nnmail-expiry-target 'delete)
 279                 (with-temp-buffer
 280                   (nnmh-request-article (car articles)
 281                                         newsgroup server (current-buffer))
 282                   (nnmail-expiry-target-group
 283                    nnmail-expiry-target newsgroup)))
 284               (nnheader-message 5 "Deleting article %s in %s..."
 285                                 article newsgroup)
 286               (condition-case ()
 287                   (funcall nnmail-delete-file-function article)
 288                 (file-error
 289                  (nnheader-message 1 "Couldn't delete article %s in %s"
 290                                    article newsgroup)
 291                  (push (car articles) rest))))
 292           (push (car articles) rest)))
 293       (setq articles (cdr articles)))
 294     (nnheader-message 5 "")
 295     (nconc rest articles)))
 296
 297 (deffoo nnmh-close-group (group &optional server)
 298   t)
 299
 300 (deffoo nnmh-request-move-article
 301     (article group server accept-form &optional last)
 302   (let ((buf (get-buffer-create " *nnmh move*"))
 303         result)
 304     (and
 305      (nnmh-deletable-article-p group article)
 306      (nnmh-request-article article group server)
 307      (save-excursion
 308        (set-buffer buf)
 309        (erase-buffer)
 310        (insert-buffer-substring nntp-server-buffer)
 311        (setq result (eval accept-form))
 312        (kill-buffer (current-buffer))
 313        result)
 314      (progn
 315        (nnmh-possibly-change-directory group server)
 316        (condition-case ()
 317            (funcall nnmail-delete-file-function
 318                     (concat nnmh-current-directory (int-to-string article)))
 319          (file-error nil))))
 320     result))
 321
 322 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 323   (nnmh-possibly-change-directory group server)
 324   (if (and (not (equal group "queue"))
 325            (not (equal group "draft")))
 326       (nnmail-check-syntax))
 327   (when nnmail-cache-accepted-message-ids
 328     (nnmail-cache-insert (nnmail-fetch-field "message-id")))
 329   (nnheader-init-server-buffer)
 330   (prog1
 331       (if (stringp group)
 332           (if noinsert
 333               (nnmh-active-number group)
 334             (car (nnmh-save-mail
 335                   (list (cons group (nnmh-active-number group)))
 336                   noinsert)))
 337         (let ((res (nnmail-article-group 'nnmh-active-number)))
 338           (if (and (null res)
 339                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 340               'junk
 341             (car (nnmh-save-mail res noinsert)))))
 342     (when (and last nnmail-cache-accepted-message-ids)
 343       (nnmail-cache-close))))
 344
 345 (deffoo nnmh-request-replace-article (article group buffer)
 346   (nnmh-possibly-change-directory group)
 347   (save-excursion
 348     (set-buffer buffer)
 349     (nnmh-possibly-create-directory group)
 350     (ignore-errors
 351       (nnmail-write-region
 352        (point-min) (point-max)
 353        (concat nnmh-current-directory (int-to-string article))
 354        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 355       t)))
 356
 357 (deffoo nnmh-request-create-group (group &optional server args)
 358   (nnheader-init-server-buffer)
 359   (unless (assoc group nnmh-group-alist)
 360     (let (active)
 361       (push (list group (setq active (cons 1 0)))
 362             nnmh-group-alist)
 363       (nnmh-possibly-create-directory group)
 364       (nnmh-possibly-change-directory group server)
 365       (let ((articles (mapcar
 366                        (lambda (file)
 367                          (string-to-int file))
 368                        (directory-files
 369                         nnmh-current-directory nil "^[0-9]+$"))))
 370         (when articles
 371           (setcar active (apply 'min articles))
 372           (setcdr active (apply 'max articles))))))
 373   t)
 374
 375 (deffoo nnmh-request-delete-group (group &optional force server)
 376   (nnmh-possibly-change-directory group server)
 377   ;; Delete all articles in GROUP.
 378   (if (not force)
 379       ()                                ; Don't delete the articles.
 380     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 381       (while articles
 382         (when (file-writable-p (car articles))
 383           (nnheader-message 5 "Deleting article %s in %s..."
 384                             (car articles) group)
 385           (funcall nnmail-delete-file-function (car articles)))
 386         (setq articles (cdr articles))))
 387     ;; Try to delete the directory itself.
 388     (ignore-errors
 389       (delete-directory nnmh-current-directory)))
 390   ;; Remove the group from all structures.
 391   (setq nnmh-group-alist
 392         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 393         nnmh-current-directory nil)
 394   t)
 395
 396 (deffoo nnmh-request-rename-group (group new-name &optional server)
 397   (nnmh-possibly-change-directory group server)
 398   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 399         (old-dir (nnmail-group-pathname group nnmh-directory)))
 400     (when (ignore-errors
 401             (make-directory new-dir t)
 402             t)
 403       ;; We move the articles file by file instead of renaming
 404       ;; the directory -- there may be subgroups in this group.
 405       ;; One might be more clever, I guess.
 406       (let ((files (nnheader-article-to-file-alist old-dir)))
 407         (while files
 408           (rename-file
 409            (concat old-dir (cdar files))
 410            (concat new-dir (cdar files)))
 411           (pop files)))
 412       (when (<= (length (directory-files old-dir)) 2)
 413         (ignore-errors
 414           (delete-directory old-dir)))
 415       ;; That went ok, so we change the internal structures.
 416       (let ((entry (assoc group nnmh-group-alist)))
 417         (when entry
 418           (setcar entry new-name))
 419         (setq nnmh-current-directory nil)
 420         t))))
 421
 422 (nnoo-define-skeleton nnmh)
 423
 424 \f
 425 ;;; Internal functions.
 426
 427 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 428   (when (and server
 429              (not (nnmh-server-opened server)))
 430     (nnmh-open-server server))
 431   (when newsgroup
 432     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 433           (file-name-coding-system nnmail-pathname-coding-system)
 434           (pathname-coding-system nnmail-pathname-coding-system))
 435       (if (file-directory-p pathname)
 436           (setq nnmh-current-directory pathname)
 437         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 438
 439 (defun nnmh-possibly-create-directory (group)
 440   (let (dir dirs)
 441     (setq dir (nnmail-group-pathname group nnmh-directory))
 442     (while (not (file-directory-p dir))
 443       (push dir dirs)
 444       (setq dir (file-name-directory (directory-file-name dir))))
 445     (while dirs
 446       (when (make-directory (directory-file-name (car dirs)))
 447         (error "Could not create directory %s" (car dirs)))
 448       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 449       (setq dirs (cdr dirs)))))
 450
 451 (defun nnmh-save-mail (group-art &optional noinsert)
 452   "Called narrowed to an article."
 453   (unless noinsert
 454     (nnmail-insert-lines)
 455     (nnmail-insert-xref group-art))
 456   (run-hooks 'nnmail-prepare-save-mail-hook)
 457   (run-hooks 'nnmh-prepare-save-mail-hook)
 458   (goto-char (point-min))
 459   (while (looking-at "From ")
 460     (replace-match "X-From-Line: ")
 461     (forward-line 1))
 462   ;; We save the article in all the newsgroups it belongs in.
 463   (let ((ga group-art)
 464         first)
 465     (while ga
 466       (nnmh-possibly-create-directory (caar ga))
 467       (let ((file (concat (nnmail-group-pathname
 468                            (caar ga) nnmh-directory)
 469                           (int-to-string (cdar ga)))))
 470         (if first
 471             ;; It was already saved, so we just make a hard link.
 472             (funcall nnmail-crosspost-link-function first file t)
 473           ;; Save the article.
 474           (nnmail-write-region (point-min) (point-max) file nil nil)
 475           (setq first file)))
 476       (setq ga (cdr ga))))
 477   group-art)
 478
 479 (defun nnmh-active-number (group)
 480   "Compute the next article number in GROUP."
 481   (let ((active (cadr (assoc group nnmh-group-alist)))
 482         (dir (nnmail-group-pathname group nnmh-directory))
 483         (file-name-coding-system nnmail-pathname-coding-system)
 484         (pathname-coding-system nnmail-pathname-coding-system)
 485         file)
 486     (unless active
 487       ;; The group wasn't known to nnmh, so we just create an active
 488       ;; entry for it.
 489       (setq active (cons 1 0))
 490       (push (list group active) nnmh-group-alist)
 491       (unless (file-exists-p dir)
 492         (gnus-make-directory dir))
 493       ;; Find the highest number in the group.
 494       (let ((files (sort
 495                     (mapcar
 496                      (lambda (f)
 497                        (string-to-int f))
 498                      (directory-files dir nil "^[0-9]+$"))
 499                     '>)))
 500         (when files
 501           (setcdr active (car files)))))
 502     (setcdr active (1+ (cdr active)))
 503     (while (or
 504             ;; See whether the file exists...
 505             (file-exists-p
 506              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 507                                 (int-to-string (cdr active)))))
 508             ;; ... or there is a buffer that will make that file exist
 509             ;; in the future.
 510             (get-file-buffer file))
 511       ;; Skip past that file.
 512       (setcdr active (1+ (cdr active))))
 513     (cdr active)))
 514
 515 (defun nnmh-update-gnus-unreads (group)
 516   ;; Go through the .nnmh-articles file and compare with the actual
 517   ;; articles in this folder.  The articles that are "new" will be
 518   ;; marked as unread by Gnus.
 519   (let* ((dir nnmh-current-directory)
 520          (files (sort (mapcar (function (lambda (name) (string-to-int name)))
 521                               (directory-files nnmh-current-directory
 522                                                nil "^[0-9]+$" t))
 523                       '<))
 524          (nnmh-file (concat dir ".nnmh-articles"))
 525          new articles)
 526     ;; Load the .nnmh-articles file.
 527     (when (file-exists-p nnmh-file)
 528       (setq articles
 529             (let (nnmh-newsgroup-articles)
 530               (ignore-errors (load nnmh-file nil t t))
 531               nnmh-newsgroup-articles)))
 532     ;; Add all new articles to the `new' list.
 533     (let ((art files))
 534       (while art
 535         (unless (assq (car art) articles)
 536           (push (car art) new))
 537         (setq art (cdr art))))
 538     ;; Remove all deleted articles.
 539     (let ((art articles))
 540       (while art
 541         (unless (memq (caar art) files)
 542           (setq articles (delq (car art) articles)))
 543         (setq art (cdr art))))
 544     ;; Check whether the articles really are the ones that Gnus thinks
 545     ;; they are by looking at the time-stamps.
 546     (let ((arts articles)
 547           art)
 548       (while (setq art (pop arts))
 549         (when (not (equal
 550                     (nth 5 (file-attributes
 551                             (concat dir (int-to-string (car art)))))
 552                     (cdr art)))
 553           (setq articles (delq art articles))
 554           (push (car art) new))))
 555     ;; Go through all the new articles and add them, and their
 556     ;; time-stamps, to the list.
 557     (setq articles
 558           (nconc articles
 559                  (mapcar
 560                   (lambda (art)
 561                     (cons art
 562                           (nth 5 (file-attributes
 563                                   (concat dir (int-to-string art))))))
 564                   new)))
 565     ;; Make Gnus mark all new articles as unread.
 566     (when new
 567       (gnus-make-articles-unread
 568        (gnus-group-prefixed-name group (list 'nnmh ""))
 569        (setq new (sort new '<))))
 570     ;; Sort the article list with highest numbers first.
 571     (setq articles (sort articles (lambda (art1 art2)
 572                                     (> (car art1) (car art2)))))
 573     ;; Finally write this list back to the .nnmh-articles file.
 574     (with-temp-file nnmh-file
 575       (insert ";; Gnus article active file for " group "\n\n")
 576       (insert "(setq nnmh-newsgroup-articles '")
 577       (gnus-prin1 articles)
 578       (insert ")\n"))))
 579
 580 (defun nnmh-deletable-article-p (group article)
 581   "Say whether ARTICLE in GROUP can be deleted."
 582   (let ((path (concat nnmh-current-directory (int-to-string article))))
 583     ;; Writable.
 584     (and (file-writable-p path)
 585          (or
 586           ;; We can never delete the last article in the group.
 587           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 588                    article))
 589           ;; Well, we can.
 590           nnmh-allow-delete-final))))
 591
 592 (provide 'nnmh)
 593
 594 ;;; nnmh.el ends here