git.chise.org Git - elisp/gnus.git-/blob - lisp/nnweb.el

   1 ;;; nnweb.el --- retrieving articles via web search engines
   2 ;; Copyright (C) 1996,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'nnoo)
  34 (require 'message)
  35 (require 'gnus-util)
  36 (require 'gnus)
  37 (require 'nnmail)
  38 (require 'mm-util)
  39 (eval-when-compile
  40   (ignore-errors
  41     (require 'w3)
  42     (require 'url)
  43     (require 'w3-forms)))
  44 ;; Report failure to find w3 at load time if appropriate.
  45 (eval '(progn
  46          (require 'w3)
  47          (require 'url)
  48          (require 'w3-forms)))
  49
  50 (nnoo-declare nnweb)
  51
  52 (defvoo nnweb-directory (nnheader-concat gnus-directory "nnweb/")
  53   "Where nnweb will save its files.")
  54
  55 (defvoo nnweb-type 'dejanews
  56   "What search engine type is being used.
  57 Valid types include `dejanews', `dejanewsold', `reference',
  58 and `altavista'.")
  59
  60 (defvar nnweb-type-definition
  61   '((dejanews
  62      (article . ignore)
  63      (id . "http://search.dejanews.com/msgid.xp?MID=%s&fmt=text")
  64      (map . nnweb-dejanews-create-mapping)
  65      (search . nnweb-dejanews-search)
  66      (address . "http://www.deja.com/=dnc/qs.xp")
  67      (identifier . nnweb-dejanews-identity))
  68     (dejanewsold
  69      (article . ignore)
  70      (map . nnweb-dejanews-create-mapping)
  71      (search . nnweb-dejanewsold-search)
  72      (address . "http://www.deja.com/dnquery.xp")
  73      (identifier . nnweb-dejanews-identity))
  74     (reference
  75      (article . nnweb-reference-wash-article)
  76      (map . nnweb-reference-create-mapping)
  77      (search . nnweb-reference-search)
  78      (address . "http://www.reference.com/cgi-bin/pn/go")
  79      (identifier . identity))
  80     (altavista
  81      (article . nnweb-altavista-wash-article)
  82      (map . nnweb-altavista-create-mapping)
  83      (search . nnweb-altavista-search)
  84      (address . "http://www.altavista.digital.com/cgi-bin/query")
  85      (id . "/cgi-bin/news?id@%s")
  86      (identifier . identity)))
  87   "Type-definition alist.")
  88
  89 (defvoo nnweb-search nil
  90   "Search string to feed to DejaNews.")
  91
  92 (defvoo nnweb-max-hits 999
  93   "Maximum number of hits to display.")
  94
  95 (defvoo nnweb-ephemeral-p nil
  96   "Whether this nnweb server is ephemeral.")
  97
  98 ;;; Internal variables
  99
 100 (defvoo nnweb-articles nil)
 101 (defvoo nnweb-buffer nil)
 102 (defvoo nnweb-group-alist nil)
 103 (defvoo nnweb-group nil)
 104 (defvoo nnweb-hashtb nil)
 105
 106 ;;; Interface functions
 107
 108 (nnoo-define-basics nnweb)
 109
 110 (deffoo nnweb-retrieve-headers (articles &optional group server fetch-old)
 111   (nnweb-possibly-change-server group server)
 112   (save-excursion
 113     (set-buffer nntp-server-buffer)
 114     (erase-buffer)
 115     (let (article header)
 116       (mm-with-unibyte-current-buffer
 117         (while (setq article (pop articles))
 118           (when (setq header (cadr (assq article nnweb-articles)))
 119             (nnheader-insert-nov header))))
 120       'nov)))
 121
 122 (deffoo nnweb-request-scan (&optional group server)
 123   (nnweb-possibly-change-server group server)
 124   (setq nnweb-hashtb (gnus-make-hashtable 4095))
 125   (funcall (nnweb-definition 'map))
 126   (unless nnweb-ephemeral-p
 127     (nnweb-write-active)
 128     (nnweb-write-overview group)))
 129
 130 (deffoo nnweb-request-group (group &optional server dont-check)
 131   (nnweb-possibly-change-server nil server)
 132   (when (and group
 133              (not (equal group nnweb-group))
 134              (not nnweb-ephemeral-p))
 135     (let ((info (assoc group nnweb-group-alist)))
 136       (when info
 137         (setq nnweb-group group)
 138         (setq nnweb-type (nth 2 info))
 139         (setq nnweb-search (nth 3 info))
 140         (unless dont-check
 141           (nnweb-read-overview group)))))
 142   (unless dont-check
 143     (nnweb-request-scan group))
 144   (cond
 145    ((not nnweb-articles)
 146     (nnheader-report 'nnweb "No matching articles"))
 147    (t
 148     (let ((active (if nnweb-ephemeral-p
 149                       (cons (caar nnweb-articles)
 150                             (caar (last nnweb-articles)))
 151                     (cadr (assoc group nnweb-group-alist)))))
 152       (nnheader-report 'nnweb "Opened group %s" group)
 153       (nnheader-insert
 154        "211 %d %d %d %s\n" (length nnweb-articles)
 155        (car active) (cdr active) group)))))
 156
 157 (deffoo nnweb-close-group (group &optional server)
 158   (nnweb-possibly-change-server group server)
 159   (when (gnus-buffer-live-p nnweb-buffer)
 160     (save-excursion
 161       (set-buffer nnweb-buffer)
 162       (set-buffer-modified-p nil)
 163       (kill-buffer nnweb-buffer)))
 164   t)
 165
 166 (deffoo nnweb-request-article (article &optional group server buffer)
 167   (nnweb-possibly-change-server group server)
 168   (save-excursion
 169     (set-buffer (or buffer nntp-server-buffer))
 170     (let* ((header (cadr (assq article nnweb-articles)))
 171            (url (and header (mail-header-xref header))))
 172       (when (or (and url
 173                      (mm-with-unibyte-current-buffer
 174                        (nnweb-fetch-url url)))
 175                 (and (stringp article)
 176                      (nnweb-definition 'id t)
 177                      (let ((fetch (nnweb-definition 'id))
 178                            art)
 179                        (when (string-match "^<\\(.*\\)>$" article)
 180                          (setq art (match-string 1 article)))
 181                        (and fetch
 182                             art
 183                             (mm-with-unibyte-current-buffer
 184                               (nnweb-fetch-url
 185                                (format fetch article)))))))
 186         (unless nnheader-callback-function
 187           (funcall (nnweb-definition 'article))
 188           (nnweb-decode-entities))
 189         (nnheader-report 'nnweb "Fetched article %s" article)
 190         t))))
 191
 192 (deffoo nnweb-close-server (&optional server)
 193   (when (and (nnweb-server-opened server)
 194              (gnus-buffer-live-p nnweb-buffer))
 195     (save-excursion
 196       (set-buffer nnweb-buffer)
 197       (set-buffer-modified-p nil)
 198       (kill-buffer nnweb-buffer)))
 199   (nnoo-close-server 'nnweb server))
 200
 201 (deffoo nnweb-request-list (&optional server)
 202   (nnweb-possibly-change-server nil server)
 203   (save-excursion
 204     (set-buffer nntp-server-buffer)
 205     (nnmail-generate-active nnweb-group-alist)
 206     t))
 207
 208 (deffoo nnweb-request-update-info (group info &optional server)
 209   (nnweb-possibly-change-server group server)
 210   ;;(setcar (cddr info) nil)
 211   )
 212
 213 (deffoo nnweb-asynchronous-p ()
 214   t)
 215
 216 (deffoo nnweb-request-create-group (group &optional server args)
 217   (nnweb-possibly-change-server nil server)
 218   (nnweb-request-delete-group group)
 219   (push `(,group ,(cons 1 0) ,@args) nnweb-group-alist)
 220   (nnweb-write-active)
 221   t)
 222
 223 (deffoo nnweb-request-delete-group (group &optional force server)
 224   (nnweb-possibly-change-server group server)
 225   (gnus-pull group nnweb-group-alist t)
 226   (nnweb-write-active)
 227   (gnus-delete-file (nnweb-overview-file group))
 228   t)
 229
 230 (nnoo-define-skeleton nnweb)
 231
 232 ;;; Internal functions
 233
 234 (defun nnweb-read-overview (group)
 235   "Read the overview of GROUP and build the map."
 236   (when (file-exists-p (nnweb-overview-file group))
 237     (mm-with-unibyte-buffer
 238       (nnheader-insert-file-contents (nnweb-overview-file group))
 239       (goto-char (point-min))
 240       (let (header)
 241         (while (not (eobp))
 242           (setq header (nnheader-parse-nov))
 243           (forward-line 1)
 244           (push (list (mail-header-number header)
 245                       header (mail-header-xref header))
 246                 nnweb-articles)
 247           (nnweb-set-hashtb header (car nnweb-articles)))))))
 248
 249 (defun nnweb-write-overview (group)
 250   "Write the overview file for GROUP."
 251   (with-temp-file (nnweb-overview-file group)
 252     (let ((articles nnweb-articles))
 253       (while articles
 254         (nnheader-insert-nov (cadr (pop articles)))))))
 255
 256 (defun nnweb-set-hashtb (header data)
 257   (gnus-sethash (nnweb-identifier (mail-header-xref header))
 258                 data nnweb-hashtb))
 259
 260 (defun nnweb-get-hashtb (url)
 261   (gnus-gethash (nnweb-identifier url) nnweb-hashtb))
 262
 263 (defun nnweb-identifier (ident)
 264   (funcall (nnweb-definition 'identifier) ident))
 265
 266 (defun nnweb-overview-file (group)
 267   "Return the name of the overview file of GROUP."
 268   (nnheader-concat nnweb-directory group ".overview"))
 269
 270 (defun nnweb-write-active ()
 271   "Save the active file."
 272   (gnus-make-directory nnweb-directory)
 273   (with-temp-file (nnheader-concat nnweb-directory "active")
 274     (prin1 `(setq nnweb-group-alist ',nnweb-group-alist) (current-buffer))))
 275
 276 (defun nnweb-read-active ()
 277   "Read the active file."
 278   (load (nnheader-concat nnweb-directory "active") t t t))
 279
 280 (defun nnweb-definition (type &optional noerror)
 281   "Return the definition of TYPE."
 282   (let ((def (cdr (assq type (assq nnweb-type nnweb-type-definition)))))
 283     (when (and (not def)
 284                (not noerror))
 285       (error "Undefined definition %s" type))
 286     def))
 287
 288 (defun nnweb-possibly-change-server (&optional group server)
 289   (nnweb-init server)
 290   (when server
 291     (unless (nnweb-server-opened server)
 292       (nnweb-open-server server)))
 293   (unless nnweb-group-alist
 294     (nnweb-read-active))
 295   (when group
 296     (when (and (not nnweb-ephemeral-p)
 297                (not (equal group nnweb-group)))
 298       (nnweb-request-group group nil t))))
 299
 300 (defun nnweb-init (server)
 301   "Initialize buffers and such."
 302   (unless (gnus-buffer-live-p nnweb-buffer)
 303     (setq nnweb-buffer
 304           (save-excursion
 305             (let ((multibyte (default-value 'enable-multibyte-characters)))
 306               (unwind-protect
 307                   (progn
 308                     (setq-default enable-multibyte-characters nil)
 309                     (nnheader-set-temp-buffer
 310                      (format " *nnweb %s %s %s*"
 311                              nnweb-type nnweb-search server)))
 312                 (setq-default enable-multibyte-characters multibyte))
 313               (current-buffer))))))
 314
 315 (defun nnweb-fetch-url (url)
 316   (let (buf)
 317     (save-excursion
 318       (if (not nnheader-callback-function)
 319           (progn
 320             (with-temp-buffer
 321               (mm-enable-multibyte)
 322               (let ((coding-system-for-read 'binary)
 323                     (coding-system-for-write 'binary)
 324                     (default-process-coding-system 'binary))
 325                 (nnweb-insert url))
 326               (setq buf (buffer-string)))
 327             (erase-buffer)
 328             (insert buf)
 329             t)
 330         (nnweb-url-retrieve-asynch
 331          url 'nnweb-callback (current-buffer) nnheader-callback-function)
 332         t))))
 333
 334 (defun nnweb-callback (buffer callback)
 335   (when (gnus-buffer-live-p url-working-buffer)
 336     (save-excursion
 337       (set-buffer url-working-buffer)
 338       (funcall (nnweb-definition 'article))
 339       (nnweb-decode-entities)
 340       (set-buffer buffer)
 341       (goto-char (point-max))
 342       (insert-buffer-substring url-working-buffer))
 343     (funcall callback t)
 344     (gnus-kill-buffer url-working-buffer)))
 345
 346 (defun nnweb-url-retrieve-asynch (url callback &rest data)
 347   (let ((url-request-method "GET")
 348         (old-asynch url-be-asynchronous)
 349         (url-request-data nil)
 350         (url-request-extra-headers nil)
 351         (url-working-buffer (generate-new-buffer-name " *nnweb*")))
 352     (setq-default url-be-asynchronous t)
 353     (save-excursion
 354       (set-buffer (get-buffer-create url-working-buffer))
 355       (setq url-current-callback-data data
 356             url-be-asynchronous t
 357             url-current-callback-func callback)
 358       (url-retrieve url))
 359     (setq-default url-be-asynchronous old-asynch)))
 360
 361 ;;;
 362 ;;; DejaNews functions.
 363 ;;;
 364
 365 (defun nnweb-dejanews-create-mapping ()
 366   "Perform the search and create an number-to-url alist."
 367   (save-excursion
 368     (set-buffer nnweb-buffer)
 369     (erase-buffer)
 370     (when (funcall (nnweb-definition 'search) nnweb-search)
 371       (let ((i 0)
 372             (more t)
 373             (case-fold-search t)
 374             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 375                         (cons 1 0)))
 376             subject date from
 377             map url parse a table group text)
 378         (while more
 379           ;; Go through all the article hits on this page.
 380           (goto-char (point-min))
 381           (setq parse (w3-parse-buffer (current-buffer))
 382                 table (nth 1 (nnweb-parse-find-all 'table parse)))
 383           (dolist (row (nth 2 (car (nth 2 table))))
 384             (setq a (nnweb-parse-find 'a row)
 385                   url (cdr (assq 'href (nth 1 a)))
 386                   text (nreverse (nnweb-text row)))
 387             (when a
 388               (setq subject (nth 4 text)
 389                     group (nth 2 text)
 390                     date (nth 1 text)
 391                     from (nth 0 text))
 392               (if (string-match "\\([0-9]+\\)/\\([0-9]+\\)/\\([0-9]+\\)" date)
 393                   (setq date (format "%s %s 00:00:00 %s"
 394                                      (car (rassq (string-to-number
 395                                                   (match-string 2 date))
 396                                                  parse-time-months))
 397                                      (match-string 3 date)
 398                                      (match-string 1 date)))
 399                 (setq date "Jan 1 00:00:00 0000"))
 400               (incf i)
 401               (setq url (concat url "&fmt=text"))
 402               (unless (nnweb-get-hashtb url)
 403                 (push
 404                  (list
 405                   (incf (cdr active))
 406                   (make-full-mail-header
 407                    (cdr active) (concat subject " (" group ")") from date
 408                    (concat "<" (nnweb-identifier url) "@dejanews>")
 409                    nil 0 0 url))
 410                  map)
 411                 (nnweb-set-hashtb (cadar map) (car map)))))
 412           ;; See whether there is a "Get next 20 hits" button here.
 413           (goto-char (point-min))
 414           (if (or (not (re-search-forward
 415                         "HREF=\"\\([^\"]+\\)\"[<>b]+Next result" nil t))
 416                   (>= i nnweb-max-hits))
 417               (setq more nil)
 418             ;; Yup -- fetch it.
 419             (setq more (match-string 1))
 420             (erase-buffer)
 421             (url-insert-file-contents more)))
 422         ;; Return the articles in the right order.
 423         (setq nnweb-articles
 424               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 425
 426 (defun nnweb-dejanews-search (search)
 427   (nnweb-insert
 428    (concat
 429     (nnweb-definition 'address)
 430     "?"
 431     (nnweb-encode-www-form-urlencoded
 432      `(("ST" . "PS")
 433        ("svcclass" . "dnyr")
 434        ("QRY" . ,search)
 435        ("defaultOp" . "AND")
 436        ("DBS" . "1")
 437        ("OP" . "dnquery.xp")
 438        ("LNG" . "ALL")
 439        ("maxhits" . "100")
 440        ("threaded" . "0")
 441        ("format" . "verbose2")
 442        ("showsort" . "date")
 443        ("agesign" . "1")
 444        ("ageweight" . "1")))))
 445   t)
 446
 447 (defun nnweb-dejanewsold-search (search)
 448   (nnweb-fetch-form
 449    (nnweb-definition 'address)
 450    `(("query" . ,search)
 451      ("defaultOp" . "AND")
 452      ("svcclass" . "dnold")
 453      ("maxhits" . "100")
 454      ("format" . "verbose2")
 455      ("threaded" . "0")
 456      ("showsort" . "date")
 457      ("agesign" . "1")
 458      ("ageweight" . "1")))
 459   t)
 460
 461 (defun nnweb-dejanews-identity (url)
 462   "Return an unique identifier based on URL."
 463   (if (string-match "AN=\\([0-9]+\\)" url)
 464       (match-string 1 url)
 465     url))
 466
 467 ;;;
 468 ;;; InReference
 469 ;;;
 470
 471 (defun nnweb-reference-create-mapping ()
 472   "Perform the search and create an number-to-url alist."
 473   (save-excursion
 474     (set-buffer nnweb-buffer)
 475     (erase-buffer)
 476     (when (funcall (nnweb-definition 'search) nnweb-search)
 477       (let ((i 0)
 478             (more t)
 479             (case-fold-search t)
 480             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 481                         (cons 1 0)))
 482             Subject Score Date Newsgroups From Message-ID
 483             map url)
 484         (while more
 485           ;; Go through all the article hits on this page.
 486           (goto-char (point-min))
 487           (search-forward "</pre><hr>" nil t)
 488           (delete-region (point-min) (point))
 489                                         ;(nnweb-decode-entities)
 490           (goto-char (point-min))
 491           (while (re-search-forward "^ +[0-9]+\\." nil t)
 492             (narrow-to-region
 493              (point)
 494              (if (re-search-forward "^$" nil t)
 495                  (match-beginning 0)
 496                (point-max)))
 497             (goto-char (point-min))
 498             (when (looking-at ".*href=\"\\([^\"]+\\)\"")
 499               (setq url (match-string 1)))
 500             (nnweb-remove-markup)
 501             (goto-char (point-min))
 502             (while (search-forward "\t" nil t)
 503               (replace-match " "))
 504             (goto-char (point-min))
 505             (while (re-search-forward "^\\([^:]+\\): \\(.*\\)$" nil t)
 506               (set (intern (match-string 1)) (match-string 2)))
 507             (widen)
 508             (search-forward "</pre>" nil t)
 509             (incf i)
 510             (unless (nnweb-get-hashtb url)
 511               (push
 512                (list
 513                 (incf (cdr active))
 514                 (make-full-mail-header
 515                  (cdr active) (concat  "(" Newsgroups ") " Subject) From Date
 516                  Message-ID
 517                  nil 0 (string-to-int Score) url))
 518                map)
 519               (nnweb-set-hashtb (cadar map) (car map))))
 520           (setq more nil))
 521         ;; Return the articles in the right order.
 522         (setq nnweb-articles
 523               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 524
 525 (defun nnweb-reference-wash-article ()
 526   (let ((case-fold-search t))
 527     (goto-char (point-min))
 528     (re-search-forward "^</center><hr>" nil t)
 529     (delete-region (point-min) (point))
 530     (search-forward "<pre>" nil t)
 531     (forward-line -1)
 532     (let ((body (point-marker)))
 533       (search-forward "</pre>" nil t)
 534       (delete-region (point) (point-max))
 535       (nnweb-remove-markup)
 536       (goto-char (point-min))
 537       (while (looking-at " *$")
 538         (gnus-delete-line))
 539       (narrow-to-region (point-min) body)
 540       (while (and (re-search-forward "^$" nil t)
 541                   (not (eobp)))
 542         (gnus-delete-line))
 543       (goto-char (point-min))
 544       (while (looking-at "\\(^[^ ]+:\\) *")
 545         (replace-match "\\1 " t)
 546         (forward-line 1))
 547       (goto-char (point-min))
 548       (when (re-search-forward "^References:" nil t)
 549         (narrow-to-region
 550          (point) (if (re-search-forward "^$\\|^[^:]+:" nil t)
 551                      (match-beginning 0)
 552                    (point-max)))
 553         (goto-char (point-min))
 554         (while (not (eobp))
 555           (unless (looking-at "References")
 556             (insert "\t")
 557             (forward-line 1)))
 558         (goto-char (point-min))
 559         (while (search-forward "," nil t)
 560           (replace-match " " t t)))
 561       (widen)
 562       (set-marker body nil))))
 563
 564 (defun nnweb-reference-search (search)
 565   (url-insert-file-contents
 566    (concat
 567     (nnweb-definition 'address)
 568     "?"
 569     (nnweb-encode-www-form-urlencoded
 570      `(("search" . "advanced")
 571        ("querytext" . ,search)
 572        ("subj" . "")
 573        ("name" . "")
 574        ("login" . "")
 575        ("host" . "")
 576        ("organization" . "")
 577        ("groups" . "")
 578        ("keywords" . "")
 579        ("choice" . "Search")
 580        ("startmonth" . "Jul")
 581        ("startday" . "25")
 582        ("startyear" . "1996")
 583        ("endmonth" . "Aug")
 584        ("endday" . "24")
 585        ("endyear" . "1996")
 586        ("mode" . "Quick")
 587        ("verbosity" . "Verbose")
 588        ("ranking" . "Relevance")
 589        ("first" . "1")
 590        ("last" . "25")
 591        ("score" . "50")))))
 592   (setq buffer-file-name nil)
 593   t)
 594
 595 ;;;
 596 ;;; Alta Vista
 597 ;;;
 598
 599 (defun nnweb-altavista-create-mapping ()
 600   "Perform the search and create an number-to-url alist."
 601   (save-excursion
 602     (set-buffer nnweb-buffer)
 603     (erase-buffer)
 604     (let ((part 0))
 605       (when (funcall (nnweb-definition 'search) nnweb-search part)
 606         (let ((i 0)
 607               (more t)
 608               (case-fold-search t)
 609               (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 610                           (cons 1 0)))
 611               subject date from id group
 612               map url)
 613           (while more
 614             ;; Go through all the article hits on this page.
 615             (goto-char (point-min))
 616             (search-forward "<dt>" nil t)
 617             (delete-region (point-min) (match-beginning 0))
 618             (goto-char (point-min))
 619             (while (search-forward "<dt>" nil t)
 620               (replace-match "\n<blubb>"))
 621             (nnweb-decode-entities)
 622             (goto-char (point-min))
 623             (while (re-search-forward "<blubb>.*href=\"\\([^\"]+\\)\"><strong>\\([^>]*\\)</strong></a><dd>\\([^-]+\\)- <b>\\([^<]+\\)<.*href=\"news:\\([^\"]+\\)\">.*\">\\(.+\\)</a><P>"
 624                                       nil t)
 625               (setq url (match-string 1)
 626                     subject (match-string 2)
 627                     date (match-string 3)
 628                     group (match-string 4)
 629                     id (concat "<" (match-string 5) ">")
 630                     from (match-string 6))
 631               (incf i)
 632               (unless (nnweb-get-hashtb url)
 633                 (push
 634                  (list
 635                   (incf (cdr active))
 636                   (make-full-mail-header
 637                    (cdr active) (concat  "(" group ") " subject) from date
 638                    id nil 0 0 url))
 639                  map)
 640                 (nnweb-set-hashtb (cadar map) (car map))))
 641             ;; See if we want more.
 642             (when (or (not nnweb-articles)
 643                       (>= i nnweb-max-hits)
 644                       (not (funcall (nnweb-definition 'search)
 645                                     nnweb-search (incf part))))
 646               (setq more nil)))
 647           ;; Return the articles in the right order.
 648           (setq nnweb-articles
 649                 (sort (nconc nnweb-articles map) 'car-less-than-car)))))))
 650
 651 (defun nnweb-altavista-wash-article ()
 652   (goto-char (point-min))
 653   (let ((case-fold-search t))
 654     (when (re-search-forward "^<strong>" nil t)
 655       (delete-region (point-min) (match-beginning 0)))
 656     (goto-char (point-min))
 657     (while (looking-at "<strong>\\([^ ]+\\) +</strong> +\\(.*\\)$")
 658       (replace-match "\\1: \\2" t)
 659       (forward-line 1))
 660     (when (re-search-backward "^References:" nil t)
 661       (narrow-to-region (point) (progn (forward-line 1) (point)))
 662       (goto-char (point-min))
 663       (while (re-search-forward "<A.*\\?id@\\([^\"]+\\)\">[0-9]+</A>" nil t)
 664         (replace-match "&lt;\\1&gt; " t)))
 665     (widen)
 666     (nnweb-remove-markup)))
 667
 668 (defun nnweb-altavista-search (search &optional part)
 669   (url-insert-file-contents
 670    (concat
 671     (nnweb-definition 'address)
 672     "?"
 673     (nnweb-encode-www-form-urlencoded
 674      `(("pg" . "aq")
 675        ("what" . "news")
 676        ,@(when part `(("stq" . ,(int-to-string (* part 30)))))
 677        ("fmt" . "d")
 678        ("q" . ,search)
 679        ("r" . "")
 680        ("d0" . "")
 681        ("d1" . "")))))
 682   (setq buffer-file-name nil)
 683   t)
 684
 685 ;;;
 686 ;;; General web/w3 interface utility functions
 687 ;;;
 688
 689 (defun nnweb-insert-html (parse)
 690   "Insert HTML based on a w3 parse tree."
 691   (if (stringp parse)
 692       (insert parse)
 693     (insert "<" (symbol-name (car parse)) " ")
 694     (insert (mapconcat
 695              (lambda (param)
 696                (concat (symbol-name (car param)) "="
 697                        (prin1-to-string
 698                         (if (consp (cdr param))
 699                             (cadr param)
 700                           (cdr param)))))
 701              (nth 1 parse)
 702              " "))
 703     (insert ">\n")
 704     (mapcar 'nnweb-insert-html (nth 2 parse))
 705     (insert "</" (symbol-name (car parse)) ">\n")))
 706
 707 (defun nnweb-encode-www-form-urlencoded (pairs)
 708   "Return PAIRS encoded for forms."
 709   (mapconcat
 710    (function
 711     (lambda (data)
 712       (concat (w3-form-encode-xwfu (car data)) "="
 713               (w3-form-encode-xwfu (cdr data)))))
 714    pairs "&"))
 715
 716 (defun nnweb-fetch-form (url pairs)
 717   "Fetch a form from URL with PAIRS as the data using the POST method."
 718   (let ((url-request-data (nnweb-encode-www-form-urlencoded pairs))
 719         (url-request-method "POST")
 720         (url-request-extra-headers
 721          '(("Content-type" . "application/x-www-form-urlencoded"))))
 722     (url-insert-file-contents url)
 723     (setq buffer-file-name nil))
 724   t)
 725
 726 (defun nnweb-decode-entities ()
 727   "Decode all HTML entities."
 728   (goto-char (point-min))
 729   (while (re-search-forward "&\\([a-z]+\\);" nil t)
 730     (replace-match (char-to-string (or (cdr (assq (intern (match-string 1))
 731                                                   w3-html-entities))
 732                                        ?#))
 733                    t t)))
 734
 735 (defun nnweb-remove-markup ()
 736   "Remove all HTML markup, leaving just plain text."
 737   (goto-char (point-min))
 738   (while (search-forward "<!--" nil t)
 739     (delete-region (match-beginning 0)
 740                    (or (search-forward "-->" nil t)
 741                        (point-max))))
 742   (goto-char (point-min))
 743   (while (re-search-forward "<[^>]+>" nil t)
 744     (replace-match "" t t)))
 745
 746 (defun nnweb-insert (url)
 747   "Insert the contents from an URL in the current buffer."
 748   (let ((name buffer-file-name))
 749     (url-insert-file-contents url)
 750     (setq buffer-file-name name)))
 751
 752 (defun nnweb-parse-find (type parse &optional maxdepth)
 753   "Find the element of TYPE in PARSE."
 754   (catch 'found
 755     (nnweb-parse-find-1 type parse maxdepth)))
 756
 757 (defun nnweb-parse-find-1 (type contents maxdepth)
 758   (when (or (null maxdepth)
 759             (not (zerop maxdepth)))
 760     (when (consp contents)
 761       (when (eq (car contents) type)
 762         (throw 'found contents))
 763       (when (listp (cdr contents))
 764         (dolist (element contents)
 765           (when (consp element)
 766             (nnweb-parse-find-1 type element
 767                                 (and maxdepth (1- maxdepth)))))))))
 768
 769 (defun nnweb-parse-find-all (type parse)
 770   "Find all elements of TYPE in PARSE."
 771   (catch 'found
 772     (nnweb-parse-find-all-1 type parse)))
 773
 774 (defun nnweb-parse-find-all-1 (type contents)
 775   (let (result)
 776     (when (consp contents)
 777       (if (eq (car contents) type)
 778           (push contents result)
 779         (when (listp (cdr contents))
 780           (dolist (element contents)
 781             (when (consp element)
 782               (setq result
 783                     (nconc result (nnweb-parse-find-all-1 type element))))))))
 784     result))
 785
 786 (defvar nnweb-text)
 787 (defun nnweb-text (parse)
 788   "Return a list of text contents in PARSE."
 789   (let ((nnweb-text nil))
 790     (nnweb-text-1 parse)
 791     (nreverse nnweb-text)))
 792
 793 (defun nnweb-text-1 (contents)
 794   (dolist (element contents)
 795     (if (stringp element)
 796         (push element nnweb-text)
 797       (when (and (consp element)
 798                  (listp (cdr element)))
 799         (nnweb-text-1 element)))))
 800
 801 (provide 'nnweb)
 802
 803 ;;; nnweb.el ends here