git.chise.org Git - elisp/gnus.git-/blob - lisp/nnweb.el

   1 ;;; nnweb.el --- retrieving articles via web search engines
   2 ;; Copyright (C) 1996,97,98,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;; Keywords: news
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Note: You need to have `url' and `w3' installed for this
  27 ;; backend to work.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32
  33 (require 'nnoo)
  34 (require 'message)
  35 (require 'gnus-util)
  36 (require 'gnus)
  37 (require 'nnmail)
  38 (eval-when-compile
  39   (ignore-errors
  40     (require 'w3)
  41     (require 'url)
  42     (require 'w3-forms)))
  43 ;; Report failure to find w3 at load time if appropriate.
  44 (eval '(progn
  45          (require 'w3)
  46          (require 'url)
  47          (require 'w3-forms)))
  48
  49 (nnoo-declare nnweb)
  50
  51 (defvoo nnweb-directory (nnheader-concat gnus-directory "nnweb/")
  52   "Where nnweb will save its files.")
  53
  54 (defvoo nnweb-type 'dejanews
  55   "What search engine type is being used.
  56 Valid types include `dejanews', `dejanewsold', `reference',
  57 and `altavista'.")
  58
  59 (defvoo nnweb-type-definition
  60   '((dejanews
  61      (article . nnweb-dejanews-wash-article)
  62      (map . nnweb-dejanews-create-mapping)
  63      (search . nnweb-dejanews-search)
  64      (address . "http://x8.dejanews.com/dnquery.xp")
  65      (identifier . nnweb-dejanews-identity))
  66     (dejanewsold
  67      (article . nnweb-dejanews-wash-article)
  68      (map . nnweb-dejanews-create-mapping)
  69      (search . nnweb-dejanewsold-search)
  70      (address . "http://x8.dejanews.com/dnquery.xp")
  71      (identifier . nnweb-dejanews-identity))
  72     (reference
  73      (article . nnweb-reference-wash-article)
  74      (map . nnweb-reference-create-mapping)
  75      (search . nnweb-reference-search)
  76      (address . "http://www.reference.com/cgi-bin/pn/go")
  77      (identifier . identity))
  78     (altavista
  79      (article . nnweb-altavista-wash-article)
  80      (map . nnweb-altavista-create-mapping)
  81      (search . nnweb-altavista-search)
  82      (address . "http://www.altavista.digital.com/cgi-bin/query")
  83      (id . "/cgi-bin/news?id@%s")
  84      (identifier . identity)))
  85   "Type-definition alist.")
  86
  87 (defvoo nnweb-search nil
  88   "Search string to feed to DejaNews.")
  89
  90 (defvoo nnweb-max-hits 999
  91   "Maximum number of hits to display.")
  92
  93 (defvoo nnweb-ephemeral-p nil
  94   "Whether this nnweb server is ephemeral.")
  95
  96 ;;; Internal variables
  97
  98 (defvoo nnweb-articles nil)
  99 (defvoo nnweb-buffer nil)
 100 (defvoo nnweb-group-alist nil)
 101 (defvoo nnweb-group nil)
 102 (defvoo nnweb-hashtb nil)
 103
 104 ;;; Interface functions
 105
 106 (nnoo-define-basics nnweb)
 107
 108 (deffoo nnweb-retrieve-headers (articles &optional group server fetch-old)
 109   (nnweb-possibly-change-server group server)
 110   (save-excursion
 111     (set-buffer nntp-server-buffer)
 112     (erase-buffer)
 113     (let (article header)
 114       (while (setq article (pop articles))
 115         (when (setq header (cadr (assq article nnweb-articles)))
 116           (nnheader-insert-nov header)))
 117       'nov)))
 118
 119 (deffoo nnweb-request-scan (&optional group server)
 120   (nnweb-possibly-change-server group server)
 121   (setq nnweb-hashtb (gnus-make-hashtable 4095))
 122   (funcall (nnweb-definition 'map))
 123   (unless nnweb-ephemeral-p
 124     (nnweb-write-active)
 125     (nnweb-write-overview group)))
 126
 127 (deffoo nnweb-request-group (group &optional server dont-check)
 128   (nnweb-possibly-change-server nil server)
 129   (when (and group
 130              (not (equal group nnweb-group))
 131              (not nnweb-ephemeral-p))
 132     (let ((info (assoc group nnweb-group-alist)))
 133       (setq nnweb-group group)
 134       (setq nnweb-type (nth 2 info))
 135       (setq nnweb-search (nth 3 info))
 136       (unless dont-check
 137         (nnweb-read-overview group))))
 138   (cond
 139    ((not nnweb-articles)
 140     (nnheader-report 'nnweb "No matching articles"))
 141    (t
 142     (let ((active (if nnweb-ephemeral-p
 143                       (cons (caar nnweb-articles)
 144                             (caar (last nnweb-articles)))
 145                     (cadr (assoc group nnweb-group-alist)))))
 146       (nnheader-report 'nnweb "Opened group %s" group)
 147       (nnheader-insert
 148        "211 %d %d %d %s\n" (length nnweb-articles)
 149        (car active) (cdr active) group)))))
 150
 151 (deffoo nnweb-close-group (group &optional server)
 152   (nnweb-possibly-change-server group server)
 153   (when (gnus-buffer-live-p nnweb-buffer)
 154     (save-excursion
 155       (set-buffer nnweb-buffer)
 156       (set-buffer-modified-p nil)
 157       (kill-buffer nnweb-buffer)))
 158   t)
 159
 160 (deffoo nnweb-request-article (article &optional group server buffer)
 161   (nnweb-possibly-change-server group server)
 162   (save-excursion
 163     (set-buffer (or buffer nntp-server-buffer))
 164     (let* ((header (cadr (assq article nnweb-articles)))
 165            (url (and header (mail-header-xref header))))
 166       (when (or (and url
 167                      (nnweb-fetch-url url))
 168                 (and (stringp article)
 169                      (nnweb-definition 'id t)
 170                      (let ((fetch (nnweb-definition 'id))
 171                            art)
 172                        (when (string-match "^<\\(.*\\)>$" article)
 173                          (setq art (match-string 1 article)))
 174                        (and fetch
 175                             art
 176                             (nnweb-fetch-url
 177                              (format fetch article))))))
 178         (unless nnheader-callback-function
 179           (funcall (nnweb-definition 'article))
 180           (nnweb-decode-entities))
 181         (nnheader-report 'nnweb "Fetched article %s" article)
 182         t))))
 183
 184 (deffoo nnweb-close-server (&optional server)
 185   (when (and (nnweb-server-opened server)
 186              (gnus-buffer-live-p nnweb-buffer))
 187     (save-excursion
 188       (set-buffer nnweb-buffer)
 189       (set-buffer-modified-p nil)
 190       (kill-buffer nnweb-buffer)))
 191   (nnoo-close-server 'nnweb server))
 192
 193 (deffoo nnweb-request-list (&optional server)
 194   (nnweb-possibly-change-server nil server)
 195   (save-excursion
 196     (set-buffer nntp-server-buffer)
 197     (nnmail-generate-active nnweb-group-alist)
 198     t))
 199
 200 (deffoo nnweb-request-update-info (group info &optional server)
 201   (nnweb-possibly-change-server group server)
 202   ;;(setcar (cddr info) nil)
 203   )
 204
 205 (deffoo nnweb-asynchronous-p ()
 206   t)
 207
 208 (deffoo nnweb-request-create-group (group &optional server args)
 209   (nnweb-possibly-change-server nil server)
 210   (nnweb-request-delete-group group)
 211   (push `(,group ,(cons 1 0) ,@args) nnweb-group-alist)
 212   (nnweb-write-active)
 213   t)
 214
 215 (deffoo nnweb-request-delete-group (group &optional force server)
 216   (nnweb-possibly-change-server group server)
 217   (gnus-pull group nnweb-group-alist t)
 218   (nnweb-write-active)
 219   (gnus-delete-file (nnweb-overview-file group))
 220   t)
 221
 222 (nnoo-define-skeleton nnweb)
 223
 224 ;;; Internal functions
 225
 226 (defun nnweb-read-overview (group)
 227   "Read the overview of GROUP and build the map."
 228   (when (file-exists-p (nnweb-overview-file group))
 229     (with-temp-buffer
 230       (nnheader-insert-file-contents (nnweb-overview-file group))
 231       (goto-char (point-min))
 232       (let (header)
 233         (while (not (eobp))
 234           (setq header (nnheader-parse-nov))
 235           (forward-line 1)
 236           (push (list (mail-header-number header)
 237                       header (mail-header-xref header))
 238                 nnweb-articles)
 239           (nnweb-set-hashtb header (car nnweb-articles)))))))
 240
 241 (defun nnweb-write-overview (group)
 242   "Write the overview file for GROUP."
 243   (with-temp-file (nnweb-overview-file group)
 244     (let ((articles nnweb-articles))
 245       (while articles
 246         (nnheader-insert-nov (cadr (pop articles)))))))
 247
 248 (defun nnweb-set-hashtb (header data)
 249   (gnus-sethash (nnweb-identifier (mail-header-xref header))
 250                 data nnweb-hashtb))
 251
 252 (defun nnweb-get-hashtb (url)
 253   (gnus-gethash (nnweb-identifier url) nnweb-hashtb))
 254
 255 (defun nnweb-identifier (ident)
 256   (funcall (nnweb-definition 'identifier) ident))
 257
 258 (defun nnweb-overview-file (group)
 259   "Return the name of the overview file of GROUP."
 260   (nnheader-concat nnweb-directory group ".overview"))
 261
 262 (defun nnweb-write-active ()
 263   "Save the active file."
 264   (with-temp-file (nnheader-concat nnweb-directory "active")
 265     (prin1 `(setq nnweb-group-alist ',nnweb-group-alist) (current-buffer))))
 266
 267 (defun nnweb-read-active ()
 268   "Read the active file."
 269   (load (nnheader-concat nnweb-directory "active") t t t))
 270
 271 (defun nnweb-definition (type &optional noerror)
 272   "Return the definition of TYPE."
 273   (let ((def (cdr (assq type (assq nnweb-type nnweb-type-definition)))))
 274     (when (and (not def)
 275                (not noerror))
 276       (error "Undefined definition %s" type))
 277     def))
 278
 279 (defun nnweb-possibly-change-server (&optional group server)
 280   (nnweb-init server)
 281   (when server
 282     (unless (nnweb-server-opened server)
 283       (nnweb-open-server server)))
 284   (unless nnweb-group-alist
 285     (nnweb-read-active))
 286   (when group
 287     (when (and (not nnweb-ephemeral-p)
 288                (not (equal group nnweb-group)))
 289       (nnweb-request-group group nil t))))
 290
 291 (defun nnweb-init (server)
 292   "Initialize buffers and such."
 293   (unless (gnus-buffer-live-p nnweb-buffer)
 294     (setq nnweb-buffer
 295           (save-excursion
 296             (nnheader-set-temp-buffer
 297              (format " *nnweb %s %s %s*" nnweb-type nnweb-search server))))))
 298
 299 (defun nnweb-fetch-url (url)
 300   (save-excursion
 301     (if (not nnheader-callback-function)
 302         (let ((buf (current-buffer)))
 303           (save-excursion
 304             (set-buffer nnweb-buffer)
 305             (erase-buffer)
 306             (url-insert-file-contents url)
 307             (copy-to-buffer buf (point-min) (point-max))
 308             t))
 309       (nnweb-url-retrieve-asynch
 310        url 'nnweb-callback (current-buffer) nnheader-callback-function)
 311       t)))
 312
 313 (defun nnweb-callback (buffer callback)
 314   (when (gnus-buffer-live-p url-working-buffer)
 315     (save-excursion
 316       (set-buffer url-working-buffer)
 317       (funcall (nnweb-definition 'article))
 318       (nnweb-decode-entities)
 319       (set-buffer buffer)
 320       (goto-char (point-max))
 321       (insert-buffer-substring url-working-buffer))
 322     (funcall callback t)
 323     (gnus-kill-buffer url-working-buffer)))
 324
 325 (defun nnweb-url-retrieve-asynch (url callback &rest data)
 326   (let ((url-request-method "GET")
 327         (old-asynch url-be-asynchronous)
 328         (url-request-data nil)
 329         (url-request-extra-headers nil)
 330         (url-working-buffer (generate-new-buffer-name " *nnweb*")))
 331     (setq-default url-be-asynchronous t)
 332     (save-excursion
 333       (set-buffer (get-buffer-create url-working-buffer))
 334       (setq url-current-callback-data data
 335             url-be-asynchronous t
 336             url-current-callback-func callback)
 337       (url-retrieve url))
 338     (setq-default url-be-asynchronous old-asynch)))
 339
 340 (defun nnweb-encode-www-form-urlencoded (pairs)
 341   "Return PAIRS encoded for forms."
 342   (mapconcat
 343    (function
 344     (lambda (data)
 345       (concat (w3-form-encode-xwfu (car data)) "="
 346               (w3-form-encode-xwfu (cdr data)))))
 347    pairs "&"))
 348
 349 (defun nnweb-fetch-form (url pairs)
 350   (let ((url-request-data (nnweb-encode-www-form-urlencoded pairs))
 351         (url-request-method "POST")
 352         (url-request-extra-headers
 353          '(("Content-type" . "application/x-www-form-urlencoded"))))
 354     (url-insert-file-contents url)
 355     (setq buffer-file-name nil))
 356   t)
 357
 358 (defun nnweb-decode-entities ()
 359   (goto-char (point-min))
 360   (while (re-search-forward "&\\([a-z]+\\);" nil t)
 361     (replace-match (char-to-string (or (cdr (assq (intern (match-string 1))
 362                                                   w3-html-entities))
 363                                        ?#))
 364                    t t)))
 365
 366 (defun nnweb-remove-markup ()
 367   (goto-char (point-min))
 368   (while (search-forward "<!--" nil t)
 369     (delete-region (match-beginning 0)
 370                    (or (search-forward "-->" nil t)
 371                        (point-max))))
 372   (goto-char (point-min))
 373   (while (re-search-forward "<[^>]+>" nil t)
 374     (replace-match "" t t)))
 375
 376 ;;;
 377 ;;; DejaNews functions.
 378 ;;;
 379
 380 (defun nnweb-dejanews-create-mapping ()
 381   "Perform the search and create an number-to-url alist."
 382   (save-excursion
 383     (set-buffer nnweb-buffer)
 384     (erase-buffer)
 385     (when (funcall (nnweb-definition 'search) nnweb-search)
 386       (let ((i 0)
 387             (more t)
 388             (case-fold-search t)
 389             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 390                         (cons 1 0)))
 391             Subject (Score "0") Date Newsgroup Author
 392             map url)
 393         (while more
 394           ;; Go through all the article hits on this page.
 395           (goto-char (point-min))
 396           (nnweb-decode-entities)
 397           (goto-char (point-min))
 398           (while (re-search-forward "^ <P>\n" nil t)
 399             (narrow-to-region
 400              (point)
 401              (cond ((re-search-forward "^ <P>\n" nil t)
 402                     (match-beginning 0))
 403                    ((search-forward "\n\n" nil t)
 404                     (point))
 405                    (t
 406                     (point-max))))
 407             (goto-char (point-min))
 408             (looking-at ".*HREF=\"\\([^\"]+\\)\"\\(.*\\)")
 409             (setq url (match-string 1))
 410             (let ((begin (point)))
 411               (nnweb-remove-markup)
 412               (goto-char begin)
 413               (while (search-forward "\t" nil t)
 414                 (replace-match " "))
 415               (goto-char begin)
 416               (end-of-line)
 417               (setq Subject (buffer-substring begin (point)))
 418               (if (re-search-forward
 419                    "^ Newsgroup: \\(.*\\)\n Posted on \\([0-9/]+\\) by \\(.*\\)$" nil t)
 420                   (setq Newsgroup (match-string 1)
 421                         Date (match-string 2)
 422                         Author (match-string 3))))
 423             (widen)
 424             (incf i)
 425             (unless (nnweb-get-hashtb url)
 426               (push
 427                (list
 428                 (incf (cdr active))
 429                 (make-full-mail-header
 430                  (cdr active) Subject Author Date
 431                  (concat "<" (nnweb-identifier url) "@dejanews>")
 432                  nil 0 (string-to-int Score) url))
 433                map)
 434               (nnweb-set-hashtb (cadar map) (car map))))
 435           ;; See whether there is a "Get next 20 hits" button here.
 436           (if (or (not (re-search-forward
 437                         "HREF=\"\\([^\"]+\\)\"[<>b]+Next result" nil t))
 438                   (>= i nnweb-max-hits))
 439               (setq more nil)
 440             ;; Yup -- fetch it.
 441             (setq more (match-string 1))
 442             (erase-buffer)
 443             (url-insert-file-contents more)))
 444         ;; Return the articles in the right order.
 445         (setq nnweb-articles
 446               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 447
 448 (defun nnweb-dejanews-wash-article ()
 449   (let ((case-fold-search t))
 450     (goto-char (point-min))
 451     (re-search-forward "<PRE>" nil t)
 452     (delete-region (point-min) (point))
 453     (re-search-forward "</PRE>" nil t)
 454     (delete-region (point) (point-max))
 455     (nnweb-remove-markup)
 456     (goto-char (point-min))
 457     (while (and (looking-at " *$")
 458                 (not (eobp)))
 459       (gnus-delete-line))
 460     (while (looking-at "\\(^[^ ]+:\\) *")
 461       (replace-match "\\1 " t)
 462       (forward-line 1))
 463     (when (re-search-forward "\n\n+" nil t)
 464       (replace-match "\n" t t))
 465     (goto-char (point-min))
 466     (when (search-forward "[More Headers]" nil t)
 467       (replace-match "" t t))))
 468
 469 (defun nnweb-dejanews-search (search)
 470   (nnweb-fetch-form
 471    (nnweb-definition 'address)
 472    `(("query" . ,search)
 473      ("defaultOp" . "AND")
 474      ("svcclass" . "dncurrent")
 475      ("maxhits" . "100")
 476      ("format" . "verbose2")
 477      ("threaded" . "0")
 478      ("showsort" . "date")
 479      ("agesign" . "1")
 480      ("ageweight" . "1")))
 481   t)
 482
 483 (defun nnweb-dejanewsold-search (search)
 484   (nnweb-fetch-form
 485    (nnweb-definition 'address)
 486    `(("query" . ,search)
 487      ("defaultOp" . "AND")
 488      ("svcclass" . "dnold")
 489      ("maxhits" . "100")
 490      ("format" . "verbose2")
 491      ("threaded" . "0")
 492      ("showsort" . "date")
 493      ("agesign" . "1")
 494      ("ageweight" . "1")))
 495   t)
 496
 497 (defun nnweb-dejanews-identity (url)
 498   "Return an unique identifier based on URL."
 499   (if (string-match "recnum=\\([0-9]+\\)" url)
 500       (match-string 1 url)
 501     url))
 502
 503 ;;;
 504 ;;; InReference
 505 ;;;
 506
 507 (defun nnweb-reference-create-mapping ()
 508   "Perform the search and create an number-to-url alist."
 509   (save-excursion
 510     (set-buffer nnweb-buffer)
 511     (erase-buffer)
 512     (when (funcall (nnweb-definition 'search) nnweb-search)
 513       (let ((i 0)
 514             (more t)
 515             (case-fold-search t)
 516             (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 517                         (cons 1 0)))
 518             Subject Score Date Newsgroups From Message-ID
 519             map url)
 520         (while more
 521           ;; Go through all the article hits on this page.
 522           (goto-char (point-min))
 523           (search-forward "</pre><hr>" nil t)
 524           (delete-region (point-min) (point))
 525                                         ;(nnweb-decode-entities)
 526           (goto-char (point-min))
 527           (while (re-search-forward "^ +[0-9]+\\." nil t)
 528             (narrow-to-region
 529              (point)
 530              (if (re-search-forward "^$" nil t)
 531                  (match-beginning 0)
 532                (point-max)))
 533             (goto-char (point-min))
 534             (when (looking-at ".*href=\"\\([^\"]+\\)\"")
 535               (setq url (match-string 1)))
 536             (nnweb-remove-markup)
 537             (goto-char (point-min))
 538             (while (search-forward "\t" nil t)
 539               (replace-match " "))
 540             (goto-char (point-min))
 541             (while (re-search-forward "^\\([^:]+\\): \\(.*\\)$" nil t)
 542               (set (intern (match-string 1)) (match-string 2)))
 543             (widen)
 544             (search-forward "</pre>" nil t)
 545             (incf i)
 546             (unless (nnweb-get-hashtb url)
 547               (push
 548                (list
 549                 (incf (cdr active))
 550                 (make-full-mail-header
 551                  (cdr active) (concat  "(" Newsgroups ") " Subject) From Date
 552                  Message-ID
 553                  nil 0 (string-to-int Score) url))
 554                map)
 555               (nnweb-set-hashtb (cadar map) (car map))))
 556           (setq more nil))
 557         ;; Return the articles in the right order.
 558         (setq nnweb-articles
 559               (sort (nconc nnweb-articles map) 'car-less-than-car))))))
 560
 561 (defun nnweb-reference-wash-article ()
 562   (let ((case-fold-search t))
 563     (goto-char (point-min))
 564     (re-search-forward "^</center><hr>" nil t)
 565     (delete-region (point-min) (point))
 566     (search-forward "<pre>" nil t)
 567     (forward-line -1)
 568     (let ((body (point-marker)))
 569       (search-forward "</pre>" nil t)
 570       (delete-region (point) (point-max))
 571       (nnweb-remove-markup)
 572       (goto-char (point-min))
 573       (while (looking-at " *$")
 574         (gnus-delete-line))
 575       (narrow-to-region (point-min) body)
 576       (while (and (re-search-forward "^$" nil t)
 577                   (not (eobp)))
 578         (gnus-delete-line))
 579       (goto-char (point-min))
 580       (while (looking-at "\\(^[^ ]+:\\) *")
 581         (replace-match "\\1 " t)
 582         (forward-line 1))
 583       (goto-char (point-min))
 584       (when (re-search-forward "^References:" nil t)
 585         (narrow-to-region
 586          (point) (if (re-search-forward "^$\\|^[^:]+:" nil t)
 587                      (match-beginning 0)
 588                    (point-max)))
 589         (goto-char (point-min))
 590         (while (not (eobp))
 591           (unless (looking-at "References")
 592             (insert "\t")
 593             (forward-line 1)))
 594         (goto-char (point-min))
 595         (while (search-forward "," nil t)
 596           (replace-match " " t t)))
 597       (widen)
 598       (set-marker body nil))))
 599
 600 (defun nnweb-reference-search (search)
 601   (url-insert-file-contents
 602    (concat
 603     (nnweb-definition 'address)
 604     "?"
 605     (nnweb-encode-www-form-urlencoded
 606      `(("search" . "advanced")
 607        ("querytext" . ,search)
 608        ("subj" . "")
 609        ("name" . "")
 610        ("login" . "")
 611        ("host" . "")
 612        ("organization" . "")
 613        ("groups" . "")
 614        ("keywords" . "")
 615        ("choice" . "Search")
 616        ("startmonth" . "Jul")
 617        ("startday" . "25")
 618        ("startyear" . "1996")
 619        ("endmonth" . "Aug")
 620        ("endday" . "24")
 621        ("endyear" . "1996")
 622        ("mode" . "Quick")
 623        ("verbosity" . "Verbose")
 624        ("ranking" . "Relevance")
 625        ("first" . "1")
 626        ("last" . "25")
 627        ("score" . "50")))))
 628   (setq buffer-file-name nil)
 629   t)
 630
 631 ;;;
 632 ;;; Alta Vista
 633 ;;;
 634
 635 (defun nnweb-altavista-create-mapping ()
 636   "Perform the search and create an number-to-url alist."
 637   (save-excursion
 638     (set-buffer nnweb-buffer)
 639     (erase-buffer)
 640     (let ((part 0))
 641       (when (funcall (nnweb-definition 'search) nnweb-search part)
 642         (let ((i 0)
 643               (more t)
 644               (case-fold-search t)
 645               (active (or (cadr (assoc nnweb-group nnweb-group-alist))
 646                           (cons 1 0)))
 647               subject date from id group
 648               map url)
 649           (while more
 650             ;; Go through all the article hits on this page.
 651             (goto-char (point-min))
 652             (search-forward "<dt>" nil t)
 653             (delete-region (point-min) (match-beginning 0))
 654             (goto-char (point-min))
 655             (while (search-forward "<dt>" nil t)
 656               (replace-match "\n<blubb>"))
 657             (nnweb-decode-entities)
 658             (goto-char (point-min))
 659             (while (re-search-forward "<blubb>.*href=\"\\([^\"]+\\)\"><strong>\\([^>]*\\)</strong></a><dd>\\([^-]+\\)- <b>\\([^<]+\\)<.*href=\"news:\\([^\"]+\\)\">.*\">\\(.+\\)</a><P>"
 660                                       nil t)
 661               (setq url (match-string 1)
 662                     subject (match-string 2)
 663                     date (match-string 3)
 664                     group (match-string 4)
 665                     id (concat "<" (match-string 5) ">")
 666                     from (match-string 6))
 667               (incf i)
 668               (unless (nnweb-get-hashtb url)
 669                 (push
 670                  (list
 671                   (incf (cdr active))
 672                   (make-full-mail-header
 673                    (cdr active) (concat  "(" group ") " subject) from date
 674                    id nil 0 0 url))
 675                  map)
 676                 (nnweb-set-hashtb (cadar map) (car map))))
 677             ;; See if we want more.
 678             (when (or (not nnweb-articles)
 679                       (>= i nnweb-max-hits)
 680                       (not (funcall (nnweb-definition 'search)
 681                                     nnweb-search (incf part))))
 682               (setq more nil)))
 683           ;; Return the articles in the right order.
 684           (setq nnweb-articles
 685                 (sort (nconc nnweb-articles map) 'car-less-than-car)))))))
 686
 687 (defun nnweb-altavista-wash-article ()
 688   (goto-char (point-min))
 689   (let ((case-fold-search t))
 690     (when (re-search-forward "^<strong>" nil t)
 691       (delete-region (point-min) (match-beginning 0)))
 692     (goto-char (point-min))
 693     (while (looking-at "<strong>\\([^ ]+\\) +</strong> +\\(.*\\)$")
 694       (replace-match "\\1: \\2" t)
 695       (forward-line 1))
 696     (when (re-search-backward "^References:" nil t)
 697       (narrow-to-region (point) (progn (forward-line 1) (point)))
 698       (goto-char (point-min))
 699       (while (re-search-forward "<A.*\\?id@\\([^\"]+\\)\">[0-9]+</A>" nil t)
 700         (replace-match "&lt;\\1&gt; " t)))
 701     (widen)
 702     (nnweb-remove-markup)))
 703
 704 (defun nnweb-altavista-search (search &optional part)
 705   (url-insert-file-contents
 706    (concat
 707     (nnweb-definition 'address)
 708     "?"
 709     (nnweb-encode-www-form-urlencoded
 710      `(("pg" . "aq")
 711        ("what" . "news")
 712        ,@(when part `(("stq" . ,(int-to-string (* part 30)))))
 713        ("fmt" . "d")
 714        ("q" . ,search)
 715        ("r" . "")
 716        ("d0" . "")
 717        ("d1" . "")))))
 718   (setq buffer-file-name nil)
 719   t)
 720
 721 (provide 'nnweb)
 722
 723 ;;; nnweb.el ends here