git.chise.org Git - elisp/gnus.git-/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org> (adding MARKS)
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  30 ;; For an overview of what the interface functions do, please see the
  31 ;; Gnus sources.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36 (eval-when-compile (require 'gnus-clfns))
  37
  38 (require 'gnus)
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'nnoo)
  42
  43 (eval-and-compile
  44   (autoload 'gnus-article-unpropagatable-p "gnus-sum"))
  45
  46 (nnoo-declare nnml)
  47
  48 (defvoo nnml-directory message-directory
  49   "Spool directory for the nnml mail backend.")
  50
  51 (defvoo nnml-active-file
  52     (expand-file-name "active" nnml-directory)
  53   "Mail active file.")
  54
  55 (defvoo nnml-newsgroups-file
  56     (expand-file-name "newsgroups" nnml-directory)
  57   "Mail newsgroups description file.")
  58
  59 (defvoo nnml-get-new-mail t
  60   "If non-nil, nnml will check the incoming mail file and split the mail.")
  61
  62 (defvoo nnml-nov-is-evil nil
  63   "If non-nil, Gnus will never generate and use nov databases for mail spools.
  64 Using nov databases will speed up header fetching considerably.
  65 This variable shouldn't be flipped much.  If you have, for some reason,
  66 set this to t, and want to set it to nil again, you should always run
  67 the `nnml-generate-nov-databases' command.  The function will go
  68 through all nnml directories and generate nov databases for them
  69 all.  This may very well take some time.")
  70
  71 (defvoo nnml-marks-is-evil nil
  72   "If non-nil, Gnus will never generate and use marks file for mail spools.
  73 Using marks files makes it possible to backup and restore mail groups
  74 separately from `.newsrc.eld'.  If you have, for some reason, set this
  75 to t, and want to set it to nil again, you should always remove the
  76 corresponding marks file (usually named `.marks' in the nnml group
  77 directory, but see `nnml-marks-file-name') for the group.  Then the
  78 marks file will be regenerated properly by Gnus.")
  79
  80 (defvoo nnml-prepare-save-mail-hook nil
  81   "Hook run narrowed to an article before saving.")
  82
  83 (defvoo nnml-inhibit-expiry nil
  84   "If non-nil, inhibit expiry.")
  85
  86 (defvoo nnml-use-compressed-files nil
  87   "If non-nil, allow using compressed message files.")
  88
  89 \f
  90
  91 (defconst nnml-version "nnml 1.0"
  92   "nnml version.")
  93
  94 (defvoo nnml-nov-file-name ".overview")
  95 (defvoo nnml-marks-file-name ".marks")
  96
  97 (defvoo nnml-current-directory nil)
  98 (defvoo nnml-current-group nil)
  99 (defvoo nnml-status-string "")
 100 (defvoo nnml-nov-buffer-alist nil)
 101 (defvoo nnml-group-alist nil)
 102 (defvoo nnml-active-timestamp nil)
 103 (defvoo nnml-article-file-alist nil)
 104
 105 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
 106
 107 (defvar nnml-nov-buffer-file-name nil)
 108
 109 (defvoo nnml-file-coding-system nnmail-file-coding-system)
 110
 111 (defvoo nnml-marks nil)
 112
 113 (defvar nnml-marks-modtime (gnus-make-hashtable))
 114
 115 \f
 116 ;;; Interface functions.
 117
 118 (nnoo-define-basics nnml)
 119
 120 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
 121   (when (nnml-possibly-change-directory group server)
 122     (save-excursion
 123       (set-buffer nntp-server-buffer)
 124       (erase-buffer)
 125       (let* ((file nil)
 126              (number (length sequence))
 127              (count 0)
 128              (file-name-coding-system nnmail-pathname-coding-system)
 129              (pathname-coding-system nnmail-pathname-coding-system)
 130              beg article)
 131         (if (stringp (car sequence))
 132             'headers
 133           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 134               'nov
 135             (while sequence
 136               (setq article (car sequence))
 137               (setq file (nnml-article-to-file article))
 138               (when (and file
 139                          (file-exists-p file)
 140                          (not (file-directory-p file)))
 141                 (insert (format "221 %d Article retrieved.\n" article))
 142                 (setq beg (point))
 143                 (nnheader-insert-head file)
 144                 (goto-char beg)
 145                 (if (re-search-forward "\n\r?\n" nil t)
 146                     (forward-char -1)
 147                   (goto-char (point-max))
 148                   (insert "\n\n"))
 149                 (insert ".\n")
 150                 (delete-region (point) (point-max)))
 151               (setq sequence (cdr sequence))
 152               (setq count (1+ count))
 153               (and (numberp nnmail-large-newsgroup)
 154                    (> number nnmail-large-newsgroup)
 155                    (zerop (% count 20))
 156                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 157                                      (/ (* count 100) number))))
 158
 159             (and (numberp nnmail-large-newsgroup)
 160                  (> number nnmail-large-newsgroup)
 161                  (nnheader-message 6 "nnml: Receiving headers...done"))
 162
 163             (nnheader-fold-continuation-lines)
 164             'headers))))))
 165
 166 (deffoo nnml-open-server (server &optional defs)
 167   (nnoo-change-server 'nnml server defs)
 168   (when (not (file-exists-p nnml-directory))
 169     (ignore-errors (make-directory nnml-directory t)))
 170   (cond
 171    ((not (file-exists-p nnml-directory))
 172     (nnml-close-server)
 173     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 174    ((not (file-directory-p (file-truename nnml-directory)))
 175     (nnml-close-server)
 176     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 177    (t
 178     (nnheader-report 'nnml "Opened server %s using directory %s"
 179                      server nnml-directory)
 180     t)))
 181
 182 (deffoo nnml-request-regenerate (server)
 183   (nnml-possibly-change-directory nil server)
 184   (nnml-generate-nov-databases server)
 185   t)
 186
 187 (deffoo nnml-request-article (id &optional group server buffer)
 188   (nnml-possibly-change-directory group server)
 189   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 190          (file-name-coding-system nnmail-pathname-coding-system)
 191          (pathname-coding-system nnmail-pathname-coding-system)
 192          path gpath group-num)
 193     (if (stringp id)
 194         (when (and (setq group-num (nnml-find-group-number id))
 195                    (cdr
 196                     (assq (cdr group-num)
 197                           (nnheader-article-to-file-alist
 198                            (setq gpath
 199                                  (nnmail-group-pathname
 200                                   (car group-num)
 201                                   nnml-directory))))))
 202           (setq path (concat gpath (int-to-string (cdr group-num)))))
 203       (setq path (nnml-article-to-file id)))
 204     (cond
 205      ((not path)
 206       (nnheader-report 'nnml "No such article: %s" id))
 207      ((not (file-exists-p path))
 208       (nnheader-report 'nnml "No such file: %s" path))
 209      ((file-directory-p path)
 210       (nnheader-report 'nnml "File is a directory: %s" path))
 211      ((not (save-excursion (let ((nnmail-file-coding-system
 212                                   nnml-file-coding-system))
 213                              (nnmail-find-file path))))
 214       (nnheader-report 'nnml "Couldn't read file: %s" path))
 215      (t
 216       (nnheader-report 'nnml "Article %s retrieved" id)
 217       ;; We return the article number.
 218       (cons (if group-num (car group-num) group)
 219             (string-to-int (file-name-nondirectory path)))))))
 220
 221 (deffoo nnml-request-group (group &optional server dont-check)
 222   (let ((file-name-coding-system nnmail-pathname-coding-system)
 223         (pathname-coding-system nnmail-pathname-coding-system))
 224     (cond
 225      ((not (nnml-possibly-change-directory group server))
 226       (nnheader-report 'nnml "Invalid group (no such directory)"))
 227      ((not (file-exists-p nnml-current-directory))
 228       (nnheader-report 'nnml "Directory %s does not exist"
 229                        nnml-current-directory))
 230      ((not (file-directory-p nnml-current-directory))
 231       (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 232      (dont-check
 233       (nnheader-report 'nnml "Group %s selected" group)
 234       t)
 235      (t
 236       (nnheader-re-read-dir nnml-current-directory)
 237       (nnmail-activate 'nnml)
 238       (let ((active (nth 1 (assoc group nnml-group-alist))))
 239         (if (not active)
 240             (nnheader-report 'nnml "No such group: %s" group)
 241           (nnheader-report 'nnml "Selected group %s" group)
 242           (nnheader-insert "211 %d %d %d %s\n"
 243                            (max (1+ (- (cdr active) (car active))) 0)
 244                            (car active) (cdr active) group)))))))
 245
 246 (deffoo nnml-request-scan (&optional group server)
 247   (setq nnml-article-file-alist nil)
 248   (nnml-possibly-change-directory group server)
 249   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 250
 251 (deffoo nnml-close-group (group &optional server)
 252   (setq nnml-article-file-alist nil)
 253   t)
 254
 255 (deffoo nnml-request-create-group (group &optional server args)
 256   (nnml-possibly-change-directory nil server)
 257   (nnmail-activate 'nnml)
 258   (cond
 259    ((assoc group nnml-group-alist)
 260     t)
 261    ((and (file-exists-p (nnmail-group-pathname group nnml-directory))
 262          (not (file-directory-p (nnmail-group-pathname group nnml-directory))))
 263     (nnheader-report 'nnml "%s is a file"
 264                      (nnmail-group-pathname group nnml-directory)))
 265    (t
 266     (let (active)
 267       (push (list group (setq active (cons 1 0)))
 268             nnml-group-alist)
 269       (nnml-possibly-create-directory group)
 270       (nnml-possibly-change-directory group server)
 271       (let ((articles (nnml-directory-articles nnml-current-directory)))
 272         (when articles
 273           (setcar active (apply 'min articles))
 274           (setcdr active (apply 'max articles))))
 275       (nnmail-save-active nnml-group-alist nnml-active-file)
 276       t))))
 277
 278 (deffoo nnml-request-list (&optional server)
 279   (save-excursion
 280     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 281           (file-name-coding-system nnmail-pathname-coding-system)
 282           (pathname-coding-system nnmail-pathname-coding-system))
 283       (nnmail-find-file nnml-active-file))
 284     (setq nnml-group-alist (nnmail-get-active))
 285     t))
 286
 287 (deffoo nnml-request-newgroups (date &optional server)
 288   (nnml-request-list server))
 289
 290 (deffoo nnml-request-list-newsgroups (&optional server)
 291   (save-excursion
 292     (nnmail-find-file nnml-newsgroups-file)))
 293
 294 (deffoo nnml-request-expire-articles (articles group &optional server force)
 295   (nnml-possibly-change-directory group server)
 296   (let ((active-articles
 297          (nnml-directory-articles nnml-current-directory))
 298         (is-old t)
 299         article rest mod-time number)
 300     (nnmail-activate 'nnml)
 301
 302     (setq active-articles (sort active-articles '<))
 303     ;; Articles not listed in active-articles are already gone,
 304     ;; so don't try to expire them.
 305     (setq articles (gnus-sorted-intersection articles active-articles))
 306
 307     (while (and articles is-old)
 308       (if (and (setq article (nnml-article-to-file
 309                               (setq number (pop articles))))
 310                (setq mod-time (nth 5 (file-attributes article)))
 311                (nnml-deletable-article-p group number)
 312                (setq is-old (nnmail-expired-article-p group mod-time force
 313                                                       nnml-inhibit-expiry)))
 314           (progn
 315             ;; Allow a special target group.
 316             (unless (eq nnmail-expiry-target 'delete)
 317               (with-temp-buffer
 318                 (nnml-request-article number group server (current-buffer))
 319                 (let (nnml-current-directory
 320                       nnml-current-group
 321                       nnml-article-file-alist)
 322                   (nnmail-expiry-target-group nnmail-expiry-target group)))
 323               ;; Maybe directory is changed during nnmail-expiry-target-group.
 324               (nnml-possibly-change-directory group server))
 325             (nnheader-message 5 "Deleting article %s in %s"
 326                               number group)
 327             (condition-case ()
 328                 (funcall nnmail-delete-file-function article)
 329               (file-error
 330                (push number rest)))
 331             (setq active-articles (delq number active-articles))
 332             (nnml-nov-delete-article group number))
 333         (push number rest)))
 334     (let ((active (nth 1 (assoc group nnml-group-alist))))
 335       (when active
 336         (setcar active (or (and active-articles
 337                                 (apply 'min active-articles))
 338                            (1+ (cdr active)))))
 339       (nnmail-save-active nnml-group-alist nnml-active-file))
 340     (nnml-save-nov)
 341     (nconc rest articles)))
 342
 343 (deffoo nnml-request-move-article
 344     (article group server accept-form &optional last)
 345   (let ((buf (get-buffer-create " *nnml move*"))
 346         result)
 347     (nnml-possibly-change-directory group server)
 348     (nnml-update-file-alist)
 349     (and
 350      (nnml-deletable-article-p group article)
 351      (nnml-request-article article group server)
 352      (let (nnml-current-directory
 353            nnml-current-group
 354            nnml-article-file-alist)
 355        (save-excursion
 356          (set-buffer buf)
 357          (insert-buffer-substring nntp-server-buffer)
 358          (setq result (eval accept-form))
 359          (kill-buffer (current-buffer))
 360          result))
 361      (progn
 362        (nnml-possibly-change-directory group server)
 363        (condition-case ()
 364            (funcall nnmail-delete-file-function
 365                     (nnml-article-to-file  article))
 366          (file-error nil))
 367        (nnml-nov-delete-article group article)
 368        (when last
 369          (nnml-save-nov)
 370          (nnmail-save-active nnml-group-alist nnml-active-file))))
 371     result))
 372
 373 (deffoo nnml-request-accept-article (group &optional server last)
 374   (nnml-possibly-change-directory group server)
 375   (nnmail-check-syntax)
 376   (let (result)
 377     (when nnmail-cache-accepted-message-ids
 378       (nnmail-cache-insert (nnmail-fetch-field "message-id") group))
 379     (if (stringp group)
 380         (and
 381          (nnmail-activate 'nnml)
 382          (setq result (car (nnml-save-mail
 383                             (list (cons group (nnml-active-number group))))))
 384          (progn
 385            (nnmail-save-active nnml-group-alist nnml-active-file)
 386            (and last (nnml-save-nov))))
 387       (and
 388        (nnmail-activate 'nnml)
 389        (if (and (not (setq result (nnmail-article-group 'nnml-active-number)))
 390                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 391            (setq result 'junk)
 392          (setq result (car (nnml-save-mail result))))
 393        (when last
 394          (nnmail-save-active nnml-group-alist nnml-active-file)
 395          (when nnmail-cache-accepted-message-ids
 396            (nnmail-cache-close))
 397          (nnml-save-nov))))
 398     result))
 399
 400 (deffoo nnml-request-post (&optional server)
 401   (nnmail-do-request-post 'nnml-request-accept-article server))
 402
 403 (deffoo nnml-request-replace-article (article group buffer)
 404   (nnml-possibly-change-directory group)
 405   (save-excursion
 406     (set-buffer buffer)
 407     (nnml-possibly-create-directory group)
 408     (let ((chars (nnmail-insert-lines))
 409           (art (concat (int-to-string article) "\t"))
 410           headers)
 411       (when (ignore-errors
 412               (nnmail-write-region
 413                (point-min) (point-max)
 414                (or (nnml-article-to-file article)
 415                    (expand-file-name (int-to-string article)
 416                                      nnml-current-directory))
 417                nil (if (nnheader-be-verbose 5) nil 'nomesg))
 418               t)
 419         (setq headers (nnml-parse-head chars article))
 420         ;; Replace the NOV line in the NOV file.
 421         (save-excursion
 422           (set-buffer (nnml-open-nov group))
 423           (goto-char (point-min))
 424           (if (or (looking-at art)
 425                   (search-forward (concat "\n" art) nil t))
 426               ;; Delete the old NOV line.
 427               (delete-region (progn (beginning-of-line) (point))
 428                              (progn (forward-line 1) (point)))
 429             ;; The line isn't here, so we have to find out where
 430             ;; we should insert it.  (This situation should never
 431             ;; occur, but one likes to make sure...)
 432             (while (and (looking-at "[0-9]+\t")
 433                         (< (string-to-int
 434                             (buffer-substring
 435                              (match-beginning 0) (match-end 0)))
 436                            article)
 437                         (zerop (forward-line 1)))))
 438           (beginning-of-line)
 439           (nnheader-insert-nov headers)
 440           (nnml-save-nov)
 441           t)))))
 442
 443 (deffoo nnml-request-delete-group (group &optional force server)
 444   (nnml-possibly-change-directory group server)
 445   (when force
 446     ;; Delete all articles in GROUP.
 447     (let ((articles
 448            (directory-files
 449             nnml-current-directory t
 450             (concat nnheader-numerical-short-files
 451                     "\\|" (regexp-quote nnml-nov-file-name) "$"
 452                     "\\|" (regexp-quote nnml-marks-file-name) "$")))
 453           article)
 454       (while articles
 455         (setq article (pop articles))
 456         (when (file-writable-p article)
 457           (nnheader-message 5 "Deleting article %s in %s..." article group)
 458           (funcall nnmail-delete-file-function article))))
 459     ;; Try to delete the directory itself.
 460     (ignore-errors (delete-directory nnml-current-directory)))
 461   ;; Remove the group from all structures.
 462   (setq nnml-group-alist
 463         (delq (assoc group nnml-group-alist) nnml-group-alist)
 464         nnml-current-group nil
 465         nnml-current-directory nil)
 466   ;; Save the active file.
 467   (nnmail-save-active nnml-group-alist nnml-active-file)
 468   t)
 469
 470 (deffoo nnml-request-rename-group (group new-name &optional server)
 471   (nnml-possibly-change-directory group server)
 472   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 473         (old-dir (nnmail-group-pathname group nnml-directory)))
 474     (when (ignore-errors
 475             (make-directory new-dir t)
 476             t)
 477       ;; We move the articles file by file instead of renaming
 478       ;; the directory -- there may be subgroups in this group.
 479       ;; One might be more clever, I guess.
 480       (let ((files (nnheader-article-to-file-alist old-dir)))
 481         (while files
 482           (rename-file
 483            (concat old-dir (cdar files))
 484            (concat new-dir (cdar files)))
 485           (pop files)))
 486       ;; Move .overview file.
 487       (let ((overview (concat old-dir nnml-nov-file-name)))
 488         (when (file-exists-p overview)
 489           (rename-file overview (concat new-dir nnml-nov-file-name))))
 490       ;; Move .marks file.
 491       (let ((marks (concat old-dir nnml-marks-file-name)))
 492         (when (file-exists-p marks)
 493           (rename-file marks (concat new-dir nnml-marks-file-name))))
 494       (when (<= (length (directory-files old-dir)) 2)
 495         (ignore-errors (delete-directory old-dir)))
 496       ;; That went ok, so we change the internal structures.
 497       (let ((entry (assoc group nnml-group-alist)))
 498         (when entry
 499           (setcar entry new-name))
 500         (setq nnml-current-directory nil
 501               nnml-current-group nil)
 502         ;; Save the new group alist.
 503         (nnmail-save-active nnml-group-alist nnml-active-file)
 504         t))))
 505
 506 (deffoo nnml-set-status (article name value &optional group server)
 507   (nnml-possibly-change-directory group server)
 508   (let ((file (nnml-article-to-file article)))
 509     (cond
 510      ((not (file-exists-p file))
 511       (nnheader-report 'nnml "File %s does not exist" file))
 512      (t
 513       (with-temp-file file
 514         (nnheader-insert-file-contents file)
 515         (nnmail-replace-status name value))
 516       t))))
 517
 518 \f
 519 ;;; Internal functions.
 520
 521 (defun nnml-article-to-file (article)
 522   (nnml-update-file-alist)
 523   (let (file)
 524     (if (setq file
 525               (if nnml-use-compressed-files
 526                   (cdr (assq article nnml-article-file-alist))
 527                 (number-to-string article)))
 528         (expand-file-name file nnml-current-directory)
 529       (when (not nnheader-directory-files-is-safe)
 530         ;; Just to make sure nothing went wrong when reading over NFS --
 531         ;; check once more.
 532         (when (file-exists-p
 533                (setq file (expand-file-name (number-to-string article)
 534                                             nnml-current-directory)))
 535           (nnml-update-file-alist t)
 536           file)))))
 537
 538 (defun nnml-deletable-article-p (group article)
 539   "Say whether ARTICLE in GROUP can be deleted."
 540   (let (path)
 541     (when (setq path (nnml-article-to-file article))
 542       (when (file-writable-p path)
 543         (or (not nnmail-keep-last-article)
 544             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 545                      article)))))))
 546
 547 ;; Find an article number in the current group given the Message-ID.
 548 (defun nnml-find-group-number (id)
 549   (save-excursion
 550     (set-buffer (get-buffer-create " *nnml id*"))
 551     (let ((alist nnml-group-alist)
 552           number)
 553       ;; We want to look through all .overview files, but we want to
 554       ;; start with the one in the current directory.  It seems most
 555       ;; likely that the article we are looking for is in that group.
 556       (if (setq number (nnml-find-id nnml-current-group id))
 557           (cons nnml-current-group number)
 558         ;; It wasn't there, so we look through the other groups as well.
 559         (while (and (not number)
 560                     alist)
 561           (or (string= (caar alist) nnml-current-group)
 562               (setq number (nnml-find-id (caar alist) id)))
 563           (or number
 564               (setq alist (cdr alist))))
 565         (and number
 566              (cons (caar alist) number))))))
 567
 568 (defun nnml-find-id (group id)
 569   (erase-buffer)
 570   (let ((nov (expand-file-name nnml-nov-file-name
 571                                (nnmail-group-pathname group nnml-directory)))
 572         number found)
 573     (when (file-exists-p nov)
 574       (nnheader-insert-file-contents nov)
 575       (while (and (not found)
 576                   (search-forward id nil t)) ; We find the ID.
 577         ;; And the id is in the fourth field.
 578         (if (not (and (search-backward "\t" nil t 4)
 579                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 580             (forward-line 1)
 581           (beginning-of-line)
 582           (setq found t)
 583           ;; We return the article number.
 584           (setq number
 585                 (ignore-errors (read (current-buffer))))))
 586       number)))
 587
 588 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 589   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 590       nil
 591     (let ((nov (expand-file-name nnml-nov-file-name nnml-current-directory)))
 592       (when (file-exists-p nov)
 593         (save-excursion
 594           (set-buffer nntp-server-buffer)
 595           (erase-buffer)
 596           (nnheader-insert-file-contents nov)
 597           (if (and fetch-old
 598                    (not (numberp fetch-old)))
 599               t                         ; Don't remove anything.
 600             (nnheader-nov-delete-outside-range
 601              (if fetch-old (max 1 (- (car articles) fetch-old))
 602                (car articles))
 603              (car (last articles)))
 604             t))))))
 605
 606 (defun nnml-possibly-change-directory (group &optional server)
 607   (when (and server
 608              (not (nnml-server-opened server)))
 609     (nnml-open-server server))
 610   (if (not group)
 611       t
 612     (let ((pathname (nnmail-group-pathname group nnml-directory))
 613           (file-name-coding-system nnmail-pathname-coding-system)
 614           (pathname-coding-system nnmail-pathname-coding-system))
 615       (when (not (equal pathname nnml-current-directory))
 616         (setq nnml-current-directory pathname
 617               nnml-current-group group
 618               nnml-article-file-alist nil))
 619       (file-exists-p nnml-current-directory))))
 620
 621 (defun nnml-possibly-create-directory (group)
 622   (let ((dir (nnmail-group-pathname group nnml-directory)))
 623     (unless (file-exists-p dir)
 624       (make-directory (directory-file-name dir) t)
 625       (nnheader-message 5 "Creating mail directory %s" dir))))
 626
 627 (defun nnml-save-mail (group-art)
 628   "Called narrowed to an article."
 629   (let (chars headers)
 630     (setq chars (nnmail-insert-lines))
 631     (nnmail-insert-xref group-art)
 632     (run-hooks 'nnmail-prepare-save-mail-hook)
 633     (run-hooks 'nnml-prepare-save-mail-hook)
 634     (goto-char (point-min))
 635     (while (looking-at "From ")
 636       (replace-match "X-From-Line: ")
 637       (forward-line 1))
 638     ;; We save the article in all the groups it belongs in.
 639     (let ((ga group-art)
 640           first)
 641       (while ga
 642         (nnml-possibly-create-directory (caar ga))
 643         (let ((file (concat (nnmail-group-pathname
 644                              (caar ga) nnml-directory)
 645                             (int-to-string (cdar ga)))))
 646           (if first
 647               ;; It was already saved, so we just make a hard link.
 648               (funcall nnmail-crosspost-link-function first file t)
 649             ;; Save the article.
 650             (nnmail-write-region (point-min) (point-max) file nil
 651                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 652             (setq first file)))
 653         (setq ga (cdr ga))))
 654     ;; Generate a nov line for this article.  We generate the nov
 655     ;; line after saving, because nov generation destroys the
 656     ;; header.
 657     (setq headers (nnml-parse-head chars))
 658     ;; Output the nov line to all nov databases that should have it.
 659     (let ((ga group-art))
 660       (while ga
 661         (nnml-add-nov (caar ga) (cdar ga) headers)
 662         (setq ga (cdr ga))))
 663     group-art))
 664
 665 (defun nnml-active-number (group)
 666   "Compute the next article number in GROUP."
 667   (let ((active (cadr (assoc group nnml-group-alist))))
 668     ;; The group wasn't known to nnml, so we just create an active
 669     ;; entry for it.
 670     (unless active
 671       ;; Perhaps the active file was corrupt?  See whether
 672       ;; there are any articles in this group.
 673       (nnml-possibly-create-directory group)
 674       (nnml-possibly-change-directory group)
 675       (unless nnml-article-file-alist
 676         (setq nnml-article-file-alist
 677               (sort
 678                (nnml-current-group-article-to-file-alist)
 679                'car-less-than-car)))
 680       (setq active
 681             (if nnml-article-file-alist
 682                 (cons (caar nnml-article-file-alist)
 683                       (caar (last nnml-article-file-alist)))
 684               (cons 1 0)))
 685       (push (list group active) nnml-group-alist))
 686     (setcdr active (1+ (cdr active)))
 687     (while (file-exists-p
 688             (expand-file-name (int-to-string (cdr active))
 689                               (nnmail-group-pathname group nnml-directory)))
 690       (setcdr active (1+ (cdr active))))
 691     (cdr active)))
 692
 693 (defun nnml-add-nov (group article headers)
 694   "Add a nov line for the GROUP base."
 695   (save-excursion
 696     (set-buffer (nnml-open-nov group))
 697     (goto-char (point-max))
 698     (mail-header-set-number headers article)
 699     (nnheader-insert-nov headers)))
 700
 701 (defsubst nnml-header-value ()
 702   (buffer-substring (match-end 0) (progn (end-of-line) (point))))
 703
 704 (defun nnml-parse-head (chars &optional number)
 705   "Parse the head of the current buffer."
 706   (save-excursion
 707     (save-restriction
 708       (unless (zerop (buffer-size))
 709         (narrow-to-region
 710          (goto-char (point-min))
 711          (if (re-search-forward "\n\r?\n" nil t) (1- (point)) (point-max))))
 712       ;; Fold continuation lines.
 713       (goto-char (point-min))
 714       (while (re-search-forward "\\(\r?\n[ \t]+\\)+" nil t)
 715         (replace-match " " t t))
 716       ;; Remove any tabs; they are too confusing.
 717       (subst-char-in-region (point-min) (point-max) ?\t ? )
 718       ;; Remove any ^M's; they are too confusing.
 719       (subst-char-in-region (point-min) (point-max) ?\r ? )
 720       (let ((headers (nnheader-parse-head t)))
 721         (mail-header-set-chars headers chars)
 722         (mail-header-set-number headers number)
 723         headers))))
 724
 725 (defun nnml-get-nov-buffer (group)
 726   (let ((buffer (get-buffer-create (format " *nnml overview %s*" group))))
 727     (save-excursion
 728       (set-buffer buffer)
 729       (set (make-local-variable 'nnml-nov-buffer-file-name)
 730            (expand-file-name
 731             nnml-nov-file-name
 732             (nnmail-group-pathname group nnml-directory)))
 733       (erase-buffer)
 734       (when (file-exists-p nnml-nov-buffer-file-name)
 735         (nnheader-insert-file-contents nnml-nov-buffer-file-name)))
 736     buffer))
 737
 738 (defun nnml-open-nov (group)
 739   (or (cdr (assoc group nnml-nov-buffer-alist))
 740       (let ((buffer (nnml-get-nov-buffer group)))
 741         (push (cons group buffer) nnml-nov-buffer-alist)
 742         buffer)))
 743
 744 (defun nnml-save-nov ()
 745   (save-excursion
 746     (while nnml-nov-buffer-alist
 747       (when (buffer-name (cdar nnml-nov-buffer-alist))
 748         (set-buffer (cdar nnml-nov-buffer-alist))
 749         (when (buffer-modified-p)
 750           (nnmail-write-region (point-min) (point-max)
 751                                nnml-nov-buffer-file-name nil 'nomesg))
 752         (set-buffer-modified-p nil)
 753         (kill-buffer (current-buffer)))
 754       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 755
 756 ;;;###autoload
 757 (defun nnml-generate-nov-databases (&optional server)
 758   "Generate NOV databases in all nnml directories."
 759   (interactive (list (or (nnoo-current-server 'nnml) "")))
 760   ;; Read the active file to make sure we don't re-use articles
 761   ;; numbers in empty groups.
 762   (nnmail-activate 'nnml)
 763   (unless (nnml-server-opened server)
 764     (nnml-open-server server))
 765   (setq nnml-directory (expand-file-name nnml-directory))
 766   ;; Recurse down the directories.
 767   (nnml-generate-nov-databases-1 nnml-directory nil t)
 768   ;; Save the active file.
 769   (nnmail-save-active nnml-group-alist nnml-active-file))
 770
 771 (defun nnml-generate-nov-databases-1 (dir &optional seen no-active)
 772   "Regenerate the NOV database in DIR."
 773   (interactive "DRegenerate NOV in: ")
 774   (setq dir (file-name-as-directory dir))
 775   ;; Only scan this sub-tree if we haven't been here yet.
 776   (unless (member (file-truename dir) seen)
 777     (push (file-truename dir) seen)
 778     ;; We descend recursively
 779     (let ((dirs (directory-files dir t nil t))
 780           dir)
 781       (while (setq dir (pop dirs))
 782         (when (and (not (string-match "^\\." (file-name-nondirectory dir)))
 783                    (file-directory-p dir))
 784           (nnml-generate-nov-databases-1 dir seen))))
 785     ;; Do this directory.
 786     (let ((files (sort (nnheader-article-to-file-alist dir)
 787                        'car-less-than-car)))
 788       (if (not files)
 789           (let* ((group (nnheader-file-to-group
 790                          (directory-file-name dir) nnml-directory))
 791                  (info (cadr (assoc group nnml-group-alist))))
 792             (when info
 793               (setcar info (1+ (cdr info)))))
 794         (funcall nnml-generate-active-function dir)
 795         ;; Generate the nov file.
 796         (nnml-generate-nov-file dir files)
 797         (unless no-active
 798           (nnmail-save-active nnml-group-alist nnml-active-file))))))
 799
 800 (eval-when-compile (defvar files))
 801 (defun nnml-generate-active-info (dir)
 802   ;; Update the active info for this group.
 803   (let* ((group (nnheader-file-to-group
 804                  (directory-file-name dir) nnml-directory))
 805          (entry (assoc group nnml-group-alist))
 806          (last (or (caadr entry) 0)))
 807     (setq nnml-group-alist (delq entry nnml-group-alist))
 808     (push (list group
 809                 (cons (or (caar files) (1+ last))
 810                       (max last
 811                            (or (let ((f files))
 812                                  (while (cdr f) (setq f (cdr f)))
 813                                  (caar f))
 814                                0))))
 815           nnml-group-alist)))
 816
 817 (defun nnml-generate-nov-file (dir files)
 818   (let* ((dir (file-name-as-directory dir))
 819          (nov (concat dir nnml-nov-file-name))
 820          (nov-buffer (get-buffer-create " *nov*"))
 821          chars file headers)
 822     (save-excursion
 823       ;; Init the nov buffer.
 824       (set-buffer nov-buffer)
 825       (buffer-disable-undo)
 826       (erase-buffer)
 827       (set-buffer nntp-server-buffer)
 828       ;; Delete the old NOV file.
 829       (when (file-exists-p nov)
 830         (funcall nnmail-delete-file-function nov))
 831       (while files
 832         (unless (file-directory-p (setq file (concat dir (cdar files))))
 833           (erase-buffer)
 834           (nnheader-insert-file-contents file)
 835           (narrow-to-region
 836            (goto-char (point-min))
 837            (progn
 838              (re-search-forward "\n\r?\n" nil t)
 839              (setq chars (- (point-max) (point)))
 840              (max (point-min) (1- (point)))))
 841           (unless (zerop (buffer-size))
 842             (goto-char (point-min))
 843             (setq headers (nnml-parse-head chars (caar files)))
 844             (save-excursion
 845               (set-buffer nov-buffer)
 846               (goto-char (point-max))
 847               (nnheader-insert-nov headers)))
 848           (widen))
 849         (setq files (cdr files)))
 850       (save-excursion
 851         (set-buffer nov-buffer)
 852         (nnmail-write-region (point-min) (point-max) nov nil 'nomesg)
 853         (kill-buffer (current-buffer))))))
 854
 855 (defun nnml-nov-delete-article (group article)
 856   (save-excursion
 857     (set-buffer (nnml-open-nov group))
 858     (when (nnheader-find-nov-line article)
 859       (delete-region (point) (progn (forward-line 1) (point)))
 860       (when (bobp)
 861         (let ((active (cadr (assoc group nnml-group-alist)))
 862               num)
 863           (when active
 864             (if (eobp)
 865                 (setf (car active) (1+ (cdr active)))
 866               (when (and (setq num (ignore-errors (read (current-buffer))))
 867                          (numberp num))
 868                 (setf (car active) num)))))))
 869     t))
 870
 871 (defun nnml-update-file-alist (&optional force)
 872   (when nnml-use-compressed-files
 873     (when (or (not nnml-article-file-alist)
 874               force)
 875       (setq nnml-article-file-alist
 876             (nnml-current-group-article-to-file-alist)))))
 877
 878 (defun nnml-directory-articles (dir)
 879   "Return a list of all article files in a directory.
 880 Use the nov database for that directory if available."
 881   (if (or gnus-nov-is-evil nnml-nov-is-evil
 882           (not (file-exists-p
 883                 (expand-file-name nnml-nov-file-name dir))))
 884       (nnheader-directory-articles dir)
 885     ;; build list from .overview if available
 886     ;; We would use nnml-open-nov, except that nnml-nov-buffer-alist is
 887     ;; defvoo'd, and we might get called when it hasn't been swapped in.
 888     (save-excursion
 889       (let ((list nil)
 890             art
 891             (buffer (nnml-get-nov-buffer nnml-current-group)))
 892         (set-buffer buffer)
 893         (goto-char (point-min))
 894         (while (not (eobp))
 895           (setq art (read (current-buffer)))
 896           (push art list)
 897           (forward-line 1))
 898         list))))
 899
 900 (defun nnml-current-group-article-to-file-alist ()
 901   "Return an alist of article/file pairs in the current group.
 902 Use the nov database for the current group if available."
 903   (if (or gnus-nov-is-evil
 904           nnml-nov-is-evil
 905           (not (file-exists-p
 906                 (expand-file-name nnml-nov-file-name
 907                                   nnml-current-directory))))
 908       (nnheader-article-to-file-alist nnml-current-directory)
 909     ;; build list from .overview if available
 910     (save-excursion
 911       (let ((alist nil)
 912             (buffer (nnml-get-nov-buffer nnml-current-group))
 913             art)
 914         (set-buffer buffer)
 915         (goto-char (point-min))
 916         (while (not (eobp))
 917           (setq art (read (current-buffer)))
 918           ;; assume file name is unadorned (ie. not compressed etc)
 919           (push (cons art (int-to-string art)) alist)
 920           (forward-line 1))
 921         alist))))
 922
 923 (deffoo nnml-request-set-mark (group actions &optional server)
 924   (nnml-possibly-change-directory group server)
 925   (unless nnml-marks-is-evil
 926     (nnml-open-marks group server)
 927     (dolist (action actions)
 928       (let ((range (nth 0 action))
 929             (what  (nth 1 action))
 930             (marks (nth 2 action)))
 931         (assert (or (eq what 'add) (eq what 'del)) t
 932                 "Unknown request-set-mark action: %s" what)
 933         (dolist (mark marks)
 934           (setq nnml-marks (gnus-update-alist-soft
 935                             mark
 936                             (funcall (if (eq what 'add) 'gnus-range-add
 937                                        'gnus-remove-from-range)
 938                                      (cdr (assoc mark nnml-marks)) range)
 939                             nnml-marks)))))
 940     (nnml-save-marks group server))
 941   nil)
 942
 943 (deffoo nnml-request-update-info (group info &optional server)
 944   (nnml-possibly-change-directory group server)
 945   (when (and (not nnml-marks-is-evil) (nnml-marks-changed-p group))
 946     (nnheader-message 8 "Updating marks for %s..." group)
 947     (nnml-open-marks group server)
 948     ;; Update info using `nnml-marks'.
 949     (mapcar (lambda (pred)
 950               (unless (memq (cdr pred) gnus-article-unpropagated-mark-lists)
 951                 (gnus-info-set-marks
 952                  info
 953                  (gnus-update-alist-soft
 954                   (cdr pred)
 955                   (cdr (assq (cdr pred) nnml-marks))
 956                   (gnus-info-marks info))
 957                  t)))
 958             gnus-article-mark-lists)
 959     (let ((seen (cdr (assq 'read nnml-marks))))
 960       (gnus-info-set-read info
 961                           (if (and (integerp (car seen))
 962                                    (null (cdr seen)))
 963                               (list (cons (car seen) (car seen)))
 964                             seen)))
 965     (nnheader-message 8 "Updating marks for %s...done" group))
 966   info)
 967
 968 (defun nnml-marks-changed-p (group)
 969   (let ((file (expand-file-name nnml-marks-file-name
 970                                 (nnmail-group-pathname group nnml-directory))))
 971     (if (null (gnus-gethash file nnml-marks-modtime))
 972         t ;; never looked at marks file, assume it has changed
 973       (not (equal (gnus-gethash file nnml-marks-modtime)
 974                   (nth 5 (file-attributes file)))))))
 975
 976 (defun nnml-save-marks (group server)
 977   (let ((file-name-coding-system nnmail-pathname-coding-system)
 978         (file (expand-file-name nnml-marks-file-name
 979                                 (nnmail-group-pathname group nnml-directory))))
 980     (condition-case err
 981         (progn
 982           (nnml-possibly-create-directory group)
 983           (with-temp-file file
 984             (erase-buffer)
 985             (gnus-prin1 nnml-marks)
 986             (insert "\n"))
 987           (gnus-sethash file
 988                         (nth 5 (file-attributes file))
 989                         nnml-marks-modtime))
 990       (error (or (gnus-yes-or-no-p
 991                   (format "Could not write to %s (%s).  Continue? " file err))
 992                  (error "Cannot write to %s (%s)" err))))))
 993
 994 (defun nnml-open-marks (group server)
 995   (let ((file (expand-file-name
 996                nnml-marks-file-name
 997                (nnmail-group-pathname group nnml-directory))))
 998     (if (file-exists-p file)
 999         (condition-case err
1000             (with-temp-buffer
1001               (gnus-sethash file (nth 5 (file-attributes file))
1002                             nnml-marks-modtime)
1003               (nnheader-insert-file-contents file)
1004               (setq nnml-marks (read (current-buffer)))
1005               (dolist (el gnus-article-unpropagated-mark-lists)
1006                 (setq nnml-marks (gnus-remassoc el nnml-marks))))
1007           (error (or (gnus-yes-or-no-p
1008                       (format "Error reading nnml marks file %s (%s).  Continuing will use marks from .newsrc.eld.  Continue? " file err))
1009                      (error "Cannot read nnml marks file %s (%s)" file err))))
1010       ;; User didn't have a .marks file.  Probably first time
1011       ;; user of the .marks stuff.  Bootstrap it from .newsrc.eld.
1012       (let ((info (gnus-get-info
1013                    (gnus-group-prefixed-name
1014                     group
1015                     (gnus-server-to-method (format "nnml:%s" server))))))
1016         (nnheader-message 7 "Bootstrapping marks for %s..." group)
1017         (setq nnml-marks (gnus-info-marks info))
1018         (push (cons 'read (gnus-info-read info)) nnml-marks)
1019         (dolist (el gnus-article-unpropagated-mark-lists)
1020           (setq nnml-marks (gnus-remassoc el nnml-marks)))
1021         (nnml-save-marks group server)
1022         (nnheader-message 7 "Bootstrapping marks for %s...done" group)))))
1023
1024 (provide 'nnml)
1025
1026 ;;; nnml.el ends here