git.chise.org Git - elisp/gnus.git-/blob - lisp/nnml.el

   1 ;;; nnml.el --- mail spool access for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org> (adding MARKS)
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  30 ;; For an overview of what the interface functions do, please see the
  31 ;; Gnus sources.
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36 (eval-when-compile (require 'gnus-clfns))
  37
  38 (require 'gnus)
  39 (require 'nnheader)
  40 (require 'nnmail)
  41 (require 'nnoo)
  42
  43 (eval-and-compile
  44   (autoload 'gnus-article-unpropagatable-p "gnus-sum"))
  45
  46 (nnoo-declare nnml)
  47
  48 (defvoo nnml-directory message-directory
  49   "Spool directory for the nnml mail backend.")
  50
  51 (defvoo nnml-active-file
  52     (expand-file-name "active" nnml-directory)
  53   "Mail active file.")
  54
  55 (defvoo nnml-newsgroups-file
  56     (expand-file-name "newsgroups" nnml-directory)
  57   "Mail newsgroups description file.")
  58
  59 (defvoo nnml-get-new-mail t
  60   "If non-nil, nnml will check the incoming mail file and split the mail.")
  61
  62 (defvoo nnml-nov-is-evil nil
  63   "If non-nil, Gnus will never generate and use nov databases for mail spools.
  64 Using nov databases will speed up header fetching considerably.
  65 This variable shouldn't be flipped much.  If you have, for some reason,
  66 set this to t, and want to set it to nil again, you should always run
  67 the `nnml-generate-nov-databases' command.  The function will go
  68 through all nnml directories and generate nov databases for them
  69 all.  This may very well take some time.")
  70
  71 (defvoo nnml-marks-is-evil nil
  72   "If non-nil, Gnus will never generate and use marks file for mail spools.
  73 Using marks files makes it possible to backup and restore mail groups
  74 separately from `.newsrc.eld'.  If you have, for some reason, set this
  75 to t, and want to set it to nil again, you should always remove the
  76 corresponding marks file (usually named `.marks' in the nnml group
  77 directory, but see `nnml-marks-file-name') for the group.  Then the
  78 marks file will be regenerated properly by Gnus.")
  79
  80 (defvoo nnml-prepare-save-mail-hook nil
  81   "Hook run narrowed to an article before saving.")
  82
  83 (defvoo nnml-inhibit-expiry nil
  84   "If non-nil, inhibit expiry.")
  85
  86 (defvoo nnml-use-compressed-files nil
  87   "If non-nil, allow using compressed message files.")
  88
  89 \f
  90
  91 (defconst nnml-version "nnml 1.0"
  92   "nnml version.")
  93
  94 (defvoo nnml-nov-file-name ".overview")
  95 (defvoo nnml-marks-file-name ".marks")
  96
  97 (defvoo nnml-current-directory nil)
  98 (defvoo nnml-current-group nil)
  99 (defvoo nnml-status-string "")
 100 (defvoo nnml-nov-buffer-alist nil)
 101 (defvoo nnml-group-alist nil)
 102 (defvoo nnml-active-timestamp nil)
 103 (defvoo nnml-article-file-alist nil)
 104
 105 (defvoo nnml-generate-active-function 'nnml-generate-active-info)
 106
 107 (defvar nnml-nov-buffer-file-name nil)
 108
 109 (defvoo nnml-file-coding-system nnmail-file-coding-system)
 110
 111 (defvoo nnml-marks nil)
 112
 113 (defvar nnml-marks-modtime (gnus-make-hashtable))
 114
 115 \f
 116 ;;; Interface functions.
 117
 118 (nnoo-define-basics nnml)
 119
 120 (deffoo nnml-retrieve-headers (sequence &optional group server fetch-old)
 121   (when (nnml-possibly-change-directory group server)
 122     (save-excursion
 123       (set-buffer nntp-server-buffer)
 124       (erase-buffer)
 125       (let* ((file nil)
 126              (number (length sequence))
 127              (count 0)
 128              (file-name-coding-system nnmail-pathname-coding-system)
 129              (pathname-coding-system nnmail-pathname-coding-system)
 130              beg article)
 131         (if (stringp (car sequence))
 132             'headers
 133           (if (nnml-retrieve-headers-with-nov sequence fetch-old)
 134               'nov
 135             (while sequence
 136               (setq article (car sequence))
 137               (setq file (nnml-article-to-file article))
 138               (when (and file
 139                          (file-exists-p file)
 140                          (not (file-directory-p file)))
 141                 (insert (format "221 %d Article retrieved.\n" article))
 142                 (setq beg (point))
 143                 (nnheader-insert-head file)
 144                 (goto-char beg)
 145                 (if (re-search-forward "\n\r?\n" nil t)
 146                     (forward-char -1)
 147                   (goto-char (point-max))
 148                   (insert "\n\n"))
 149                 (insert ".\n")
 150                 (delete-region (point) (point-max)))
 151               (setq sequence (cdr sequence))
 152               (setq count (1+ count))
 153               (and (numberp nnmail-large-newsgroup)
 154                    (> number nnmail-large-newsgroup)
 155                    (zerop (% count 20))
 156                    (nnheader-message 6 "nnml: Receiving headers... %d%%"
 157                                      (/ (* count 100) number))))
 158
 159             (and (numberp nnmail-large-newsgroup)
 160                  (> number nnmail-large-newsgroup)
 161                  (nnheader-message 6 "nnml: Receiving headers...done"))
 162
 163             (nnheader-fold-continuation-lines)
 164             'headers))))))
 165
 166 (deffoo nnml-open-server (server &optional defs)
 167   (nnoo-change-server 'nnml server defs)
 168   (when (not (file-exists-p nnml-directory))
 169     (ignore-errors (make-directory nnml-directory t)))
 170   (cond
 171    ((not (file-exists-p nnml-directory))
 172     (nnml-close-server)
 173     (nnheader-report 'nnml "Couldn't create directory: %s" nnml-directory))
 174    ((not (file-directory-p (file-truename nnml-directory)))
 175     (nnml-close-server)
 176     (nnheader-report 'nnml "Not a directory: %s" nnml-directory))
 177    (t
 178     (nnheader-report 'nnml "Opened server %s using directory %s"
 179                      server nnml-directory)
 180     t)))
 181
 182 (deffoo nnml-request-regenerate (server)
 183   (nnml-possibly-change-directory nil server)
 184   (nnml-generate-nov-databases server)
 185   t)
 186
 187 (deffoo nnml-request-article (id &optional group server buffer)
 188   (nnml-possibly-change-directory group server)
 189   (let* ((nntp-server-buffer (or buffer nntp-server-buffer))
 190          (file-name-coding-system nnmail-pathname-coding-system)
 191          (pathname-coding-system nnmail-pathname-coding-system)
 192          path gpath group-num)
 193     (if (stringp id)
 194         (when (and (setq group-num (nnml-find-group-number id))
 195                    (cdr
 196                     (assq (cdr group-num)
 197                           (nnheader-article-to-file-alist
 198                            (setq gpath
 199                                  (nnmail-group-pathname
 200                                   (car group-num)
 201                                   nnml-directory))))))
 202           (setq path (concat gpath (int-to-string (cdr group-num)))))
 203       (setq path (nnml-article-to-file id)))
 204     (cond
 205      ((not path)
 206       (nnheader-report 'nnml "No such article: %s" id))
 207      ((not (file-exists-p path))
 208       (nnheader-report 'nnml "No such file: %s" path))
 209      ((file-directory-p path)
 210       (nnheader-report 'nnml "File is a directory: %s" path))
 211      ((not (save-excursion (let ((nnmail-file-coding-system
 212                                   nnml-file-coding-system))
 213                              (nnmail-find-file path))))
 214       (nnheader-report 'nnml "Couldn't read file: %s" path))
 215      (t
 216       (nnheader-report 'nnml "Article %s retrieved" id)
 217       ;; We return the article number.
 218       (cons (if group-num (car group-num) group)
 219             (string-to-int (file-name-nondirectory path)))))))
 220
 221 (deffoo nnml-request-group (group &optional server dont-check)
 222   (let ((file-name-coding-system nnmail-pathname-coding-system)
 223         (pathname-coding-system nnmail-pathname-coding-system))
 224     (cond
 225      ((not (nnml-possibly-change-directory group server))
 226       (nnheader-report 'nnml "Invalid group (no such directory)"))
 227      ((not (file-exists-p nnml-current-directory))
 228       (nnheader-report 'nnml "Directory %s does not exist"
 229                        nnml-current-directory))
 230      ((not (file-directory-p nnml-current-directory))
 231       (nnheader-report 'nnml "%s is not a directory" nnml-current-directory))
 232      (dont-check
 233       (nnheader-report 'nnml "Group %s selected" group)
 234       t)
 235      (t
 236       (nnheader-re-read-dir nnml-current-directory)
 237       (nnmail-activate 'nnml)
 238       (let ((active (nth 1 (assoc group nnml-group-alist))))
 239         (if (not active)
 240             (nnheader-report 'nnml "No such group: %s" group)
 241           (nnheader-report 'nnml "Selected group %s" group)
 242           (nnheader-insert "211 %d %d %d %s\n"
 243                            (max (1+ (- (cdr active) (car active))) 0)
 244                            (car active) (cdr active) group)))))))
 245
 246 (deffoo nnml-request-scan (&optional group server)
 247   (setq nnml-article-file-alist nil)
 248   (nnml-possibly-change-directory group server)
 249   (nnmail-get-new-mail 'nnml 'nnml-save-nov nnml-directory group))
 250
 251 (deffoo nnml-close-group (group &optional server)
 252   (setq nnml-article-file-alist nil)
 253   t)
 254
 255 (deffoo nnml-request-create-group (group &optional server args)
 256   (nnml-possibly-change-directory nil server)
 257   (nnmail-activate 'nnml)
 258   (cond
 259    ((assoc group nnml-group-alist)
 260     t)
 261    ((and (file-exists-p (nnmail-group-pathname group nnml-directory))
 262          (not (file-directory-p (nnmail-group-pathname group nnml-directory))))
 263     (nnheader-report 'nnml "%s is a file"
 264                      (nnmail-group-pathname group nnml-directory)))
 265    (t
 266     (let (active)
 267       (push (list group (setq active (cons 1 0)))
 268             nnml-group-alist)
 269       (nnml-possibly-create-directory group)
 270       (nnml-possibly-change-directory group server)
 271       (let ((articles (nnml-directory-articles nnml-current-directory)))
 272         (when articles
 273           (setcar active (apply 'min articles))
 274           (setcdr active (apply 'max articles))))
 275       (nnmail-save-active nnml-group-alist nnml-active-file)
 276       t))))
 277
 278 (deffoo nnml-request-list (&optional server)
 279   (save-excursion
 280     (let ((nnmail-file-coding-system nnmail-active-file-coding-system)
 281           (file-name-coding-system nnmail-pathname-coding-system)
 282           (pathname-coding-system nnmail-pathname-coding-system))
 283       (nnmail-find-file nnml-active-file))
 284     (setq nnml-group-alist (nnmail-get-active))
 285     t))
 286
 287 (deffoo nnml-request-newgroups (date &optional server)
 288   (nnml-request-list server))
 289
 290 (deffoo nnml-request-list-newsgroups (&optional server)
 291   (save-excursion
 292     (nnmail-find-file nnml-newsgroups-file)))
 293
 294 (deffoo nnml-request-expire-articles (articles group &optional server force)
 295   (nnml-possibly-change-directory group server)
 296   (let ((active-articles
 297          (nnml-directory-articles nnml-current-directory))
 298         (is-old t)
 299         article rest mod-time number)
 300     (nnmail-activate 'nnml)
 301
 302     (setq active-articles (sort active-articles '<))
 303     ;; Articles not listed in active-articles are already gone,
 304     ;; so don't try to expire them.
 305     (setq articles (gnus-sorted-intersection articles active-articles))
 306
 307     (while (and articles is-old)
 308       (if (and (setq article (nnml-article-to-file
 309                               (setq number (pop articles))))
 310                (setq mod-time (nth 5 (file-attributes article)))
 311                (nnml-deletable-article-p group number)
 312                (setq is-old (nnmail-expired-article-p group mod-time force
 313                                                       nnml-inhibit-expiry)))
 314           (progn
 315             ;; Allow a special target group.
 316             (unless (eq nnmail-expiry-target 'delete)
 317               (with-temp-buffer
 318                 (nnml-request-article number group server (current-buffer))
 319                 (let (nnml-current-directory
 320                       nnml-current-group
 321                       nnml-article-file-alist)
 322                   (nnmail-expiry-target-group nnmail-expiry-target group)))
 323               ;; Maybe directory is changed during nnmail-expiry-target-group.
 324               (nnml-possibly-change-directory group server))
 325             (nnheader-message 5 "Deleting article %s in %s"
 326                               number group)
 327             (condition-case ()
 328                 (funcall nnmail-delete-file-function article)
 329               (file-error
 330                (push number rest)))
 331             (setq active-articles (delq number active-articles))
 332             (nnml-nov-delete-article group number))
 333         (push number rest)))
 334     (let ((active (nth 1 (assoc group nnml-group-alist))))
 335       (when active
 336         (setcar active (or (and active-articles
 337                                 (apply 'min active-articles))
 338                            (1+ (cdr active)))))
 339       (nnmail-save-active nnml-group-alist nnml-active-file))
 340     (nnml-save-nov)
 341     (nconc rest articles)))
 342
 343 (deffoo nnml-request-move-article
 344     (article group server accept-form &optional last)
 345   (let ((buf (get-buffer-create " *nnml move*"))
 346         result)
 347     (nnml-possibly-change-directory group server)
 348     (nnml-update-file-alist)
 349     (and
 350      (nnml-deletable-article-p group article)
 351      (nnml-request-article article group server)
 352      (let (nnml-current-directory
 353            nnml-current-group
 354            nnml-article-file-alist)
 355        (save-excursion
 356          (set-buffer buf)
 357          (insert-buffer-substring nntp-server-buffer)
 358          (setq result (eval accept-form))
 359          (kill-buffer (current-buffer))
 360          result))
 361      (progn
 362        (nnml-possibly-change-directory group server)
 363        (condition-case ()
 364            (funcall nnmail-delete-file-function
 365                     (nnml-article-to-file  article))
 366          (file-error nil))
 367        (nnml-nov-delete-article group article)
 368        (when last
 369          (nnml-save-nov)
 370          (nnmail-save-active nnml-group-alist nnml-active-file))))
 371     result))
 372
 373 (deffoo nnml-request-accept-article (group &optional server last)
 374   (nnml-possibly-change-directory group server)
 375   (nnmail-check-syntax)
 376   (let (result)
 377     (when nnmail-cache-accepted-message-ids
 378       (nnmail-cache-insert (nnmail-fetch-field "message-id") group))
 379     (if (stringp group)
 380         (and
 381          (nnmail-activate 'nnml)
 382          (setq result (car (nnml-save-mail
 383                             (list (cons group (nnml-active-number group))))))
 384          (progn
 385            (nnmail-save-active nnml-group-alist nnml-active-file)
 386            (and last (nnml-save-nov))))
 387       (and
 388        (nnmail-activate 'nnml)
 389        (if (and (not (setq result (nnmail-article-group 'nnml-active-number)))
 390                 (yes-or-no-p "Moved to `junk' group; delete article? "))
 391            (setq result 'junk)
 392          (setq result (car (nnml-save-mail result))))
 393        (when last
 394          (nnmail-save-active nnml-group-alist nnml-active-file)
 395          (when nnmail-cache-accepted-message-ids
 396            (nnmail-cache-close))
 397          (nnml-save-nov))))
 398     result))
 399
 400 (deffoo nnml-request-post (&optional server)
 401   (nnmail-do-request-post 'nnml-request-accept-article server))
 402
 403 (deffoo nnml-request-replace-article (article group buffer)
 404   (nnml-possibly-change-directory group)
 405   (save-excursion
 406     (set-buffer buffer)
 407     (nnml-possibly-create-directory group)
 408     (let ((chars (nnmail-insert-lines))
 409           (art (concat (int-to-string article) "\t"))
 410           headers)
 411       (when (ignore-errors
 412               (nnmail-write-region
 413                (point-min) (point-max)
 414                (or (nnml-article-to-file article)
 415                    (expand-file-name (int-to-string article)
 416                                      nnml-current-directory))
 417                nil (if (nnheader-be-verbose 5) nil 'nomesg))
 418               t)
 419         (setq headers (nnml-parse-head chars article))
 420         ;; Replace the NOV line in the NOV file.
 421         (save-excursion
 422           (set-buffer (nnml-open-nov group))
 423           (goto-char (point-min))
 424           (if (or (looking-at art)
 425                   (search-forward (concat "\n" art) nil t))
 426               ;; Delete the old NOV line.
 427               (gnus-delete-line)
 428             ;; The line isn't here, so we have to find out where
 429             ;; we should insert it.  (This situation should never
 430             ;; occur, but one likes to make sure...)
 431             (while (and (looking-at "[0-9]+\t")
 432                         (< (string-to-int
 433                             (buffer-substring
 434                              (match-beginning 0) (match-end 0)))
 435                            article)
 436                         (zerop (forward-line 1)))))
 437           (beginning-of-line)
 438           (nnheader-insert-nov headers)
 439           (nnml-save-nov)
 440           t)))))
 441
 442 (deffoo nnml-request-delete-group (group &optional force server)
 443   (nnml-possibly-change-directory group server)
 444   (when force
 445     ;; Delete all articles in GROUP.
 446     (let ((articles
 447            (directory-files
 448             nnml-current-directory t
 449             (concat nnheader-numerical-short-files
 450                     "\\|" (regexp-quote nnml-nov-file-name) "$"
 451                     "\\|" (regexp-quote nnml-marks-file-name) "$")))
 452           article)
 453       (while articles
 454         (setq article (pop articles))
 455         (when (file-writable-p article)
 456           (nnheader-message 5 "Deleting article %s in %s..." article group)
 457           (funcall nnmail-delete-file-function article))))
 458     ;; Try to delete the directory itself.
 459     (ignore-errors (delete-directory nnml-current-directory)))
 460   ;; Remove the group from all structures.
 461   (setq nnml-group-alist
 462         (delq (assoc group nnml-group-alist) nnml-group-alist)
 463         nnml-current-group nil
 464         nnml-current-directory nil)
 465   ;; Save the active file.
 466   (nnmail-save-active nnml-group-alist nnml-active-file)
 467   t)
 468
 469 (deffoo nnml-request-rename-group (group new-name &optional server)
 470   (nnml-possibly-change-directory group server)
 471   (let ((new-dir (nnmail-group-pathname new-name nnml-directory))
 472         (old-dir (nnmail-group-pathname group nnml-directory)))
 473     (when (ignore-errors
 474             (make-directory new-dir t)
 475             t)
 476       ;; We move the articles file by file instead of renaming
 477       ;; the directory -- there may be subgroups in this group.
 478       ;; One might be more clever, I guess.
 479       (let ((files (nnheader-article-to-file-alist old-dir)))
 480         (while files
 481           (rename-file
 482            (concat old-dir (cdar files))
 483            (concat new-dir (cdar files)))
 484           (pop files)))
 485       ;; Move .overview file.
 486       (let ((overview (concat old-dir nnml-nov-file-name)))
 487         (when (file-exists-p overview)
 488           (rename-file overview (concat new-dir nnml-nov-file-name))))
 489       ;; Move .marks file.
 490       (let ((marks (concat old-dir nnml-marks-file-name)))
 491         (when (file-exists-p marks)
 492           (rename-file marks (concat new-dir nnml-marks-file-name))))
 493       (when (<= (length (directory-files old-dir)) 2)
 494         (ignore-errors (delete-directory old-dir)))
 495       ;; That went ok, so we change the internal structures.
 496       (let ((entry (assoc group nnml-group-alist)))
 497         (when entry
 498           (setcar entry new-name))
 499         (setq nnml-current-directory nil
 500               nnml-current-group nil)
 501         ;; Save the new group alist.
 502         (nnmail-save-active nnml-group-alist nnml-active-file)
 503         t))))
 504
 505 (deffoo nnml-set-status (article name value &optional group server)
 506   (nnml-possibly-change-directory group server)
 507   (let ((file (nnml-article-to-file article)))
 508     (cond
 509      ((not (file-exists-p file))
 510       (nnheader-report 'nnml "File %s does not exist" file))
 511      (t
 512       (with-temp-file file
 513         (nnheader-insert-file-contents file)
 514         (nnmail-replace-status name value))
 515       t))))
 516
 517 \f
 518 ;;; Internal functions.
 519
 520 (defun nnml-article-to-file (article)
 521   (nnml-update-file-alist)
 522   (let (file)
 523     (if (setq file
 524               (if nnml-use-compressed-files
 525                   (cdr (assq article nnml-article-file-alist))
 526                 (number-to-string article)))
 527         (expand-file-name file nnml-current-directory)
 528       (when (not nnheader-directory-files-is-safe)
 529         ;; Just to make sure nothing went wrong when reading over NFS --
 530         ;; check once more.
 531         (when (file-exists-p
 532                (setq file (expand-file-name (number-to-string article)
 533                                             nnml-current-directory)))
 534           (nnml-update-file-alist t)
 535           file)))))
 536
 537 (defun nnml-deletable-article-p (group article)
 538   "Say whether ARTICLE in GROUP can be deleted."
 539   (let (path)
 540     (when (setq path (nnml-article-to-file article))
 541       (when (file-writable-p path)
 542         (or (not nnmail-keep-last-article)
 543             (not (eq (cdr (nth 1 (assoc group nnml-group-alist)))
 544                      article)))))))
 545
 546 ;; Find an article number in the current group given the Message-ID.
 547 (defun nnml-find-group-number (id)
 548   (save-excursion
 549     (set-buffer (get-buffer-create " *nnml id*"))
 550     (let ((alist nnml-group-alist)
 551           number)
 552       ;; We want to look through all .overview files, but we want to
 553       ;; start with the one in the current directory.  It seems most
 554       ;; likely that the article we are looking for is in that group.
 555       (if (setq number (nnml-find-id nnml-current-group id))
 556           (cons nnml-current-group number)
 557         ;; It wasn't there, so we look through the other groups as well.
 558         (while (and (not number)
 559                     alist)
 560           (or (string= (caar alist) nnml-current-group)
 561               (setq number (nnml-find-id (caar alist) id)))
 562           (or number
 563               (setq alist (cdr alist))))
 564         (and number
 565              (cons (caar alist) number))))))
 566
 567 (defun nnml-find-id (group id)
 568   (erase-buffer)
 569   (let ((nov (expand-file-name nnml-nov-file-name
 570                                (nnmail-group-pathname group nnml-directory)))
 571         number found)
 572     (when (file-exists-p nov)
 573       (nnheader-insert-file-contents nov)
 574       (while (and (not found)
 575                   (search-forward id nil t)) ; We find the ID.
 576         ;; And the id is in the fourth field.
 577         (if (not (and (search-backward "\t" nil t 4)
 578                       (not (search-backward"\t" (gnus-point-at-bol) t))))
 579             (forward-line 1)
 580           (beginning-of-line)
 581           (setq found t)
 582           ;; We return the article number.
 583           (setq number
 584                 (ignore-errors (read (current-buffer))))))
 585       number)))
 586
 587 (defun nnml-retrieve-headers-with-nov (articles &optional fetch-old)
 588   (if (or gnus-nov-is-evil nnml-nov-is-evil)
 589       nil
 590     (let ((nov (expand-file-name nnml-nov-file-name nnml-current-directory)))
 591       (when (file-exists-p nov)
 592         (save-excursion
 593           (set-buffer nntp-server-buffer)
 594           (erase-buffer)
 595           (nnheader-insert-file-contents nov)
 596           (if (and fetch-old
 597                    (not (numberp fetch-old)))
 598               t                         ; Don't remove anything.
 599             (nnheader-nov-delete-outside-range
 600              (if fetch-old (max 1 (- (car articles) fetch-old))
 601                (car articles))
 602              (car (last articles)))
 603             t))))))
 604
 605 (defun nnml-possibly-change-directory (group &optional server)
 606   (when (and server
 607              (not (nnml-server-opened server)))
 608     (nnml-open-server server))
 609   (if (not group)
 610       t
 611     (let ((pathname (nnmail-group-pathname group nnml-directory))
 612           (file-name-coding-system nnmail-pathname-coding-system)
 613           (pathname-coding-system nnmail-pathname-coding-system))
 614       (when (not (equal pathname nnml-current-directory))
 615         (setq nnml-current-directory pathname
 616               nnml-current-group group
 617               nnml-article-file-alist nil))
 618       (file-exists-p nnml-current-directory))))
 619
 620 (defun nnml-possibly-create-directory (group)
 621   (let ((dir (nnmail-group-pathname group nnml-directory)))
 622     (unless (file-exists-p dir)
 623       (make-directory (directory-file-name dir) t)
 624       (nnheader-message 5 "Creating mail directory %s" dir))))
 625
 626 (defun nnml-save-mail (group-art)
 627   "Called narrowed to an article."
 628   (let (chars headers)
 629     (setq chars (nnmail-insert-lines))
 630     (nnmail-insert-xref group-art)
 631     (run-hooks 'nnmail-prepare-save-mail-hook)
 632     (run-hooks 'nnml-prepare-save-mail-hook)
 633     (goto-char (point-min))
 634     (while (looking-at "From ")
 635       (replace-match "X-From-Line: ")
 636       (forward-line 1))
 637     ;; We save the article in all the groups it belongs in.
 638     (let ((ga group-art)
 639           first)
 640       (while ga
 641         (nnml-possibly-create-directory (caar ga))
 642         (let ((file (concat (nnmail-group-pathname
 643                              (caar ga) nnml-directory)
 644                             (int-to-string (cdar ga)))))
 645           (if first
 646               ;; It was already saved, so we just make a hard link.
 647               (funcall nnmail-crosspost-link-function first file t)
 648             ;; Save the article.
 649             (nnmail-write-region (point-min) (point-max) file nil
 650                                  (if (nnheader-be-verbose 5) nil 'nomesg))
 651             (setq first file)))
 652         (setq ga (cdr ga))))
 653     ;; Generate a nov line for this article.  We generate the nov
 654     ;; line after saving, because nov generation destroys the
 655     ;; header.
 656     (setq headers (nnml-parse-head chars))
 657     ;; Output the nov line to all nov databases that should have it.
 658     (let ((ga group-art))
 659       (while ga
 660         (nnml-add-nov (caar ga) (cdar ga) headers)
 661         (setq ga (cdr ga))))
 662     group-art))
 663
 664 (defun nnml-active-number (group)
 665   "Compute the next article number in GROUP."
 666   (let ((active (cadr (assoc group nnml-group-alist))))
 667     ;; The group wasn't known to nnml, so we just create an active
 668     ;; entry for it.
 669     (unless active
 670       ;; Perhaps the active file was corrupt?  See whether
 671       ;; there are any articles in this group.
 672       (nnml-possibly-create-directory group)
 673       (nnml-possibly-change-directory group)
 674       (unless nnml-article-file-alist
 675         (setq nnml-article-file-alist
 676               (sort
 677                (nnml-current-group-article-to-file-alist)
 678                'car-less-than-car)))
 679       (setq active
 680             (if nnml-article-file-alist
 681                 (cons (caar nnml-article-file-alist)
 682                       (caar (last nnml-article-file-alist)))
 683               (cons 1 0)))
 684       (push (list group active) nnml-group-alist))
 685     (setcdr active (1+ (cdr active)))
 686     (while (file-exists-p
 687             (expand-file-name (int-to-string (cdr active))
 688                               (nnmail-group-pathname group nnml-directory)))
 689       (setcdr active (1+ (cdr active))))
 690     (cdr active)))
 691
 692 (defun nnml-add-nov (group article headers)
 693   "Add a nov line for the GROUP base."
 694   (save-excursion
 695     (set-buffer (nnml-open-nov group))
 696     (goto-char (point-max))
 697     (mail-header-set-number headers article)
 698     (nnheader-insert-nov headers)))
 699
 700 (defsubst nnml-header-value ()
 701   (buffer-substring (match-end 0) (gnus-point-at-eol)))
 702
 703 (defun nnml-parse-head (chars &optional number)
 704   "Parse the head of the current buffer."
 705   (save-excursion
 706     (save-restriction
 707       (unless (zerop (buffer-size))
 708         (narrow-to-region
 709          (goto-char (point-min))
 710          (if (re-search-forward "\n\r?\n" nil t)
 711              (1- (point))
 712            (point-max))))
 713       (let ((headers (nnheader-parse-naked-head)))
 714         (mail-header-set-chars headers chars)
 715         (mail-header-set-number headers number)
 716         headers))))
 717
 718 (defun nnml-get-nov-buffer (group)
 719   (let ((buffer (get-buffer-create (format " *nnml overview %s*" group))))
 720     (save-excursion
 721       (set-buffer buffer)
 722       (set (make-local-variable 'nnml-nov-buffer-file-name)
 723            (expand-file-name
 724             nnml-nov-file-name
 725             (nnmail-group-pathname group nnml-directory)))
 726       (erase-buffer)
 727       (when (file-exists-p nnml-nov-buffer-file-name)
 728         (nnheader-insert-file-contents nnml-nov-buffer-file-name)))
 729     buffer))
 730
 731 (defun nnml-open-nov (group)
 732   (or (cdr (assoc group nnml-nov-buffer-alist))
 733       (let ((buffer (nnml-get-nov-buffer group)))
 734         (push (cons group buffer) nnml-nov-buffer-alist)
 735         buffer)))
 736
 737 (defun nnml-save-nov ()
 738   (save-excursion
 739     (while nnml-nov-buffer-alist
 740       (when (buffer-name (cdar nnml-nov-buffer-alist))
 741         (set-buffer (cdar nnml-nov-buffer-alist))
 742         (when (buffer-modified-p)
 743           (nnmail-write-region (point-min) (point-max)
 744                                nnml-nov-buffer-file-name nil 'nomesg))
 745         (set-buffer-modified-p nil)
 746         (kill-buffer (current-buffer)))
 747       (setq nnml-nov-buffer-alist (cdr nnml-nov-buffer-alist)))))
 748
 749 ;;;###autoload
 750 (defun nnml-generate-nov-databases (&optional server)
 751   "Generate NOV databases in all nnml directories."
 752   (interactive (list (or (nnoo-current-server 'nnml) "")))
 753   ;; Read the active file to make sure we don't re-use articles
 754   ;; numbers in empty groups.
 755   (nnmail-activate 'nnml)
 756   (unless (nnml-server-opened server)
 757     (nnml-open-server server))
 758   (setq nnml-directory (expand-file-name nnml-directory))
 759   ;; Recurse down the directories.
 760   (nnml-generate-nov-databases-1 nnml-directory nil t)
 761   ;; Save the active file.
 762   (nnmail-save-active nnml-group-alist nnml-active-file))
 763
 764 (defun nnml-generate-nov-databases-1 (dir &optional seen no-active)
 765   "Regenerate the NOV database in DIR."
 766   (interactive "DRegenerate NOV in: ")
 767   (setq dir (file-name-as-directory dir))
 768   ;; Only scan this sub-tree if we haven't been here yet.
 769   (unless (member (file-truename dir) seen)
 770     (push (file-truename dir) seen)
 771     ;; We descend recursively
 772     (let ((dirs (directory-files dir t nil t))
 773           dir)
 774       (while (setq dir (pop dirs))
 775         (when (and (not (string-match "^\\." (file-name-nondirectory dir)))
 776                    (file-directory-p dir))
 777           (nnml-generate-nov-databases-1 dir seen))))
 778     ;; Do this directory.
 779     (let ((files (sort (nnheader-article-to-file-alist dir)
 780                        'car-less-than-car)))
 781       (if (not files)
 782           (let* ((group (nnheader-file-to-group
 783                          (directory-file-name dir) nnml-directory))
 784                  (info (cadr (assoc group nnml-group-alist))))
 785             (when info
 786               (setcar info (1+ (cdr info)))))
 787         (funcall nnml-generate-active-function dir)
 788         ;; Generate the nov file.
 789         (nnml-generate-nov-file dir files)
 790         (unless no-active
 791           (nnmail-save-active nnml-group-alist nnml-active-file))))))
 792
 793 (eval-when-compile (defvar files))
 794 (defun nnml-generate-active-info (dir)
 795   ;; Update the active info for this group.
 796   (let* ((group (nnheader-file-to-group
 797                  (directory-file-name dir) nnml-directory))
 798          (entry (assoc group nnml-group-alist))
 799          (last (or (caadr entry) 0)))
 800     (setq nnml-group-alist (delq entry nnml-group-alist))
 801     (push (list group
 802                 (cons (or (caar files) (1+ last))
 803                       (max last
 804                            (or (let ((f files))
 805                                  (while (cdr f) (setq f (cdr f)))
 806                                  (caar f))
 807                                0))))
 808           nnml-group-alist)))
 809
 810 (defun nnml-generate-nov-file (dir files)
 811   (let* ((dir (file-name-as-directory dir))
 812          (nov (concat dir nnml-nov-file-name))
 813          (nov-buffer (get-buffer-create " *nov*"))
 814          chars file headers)
 815     (save-excursion
 816       ;; Init the nov buffer.
 817       (set-buffer nov-buffer)
 818       (buffer-disable-undo)
 819       (erase-buffer)
 820       (set-buffer nntp-server-buffer)
 821       ;; Delete the old NOV file.
 822       (when (file-exists-p nov)
 823         (funcall nnmail-delete-file-function nov))
 824       (while files
 825         (unless (file-directory-p (setq file (concat dir (cdar files))))
 826           (erase-buffer)
 827           (nnheader-insert-file-contents file)
 828           (narrow-to-region
 829            (goto-char (point-min))
 830            (progn
 831              (re-search-forward "\n\r?\n" nil t)
 832              (setq chars (- (point-max) (point)))
 833              (max (point-min) (1- (point)))))
 834           (unless (zerop (buffer-size))
 835             (goto-char (point-min))
 836             (setq headers (nnml-parse-head chars (caar files)))
 837             (save-excursion
 838               (set-buffer nov-buffer)
 839               (goto-char (point-max))
 840               (nnheader-insert-nov headers)))
 841           (widen))
 842         (setq files (cdr files)))
 843       (save-excursion
 844         (set-buffer nov-buffer)
 845         (nnmail-write-region (point-min) (point-max) nov nil 'nomesg)
 846         (kill-buffer (current-buffer))))))
 847
 848 (defun nnml-nov-delete-article (group article)
 849   (save-excursion
 850     (set-buffer (nnml-open-nov group))
 851     (when (nnheader-find-nov-line article)
 852       (delete-region (point) (progn (forward-line 1) (point)))
 853       (when (bobp)
 854         (let ((active (cadr (assoc group nnml-group-alist)))
 855               num)
 856           (when active
 857             (if (eobp)
 858                 (setf (car active) (1+ (cdr active)))
 859               (when (and (setq num (ignore-errors (read (current-buffer))))
 860                          (numberp num))
 861                 (setf (car active) num)))))))
 862     t))
 863
 864 (defun nnml-update-file-alist (&optional force)
 865   (when nnml-use-compressed-files
 866     (when (or (not nnml-article-file-alist)
 867               force)
 868       (setq nnml-article-file-alist
 869             (nnml-current-group-article-to-file-alist)))))
 870
 871 (defun nnml-directory-articles (dir)
 872   "Return a list of all article files in a directory.
 873 Use the nov database for that directory if available."
 874   (if (or gnus-nov-is-evil nnml-nov-is-evil
 875           (not (file-exists-p
 876                 (expand-file-name nnml-nov-file-name dir))))
 877       (nnheader-directory-articles dir)
 878     ;; build list from .overview if available
 879     ;; We would use nnml-open-nov, except that nnml-nov-buffer-alist is
 880     ;; defvoo'd, and we might get called when it hasn't been swapped in.
 881     (save-excursion
 882       (let ((list nil)
 883             art
 884             (buffer (nnml-get-nov-buffer nnml-current-group)))
 885         (set-buffer buffer)
 886         (goto-char (point-min))
 887         (while (not (eobp))
 888           (setq art (read (current-buffer)))
 889           (push art list)
 890           (forward-line 1))
 891         list))))
 892
 893 (defun nnml-current-group-article-to-file-alist ()
 894   "Return an alist of article/file pairs in the current group.
 895 Use the nov database for the current group if available."
 896   (if (or gnus-nov-is-evil
 897           nnml-nov-is-evil
 898           (not (file-exists-p
 899                 (expand-file-name nnml-nov-file-name
 900                                   nnml-current-directory))))
 901       (nnheader-article-to-file-alist nnml-current-directory)
 902     ;; build list from .overview if available
 903     (save-excursion
 904       (let ((alist nil)
 905             (buffer (nnml-get-nov-buffer nnml-current-group))
 906             art)
 907         (set-buffer buffer)
 908         (goto-char (point-min))
 909         (while (not (eobp))
 910           (setq art (read (current-buffer)))
 911           ;; assume file name is unadorned (ie. not compressed etc)
 912           (push (cons art (int-to-string art)) alist)
 913           (forward-line 1))
 914         alist))))
 915
 916 (deffoo nnml-request-set-mark (group actions &optional server)
 917   (nnml-possibly-change-directory group server)
 918   (unless nnml-marks-is-evil
 919     (nnml-open-marks group server)
 920     (dolist (action actions)
 921       (let ((range (nth 0 action))
 922             (what  (nth 1 action))
 923             (marks (nth 2 action)))
 924         (assert (or (eq what 'add) (eq what 'del)) t
 925                 "Unknown request-set-mark action: %s" what)
 926         (dolist (mark marks)
 927           (setq nnml-marks (gnus-update-alist-soft
 928                             mark
 929                             (funcall (if (eq what 'add) 'gnus-range-add
 930                                        'gnus-remove-from-range)
 931                                      (cdr (assoc mark nnml-marks)) range)
 932                             nnml-marks)))))
 933     (nnml-save-marks group server))
 934   nil)
 935
 936 (deffoo nnml-request-update-info (group info &optional server)
 937   (nnml-possibly-change-directory group server)
 938   (when (and (not nnml-marks-is-evil) (nnml-marks-changed-p group))
 939     (nnheader-message 8 "Updating marks for %s..." group)
 940     (nnml-open-marks group server)
 941     ;; Update info using `nnml-marks'.
 942     (mapcar (lambda (pred)
 943               (unless (memq (cdr pred) gnus-article-unpropagated-mark-lists)
 944                 (gnus-info-set-marks
 945                  info
 946                  (gnus-update-alist-soft
 947                   (cdr pred)
 948                   (cdr (assq (cdr pred) nnml-marks))
 949                   (gnus-info-marks info))
 950                  t)))
 951             gnus-article-mark-lists)
 952     (let ((seen (cdr (assq 'read nnml-marks))))
 953       (gnus-info-set-read info
 954                           (if (and (integerp (car seen))
 955                                    (null (cdr seen)))
 956                               (list (cons (car seen) (car seen)))
 957                             seen)))
 958     (nnheader-message 8 "Updating marks for %s...done" group))
 959   info)
 960
 961 (defun nnml-marks-changed-p (group)
 962   (let ((file (expand-file-name nnml-marks-file-name
 963                                 (nnmail-group-pathname group nnml-directory))))
 964     (if (null (gnus-gethash file nnml-marks-modtime))
 965         t ;; never looked at marks file, assume it has changed
 966       (not (equal (gnus-gethash file nnml-marks-modtime)
 967                   (nth 5 (file-attributes file)))))))
 968
 969 (defun nnml-save-marks (group server)
 970   (let ((file-name-coding-system nnmail-pathname-coding-system)
 971         (file (expand-file-name nnml-marks-file-name
 972                                 (nnmail-group-pathname group nnml-directory))))
 973     (condition-case err
 974         (progn
 975           (nnml-possibly-create-directory group)
 976           (with-temp-file file
 977             (erase-buffer)
 978             (gnus-prin1 nnml-marks)
 979             (insert "\n"))
 980           (gnus-sethash file
 981                         (nth 5 (file-attributes file))
 982                         nnml-marks-modtime))
 983       (error (or (gnus-yes-or-no-p
 984                   (format "Could not write to %s (%s).  Continue? " file err))
 985                  (error "Cannot write to %s (%s)" err))))))
 986
 987 (defun nnml-open-marks (group server)
 988   (let ((file (expand-file-name
 989                nnml-marks-file-name
 990                (nnmail-group-pathname group nnml-directory))))
 991     (if (file-exists-p file)
 992         (condition-case err
 993             (with-temp-buffer
 994               (gnus-sethash file (nth 5 (file-attributes file))
 995                             nnml-marks-modtime)
 996               (nnheader-insert-file-contents file)
 997               (setq nnml-marks (read (current-buffer)))
 998               (dolist (el gnus-article-unpropagated-mark-lists)
 999                 (setq nnml-marks (gnus-remassoc el nnml-marks))))
1000           (error (or (gnus-yes-or-no-p
1001                       (format "Error reading nnml marks file %s (%s).  Continuing will use marks from .newsrc.eld.  Continue? " file err))
1002                      (error "Cannot read nnml marks file %s (%s)" file err))))
1003       ;; User didn't have a .marks file.  Probably first time
1004       ;; user of the .marks stuff.  Bootstrap it from .newsrc.eld.
1005       (let ((info (gnus-get-info
1006                    (gnus-group-prefixed-name
1007                     group
1008                     (gnus-server-to-method (format "nnml:%s" server))))))
1009         (nnheader-message 7 "Bootstrapping marks for %s..." group)
1010         (setq nnml-marks (gnus-info-marks info))
1011         (push (cons 'read (gnus-info-read info)) nnml-marks)
1012         (dolist (el gnus-article-unpropagated-mark-lists)
1013           (setq nnml-marks (gnus-remassoc el nnml-marks)))
1014         (nnml-save-marks group server)
1015         (nnheader-message 7 "Bootstrapping marks for %s...done" group)))))
1016
1017 (provide 'nnml)
1018
1019 ;;; nnml.el ends here