git.chise.org Git - elisp/gnus.git-/blob - lisp/nnvirtual.el

   1 ;;; nnvirtual.el --- virtual newsgroups access for Gnus
   2 ;; Copyright (C) 1994,95,96,97,98 Free Software Foundation, Inc.
   3
   4 ;; Author: David Moore <dmoore@ucsd.edu>
   5 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The other access methods (nntp, nnspool, etc) are general news
  29 ;; access methods.  This module relies on Gnus and can not be used
  30 ;; separately.
  31
  32 ;;; Code:
  33
  34 (require 'nntp)
  35 (require 'nnheader)
  36 (require 'gnus)
  37 (require 'nnoo)
  38 (require 'gnus-util)
  39 (require 'gnus-start)
  40 (require 'gnus-sum)
  41 (require 'gnus-msg)
  42 (require 'cl)
  43
  44 (nnoo-declare nnvirtual)
  45
  46 (defvoo nnvirtual-always-rescan t
  47   "*If non-nil, always scan groups for unread articles when entering a group.
  48 If this variable is nil (which is the default) and you read articles
  49 in a component group after the virtual group has been activated, the
  50 read articles from the component group will show up when you enter the
  51 virtual group.")
  52
  53 (defvoo nnvirtual-component-regexp nil
  54   "*Regexp to match component groups.")
  55
  56 (defvoo nnvirtual-component-groups nil
  57   "Component group in this nnvirtual group.")
  58
  59 \f
  60
  61 (defconst nnvirtual-version "nnvirtual 1.1")
  62
  63 (defvoo nnvirtual-current-group nil)
  64
  65 (defvoo nnvirtual-mapping-table nil
  66   "Table of rules on how to map between component group and article number
  67 to virtual article number.")
  68
  69 (defvoo nnvirtual-mapping-offsets nil
  70   "Table indexed by component group to an offset to be applied to article numbers in that group.")
  71
  72 (defvoo nnvirtual-mapping-len 0
  73   "Number of articles in this virtual group.")
  74
  75 (defvoo nnvirtual-mapping-reads nil
  76   "Compressed sequence of read articles on the virtual group as computed from the unread status of individual component groups.")
  77
  78 (defvoo nnvirtual-mapping-marks nil
  79   "Compressed marks alist for the virtual group as computed from the marks of individual component groups.")
  80
  81 (defvoo nnvirtual-info-installed nil
  82   "T if we have already installed the group info for this group, and shouldn't blast over it again.")
  83
  84 (defvoo nnvirtual-status-string "")
  85
  86 (eval-and-compile
  87   (autoload 'gnus-cache-articles-in-group "gnus-cache"))
  88
  89 \f
  90
  91 ;;; Interface functions.
  92
  93 (nnoo-define-basics nnvirtual)
  94
  95
  96 (deffoo nnvirtual-retrieve-headers (articles &optional newsgroup
  97                                              server fetch-old)
  98   (when (nnvirtual-possibly-change-server server)
  99     (save-excursion
 100       (set-buffer nntp-server-buffer)
 101       (erase-buffer)
 102       (if (stringp (car articles))
 103           'headers
 104         (let ((vbuf (nnheader-set-temp-buffer
 105                      (get-buffer-create " *virtual headers*")))
 106               (carticles (nnvirtual-partition-sequence articles))
 107               (system-name (system-name))
 108               cgroup carticle article result prefix)
 109           (while carticles
 110             (setq cgroup (caar carticles))
 111             (setq articles (cdar carticles))
 112             (pop carticles)
 113             (when (and articles
 114                        (gnus-check-server
 115                         (gnus-find-method-for-group cgroup) t)
 116                        (gnus-request-group cgroup t)
 117                        (setq prefix (gnus-group-real-prefix cgroup))
 118                        ;; FIX FIX FIX we want to check the cache!
 119                        ;; This is probably evil if people have set
 120                        ;; gnus-use-cache to nil themselves, but I
 121                        ;; have no way of finding the true value of it.
 122                        (let ((gnus-use-cache t))
 123                          (setq result (gnus-retrieve-headers
 124                                        articles cgroup nil))))
 125             (set-buffer nntp-server-buffer)
 126             ;; If we got HEAD headers, we convert them into NOV
 127             ;; headers.  This is slow, inefficient and, come to think
 128             ;; of it, downright evil.  So sue me.  I couldn't be
 129             ;; bothered to write a header parse routine that could
 130             ;; parse a mixed HEAD/NOV buffer.
 131             (when (eq result 'headers)
 132               (nnvirtual-convert-headers))
 133             (goto-char (point-min))
 134             (while (not (eobp))
 135               (delete-region (point)
 136                              (progn
 137                                (setq carticle (read nntp-server-buffer))
 138                                (point)))
 139
 140               ;; We remove this article from the articles list, if
 141               ;; anything is left in the articles list after going through
 142               ;; the entire buffer, then those articles have been
 143               ;; expired or canceled, so we appropriately update the
 144               ;; component group below.  They should be coming up
 145               ;; generally in order, so this shouldn't be slow.
 146               (setq articles (delq carticle articles))
 147
 148               (setq article (nnvirtual-reverse-map-article cgroup carticle))
 149               (if (null article)
 150                   ;; This line has no reverse mapping, that means it
 151                   ;; was an extra article reference returned by nntp.
 152                   (progn
 153                     (beginning-of-line)
 154                     (delete-region (point) (progn (forward-line 1) (point))))
 155                 ;; Otherwise insert the virtual article number,
 156                 ;; and clean up the xrefs.
 157                 (princ article nntp-server-buffer)
 158                 (nnvirtual-update-xref-header cgroup carticle
 159                                               prefix system-name)
 160                 (forward-line 1))
 161               )
 162
 163             (set-buffer vbuf)
 164             (goto-char (point-max))
 165             (insert-buffer-substring nntp-server-buffer))
 166             ;; Anything left in articles is expired or canceled.
 167             ;; Could be smart and not tell it about articles already known?
 168             (when articles
 169               (gnus-group-make-articles-read cgroup articles))
 170             )
 171
 172           ;; The headers are ready for reading, so they are inserted into
 173           ;; the nntp-server-buffer, which is where Gnus expects to find
 174           ;; them.
 175           (prog1
 176               (save-excursion
 177                 (set-buffer nntp-server-buffer)
 178                 (erase-buffer)
 179                 (insert-buffer-substring vbuf)
 180                 ;; FIX FIX FIX, we should be able to sort faster than
 181                 ;; this if needed, since each cgroup is sorted, we just
 182                 ;; need to merge
 183                 (sort-numeric-fields 1 (point-min) (point-max))
 184                 'nov)
 185             (kill-buffer vbuf)))))))
 186
 187
 188 (defvoo nnvirtual-last-accessed-component-group nil)
 189
 190 (deffoo nnvirtual-request-article (article &optional group server buffer)
 191   (when (nnvirtual-possibly-change-server server)
 192     (if (stringp article)
 193         ;; This is a fetch by Message-ID.
 194         (cond
 195          ((not nnvirtual-last-accessed-component-group)
 196           (nnheader-report
 197            'nnvirtual "Don't know what server to request from"))
 198          (t
 199           (save-excursion
 200             (when buffer
 201               (set-buffer buffer))
 202             (let ((method (gnus-find-method-for-group
 203                            nnvirtual-last-accessed-component-group)))
 204               (funcall (gnus-get-function method 'request-article)
 205                        article nil (nth 1 method) buffer)))))
 206       ;; This is a fetch by number.
 207       (let* ((amap (nnvirtual-map-article article))
 208              (cgroup (car amap)))
 209         (cond
 210          ((not amap)
 211           (nnheader-report 'nnvirtual "No such article: %s" article))
 212          ((not (gnus-check-group cgroup))
 213           (nnheader-report
 214            'nnvirtual "Can't open server where %s exists" cgroup))
 215          ((not (gnus-request-group cgroup t))
 216           (nnheader-report 'nnvirtual "Can't open component group %s" cgroup))
 217          (t
 218           (setq nnvirtual-last-accessed-component-group cgroup)
 219           (if buffer
 220               (save-excursion
 221                 (set-buffer buffer)
 222                 (gnus-request-article-this-buffer (cdr amap) cgroup))
 223             (gnus-request-article (cdr amap) cgroup))))))))
 224
 225
 226 (deffoo nnvirtual-open-server (server &optional defs)
 227   (unless (assq 'nnvirtual-component-regexp defs)
 228     (push `(nnvirtual-component-regexp ,server)
 229           defs))
 230   (nnoo-change-server 'nnvirtual server defs)
 231   (if nnvirtual-component-groups
 232       t
 233     (setq nnvirtual-mapping-table nil
 234           nnvirtual-mapping-offsets nil
 235           nnvirtual-mapping-len 0
 236           nnvirtual-mapping-reads nil
 237           nnvirtual-mapping-marks nil
 238           nnvirtual-info-installed nil)
 239     (when nnvirtual-component-regexp
 240       ;; Go through the newsrc alist and find all component groups.
 241       (let ((newsrc (cdr gnus-newsrc-alist))
 242             group)
 243         (while (setq group (car (pop newsrc)))
 244           (when (string-match nnvirtual-component-regexp group) ; Match
 245             ;; Add this group to the list of component groups.
 246             (setq nnvirtual-component-groups
 247                   (cons group (delete group nnvirtual-component-groups)))))))
 248     (if (not nnvirtual-component-groups)
 249         (nnheader-report 'nnvirtual "No component groups: %s" server)
 250       t)))
 251
 252
 253 (deffoo nnvirtual-request-group (group &optional server dont-check)
 254   (nnvirtual-possibly-change-server server)
 255   (setq nnvirtual-component-groups
 256         (delete (nnvirtual-current-group) nnvirtual-component-groups))
 257   (cond
 258    ((null nnvirtual-component-groups)
 259     (setq nnvirtual-current-group nil)
 260     (nnheader-report 'nnvirtual "No component groups in %s" group))
 261    (t
 262     (setq nnvirtual-current-group group)
 263     (when (or (not dont-check)
 264               nnvirtual-always-rescan)
 265       (nnvirtual-create-mapping)
 266       (when nnvirtual-always-rescan
 267         (nnvirtual-request-update-info
 268          (nnvirtual-current-group)
 269          (gnus-get-info (nnvirtual-current-group)))))
 270     (nnheader-insert "211 %d 1 %d %s\n"
 271                      nnvirtual-mapping-len nnvirtual-mapping-len group))))
 272
 273
 274 (deffoo nnvirtual-request-type (group &optional article)
 275   (if (not article)
 276       'unknown
 277     (if (numberp article)
 278         (let ((mart (nnvirtual-map-article article)))
 279           (if mart
 280               (gnus-request-type (car mart) (cdr mart))))
 281       (gnus-request-type
 282        nnvirtual-last-accessed-component-group nil))))
 283
 284 (deffoo nnvirtual-request-update-mark (group article mark)
 285   (let* ((nart (nnvirtual-map-article article))
 286          (cgroup (car nart))
 287          ;; The component group might be a virtual group.
 288          (nmark (gnus-request-update-mark cgroup (cdr nart) mark)))
 289     (when (and nart
 290                (= mark nmark)
 291                (gnus-group-auto-expirable-p cgroup))
 292       (setq mark gnus-expirable-mark)))
 293   mark)
 294
 295
 296 (deffoo nnvirtual-close-group (group &optional server)
 297   (when (and (nnvirtual-possibly-change-server server)
 298              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 299     (nnvirtual-update-read-and-marked t t))
 300   t)
 301
 302
 303 (deffoo nnvirtual-request-list (&optional server)
 304   (nnheader-report 'nnvirtual "LIST is not implemented."))
 305
 306
 307 (deffoo nnvirtual-request-newgroups (date &optional server)
 308   (nnheader-report 'nnvirtual "NEWGROUPS is not supported."))
 309
 310
 311 (deffoo nnvirtual-request-list-newsgroups (&optional server)
 312   (nnheader-report 'nnvirtual "LIST NEWSGROUPS is not implemented."))
 313
 314
 315 (deffoo nnvirtual-request-update-info (group info &optional server)
 316   (when (and (nnvirtual-possibly-change-server server)
 317              (not nnvirtual-info-installed))
 318     ;; Install the precomputed lists atomically, so the virtual group
 319     ;; is not left in a half-way state in case of C-g.
 320     (gnus-atomic-progn
 321       (setcar (cddr info) nnvirtual-mapping-reads)
 322       (if (nthcdr 3 info)
 323           (setcar (nthcdr 3 info) nnvirtual-mapping-marks)
 324         (when nnvirtual-mapping-marks
 325           (setcdr (nthcdr 2 info) (list nnvirtual-mapping-marks))))
 326       (setq nnvirtual-info-installed t))
 327     t))
 328
 329
 330 (deffoo nnvirtual-catchup-group (group &optional server all)
 331   (when (and (nnvirtual-possibly-change-server server)
 332              (not (gnus-ephemeral-group-p (nnvirtual-current-group))))
 333     ;; copy over existing marks first, in case they set anything
 334     (nnvirtual-update-read-and-marked nil nil)
 335     ;; do a catchup on all component groups
 336     (let ((gnus-group-marked (copy-sequence nnvirtual-component-groups))
 337           (gnus-expert-user t))
 338       ;; Make sure all groups are activated.
 339       (mapcar
 340        (lambda (g)
 341          (when (not (numberp (car (gnus-gethash g gnus-newsrc-hashtb))))
 342            (gnus-activate-group g)))
 343        nnvirtual-component-groups)
 344       (save-excursion
 345         (set-buffer gnus-group-buffer)
 346         (gnus-group-catchup-current nil all)))))
 347
 348
 349 (deffoo nnvirtual-find-group-art (group article)
 350   "Return the real group and article for virtual GROUP and ARTICLE."
 351   (nnvirtual-map-article article))
 352
 353
 354 (deffoo nnvirtual-request-post (&optional server)
 355   (if (not gnus-message-group-art)
 356       (nnheader-report 'nnvirtual "Can't post to an nnvirtual group")
 357     (let ((group (car (nnvirtual-find-group-art
 358                        (car gnus-message-group-art)
 359                        (cdr gnus-message-group-art)))))
 360       (gnus-request-post (gnus-find-method-for-group group)))))
 361
 362 \f
 363 ;;; Internal functions.
 364
 365 (defun nnvirtual-convert-headers ()
 366   "Convert HEAD headers into NOV headers."
 367   (save-excursion
 368     (set-buffer nntp-server-buffer)
 369     (let* ((dependencies (make-vector 100 0))
 370            (headers (gnus-get-newsgroup-headers dependencies))
 371            header)
 372       (erase-buffer)
 373       (while (setq header (pop headers))
 374         (nnheader-insert-nov header)))))
 375
 376
 377 (defun nnvirtual-update-xref-header (group article prefix system-name)
 378   "Edit current NOV header in current buffer to have an xref to the component group, and also server prefix any existing xref lines."
 379   ;; Move to beginning of Xref field, creating a slot if needed.
 380   (beginning-of-line)
 381   (looking-at
 382    "[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t[^\t]*\t")
 383   (goto-char (match-end 0))
 384   (unless (search-forward "\t" (gnus-point-at-eol) 'move)
 385     (insert "\t"))
 386
 387   ;; Remove any spaces at the beginning of the Xref field.
 388   (while (= (char-after (1- (point))) ? )
 389     (forward-char -1)
 390     (delete-char 1))
 391
 392   (insert "Xref: " system-name " " group ":")
 393   (princ article (current-buffer))
 394   (insert " ")
 395
 396   ;; If there were existing xref lines, clean them up to have the correct
 397   ;; component server prefix.
 398   (save-restriction
 399     (narrow-to-region (point)
 400                       (or (search-forward "\t" (gnus-point-at-eol) t)
 401                           (gnus-point-at-eol)))
 402     (goto-char (point-min))
 403     (when (re-search-forward "Xref: *[^\n:0-9 ]+ *" nil t)
 404       (replace-match "" t t))
 405     (goto-char (point-min))
 406     (when (re-search-forward
 407            (concat (regexp-quote (gnus-group-real-name group)) ":[0-9]+")
 408            nil t)
 409       (replace-match "" t t))
 410     (unless (= (point) (point-max))
 411       (insert " ")
 412       (when (not (string= "" prefix))
 413         (while (re-search-forward "[^ ]+:[0-9]+" nil t)
 414           (save-excursion
 415             (goto-char (match-beginning 0))
 416             (insert prefix))))))
 417
 418   ;; Ensure a trailing \t.
 419   (end-of-line)
 420   (or (= (char-after (1- (point))) ?\t)
 421       (insert ?\t)))
 422
 423
 424 (defun nnvirtual-possibly-change-server (server)
 425   (or (not server)
 426       (nnoo-current-server-p 'nnvirtual server)
 427       (nnvirtual-open-server server)))
 428
 429
 430 (defun nnvirtual-update-read-and-marked (read-p update-p)
 431   "Copy marks from the virtual group to the component groups.
 432 If READ-P is not nil, update the (un)read status of the components.
 433 If UPDATE-P is not nil, call gnus-group-update-group on the components."
 434   (when nnvirtual-current-group
 435     (let ((unreads (and read-p
 436                         (nnvirtual-partition-sequence
 437                          (gnus-list-of-unread-articles
 438                           (nnvirtual-current-group)))))
 439           (type-marks (mapcar (lambda (ml)
 440                                 (cons (car ml)
 441                                       (nnvirtual-partition-sequence (cdr ml))))
 442                               (gnus-info-marks (gnus-get-info
 443                                                 (nnvirtual-current-group)))))
 444           mark type groups carticles info entry)
 445
 446       ;; Ok, atomically move all of the (un)read info, clear any old
 447       ;; marks, and move all of the current marks.  This way if someone
 448       ;; hits C-g, you won't leave the component groups in a half-way state.
 449       (gnus-atomic-progn
 450         ;; move (un)read
 451         (let ((gnus-newsgroup-active nil)) ;workaround guns-update-read-articles
 452           (while (setq entry (pop unreads))
 453             (gnus-update-read-articles (car entry) (cdr entry))))
 454
 455         ;; clear all existing marks on the component groups
 456         (setq groups nnvirtual-component-groups)
 457         (while groups
 458           (when (and (setq info (gnus-get-info (pop groups)))
 459                      (gnus-info-marks info))
 460             (gnus-info-set-marks info nil)))
 461
 462         ;; Ok, currently type-marks is an assq list with keys of a mark type,
 463         ;; with data of an assq list with keys of component group names
 464         ;; and the articles which correspond to that key/group pair.
 465         (while (setq mark (pop type-marks))
 466           (setq type (car mark))
 467           (setq groups (cdr mark))
 468           (while (setq carticles (pop groups))
 469             (gnus-add-marked-articles (car carticles) type (cdr carticles)
 470                                       nil t))))
 471
 472       ;; possibly update the display, it is really slow
 473       (when update-p
 474         (setq groups nnvirtual-component-groups)
 475         (while groups
 476           (gnus-group-update-group (pop groups) t))))))
 477
 478
 479 (defun nnvirtual-current-group ()
 480   "Return the prefixed name of the current nnvirtual group."
 481   (concat "nnvirtual:" nnvirtual-current-group))
 482
 483
 484
 485 ;;; This is currently O(kn^2) to merge n lists of length k.
 486 ;;; You could do it in O(knlogn), but we have a small n, and the
 487 ;;; overhead of the other approach is probably greater.
 488 (defun nnvirtual-merge-sorted-lists (&rest lists)
 489   "Merge many sorted lists of numbers."
 490   (if (null (cdr lists))
 491       (car lists)
 492     (sort (apply 'nconc lists) '<)))
 493
 494
 495 ;;; We map between virtual articles and real articles in a manner
 496 ;;; which keeps the size of the virtual active list the same as
 497 ;;; the sum of the component active lists.
 498 ;;; To achieve fair mixing of the groups, the last article in
 499 ;;; each of N component groups will be in the the last N articles
 500 ;;; in the virtual group.
 501
 502 ;;; If you have 3 components A, B and C, with articles 1-8, 1-5, and 6-7
 503 ;;; resprectively, then the virtual article numbers look like:
 504 ;;;
 505 ;;;  1  2  3  4  5  6  7  8  9  10 11 12 13 14 15
 506 ;;;  A1 A2 A3 A4 B1 A5 B2 A6 B3 A7 B4 C6 A8 B5 C7
 507
 508 ;;; To compute these mappings we generate a couple tables and then
 509 ;;; do some fast operations on them.  Tables for the example above:
 510 ;;;
 511 ;;; Offsets - [(A 0) (B -3) (C -1)]
 512 ;;;
 513 ;;;               a  b  c  d  e
 514 ;;; Mapping - ([  3  0  1  3  0 ]
 515 ;;;            [  6  3  2  9  3 ]
 516 ;;;            [  8  6  3 15  9 ])
 517 ;;;
 518 ;;; (note column 'e' is different in real algorithm, which is slightly
 519 ;;;  different than described here, but this gives you the methodology.)
 520 ;;;
 521 ;;; The basic idea is this, when going from component->virtual, apply
 522 ;;; the appropriate offset to the article number.  Then search the first
 523 ;;; column of the table for a row where 'a' is less than or equal to the
 524 ;;; modified number.  You can see that only group A can therefore go to
 525 ;;; the first row, groups A and B to the second, and all to the last.
 526 ;;; The third column of the table is telling us the number of groups
 527 ;;; which might be able to reach that row (it might increase by more than
 528 ;;; 1 if several groups have the same size).
 529 ;;; Then column 'b' provides an additional offset you apply when you have
 530 ;;; found the correct row.  You then multiply by 'c' and add on the groups
 531 ;;; _position_ in the offset table.  The basic idea here is that on
 532 ;;; any given row we are going to map back and forth using X'=X*c+Y and
 533 ;;; X=(X'/c), Y=(X' mod c).  Then once you've done this transformation,
 534 ;;; you apply a final offset from column 'e' to give the virtual article.
 535 ;;;
 536 ;;; Going the other direction, you instead search on column 'd' instead
 537 ;;; of 'a', and apply everything in reverse order.
 538
 539 ;;; Convert component -> virtual:
 540 ;;; set num = num - Offset(group)
 541 ;;; find first row in Mapping where num <= 'a'
 542 ;;; num = (num-'b')*c + Position(group) + 'e'
 543
 544 ;;; Convert virtual -> component:
 545 ;;; find first row in Mapping where num <= 'd'
 546 ;;; num = num - 'e'
 547 ;;; group_pos = num mod 'c'
 548 ;;; num = (num / 'c') + 'b' + Offset(group_pos)
 549
 550 ;;; Easy no? :)
 551 ;;;
 552 ;;; Well actually, you need to keep column e offset smaller by the 'c'
 553 ;;; column for that line, and always add 1 more when going from
 554 ;;; component -> virtual.  Otherwise you run into a problem with
 555 ;;; unique reverse mapping.
 556
 557 (defun nnvirtual-map-article (article)
 558   "Return a cons of the component group and article corresponding to the given virtual ARTICLE."
 559   (let ((table nnvirtual-mapping-table)
 560         entry group-pos)
 561     (while (and table
 562                 (> article (aref (car table) 3)))
 563       (setq table (cdr table)))
 564     (when (and table
 565                (> article 0))
 566       (setq entry (car table))
 567       (setq article (- article (aref entry 4) 1))
 568       (setq group-pos (mod article (aref entry 2)))
 569       (cons (car (aref nnvirtual-mapping-offsets group-pos))
 570             (+ (/ article (aref entry 2))
 571                (aref entry 1)
 572                (cdr (aref nnvirtual-mapping-offsets group-pos)))
 573             ))
 574       ))
 575
 576
 577
 578 (defun nnvirtual-reverse-map-article (group article)
 579   "Return the virtual article number corresponding to the given component GROUP and ARTICLE."
 580   (when (numberp article)
 581     (let ((table nnvirtual-mapping-table)
 582           (group-pos 0)
 583           entry)
 584       (while (not (string= group (car (aref nnvirtual-mapping-offsets
 585                                             group-pos))))
 586         (setq group-pos (1+ group-pos)))
 587       (setq article (- article (cdr (aref nnvirtual-mapping-offsets
 588                                           group-pos))))
 589       (while (and table
 590                   (> article (aref (car table) 0)))
 591         (setq table (cdr table)))
 592       (setq entry (car table))
 593       (when (and entry
 594                  (> article 0)
 595                  (< group-pos (aref entry 2))) ; article not out of range below
 596         (+ (aref entry 4)
 597            group-pos
 598            (* (- article (aref entry 1))
 599               (aref entry 2))
 600            1))
 601       )))
 602
 603
 604 (defsubst nnvirtual-reverse-map-sequence (group articles)
 605   "Return list of virtual article numbers for all ARTICLES in GROUP.
 606 The ARTICLES should be sorted, and can be a compressed sequence.
 607 If any of the article numbers has no corresponding virtual article,
 608 then it is left out of the result."
 609   (when (numberp (cdr-safe articles))
 610     (setq articles (list articles)))
 611   (let (result a i j new-a)
 612     (while (setq a (pop articles))
 613       (if (atom a)
 614           (setq i a
 615                 j a)
 616         (setq i (car a)
 617               j (cdr a)))
 618       (while (<= i j)
 619         ;; If this is slow, you can optimize by moving article checking
 620         ;; into here.  You don't have to recompute the group-pos,
 621         ;; nor scan the table every time.
 622         (when (setq new-a (nnvirtual-reverse-map-article group i))
 623           (push new-a result))
 624         (setq i (1+ i))))
 625     (nreverse result)))
 626
 627
 628 (defun nnvirtual-partition-sequence (articles)
 629   "Return an association list of component article numbers.
 630 These are indexed by elements of nnvirtual-component-groups, based on
 631 the sequence ARTICLES of virtual article numbers.  ARTICLES should be
 632 sorted, and can be a compressed sequence. If any of the article
 633 numbers has no corresponding component article, then it is left out of
 634 the result."
 635   (when (numberp (cdr-safe articles))
 636     (setq articles (list articles)))
 637   (let ((carticles (mapcar (lambda (g) (list g))
 638                            nnvirtual-component-groups))
 639         a i j article entry)
 640     (while (setq a (pop articles))
 641       (if (atom a)
 642           (setq i a
 643                 j a)
 644         (setq i (car a)
 645               j (cdr a)))
 646       (while (<= i j)
 647         (when (setq article (nnvirtual-map-article i))
 648           (setq entry (assoc (car article) carticles))
 649           (setcdr entry (cons (cdr article) (cdr entry))))
 650         (setq i (1+ i))))
 651     (mapcar (lambda (x) (setcdr x (nreverse (cdr x))))
 652             carticles)
 653     carticles))
 654
 655
 656 (defun nnvirtual-create-mapping ()
 657   "Build the tables necessary to map between component (group, article) to virtual article.
 658 Generate the set of read messages and marks for the virtual group
 659 based on the marks on the component groups."
 660   (let ((cnt 0)
 661         (tot 0)
 662         (M 0)
 663         (i 0)
 664         actives all-unreads all-marks
 665         active min max size unreads marks
 666         next-M next-tot
 667         reads beg)
 668     ;; Ok, we loop over all component groups and collect a lot of
 669     ;; information:
 670     ;; Into actives we place (g size max), where size is max-min+1.
 671     ;; Into all-unreads we put (g unreads).
 672     ;; Into all-marks we put (g marks).
 673     ;; We also increment cnt and tot here, and compute M (max of sizes).
 674     (mapc (lambda (g)
 675             (setq active (gnus-activate-group g)
 676                   min (car active)
 677                   max (cdr active))
 678             (when (and active (>= max min) (not (zerop max)))
 679               ;; store active information
 680               (push (list g (- max min -1) max) actives)
 681               ;; collect unread/mark info for later
 682               (setq unreads (gnus-list-of-unread-articles g))
 683               (setq marks (gnus-info-marks (gnus-get-info g)))
 684               (when gnus-use-cache
 685                 (push (cons 'cache
 686                             (gnus-cache-articles-in-group g))
 687                       marks))
 688               (push (cons g unreads) all-unreads)
 689               (push (cons g marks) all-marks)
 690               ;; count groups, total #articles, and max size
 691               (setq size (- max min -1))
 692               (setq cnt (1+ cnt)
 693                     tot (+ tot size)
 694                     M (max M size))))
 695           nnvirtual-component-groups)
 696
 697     ;; Number of articles in the virtual group.
 698     (setq nnvirtual-mapping-len tot)
 699
 700
 701     ;; We want the actives list sorted by size, to build the tables.
 702     (setq actives (sort actives (lambda (g1 g2) (< (nth 1 g1) (nth 1 g2)))))
 703
 704     ;; Build the offset table.  Largest sized groups are at the front.
 705     (setq nnvirtual-mapping-offsets
 706           (vconcat
 707            (nreverse
 708             (mapcar (lambda (entry)
 709                       (cons (nth 0 entry)
 710                             (- (nth 2 entry) M)))
 711                     actives))))
 712
 713     ;; Build the mapping table.
 714     (setq nnvirtual-mapping-table nil)
 715     (setq actives (mapcar (lambda (entry) (nth 1 entry)) actives))
 716     (while actives
 717       (setq size (car actives))
 718       (setq next-M (- M size))
 719       (setq next-tot (- tot (* cnt size)))
 720       ;; make current row in table
 721       (push (vector M next-M cnt tot (- next-tot cnt))
 722             nnvirtual-mapping-table)
 723       ;; update M and tot
 724       (setq M next-M)
 725       (setq tot next-tot)
 726       ;; subtract the current size from all entries.
 727       (setq actives (mapcar (lambda (x) (- x size)) actives))
 728       ;; remove anything that went to 0.
 729       (while (and actives
 730                   (= (car actives) 0))
 731         (pop actives)
 732         (setq cnt (- cnt 1))))
 733
 734
 735     ;; Now that the mapping tables are generated, we can convert
 736     ;; and combine the separate component unreads and marks lists
 737     ;; into single lists of virtual article numbers.
 738     (setq unreads (apply 'nnvirtual-merge-sorted-lists
 739                          (mapcar (lambda (x)
 740                                    (nnvirtual-reverse-map-sequence
 741                                     (car x) (cdr x)))
 742                                  all-unreads)))
 743     (setq marks (mapcar
 744                  (lambda (type)
 745                    (cons (cdr type)
 746                          (gnus-compress-sequence
 747                           (apply
 748                            'nnvirtual-merge-sorted-lists
 749                            (mapcar (lambda (x)
 750                                      (nnvirtual-reverse-map-sequence
 751                                       (car x)
 752                                       (cdr (assq (cdr type) (cdr x)))))
 753                                    all-marks)))))
 754                  gnus-article-mark-lists))
 755
 756     ;; Remove any empty marks lists, and store.
 757     (setq nnvirtual-mapping-marks nil)
 758     (while marks
 759       (if (cdr (car marks))
 760           (push (car marks) nnvirtual-mapping-marks))
 761       (setq marks (cdr marks)))
 762
 763     ;; We need to convert the unreads to reads.  We compress the
 764     ;; sequence as we go, otherwise it could be huge.
 765     (while (and (<= (incf i) nnvirtual-mapping-len)
 766                 unreads)
 767       (if (= i (car unreads))
 768           (setq unreads (cdr unreads))
 769         ;; try to get a range.
 770         (setq beg i)
 771         (while (and (<= (incf i) nnvirtual-mapping-len)
 772                     (not (= i (car unreads)))))
 773         (setq i (- i 1))
 774         (if (= i beg)
 775             (push i reads)
 776           (push (cons beg i) reads))
 777         ))
 778     (when (<= i nnvirtual-mapping-len)
 779       (if (= i nnvirtual-mapping-len)
 780           (push i reads)
 781         (push (cons i nnvirtual-mapping-len) reads)))
 782
 783     ;; Store the reads list for later use.
 784     (setq nnvirtual-mapping-reads (nreverse reads))
 785
 786     ;; Throw flag to show we changed the info.
 787     (setq nnvirtual-info-installed nil)
 788     ))
 789
 790 (provide 'nnvirtual)
 791
 792 ;;; nnvirtual.el ends here