git.chise.org Git - elisp/gnus.git-/blob - lisp/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   7 ;;      Daiki Ueno  <ueno@ueda.info.waseda.ac.jp>
   8 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   9 ;; Maintainer: Volunteers
  10 ;; Keywords: mail
  11
  12 ;; This file is part of T-gnus.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  32 ;; are implemented.  The LIST command has not been implemented due to lack
  33 ;; of actual usefulness.
  34 ;; The optional POP3 command TOP has not been implemented.
  35
  36 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  37
  38 ;; You have to set the variable `pop3-connection-type' to `ssl' or
  39 ;; `tls' expressly, if you would like to use this module with Gnus
  40 ;; (not T-gnus) for those connection types.  For examples:
  41 ;;
  42 ;;(setq mail-sources '((pop :server "POPSERVER" :port 995 :connection ssl
  43 ;;                          :authentication apop)))
  44 ;;(setq pop3-connection-type 'ssl)
  45
  46 ;;; Code:
  47
  48 (eval-when-compile
  49   (require 'cl)
  50   ;; For compiling this module in Gnus with XEmacs -no-autoloads.
  51   (require 'advice))
  52
  53 ;; as-binary-process, open-network-stream-as-binary, write-region-as-binary
  54 (require 'pces)
  55 ;; exec-installed-p
  56 (require 'path-util)
  57
  58 (require 'mail-utils)
  59
  60 (defvar pop3-maildrop (or (user-login-name) (getenv "LOGNAME") (getenv "USER") nil)
  61   "*POP3 maildrop.")
  62 (defvar pop3-mailhost (or (getenv "MAILHOST") nil)
  63   "*POP3 mailhost.")
  64 (defvar pop3-port 110
  65   "*POP3 port.")
  66 (defvar pop3-connection-type nil
  67   "*POP3 connection type.")
  68
  69 (defvar pop3-password-required t
  70   "*Non-nil if a password is required when connecting to POP server.")
  71 (defvar pop3-password nil
  72   "*Password to use when connecting to POP server.")
  73
  74 (defvar pop3-authentication-scheme 'pass
  75   "*POP3 authentication scheme.
  76 Defaults to 'pass, for the standard USER/PASS authentication.  Other valid
  77 values are 'apop.")
  78
  79 (defvar pop3-timestamp nil
  80   "Timestamp returned when initially connected to the POP server.
  81 Used for APOP authentication.")
  82
  83 (defvar pop3-leave-mail-on-server nil
  84   "Non-nil if mail is to be left on the server and UIDL used for message retrieval.")
  85
  86 (defvar pop3-maximum-message-size nil
  87   "If non-nil only download messages smaller than this.")
  88
  89 (defvar pop3-except-header-regexp nil
  90   "If non-nil we do not retrieve messages whose headers are matching this regexp.")
  91
  92 (defvar pop3-uidl-file-name "~/.uidls"
  93   "File in which to store the UIDL of processed messages.")
  94
  95 (defvar pop3-uidl-support nil
  96   "Alist of servers and flags of whether they support UIDLs.
  97 Users don't have to set this value.")
  98
  99 (defvar pop3-uidl-obarray (make-vector 31 0)
 100   "Uidl hash table.")
 101
 102 (defvar pop3-read-point nil)
 103 (defvar pop3-debug nil)
 104
 105 (eval-and-compile
 106   (autoload 'starttls-open-stream "starttls")
 107   (autoload 'starttls-negotiate "starttls"))
 108
 109 (defvar pop3-ssl-program-name
 110   (if (exec-installed-p "openssl")
 111       "openssl"
 112     "ssleay")
 113   "The program to run in a subprocess to open an SSL connection.")
 114
 115 (defvar pop3-ssl-program-arguments
 116   '("s_client" "-quiet")
 117   "Arguments to be passed to the program `pop3-ssl-program-name'.")
 118
 119 (defun pop3-progress-message (format percent &rest args)
 120   (apply (function message) format args))
 121
 122 (defun pop3-movemail (&optional crashbox)
 123   "Transfer contents of a maildrop to the specified CRASHBOX."
 124   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
 125   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 126          (crashbuf (get-buffer-create " *pop3-retr*"))
 127          (n 1)
 128          message-count
 129          (pop3-password pop3-password)
 130          (pop3-uidl-file-name (convert-standard-filename
 131                                (concat pop3-uidl-file-name "-"
 132                                        pop3-mailhost)))
 133          retrieved-messages messages)
 134     ;; for debugging only
 135     (if pop3-debug (switch-to-buffer (process-buffer process)))
 136     ;; query for password
 137     (if (and pop3-password-required (not pop3-password))
 138         (setq pop3-password
 139               (read-passwd (format "Password for %s: " pop3-maildrop))))
 140     (cond ((equal 'apop pop3-authentication-scheme)
 141            (pop3-apop process pop3-maildrop))
 142           ((equal 'pass pop3-authentication-scheme)
 143            (pop3-user process pop3-maildrop)
 144            (pop3-pass process))
 145           (t (error "Invalid POP3 authentication scheme")))
 146     ;; get messages that are suitable for download
 147     (message "Retrieving message list...")
 148     (setq messages (pop3-get-message-numbers process)
 149           message-count (length (cdr messages)))
 150     (message "Retrieving message list...%d of %d unread"
 151              message-count (pop messages))
 152     (unwind-protect
 153         (unless (not (stringp crashbox))
 154           (while messages
 155             (pop3-progress-message
 156              "Retrieving message %d of %d (%d octets) from %s..."
 157              (floor (* (/ (float n) message-count) 100))
 158              n message-count (cdar messages) pop3-mailhost)
 159             (pop3-retr process (caar messages) crashbuf)
 160             (push (caar messages) retrieved-messages)
 161             (setq messages (cdr messages)
 162                   n (1+ n)))
 163           (with-current-buffer crashbuf
 164             (write-region-as-binary (point-min) (point-max)
 165                                     crashbox 'append 'nomesg))
 166           ;; mark messages as read
 167           (when pop3-leave-mail-on-server
 168             (pop3-save-uidls))
 169           ;; now delete the messages we have retrieved
 170           (unless pop3-leave-mail-on-server
 171             (dolist (n retrieved-messages)
 172               (message "Deleting message %d of %d from %s..."
 173                        n message-count pop3-mailhost)
 174               (pop3-dele process n)))
 175           )
 176       (pop3-quit process))
 177     (kill-buffer crashbuf)
 178     message-count))
 179
 180 (defun pop3-get-message-count ()
 181   "Return the number of messages in the maildrop."
 182   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 183          message-count
 184          (pop3-password pop3-password)
 185          )
 186     ;; for debugging only
 187     (if pop3-debug (switch-to-buffer (process-buffer process)))
 188     ;; query for password
 189     (if (and pop3-password-required (not pop3-password))
 190         (setq pop3-password
 191               (read-passwd (format "Password for %s: " pop3-maildrop))))
 192     (cond ((equal 'apop pop3-authentication-scheme)
 193            (pop3-apop process pop3-maildrop))
 194           ((equal 'pass pop3-authentication-scheme)
 195            (pop3-user process pop3-maildrop)
 196            (pop3-pass process))
 197           (t (error "Invalid POP3 authentication scheme")))
 198     (setq message-count (car (pop3-stat process)))
 199     (pop3-quit process)
 200     message-count))
 201
 202 (defun pop3-open-server (mailhost port)
 203   "Open TCP connection to MAILHOST on PORT.
 204 Returns the process associated with the connection.
 205 Argument PORT specifies connecting port."
 206   (let (process)
 207     (save-excursion
 208       (set-buffer (get-buffer-create (concat " trace of POP session to "
 209                                              mailhost)))
 210       (erase-buffer)
 211       (setq pop3-read-point (point-min))
 212       (setq
 213        process
 214        (cond
 215         ((eq pop3-connection-type 'ssl)
 216          (pop3-open-ssl-stream "POP" (current-buffer) mailhost port))
 217         ((eq pop3-connection-type 'tls)
 218          (pop3-open-tls-stream "POP" (current-buffer) mailhost port))
 219         (t
 220          (open-network-stream-as-binary "POP" (current-buffer)
 221                                         mailhost port))))
 222       (let ((response (pop3-read-response process t)))
 223         (setq pop3-timestamp
 224               (substring response (or (string-match "<" response) 0)
 225                          (+ 1 (or (string-match ">" response) -1)))))
 226       process)))
 227
 228 (defun pop3-open-ssl-stream-1 (name buffer host service extra-arg)
 229   (require 'ssl)
 230   (let* ((ssl-program-name
 231           pop3-ssl-program-name)
 232          (ssl-program-arguments
 233           `(,@pop3-ssl-program-arguments
 234             ,extra-arg
 235             "-connect" ,(format "%s:%d" host service)))
 236          (process (open-ssl-stream name buffer host service)))
 237     (when process
 238       (with-current-buffer buffer
 239         (goto-char (point-min))
 240         (while (and (memq (process-status process) '(open run))
 241                     (goto-char (point-max))
 242                     (forward-line -1)
 243                     (not (looking-at "+OK")))
 244           (nnheader-accept-process-output process)
 245           (sit-for 1))
 246         (delete-region (point-min) (point)))
 247       (and process (memq (process-status process) '(open run))
 248            process))))
 249
 250 (defun pop3-open-ssl-stream (name buffer host service)
 251   "Open a SSL connection for a service to a host.
 252 Returns a subprocess-object to represent the connection.
 253 Args are NAME BUFFER HOST SERVICE."
 254   (as-binary-process
 255    (or (pop3-open-ssl-stream-1 name buffer host service "-ssl3")
 256        (pop3-open-ssl-stream-1 name buffer host service "-ssl2"))))
 257
 258 (defun pop3-open-tls-stream (name buffer host service)
 259   "Open a TLSv1 connection for a service to a host.
 260 Returns a subprocess-object to represent the connection.
 261 Args are NAME BUFFER HOST SERVICE."
 262   (let ((process
 263          (as-binary-process (starttls-open-stream
 264                              name buffer host service))))
 265     (pop3-stls process)
 266     (starttls-negotiate process)
 267     process))
 268
 269 ;; Support functions
 270
 271 (defun pop3-process-filter (process output)
 272   (save-excursion
 273     (set-buffer (process-buffer process))
 274     (goto-char (point-max))
 275     (insert output)))
 276
 277 (defun pop3-send-command (process command)
 278   (set-buffer (process-buffer process))
 279   (goto-char (point-max))
 280 ;;  (if (= (aref command 0) ?P)
 281 ;;      (insert "PASS <omitted>\r\n")
 282 ;;    (insert command "\r\n"))
 283   (setq pop3-read-point (point))
 284   (goto-char (point-max))
 285   (process-send-string process (concat command "\r\n"))
 286   )
 287
 288 (defun pop3-read-response (process &optional return)
 289   "Read the response from the server PROCESS.
 290 Return the response string if optional second argument RETURN is non-nil."
 291   (let ((case-fold-search nil)
 292         match-end)
 293     (save-excursion
 294       (set-buffer (process-buffer process))
 295       (goto-char pop3-read-point)
 296       (while (not (search-forward "\r\n" nil t))
 297         (nnheader-accept-process-output process)
 298         (goto-char pop3-read-point))
 299       (setq match-end (point))
 300       (goto-char pop3-read-point)
 301       (if (looking-at "-ERR")
 302           (error (buffer-substring (point) (- match-end 2)))
 303         (if (not (looking-at "+OK"))
 304             (progn (setq pop3-read-point match-end) nil)
 305           (setq pop3-read-point match-end)
 306           (if return
 307               (buffer-substring (point) match-end)
 308             t)
 309           )))))
 310
 311 (defun pop3-clean-region (start end)
 312   (setq end (set-marker (make-marker) end))
 313   (save-excursion
 314     (goto-char start)
 315     (while (and (< (point) end) (search-forward "\r\n" end t))
 316       (replace-match "\n" t t))
 317     (goto-char start)
 318     (while (re-search-forward "\n\n\\(From \\)" end t)
 319       (replace-match "\n\n>\\1" t nil))
 320     (goto-char start)
 321     (while (and (< (point) end) (re-search-forward "^\\." end t))
 322       (replace-match "" t t)
 323       (forward-char)))
 324   (set-marker end nil))
 325
 326 (eval-when-compile (defvar parse-time-months))
 327
 328 ;; Copied from message-make-date.
 329 (defun pop3-make-date (&optional now)
 330   "Make a valid date header.
 331 If NOW, use that time instead."
 332   (require 'parse-time)
 333   (let* ((now (or now (current-time)))
 334          (zone (nth 8 (decode-time now)))
 335          (sign "+"))
 336     (when (< zone 0)
 337       (setq sign "-")
 338       (setq zone (- zone)))
 339     (concat
 340      (format-time-string "%d" now)
 341      ;; The month name of the %b spec is locale-specific.  Pfff.
 342      (format " %s "
 343              (capitalize (car (rassoc (nth 4 (decode-time now))
 344                                       parse-time-months))))
 345      (format-time-string "%Y %H:%M:%S " now)
 346      ;; We do all of this because XEmacs doesn't have the %z spec.
 347      (format "%s%02d%02d" sign (/ zone 3600) (/ (% zone 3600) 60)))))
 348
 349 (defun pop3-munge-message-separator (start end)
 350   "Check to see if a message separator exists.  If not, generate one."
 351   (save-excursion
 352     (save-restriction
 353       (narrow-to-region start end)
 354       (goto-char (point-min))
 355       (if (not (or (looking-at "From .?") ; Unix mail
 356                    (looking-at "\001\001\001\001\n") ; MMDF
 357                    (looking-at "BABYL OPTIONS:") ; Babyl
 358                    ))
 359           (let* ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 360                  (tdate (mail-fetch-field "Date"))
 361                  (date (split-string (or (and tdate
 362                                               (not (string= "" tdate))
 363                                               tdate)
 364                                          (pop3-make-date))
 365                                      " "))
 366                  (From_))
 367             ;; sample date formats I have seen
 368             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 369             ;; Date: 08 Jul 1996 23:22:24 -0400
 370             ;; should be
 371             ;; Tue Jul 9 09:04:21 1996
 372             (setq date
 373                   (cond ((not date)
 374                          "Tue Jan 1 00:00:0 1900")
 375                         ((string-match "[A-Z]" (nth 0 date))
 376                          (format "%s %s %s %s %s"
 377                                  (nth 0 date) (nth 2 date) (nth 1 date)
 378                                  (nth 4 date) (nth 3 date)))
 379                         (t
 380                          ;; this really needs to be better but I don't feel
 381                          ;; like writing a date to day converter.
 382                          (format "Sun %s %s %s %s"
 383                                  (nth 1 date) (nth 0 date)
 384                                  (nth 3 date) (nth 2 date)))
 385                         ))
 386             (setq From_ (format "\nFrom %s  %s\n" from date))
 387             (while (string-match "," From_)
 388               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 389                                   (substring From_ (match-end 0)))))
 390             (goto-char (point-min))
 391             (insert From_)
 392             (if (search-forward "\n\n" nil t)
 393                 nil
 394               (goto-char (point-max))
 395               (insert "\n"))
 396             (narrow-to-region (point) (point-max))
 397             (let ((size (- (point-max) (point-min))))
 398               (goto-char (point-min))
 399               (widen)
 400               (forward-line -1)
 401               (insert (format "Content-Length: %s\n" size)))
 402             )))))
 403
 404 ;; UIDL support
 405
 406 (defun pop3-get-message-numbers (process)
 407   "Get the list of message numbers and lengths to retrieve via PROCESS."
 408   ;; we use the LIST comand first anyway to get the message lengths.
 409   ;; then if we're leaving mail on the server, see if the UIDL command
 410   ;; is implemented. if so, we use it to get the message number list.
 411   (let* ((messages (pop3-list process))
 412          (total (or (pop messages) 0))
 413          (uidl (if pop3-leave-mail-on-server
 414                    (pop3-get-uidl process)))
 415          out)
 416     (while messages
 417       ;; only retrieve messages matching our regexp or in the uidl list
 418       (when (and
 419              ;; remove elements not in the uidl, this assumes the uidl is short
 420              (or (not (and pop3-leave-mail-on-server
 421                            (cdr (assoc pop3-mailhost pop3-uidl-support))))
 422                  (memq (caar messages) uidl))
 423              (caar messages)
 424              ;; don't download messages that are too large
 425              (not (and pop3-maximum-message-size
 426                        (> (cdar messages) pop3-maximum-message-size)))
 427              (not (and pop3-except-header-regexp
 428                        (string-match pop3-except-header-regexp
 429                                      (pop3-top process (caar messages) 0)))))
 430         (push (car messages) out))
 431       (setq messages (cdr messages)))
 432     (cons total (nreverse out))))
 433
 434 (defun pop3-get-uidl (process)
 435   "Use PROCESS to get a list of unread message numbers."
 436   (let ((messages (pop3-uidl process))
 437         (support (assoc pop3-mailhost pop3-uidl-support))
 438         uidl)
 439     (if support
 440         (setcdr support (and messages t))
 441       (push (cons pop3-mailhost (and messages t))
 442             pop3-uidl-support))
 443     (when messages
 444       (save-excursion
 445         (with-temp-buffer
 446           (when (file-readable-p pop3-uidl-file-name)
 447             (insert-file-contents pop3-uidl-file-name))
 448           (goto-char (point-min))
 449           (while (looking-at "\\([^ \n\t]+\\)")
 450             (set (intern (match-string 1) pop3-uidl-obarray)
 451                  (cons nil t))
 452             (forward-line 1))))
 453       (dolist (message (cdr messages))
 454         (if (setq uidl (intern-soft (cdr message) pop3-uidl-obarray))
 455             (setcar (symbol-value uidl) (car message))
 456           (set (intern (cdr message) pop3-uidl-obarray)
 457                (cons (car message) nil))))
 458       (pop3-get-unread-message-numbers))))
 459
 460 (defun pop3-get-unread-message-numbers ()
 461   "Return a sorted list of unread msg numbers to retrieve."
 462   (let (nums)
 463     (mapatoms (lambda (atom)
 464                 (if (not (cdr (symbol-value atom)))
 465                     (push (car (symbol-value atom)) nums)))
 466               pop3-uidl-obarray)
 467     (sort nums '<)))
 468
 469 (defun pop3-save-uidls ()
 470   "Save the updated UIDLs to disk for use next time."
 471   (when (and pop3-leave-mail-on-server
 472              ;; UIDL hash table is non-empty
 473              (let ((len (length pop3-uidl-obarray)))
 474                (while (< 0 len)
 475                  (setq len (if (symbolp (aref pop3-uidl-obarray (1- len)))
 476                                -1 (1- len))))
 477                (minusp len)))
 478     (when (file-readable-p pop3-uidl-file-name)
 479       (copy-file pop3-uidl-file-name
 480                  (concat pop3-uidl-file-name ".old")
 481                  'overwrite 'keeptime))
 482     (save-excursion
 483       (with-temp-file pop3-uidl-file-name
 484         (mapatoms
 485          (lambda (atom)
 486            (when (car (symbol-value atom))
 487              (insert (format "%s\n" atom))))
 488          pop3-uidl-obarray)))
 489     (fillarray pop3-uidl-obarray 0)))
 490
 491
 492 ;; The Command Set
 493
 494 ;; AUTHORIZATION STATE
 495
 496 (defun pop3-user (process user)
 497   "Send USER information to POP3 server."
 498   (pop3-send-command process (format "USER %s" user))
 499   (let ((response (pop3-read-response process t)))
 500     (if (not (and response (string-match "+OK" response)))
 501         (error (format "USER %s not valid" user)))))
 502
 503 (defun pop3-pass (process)
 504   "Send authentication information to the server."
 505   (pop3-send-command process (format "PASS %s" pop3-password))
 506   (let ((response (pop3-read-response process t)))
 507     (if (not (and response (string-match "+OK" response)))
 508         (pop3-quit process))))
 509
 510 ;; When this file is being compiled in the Gnus (not T-gnus) source
 511 ;; tree, `md5' might have been defined in w3/md5.el, ./lpath.el or one
 512 ;; of some other libraries and `md5' will accept only 3 arguments.  We
 513 ;; will deceive the byte-compiler not to say warnings.
 514 (eval-and-compile
 515   (if (fboundp 'eval-when)
 516       ;; `eval-when' might not be provided when loading .el file.
 517       (eval-when 'compile
 518         (let ((def (assq 'md5 byte-compile-function-environment)))
 519           (if def
 520               (setcdr def '(lambda (object &optional start end
 521                                            coding-system noerror)))
 522             (setq byte-compile-function-environment
 523                   (cons '(md5 . (lambda (object &optional start end
 524                                                 coding-system noerror)))
 525                         byte-compile-function-environment)))))))
 526
 527 ;; Note that `pop3-md5' should never encode a given string to use for
 528 ;; the apop authentication.
 529 (eval-and-compile
 530   (if (fboundp 'md5)
 531       (if (condition-case nil
 532               (md5 "\
 533 Check whether the 4th argument CODING-SYSTEM is allowed"
 534                    nil nil 'binary)
 535             (error nil))
 536           ;; Emacs 21 or XEmacs 21
 537           ;; (md5 OBJECT &optional START END CODING-SYSTEM NOERROR)
 538           (defun pop3-md5 (string)
 539             (md5 string nil nil 'binary))
 540         ;; The reason why the program reaches here:
 541         ;; 1. XEmacs 20 is running and the built-in `md5' doesn't
 542         ;;    allow the 4th argument.
 543         ;; 2. `md5' has been defined by one of some lisp libraries.
 544         ;; 3. This file is being compiled in the Gnus source tree,
 545         ;;    and `md5' has been defined in lpath.el.
 546         (defalias 'pop3-md5 'md5))
 547     ;; The lisp function will be provided by FLIM or other libraries.
 548     (autoload 'md5 "md5")
 549     (defalias 'pop3-md5 'md5)))
 550
 551 (defun pop3-apop (process user)
 552   "Send alternate authentication information to the server."
 553   (let ((pass pop3-password))
 554     (if (and pop3-password-required (not pass))
 555         (setq pass
 556               (read-passwd (format "Password for %s: " pop3-maildrop))))
 557     (if pass
 558         (let ((hash (pop3-md5 (concat pop3-timestamp pass))))
 559           (pop3-send-command process (format "APOP %s %s" user hash))
 560           (let ((response (pop3-read-response process t)))
 561             (if (not (and response (string-match "+OK" response)))
 562                 (pop3-quit process)))))
 563     ))
 564
 565 (defun pop3-stls (process)
 566   "Query whether TLS extension is supported"
 567   (pop3-send-command process "STLS")
 568   (let ((response (pop3-read-response process t)))
 569     (if (not (and response (string-match "+OK" response)))
 570         (pop3-quit process))))
 571
 572 ;; TRANSACTION STATE
 573
 574 (defun pop3-stat (process)
 575   "Return the number of messages in the maildrop and the maildrop's size."
 576   (pop3-send-command process "STAT")
 577   (let ((response (pop3-read-response process t)))
 578     (list (string-to-int (nth 1 (split-string response " ")))
 579           (string-to-int (nth 2 (split-string response " "))))
 580     ))
 581
 582 (defun pop3-retr (process msg crashbuf)
 583   "Retrieve message-id MSG to buffer CRASHBUF."
 584   (pop3-send-command process (format "RETR %s" msg))
 585   (pop3-read-response process)
 586   (save-excursion
 587     (let ((region (pop3-get-extended-response process)))
 588       (pop3-munge-message-separator (car region) (cadr region))
 589       (append-to-buffer crashbuf (car region) (cadr region))
 590       (delete-region (car region) (cadr region))
 591       )))
 592
 593 (defun pop3-dele (process msg)
 594   "Mark message-id MSG as deleted."
 595   (pop3-send-command process (format "DELE %s" msg))
 596   (pop3-read-response process))
 597
 598 (defun pop3-noop (process msg)
 599   "No-operation."
 600   (pop3-send-command process "NOOP")
 601   (pop3-read-response process))
 602
 603 (defun pop3-last (process)
 604   "Return highest accessed message-id number for the session."
 605   (pop3-send-command process "LAST")
 606   (let ((response (pop3-read-response process t)))
 607     (string-to-int (nth 1 (split-string response " ")))
 608     ))
 609
 610 (defun pop3-rset (process)
 611   "Remove all delete marks from current maildrop."
 612   (pop3-send-command process "RSET")
 613   (pop3-read-response process))
 614
 615 ;; UPDATE
 616
 617 (defun pop3-quit (process)
 618   "Close connection to POP3 server.
 619 Tell server to remove all messages marked as deleted, unlock the maildrop,
 620 and close the connection."
 621   (pop3-send-command process "QUIT")
 622   (pop3-read-response process t)
 623   (when process
 624     (save-excursion
 625       (set-buffer (process-buffer process))
 626       (goto-char (point-max))
 627       (delete-process process))))
 628
 629 (defun pop3-uidl (process &optional msgno)
 630   "Return the results of a UIDL command in PROCESS for optional MSGNO.
 631 If UIDL is unsupported on this mail server or if msgno is invalid, return nil.
 632 Otherwise, return a list in the form
 633
 634    (N (1 UIDL-1) (2 UIDL-2) ... (N UIDL-N))
 635
 636 where
 637
 638    N is an integer for the number of UIDLs returned (could be 0)
 639    UIDL-n is a string."
 640
 641   (if msgno
 642       (pop3-send-command process (format "UIDL %d" msgno))
 643     (pop3-send-command process "UIDL"))
 644
 645   (if (null (pop3-read-response process t))
 646       nil ;; UIDL is not supported on this server
 647     (let (pairs uidl)
 648       (save-excursion
 649         (save-restriction
 650           (apply 'narrow-to-region (pop3-get-extended-response process))
 651           (goto-char (point-min))
 652           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 653             (setq msgno (string-to-int (match-string 1))
 654                   uidl (match-string 2))
 655             (push (cons msgno uidl) pairs)
 656             (beginning-of-line 2))
 657           (cons (length pairs) (nreverse pairs))
 658           )))))
 659
 660 (defun pop3-list (process &optional msgno)
 661   "Return the results of a LIST command for PROCESS and optional MSGNO.
 662 If (optional) msgno is invalid, return nil.  Otherwise, return a list
 663 in the form
 664
 665    (N (1 LEN-1) (2 LEN-2) ... (N LEN-N))
 666
 667 where
 668
 669    N is an integer for the number of msg/len pairs (could be 0)
 670    LEN-n is an integer."
 671   (if msgno
 672       (pop3-send-command process (format "LIST %d" msgno))
 673     (pop3-send-command process "LIST"))
 674
 675   (if (null (pop3-read-response process t))
 676       nil ;; MSGNO is not valid number
 677     (let (pairs len)
 678       (save-excursion
 679         (save-restriction
 680           (apply 'narrow-to-region (pop3-get-extended-response process))
 681           (goto-char (point-min))
 682           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 683             (setq msgno (string-to-int (match-string 1))
 684                   len (string-to-int (match-string 2)))
 685             (push (cons msgno len) pairs)
 686             (beginning-of-line 2))
 687           (cons (length pairs) (nreverse pairs))
 688           )))))
 689
 690 (defun pop3-top (process msgno &optional lines)
 691   "Return the top LINES of messages for PROCESS and MSGNO.
 692 If msgno is invalid, return nil.  Otherwise, return a string."
 693   (pop3-send-command process (format "TOP %d %d" msgno (or lines 1)))
 694   (if (pop3-read-response process t)
 695       nil ;; MSGNO is not valid number
 696     (save-excursion
 697       (apply 'buffer-substring (pop3-get-extended-response process)))
 698     ))
 699
 700 ;;; Utility code
 701
 702 (defun pop3-get-extended-response (process)
 703   "Get the extended pop3 response in the PROCESS buffer."
 704   (let ((start pop3-read-point) end)
 705     (set-buffer (process-buffer process))
 706     (goto-char start)
 707     (while (not (re-search-forward "^\\.\r\n" nil t))
 708       (nnheader-accept-process-output process)
 709       (goto-char start))
 710     (setq pop3-read-point (point-marker))
 711     (goto-char (match-beginning 0))
 712     (setq end (point-marker))
 713     (pop3-clean-region start end)
 714     (list start end)))
 715
 716 \f
 717 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 718
 719 ;;; AUTHORIZATION STATE
 720
 721 ;; Initial TCP connection
 722 ;; Arguments: none
 723 ;; Restrictions: none
 724 ;; Possible responses:
 725 ;;  +OK [POP3 server ready]
 726
 727 ;; USER name
 728 ;; Arguments: a server specific user-id (required)
 729 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 730 ;; Possible responses:
 731 ;;  +OK [valid user-id]
 732 ;;  -ERR [invalid user-id]
 733
 734 ;; PASS string
 735 ;; Arguments: a server/user-id specific password (required)
 736 ;; Restrictions: authorization state, after successful USER
 737 ;; Possible responses:
 738 ;;  +OK [maildrop locked and ready]
 739 ;;  -ERR [invalid password]
 740 ;;  -ERR [unable to lock maildrop]
 741
 742 ;; STLS
 743 ;; Arguments: none
 744 ;; Restrictions: authorization state
 745 ;; Possible responses:
 746 ;;  +OK [negotiation is ready]
 747 ;;  -ERR [security layer is already active]
 748
 749 ;;; TRANSACTION STATE
 750
 751 ;; STAT
 752 ;; Arguments: none
 753 ;; Restrictions: transaction state
 754 ;; Possible responses:
 755 ;;  +OK nn mm [# of messages, size of maildrop]
 756
 757 ;; LIST [msg]
 758 ;; Arguments: a message-id (optional)
 759 ;; Restrictions: transaction state; msg must not be deleted
 760 ;; Possible responses:
 761 ;;  +OK [scan listing follows]
 762 ;;  -ERR [no such message]
 763
 764 ;; TOP msg [lines]
 765 ;; Arguments: a message-id (required), number of lines (optional)
 766 ;; Restrictions: transaction state; msg must not be deleted
 767 ;; Possible responses:
 768 ;;  +OK [partial message listing follows]
 769 ;;  -ERR [no such message]
 770
 771 ;; UIDL [msg]
 772 ;; Arguments: a message-id (optional)
 773 ;; Restrictions: transaction state; msg must not be deleted
 774 ;; Possible responses:
 775 ;;  +OK [uidl listing follows]
 776 ;;  -ERR [no such message]
 777
 778 ;; RETR msg
 779 ;; Arguments: a message-id (required)
 780 ;; Restrictions: transaction state; msg must not be deleted
 781 ;; Possible responses:
 782 ;;  +OK [message contents follow]
 783 ;;  -ERR [no such message]
 784
 785 ;; DELE msg
 786 ;; Arguments: a message-id (required)
 787 ;; Restrictions: transaction state; msg must not be deleted
 788 ;; Possible responses:
 789 ;;  +OK [message deleted]
 790 ;;  -ERR [no such message]
 791
 792 ;; NOOP
 793 ;; Arguments: none
 794 ;; Restrictions: transaction state
 795 ;; Possible responses:
 796 ;;  +OK
 797
 798 ;; LAST
 799 ;; Arguments: none
 800 ;; Restrictions: transaction state
 801 ;; Possible responses:
 802 ;;  +OK nn [highest numbered message accessed]
 803
 804 ;; RSET
 805 ;; Arguments: none
 806 ;; Restrictions: transaction state
 807 ;; Possible responses:
 808 ;;  +OK [all delete marks removed]
 809
 810 ;;; UPDATE STATE
 811
 812 ;; QUIT
 813 ;; Arguments: none
 814 ;; Restrictions: none
 815 ;; Possible responses:
 816 ;;  +OK [TCP connection closed]
 817
 818 (provide 'pop3)
 819
 820 ;;; pop3.el ends here