git.chise.org Git - elisp/gnus.git-/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: David Moore <dmoore@ucsd.edu>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can not be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'nnoo)
  38 (require 'gnus-util)
  39 (require 'gnus-start)
  40 (require 'gnus-sum)
  41 (require 'gnus-msg)
  42 (require 'cl)
  43
  44 (nnoo-declare nnvirtual)
  45
  46 (defvoo nnvirtual-always-rescan t
  47   "*If non-nil, always scan groups for unread articles when entering a group.
  48 If this variable is nil (which is the default) and you read articles
  49 in a component group after the virtual group has been activated, the
  50 read articles from the component group will show up when you enter the
  51 virtual group.")
  52
  53 (defvoo nnvirtual-component-regexp nil
  54   "*Regexp to match component groups.")
  55
  56 (defvoo nnvirtual-component-groups nil
  57   "Component group in this nnvirtual group.")
  58
  59 \f
  60
  61 (defconst nnvirtual-version "nnvirtual 1.1")
  62
  63 (defvoo nnvirtual-current-group nil)
  64
  65 (defvoo nnvirtual-mapping-table nil
  66   "Table of rules on how to map between component group and article number
  67 to virtual article number.")
  68
  69 (defvoo nnvirtual-mapping-offsets nil
  70   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  71
  72 (defvoo nnvirtual-mapping-len 0
  73   "Number of articles in this virtual group.")
  74
  75 (defvoo nnvirtual-mapping-reads nil
  76   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  77
  78 (defvoo nnvirtual-mapping-marks nil
  79   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  80
  81 (defvoo nnvirtual-info-installed nil
  82   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  83
  84 (defvoo nnvirtual-status-string "")
  85
  86 (eval-and-compile
  87   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  88
  89 \f
  90
  91 ;;; Interface functions.
  92
  93 (nnoo-define-basics nnvirtual)
  94
  95
  96 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  97                                              server fetch-old)
  98   (when (nnvirtual-possibly-change-server server)
  99     (save-excursion
 100       (set-buffer nntp-server-buffer)
 101       (erase-buffer)
 102       (if (stringp (car articles))
 103           'headers
 104         (let ((vbuf (nnheader-set-temp-buffer
 105                      (get-buffer-create " *virtual headers*")))
 106               (carticles (nnvirtual-partition-sequence articles))
 107               (system-name (system-name))
 108               cgroup carticle article result prefix)
 109           (while carticles
 110             (setq cgroup (caar carticles))
 111             (setq articles (cdar carticles))
 112             (pop carticles)
 113             (when (and articles
 114                        (gnus-check-server
 115                         (gnus-find-method-for-group cgroup) t)
 116                        (gnus-request-group cgroup t)
 117                        (setq prefix (gnus-group-real-prefix cgroup))
 118                        ;; FIX FIX FIX we want to check the cache!
 119                        ;; This is probably evil if people have set
 120                        ;; gnus-use-cache to nil themselves, but I
 121                        ;; have no way of finding the true value of it.
 122                        (let ((gnus-use-cache t))
 123                          (setq result (gnus-retrieve-headers
 124                                        articles cgroup nil))))
 125             (set-buffer nntp-server-buffer)
 126             ;; If we got HEAD headers, we convert them into NOV
 127             ;; headers.  This is slow, inefficient and, come to think
 128             ;; of it, downright evil.  So sue me.  I couldn't be
 129             ;; bothered to write a header parse routine that could
 130             ;; parse a mixed HEAD/NOV buffer.
 131             (when (eq result 'headers)
 132               (nnvirtual-convert-headers))
 133             (goto-char (point-min))
 134             (while (not (eobp))
 135               (delete-region (point)
 136                              (progn
 137                                (setq carticle (read nntp-server-buffer))
 138                                (point)))
 139
 140               ;; We remove this article from the articles list, if
 141               ;; anything is left in the articles list after going through
 142               ;; the entire buffer, then those articles have been
 143               ;; expired or canceled, so we appropriately update the
 144               ;; component group below.  They should be coming up
 145               ;; generally in order, so this shouldn't be slow.
 146               (setq articles (delq carticle articles))
 147
 148               (setq article (nnvirtual-reverse-map-article cgroup carticle))
 149               (if (null article)
 150                   ;; This line has no reverse mapping, that means it
 151                   ;; was an extra article reference returned by nntp.
 152                   (progn
 153                     (beginning-of-line)
 154                     (delete-region (point) (progn (forward-line 1) (point))))
 155                 ;; Otherwise insert the virtual article number,
 156                 ;; and clean up the xrefs.
 157                 (princ article nntp-server-buffer)
 158                 (nnvirtual-update-xref-header cgroup carticle
 159                                               prefix system-name)
 160                 (forward-line 1))
 161               )
 162
 163             (set-buffer vbuf)
 164             (goto-char (point-max))
 165             (insert-buffer-substring nntp-server-buffer))
 166             ;; Anything left in articles is expired or canceled.
 167             ;; Could be smart and not tell it about articles already known?
 168             (when articles
 169               (gnus-group-make-articles-read cgroup articles))
 170             )
 171
 172           ;; The headers are ready for reading, so they are inserted into
 173           ;; the nntp-server-buffer, which is where Gnus expects to find
 174           ;; them.
 175           (prog1
 176               (save-excursion
 177                 (set-buffer nntp-server-buffer)
 178                 (erase-buffer)
 179                 (insert-buffer-substring vbuf)
 180                 ;; FIX FIX FIX, we should be able to sort faster than
 181                 ;; this if needed, since each cgroup is sorted, we just
 182                 ;; need to merge
 183                 (sort-numeric-fields 1 (point-min) (point-max))
 184                 'nov)
 185             (kill-buffer vbuf)))))))
 186
 187
 188 (defvoo nnvirtual-last-accessed-component-group nil)
 189
 190 (deffoo nnvirtual-request-article (article &optional group server buffer)
 191   (when (nnvirtual-possibly-change-server server)
 192     (if (stringp article)
 193         ;; This is a fetch by Message-ID.
 194         (cond
 195          ((not nnvirtual-last-accessed-component-group)
 196           (nnheader-report
 197            'nnvirtual "Don't know what server to request from"))
 198          (t
 199           (save-excursion
 200             (when buffer
 201               (set-buffer buffer))
 202             (let ((method (gnus-find-method-for-group
 203                            nnvirtual-last-accessed-component-group)))
 204               (funcall (gnus-get-function method 'request-article)
 205                        article nil (nth 1 method) buffer)))))
 206       ;; This is a fetch by number.
 207       (let* ((amap (nnvirtual-map-article article))
 208              (cgroup (car amap)))
 209         (cond
 210          ((not amap)
 211           (nnheader-report 'nnvirtual "No such article: %s" article))
 212          ((not (gnus-check-group cgroup))
 213           (nnheader-report
 214            'nnvirtual "Can't open server where %s exists" cgroup))
 215          ((not (gnus-request-group cgroup t))
 216           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 217          (t
 218           (setq nnvirtual-last-accessed-component-group cgroup)
 219           (if buffer
 220               (save-excursion
 221                 (set-buffer buffer)
 222                 ;; We bind this here to avoid double decoding.
 223                 (let ((gnus-article-decode-hook nil))
 224                   (gnus-request-article-this-buffer (cdr amap) cgroup)))
 225             (gnus-request-article (cdr amap) cgroup))))))))
 226
 227
 228 (deffoo nnvirtual-open-server (server &optional defs)
 229   (unless (assq 'nnvirtual-component-regexp defs)
 230     (push `(nnvirtual-component-regexp ,server)
 231           defs))
 232   (nnoo-change-server 'nnvirtual server defs)
 233   (if nnvirtual-component-groups
 234       t
 235     (setq nnvirtual-mapping-table nil
 236           nnvirtual-mapping-offsets nil
 237           nnvirtual-mapping-len 0
 238           nnvirtual-mapping-reads nil
 239           nnvirtual-mapping-marks nil
 240           nnvirtual-info-installed nil)
 241     (when nnvirtual-component-regexp
 242       ;; Go through the newsrc alist and find all component groups.
 243       (let ((newsrc (cdr gnus-newsrc-alist))
 244             group)
 245         (while (setq group (car (pop newsrc)))
 246           (when (string-match nnvirtual-component-regexp group) ; Match
 247             ;; Add this group to the list of component groups.
 248             (setq nnvirtual-component-groups
 249                   (cons group (delete group nnvirtual-component-groups)))))))
 250     (if (not nnvirtual-component-groups)
 251         (nnheader-report 'nnvirtual "No component groups: %s" server)
 252       t)))
 253
 254
 255 (deffoo nnvirtual-request-group (group &optional server dont-check)
 256   (nnvirtual-possibly-change-server server)
 257   (setq nnvirtual-component-groups
 258         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 259   (cond
 260    ((null nnvirtual-component-groups)
 261     (setq nnvirtual-current-group nil)
 262     (nnheader-report 'nnvirtual "No component groups in %s" group))
 263    (t
 264     (setq nnvirtual-current-group group)
 265     (when (or (not dont-check)
 266               nnvirtual-always-rescan)
 267       (nnvirtual-create-mapping)
 268       (when nnvirtual-always-rescan
 269         (nnvirtual-request-update-info
 270          (nnvirtual-current-group)
 271          (gnus-get-info (nnvirtual-current-group)))))
 272     (nnheader-insert "211 %d 1 %d %s\n"
 273                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 274
 275
 276 (deffoo nnvirtual-request-type (group &optional article)
 277   (if (not article)
 278       'unknown
 279     (if (numberp article)
 280         (let ((mart (nnvirtual-map-article article)))
 281           (if mart
 282               (gnus-request-type (car mart) (cdr mart))))
 283       (gnus-request-type
 284        nnvirtual-last-accessed-component-group nil))))
 285
 286 (deffoo nnvirtual-request-update-mark (group article mark)
 287   (let* ((nart (nnvirtual-map-article article))
 288          (cgroup (car nart))
 289          ;; The component group might be a virtual group.
 290          (nmark (gnus-request-update-mark cgroup (cdr nart) mark)))
 291     (when (and nart
 292                (memq mark gnus-auto-expirable-marks)
 293                (= mark nmark)
 294                (gnus-group-auto-expirable-p cgroup))
 295       (setq mark gnus-expirable-mark)))
 296   mark)
 297
 298
 299 (deffoo nnvirtual-close-group (group &optional server)
 300   (when (and (nnvirtual-possibly-change-server server)
 301              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 302     (nnvirtual-update-read-and-marked t t))
 303   t)
 304
 305
 306 (deffoo nnvirtual-request-list (&optional server)
 307   (nnheader-report 'nnvirtual "LIST is not implemented."))
 308
 309
 310 (deffoo nnvirtual-request-newgroups (date &optional server)
 311   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 312
 313
 314 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 315   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 316
 317
 318 (deffoo nnvirtual-request-update-info (group info &optional server)
 319   (when (and (nnvirtual-possibly-change-server server)
 320              (not nnvirtual-info-installed))
 321     ;; Install the precomputed lists atomically, so the virtual group
 322     ;; is not left in a half-way state in case of C-g.
 323     (gnus-atomic-progn
 324       (setcar (cddr info) nnvirtual-mapping-reads)
 325       (if (nthcdr 3 info)
 326           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 327         (when nnvirtual-mapping-marks
 328           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 329       (setq nnvirtual-info-installed t))
 330     t))
 331
 332
 333 (deffoo nnvirtual-catchup-group (group &optional server all)
 334   (when (and (nnvirtual-possibly-change-server server)
 335              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 336     ;; copy over existing marks first, in case they set anything
 337     (nnvirtual-update-read-and-marked nil nil)
 338     ;; do a catchup on all component groups
 339     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 340           (gnus-expert-user t))
 341       ;; Make sure all groups are activated.
 342       (mapcar
 343        (lambda (g)
 344          (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
 345            (gnus-activate-group g)))
 346        nnvirtual-component-groups)
 347       (save-excursion
 348         (set-buffer gnus-group-buffer)
 349         (gnus-group-catchup-current nil all)))))
 350
 351
 352 (deffoo nnvirtual-find-group-art (group article)
 353   "Return the real group and article for virtual GROUP and ARTICLE."
 354   (nnvirtual-map-article article))
 355
 356
 357 (deffoo nnvirtual-request-post (&optional server)
 358   (if (not gnus-message-group-art)
 359       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 360     (let ((group (car (nnvirtual-find-group-art
 361                        (car gnus-message-group-art)
 362                        (cdr gnus-message-group-art)))))
 363       (gnus-request-post (gnus-find-method-for-group group)))))
 364
 365 \f
 366 ;;; Internal functions.
 367
 368 (defun nnvirtual-convert-headers ()
 369   "Convert HEAD headers into NOV headers."
 370   (save-excursion
 371     (set-buffer nntp-server-buffer)
 372     (let* ((dependencies (make-vector 100 0))
 373            (headers (gnus-get-newsgroup-headers dependencies))
 374            header)
 375       (erase-buffer)
 376       (while (setq header (pop headers))
 377         (nnheader-insert-nov header)))))
 378
 379
 380 (defun nnvirtual-update-xref-header (group article prefix system-name)
 381   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 382   ;; Move to beginning of Xref field, creating a slot if needed.
 383   (beginning-of-line)
 384   (looking-at
 385    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 386   (goto-char (match-end 0))
 387   (unless (search-forward "\t" (gnus-point-at-eol) 'move)
 388     (insert "\t"))
 389
 390   ;; Remove any spaces at the beginning of the Xref field.
 391   (while (eq (char-after (1- (point))) ? )
 392     (forward-char -1)
 393     (delete-char 1))
 394
 395   (insert "Xref: " system-name " " group ":")
 396   (princ article (current-buffer))
 397   (insert " ")
 398
 399   ;; If there were existing xref lines, clean them up to have the correct
 400   ;; component server prefix.
 401   (save-restriction
 402     (narrow-to-region (point)
 403                       (or (search-forward "\t" (gnus-point-at-eol) t)
 404                           (gnus-point-at-eol)))
 405     (goto-char (point-min))
 406     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 407       (replace-match "" t t))
 408     (goto-char (point-min))
 409     (when (re-search-forward
 410            (concat (regexp-quote (gnus-group-real-name group)) ":[0-9]+")
 411            nil t)
 412       (replace-match "" t t))
 413     (unless (= (point) (point-max))
 414       (insert " ")
 415       (when (not (string= "" prefix))
 416         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 417           (save-excursion
 418             (goto-char (match-beginning 0))
 419             (insert prefix))))))
 420
 421   ;; Ensure a trailing \t.
 422   (end-of-line)
 423   (or (eq (char-after (1- (point))) ?\t)
 424       (insert ?\t)))
 425
 426
 427 (defun nnvirtual-possibly-change-server (server)
 428   (or (not server)
 429       (nnoo-current-server-p 'nnvirtual server)
 430       (nnvirtual-open-server server)))
 431
 432
 433 (defun nnvirtual-update-read-and-marked (read-p update-p)
 434   "Copy marks from the virtual group to the component groups.
 435 If READ-P is not nil, update the (un)read status of the components.
 436 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 437   (when nnvirtual-current-group
 438     (let ((unreads (and read-p
 439                         (nnvirtual-partition-sequence
 440                          (gnus-list-of-unread-articles
 441                           (nnvirtual-current-group)))))
 442           (type-marks
 443            (delq nil
 444                  (mapcar (lambda (ml)
 445                            (if (eq (car ml) 'score)
 446                                nil
 447                              (cons (car ml)
 448                                    (nnvirtual-partition-sequence (cdr ml)))))
 449                          (gnus-info-marks (gnus-get-info
 450                                            (nnvirtual-current-group))))))
 451           mark type groups carticles info entry)
 452
 453       ;; Ok, atomically move all of the (un)read info, clear any old
 454       ;; marks, and move all of the current marks.  This way if someone
 455       ;; hits C-g, you won't leave the component groups in a half-way state.
 456       (progn
 457         ;; move (un)read
 458         ;; bind for workaround guns-update-read-articles
 459         (let ((gnus-newsgroup-active nil))
 460           (while (setq entry (pop unreads))
 461             (gnus-update-read-articles (car entry) (cdr entry))))
 462
 463         ;; clear all existing marks on the component groups
 464         (setq groups nnvirtual-component-groups)
 465         (while groups
 466           (when (and (setq info (gnus-get-info (pop groups)))
 467                      (gnus-info-marks info))
 468             (gnus-info-set-marks
 469              info
 470              (if (assq 'score (gnus-info-marks info))
 471                  (list (assq 'score (gnus-info-marks info)))
 472                nil))))
 473
 474         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 475         ;; with data of an assq list with keys of component group names
 476         ;; and the articles which correspond to that key/group pair.
 477         (while (setq mark (pop type-marks))
 478           (setq type (car mark))
 479           (setq groups (cdr mark))
 480           (while (setq carticles (pop groups))
 481             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 482                                       nil t))))
 483
 484       ;; possibly update the display, it is really slow
 485       (when update-p
 486         (setq groups nnvirtual-component-groups)
 487         (while groups
 488           (gnus-group-update-group (pop groups) t))))))
 489
 490
 491 (defun nnvirtual-current-group ()
 492   "Return the prefixed name of the current nnvirtual group."
 493   (concat "nnvirtual:" nnvirtual-current-group))
 494
 495
 496
 497 ;;; This is currently O(kn^2) to merge n lists of length k.
 498 ;;; You could do it in O(knlogn), but we have a small n, and the
 499 ;;; overhead of the other approach is probably greater.
 500 (defun nnvirtual-merge-sorted-lists (&rest lists)
 501   "Merge many sorted lists of numbers."
 502   (if (null (cdr lists))
 503       (car lists)
 504     (sort (apply 'nconc lists) '<)))
 505
 506
 507 ;;; We map between virtual articles and real articles in a manner
 508 ;;; which keeps the size of the virtual active list the same as
 509 ;;; the sum of the component active lists.
 510 ;;; To achieve fair mixing of the groups, the last article in
 511 ;;; each of N component groups will be in the the last N articles
 512 ;;; in the virtual group.
 513
 514 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and 6-7
 515 ;;; resprectively, then the virtual article numbers look like:
 516 ;;;
 517 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 518 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 519
 520 ;;; To compute these mappings we generate a couple tables and then
 521 ;;; do some fast operations on them.  Tables for the example above:
 522 ;;;
 523 ;;; Offsets - [(A 0) (B -3) (C -1)]
 524 ;;;
 525 ;;;               a  b  c  d  e
 526 ;;; Mapping - ([  3  0  1  3  0 ]
 527 ;;;            [  6  3  2  9  3 ]
 528 ;;;            [  8  6  3 15  9 ])
 529 ;;;
 530 ;;; (note column 'e' is different in real algorithm, which is slightly
 531 ;;;  different than described here, but this gives you the methodology.)
 532 ;;;
 533 ;;; The basic idea is this, when going from component->virtual, apply
 534 ;;; the appropriate offset to the article number.  Then search the first
 535 ;;; column of the table for a row where 'a' is less than or equal to the
 536 ;;; modified number.  You can see that only group A can therefore go to
 537 ;;; the first row, groups A and B to the second, and all to the last.
 538 ;;; The third column of the table is telling us the number of groups
 539 ;;; which might be able to reach that row (it might increase by more than
 540 ;;; 1 if several groups have the same size).
 541 ;;; Then column 'b' provides an additional offset you apply when you have
 542 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 543 ;;; _position_ in the offset table.  The basic idea here is that on
 544 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 545 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 546 ;;; you apply a final offset from column 'e' to give the virtual article.
 547 ;;;
 548 ;;; Going the other direction, you instead search on column 'd' instead
 549 ;;; of 'a', and apply everything in reverse order.
 550
 551 ;;; Convert component -> virtual:
 552 ;;; set num = num - Offset(group)
 553 ;;; find first row in Mapping where num <= 'a'
 554 ;;; num = (num-'b')*c + Position(group) + 'e'
 555
 556 ;;; Convert virtual -> component:
 557 ;;; find first row in Mapping where num <= 'd'
 558 ;;; num = num - 'e'
 559 ;;; group_pos = num mod 'c'
 560 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 561
 562 ;;; Easy no? :)
 563 ;;;
 564 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 565 ;;; column for that line, and always add 1 more when going from
 566 ;;; component -> virtual.  Otherwise you run into a problem with
 567 ;;; unique reverse mapping.
 568
 569 (defun nnvirtual-map-article (article)
 570   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 571   (let ((table nnvirtual-mapping-table)
 572         entry group-pos)
 573     (while (and table
 574                 (> article (aref (car table) 3)))
 575       (setq table (cdr table)))
 576     (when (and table
 577                (> article 0))
 578       (setq entry (car table))
 579       (setq article (- article (aref entry 4) 1))
 580       (setq group-pos (mod article (aref entry 2)))
 581       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 582             (+ (/ article (aref entry 2))
 583                (aref entry 1)
 584                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 585             ))
 586       ))
 587
 588
 589
 590 (defun nnvirtual-reverse-map-article (group article)
 591   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 592   (when (numberp article)
 593     (let ((table nnvirtual-mapping-table)
 594           (group-pos 0)
 595           entry)
 596       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 597                                             group-pos))))
 598         (setq group-pos (1+ group-pos)))
 599       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 600                                           group-pos))))
 601       (while (and table
 602                   (> article (aref (car table) 0)))
 603         (setq table (cdr table)))
 604       (setq entry (car table))
 605       (when (and entry
 606                  (> article 0)
 607                  (< group-pos (aref entry 2))) ; article not out of range below
 608         (+ (aref entry 4)
 609            group-pos
 610            (* (- article (aref entry 1))
 611               (aref entry 2))
 612            1))
 613       )))
 614
 615
 616 (defsubst nnvirtual-reverse-map-sequence (group articles)
 617   "Return list of virtual article numbers for all ARTICLES in GROUP.
 618 The ARTICLES should be sorted, and can be a compressed sequence.
 619 If any of the article numbers has no corresponding virtual article,
 620 then it is left out of the result."
 621   (when (numberp (cdr-safe articles))
 622     (setq articles (list articles)))
 623   (let (result a i j new-a)
 624     (while (setq a (pop articles))
 625       (if (atom a)
 626           (setq i a
 627                 j a)
 628         (setq i (car a)
 629               j (cdr a)))
 630       (while (<= i j)
 631         ;; If this is slow, you can optimize by moving article checking
 632         ;; into here.  You don't have to recompute the group-pos,
 633         ;; nor scan the table every time.
 634         (when (setq new-a (nnvirtual-reverse-map-article group i))
 635           (push new-a result))
 636         (setq i (1+ i))))
 637     (nreverse result)))
 638
 639
 640 (defun nnvirtual-partition-sequence (articles)
 641   "Return an association list of component article numbers.
 642 These are indexed by elements of nnvirtual-component-groups, based on
 643 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 644 sorted, and can be a compressed sequence. If any of the article
 645 numbers has no corresponding component article, then it is left out of
 646 the result."
 647   (when (numberp (cdr-safe articles))
 648     (setq articles (list articles)))
 649   (let ((carticles (mapcar (lambda (g) (list g))
 650                            nnvirtual-component-groups))
 651         a i j article entry)
 652     (while (setq a (pop articles))
 653       (if (atom a)
 654           (setq i a
 655                 j a)
 656         (setq i (car a)
 657               j (cdr a)))
 658       (while (<= i j)
 659         (when (setq article (nnvirtual-map-article i))
 660           (setq entry (assoc (car article) carticles))
 661           (setcdr entry (cons (cdr article) (cdr entry))))
 662         (setq i (1+ i))))
 663     (mapcar (lambda (x) (setcdr x (nreverse (cdr x))))
 664             carticles)
 665     carticles))
 666
 667
 668 (defun nnvirtual-create-mapping ()
 669   "Build the tables necessary to map between component (group, article) to virtual article.
 670 Generate the set of read messages and marks for the virtual group
 671 based on the marks on the component groups."
 672   (let ((cnt 0)
 673         (tot 0)
 674         (M 0)
 675         (i 0)
 676         actives all-unreads all-marks
 677         active min max size unreads marks
 678         next-M next-tot
 679         reads beg)
 680     ;; Ok, we loop over all component groups and collect a lot of
 681     ;; information:
 682     ;; Into actives we place (g size max), where size is max-min+1.
 683     ;; Into all-unreads we put (g unreads).
 684     ;; Into all-marks we put (g marks).
 685     ;; We also increment cnt and tot here, and compute M (max of sizes).
 686     (mapc (lambda (g)
 687             (setq active (gnus-activate-group g)
 688                   min (car active)
 689                   max (cdr active))
 690             (when (and active (>= max min) (not (zerop max)))
 691               ;; store active information
 692               (push (list g (- max min -1) max) actives)
 693               ;; collect unread/mark info for later
 694               (setq unreads (gnus-list-of-unread-articles g))
 695               (setq marks (gnus-info-marks (gnus-get-info g)))
 696               (when gnus-use-cache
 697                 (push (cons 'cache
 698                             (gnus-cache-articles-in-group g))
 699                       marks))
 700               (push (cons g unreads) all-unreads)
 701               (push (cons g marks) all-marks)
 702               ;; count groups, total #articles, and max size
 703               (setq size (- max min -1))
 704               (setq cnt (1+ cnt)
 705                     tot (+ tot size)
 706                     M (max M size))))
 707           nnvirtual-component-groups)
 708
 709     ;; Number of articles in the virtual group.
 710     (setq nnvirtual-mapping-len tot)
 711
 712
 713     ;; We want the actives list sorted by size, to build the tables.
 714     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 715
 716     ;; Build the offset table.  Largest sized groups are at the front.
 717     (setq nnvirtual-mapping-offsets
 718           (vconcat
 719            (nreverse
 720             (mapcar (lambda (entry)
 721                       (cons (nth 0 entry)
 722                             (- (nth 2 entry) M)))
 723                     actives))))
 724
 725     ;; Build the mapping table.
 726     (setq nnvirtual-mapping-table nil)
 727     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 728     (while actives
 729       (setq size (car actives))
 730       (setq next-M (- M size))
 731       (setq next-tot (- tot (* cnt size)))
 732       ;; make current row in table
 733       (push (vector M next-M cnt tot (- next-tot cnt))
 734             nnvirtual-mapping-table)
 735       ;; update M and tot
 736       (setq M next-M)
 737       (setq tot next-tot)
 738       ;; subtract the current size from all entries.
 739       (setq actives (mapcar (lambda (x) (- x size)) actives))
 740       ;; remove anything that went to 0.
 741       (while (and actives
 742                   (= (car actives) 0))
 743         (pop actives)
 744         (setq cnt (- cnt 1))))
 745
 746
 747     ;; Now that the mapping tables are generated, we can convert
 748     ;; and combine the separate component unreads and marks lists
 749     ;; into single lists of virtual article numbers.
 750     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 751                          (mapcar (lambda (x)
 752                                    (nnvirtual-reverse-map-sequence
 753                                     (car x) (cdr x)))
 754                                  all-unreads)))
 755     (setq marks (mapcar
 756                  (lambda (type)
 757                    (cons (cdr type)
 758                          (gnus-compress-sequence
 759                           (apply
 760                            'nnvirtual-merge-sorted-lists
 761                            (mapcar (lambda (x)
 762                                      (nnvirtual-reverse-map-sequence
 763                                       (car x)
 764                                       (cdr (assq (cdr type) (cdr x)))))
 765                                    all-marks)))))
 766                  gnus-article-mark-lists))
 767
 768     ;; Remove any empty marks lists, and store.
 769     (setq nnvirtual-mapping-marks nil)
 770     (while marks
 771       (if (cdr (car marks))
 772           (push (car marks) nnvirtual-mapping-marks))
 773       (setq marks (cdr marks)))
 774
 775     ;; We need to convert the unreads to reads.  We compress the
 776     ;; sequence as we go, otherwise it could be huge.
 777     (while (and (<= (incf i) nnvirtual-mapping-len)
 778                 unreads)
 779       (if (= i (car unreads))
 780           (setq unreads (cdr unreads))
 781         ;; try to get a range.
 782         (setq beg i)
 783         (while (and (<= (incf i) nnvirtual-mapping-len)
 784                     (not (= i (car unreads)))))
 785         (setq i (- i 1))
 786         (if (= i beg)
 787             (push i reads)
 788           (push (cons beg i) reads))
 789         ))
 790     (when (<= i nnvirtual-mapping-len)
 791       (if (= i nnvirtual-mapping-len)
 792           (push i reads)
 793         (push (cons i nnvirtual-mapping-len) reads)))
 794
 795     ;; Store the reads list for later use.
 796     (setq nnvirtual-mapping-reads (nreverse reads))
 797
 798     ;; Throw flag to show we changed the info.
 799     (setq nnvirtual-info-installed nil)
 800     ))
 801
 802 (provide 'nnvirtual)
 803
 804 ;;; nnvirtual.el ends here