git.chise.org Git - elisp/gnus.git-/blob - lisp/pop3.el

   1 ;;; pop3.el --- Post Office Protocol (RFC 1460) interface
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Richard L. Pieri <ratinox@peorth.gweep.net>
   7 ;;      Daiki Ueno  <ueno@ueda.info.waseda.ac.jp>
   8 ;;      Katsumi Yamaoka <yamaoka@jpl.org>
   9 ;; Maintainer: Volunteers
  10 ;; Keywords: mail
  11
  12 ;; This file is part of T-gnus.
  13
  14 ;; GNU Emacs is free software; you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation; either version 2, or (at your option)
  17 ;; any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  26 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  27 ;; Boston, MA 02111-1307, USA.
  28
  29 ;;; Commentary:
  30
  31 ;; Most of the standard Post Office Protocol version 3 (RFC 1460) commands
  32 ;; are implemented.  The LIST command has not been implemented due to lack
  33 ;; of actual usefulness.
  34 ;; The optional POP3 command TOP has not been implemented.
  35
  36 ;; This program was inspired by Kyle E. Jones's vm-pop program.
  37
  38 ;; You have to set the variable `pop3-connection-type' to `ssl' or
  39 ;; `tls' expressly, if you would like to use this module with Gnus
  40 ;; (not T-gnus) for those connection types.  For examples:
  41 ;;
  42 ;;(setq mail-sources '((pop :server "POPSERVER" :port 995 :connection ssl
  43 ;;                          :authentication apop)))
  44 ;;(setq pop3-connection-type 'ssl)
  45
  46 ;;; Code:
  47
  48 (eval-when-compile (require 'cl))
  49
  50 ;; as-binary-process, open-network-stream-as-binary, write-region-as-binary
  51 (require 'pces)
  52 ;; exec-installed-p
  53 (require 'path-util)
  54
  55 (require 'mail-utils)
  56
  57 (defvar pop3-maildrop (or (user-login-name) (getenv "LOGNAME") (getenv "USER") nil)
  58   "*POP3 maildrop.")
  59 (defvar pop3-mailhost (or (getenv "MAILHOST") nil)
  60   "*POP3 mailhost.")
  61 (defvar pop3-port 110
  62   "*POP3 port.")
  63 (defvar pop3-connection-type nil
  64   "*POP3 connection type.")
  65
  66 (defvar pop3-password-required t
  67   "*Non-nil if a password is required when connecting to POP server.")
  68 (defvar pop3-password nil
  69   "*Password to use when connecting to POP server.")
  70
  71 (defvar pop3-authentication-scheme 'pass
  72   "*POP3 authentication scheme.
  73 Defaults to 'pass, for the standard USER/PASS authentication.  Other valid
  74 values are 'apop.")
  75
  76 (defvar pop3-timestamp nil
  77   "Timestamp returned when initially connected to the POP server.
  78 Used for APOP authentication.")
  79
  80 (defvar pop3-leave-mail-on-server nil
  81   "Non-nil if mail is to be left on the server and UIDL used for message retrieval.")
  82
  83 (defvar pop3-maximum-message-size nil
  84   "If non-nil only download messages smaller than this.")
  85
  86 (defvar pop3-except-header-regexp nil
  87   "If non-nil we do not retrieve messages whose headers are matching this regexp.")
  88
  89 (defvar pop3-uidl-file-name "~/.uidls"
  90   "File in which to store the UIDL of processed messages.")
  91
  92 (defvar pop3-uidl-support 'dont-know
  93   "Whether the server supports UIDL.
  94 Nil means no, t means yes, not-nil-or-t means yet to be determined.")
  95
  96 (defvar pop3-uidl-obarray (make-vector 31 0)
  97   "Uidl hash table.")
  98
  99 (defvar pop3-read-point nil)
 100 (defvar pop3-debug nil)
 101
 102 (eval-and-compile
 103   (autoload 'starttls-open-stream "starttls")
 104   (autoload 'starttls-negotiate "starttls"))
 105
 106 (defvar pop3-ssl-program-name
 107   (if (exec-installed-p "openssl")
 108       "openssl"
 109     "ssleay")
 110   "The program to run in a subprocess to open an SSL connection.")
 111
 112 (defvar pop3-ssl-program-arguments
 113   '("s_client" "-quiet")
 114   "Arguments to be passed to the program `pop3-ssl-program-name'.")
 115
 116 (defun pop3-progress-message (format percent &rest args)
 117   (apply (function message) format args))
 118
 119 (defun pop3-movemail (&optional crashbox)
 120   "Transfer contents of a maildrop to the specified CRASHBOX."
 121   (or crashbox (setq crashbox (expand-file-name "~/.crashbox")))
 122   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 123          (crashbuf (get-buffer-create " *pop3-retr*"))
 124          (n 1)
 125          message-count
 126          (pop3-password pop3-password)
 127          (pop3-uidl-file-name (convert-standard-filename
 128                                (concat pop3-uidl-file-name "-"
 129                                        pop3-mailhost)))
 130          retrieved-messages messages)
 131     ;; for debugging only
 132     (if pop3-debug (switch-to-buffer (process-buffer process)))
 133     ;; query for password
 134     (if (and pop3-password-required (not pop3-password))
 135         (setq pop3-password
 136               (read-passwd (format "Password for %s: " pop3-maildrop))))
 137     (cond ((equal 'apop pop3-authentication-scheme)
 138            (pop3-apop process pop3-maildrop))
 139           ((equal 'pass pop3-authentication-scheme)
 140            (pop3-user process pop3-maildrop)
 141            (pop3-pass process))
 142           (t (error "Invalid POP3 authentication scheme")))
 143     ;; get messages that are suitable for download
 144     (message "Retrieving message list...")
 145     (setq messages (pop3-get-message-numbers process)
 146           message-count (length (cdr messages)))
 147     (message "Retrieving message list...%d of %d unread"
 148              message-count (pop messages))
 149     (unwind-protect
 150         (unless (not (stringp crashbox))
 151           (while messages
 152             (pop3-progress-message
 153              "Retrieving message %d of %d (%d octets) from %s..."
 154              (floor (* (/ (float n) message-count) 100))
 155              n message-count (cdar messages) pop3-mailhost)
 156             (pop3-retr process (caar messages) crashbuf)
 157             (push (caar messages) retrieved-messages)
 158             (setq messages (cdr messages)
 159                   n (1+ n)))
 160           (with-current-buffer crashbuf
 161             (write-region-as-binary (point-min) (point-max)
 162                                     crashbox 'append 'nomesg))
 163           ;; mark messages as read
 164           (when pop3-leave-mail-on-server
 165             (pop3-save-uidls))
 166           ;; now delete the messages we have retrieved
 167           (unless pop3-leave-mail-on-server
 168             (dolist (n retrieved-messages)
 169               (message "Deleting message %d of %d from %s..."
 170                        n message-count pop3-mailhost)
 171               (pop3-dele process n)))
 172           )
 173       (pop3-quit process))
 174     (kill-buffer crashbuf)
 175     message-count))
 176
 177 (defun pop3-get-message-count ()
 178   "Return the number of messages in the maildrop."
 179   (let* ((process (pop3-open-server pop3-mailhost pop3-port))
 180          message-count
 181          (pop3-password pop3-password)
 182          )
 183     ;; for debugging only
 184     (if pop3-debug (switch-to-buffer (process-buffer process)))
 185     ;; query for password
 186     (if (and pop3-password-required (not pop3-password))
 187         (setq pop3-password
 188               (read-passwd (format "Password for %s: " pop3-maildrop))))
 189     (cond ((equal 'apop pop3-authentication-scheme)
 190            (pop3-apop process pop3-maildrop))
 191           ((equal 'pass pop3-authentication-scheme)
 192            (pop3-user process pop3-maildrop)
 193            (pop3-pass process))
 194           (t (error "Invalid POP3 authentication scheme")))
 195     (setq message-count (car (pop3-stat process)))
 196     (pop3-quit process)
 197     message-count))
 198
 199 (defun pop3-open-server (mailhost port)
 200   "Open TCP connection to MAILHOST on PORT.
 201 Returns the process associated with the connection.
 202 Argument PORT specifies connecting port."
 203   (let (process)
 204     (save-excursion
 205       (set-buffer (get-buffer-create (concat " trace of POP session to "
 206                                              mailhost)))
 207       (erase-buffer)
 208       (setq pop3-read-point (point-min))
 209       (setq
 210        process
 211        (cond
 212         ((eq pop3-connection-type 'ssl)
 213          (pop3-open-ssl-stream "POP" (current-buffer) mailhost port))
 214         ((eq pop3-connection-type 'tls)
 215          (pop3-open-tls-stream "POP" (current-buffer) mailhost port))
 216         (t
 217          (open-network-stream-as-binary "POP" (current-buffer)
 218                                         mailhost port))))
 219       (let ((response (pop3-read-response process t)))
 220         (setq pop3-timestamp
 221               (substring response (or (string-match "<" response) 0)
 222                          (+ 1 (or (string-match ">" response) -1)))))
 223       process)))
 224
 225 (defun pop3-open-ssl-stream-1 (name buffer host service extra-arg)
 226   (require 'ssl)
 227   (let* ((ssl-program-name
 228           pop3-ssl-program-name)
 229          (ssl-program-arguments
 230           `(,@pop3-ssl-program-arguments
 231             ,extra-arg
 232             "-connect" ,(format "%s:%d" host service)))
 233          (process (open-ssl-stream name buffer host service)))
 234     (when process
 235       (with-current-buffer buffer
 236         (goto-char (point-min))
 237         (while (and (memq (process-status process) '(open run))
 238                     (goto-char (point-max))
 239                     (forward-line -1)
 240                     (not (looking-at "+OK")))
 241           (nnheader-accept-process-output process)
 242           (sit-for 1))
 243         (delete-region (point-min) (point)))
 244       (and process (memq (process-status process) '(open run))
 245            process))))
 246
 247 (defun pop3-open-ssl-stream (name buffer host service)
 248   "Open a SSL connection for a service to a host.
 249 Returns a subprocess-object to represent the connection.
 250 Args are NAME BUFFER HOST SERVICE."
 251   (as-binary-process
 252    (or (pop3-open-ssl-stream-1 name buffer host service "-ssl3")
 253        (pop3-open-ssl-stream-1 name buffer host service "-ssl2"))))
 254
 255 (defun pop3-open-tls-stream (name buffer host service)
 256   "Open a TLSv1 connection for a service to a host.
 257 Returns a subprocess-object to represent the connection.
 258 Args are NAME BUFFER HOST SERVICE."
 259   (let ((process
 260          (as-binary-process (starttls-open-stream
 261                              name buffer host service))))
 262     (pop3-stls process)
 263     (starttls-negotiate process)
 264     process))
 265
 266 ;; Support functions
 267
 268 (defun pop3-process-filter (process output)
 269   (save-excursion
 270     (set-buffer (process-buffer process))
 271     (goto-char (point-max))
 272     (insert output)))
 273
 274 (defun pop3-send-command (process command)
 275   (set-buffer (process-buffer process))
 276   (goto-char (point-max))
 277 ;;  (if (= (aref command 0) ?P)
 278 ;;      (insert "PASS <omitted>\r\n")
 279 ;;    (insert command "\r\n"))
 280   (setq pop3-read-point (point))
 281   (goto-char (point-max))
 282   (process-send-string process (concat command "\r\n"))
 283   )
 284
 285 (defun pop3-read-response (process &optional return)
 286   "Read the response from the server PROCESS.
 287 Return the response string if optional second argument RETURN is non-nil."
 288   (let ((case-fold-search nil)
 289         match-end)
 290     (save-excursion
 291       (set-buffer (process-buffer process))
 292       (goto-char pop3-read-point)
 293       (while (not (search-forward "\r\n" nil t))
 294         (nnheader-accept-process-output process)
 295         (goto-char pop3-read-point))
 296       (setq match-end (point))
 297       (goto-char pop3-read-point)
 298       (if (looking-at "-ERR")
 299           (error (buffer-substring (point) (- match-end 2)))
 300         (if (not (looking-at "+OK"))
 301             (progn (setq pop3-read-point match-end) nil)
 302           (setq pop3-read-point match-end)
 303           (if return
 304               (buffer-substring (point) match-end)
 305             t)
 306           )))))
 307
 308 (defun pop3-clean-region (start end)
 309   (setq end (set-marker (make-marker) end))
 310   (save-excursion
 311     (goto-char start)
 312     (while (and (< (point) end) (search-forward "\r\n" end t))
 313       (replace-match "\n" t t))
 314     (goto-char start)
 315     (while (re-search-forward "\n\n\\(From \\)" end t)
 316       (replace-match "\n\n>\\1" t nil))
 317     (goto-char start)
 318     (while (and (< (point) end) (re-search-forward "^\\." end t))
 319       (replace-match "" t t)
 320       (forward-char)))
 321   (set-marker end nil))
 322
 323 (eval-when-compile (defvar parse-time-months))
 324
 325 ;; Copied from message-make-date.
 326 (defun pop3-make-date (&optional now)
 327   "Make a valid date header.
 328 If NOW, use that time instead."
 329   (require 'parse-time)
 330   (let* ((now (or now (current-time)))
 331          (zone (nth 8 (decode-time now)))
 332          (sign "+"))
 333     (when (< zone 0)
 334       (setq sign "-")
 335       (setq zone (- zone)))
 336     (concat
 337      (format-time-string "%d" now)
 338      ;; The month name of the %b spec is locale-specific.  Pfff.
 339      (format " %s "
 340              (capitalize (car (rassoc (nth 4 (decode-time now))
 341                                       parse-time-months))))
 342      (format-time-string "%Y %H:%M:%S " now)
 343      ;; We do all of this because XEmacs doesn't have the %z spec.
 344      (format "%s%02d%02d" sign (/ zone 3600) (/ (% zone 3600) 60)))))
 345
 346 (defun pop3-munge-message-separator (start end)
 347   "Check to see if a message separator exists.  If not, generate one."
 348   (save-excursion
 349     (save-restriction
 350       (narrow-to-region start end)
 351       (goto-char (point-min))
 352       (if (not (or (looking-at "From .?") ; Unix mail
 353                    (looking-at "\001\001\001\001\n") ; MMDF
 354                    (looking-at "BABYL OPTIONS:") ; Babyl
 355                    ))
 356           (let* ((from (mail-strip-quoted-names (mail-fetch-field "From")))
 357                  (tdate (mail-fetch-field "Date"))
 358                  (date (split-string (or (and tdate
 359                                               (not (string= "" tdate))
 360                                               tdate)
 361                                          (pop3-make-date))
 362                                      " "))
 363                  (From_))
 364             ;; sample date formats I have seen
 365             ;; Date: Tue, 9 Jul 1996 09:04:21 -0400 (EDT)
 366             ;; Date: 08 Jul 1996 23:22:24 -0400
 367             ;; should be
 368             ;; Tue Jul 9 09:04:21 1996
 369             (setq date
 370                   (cond ((not date)
 371                          "Tue Jan 1 00:00:0 1900")
 372                         ((string-match "[A-Z]" (nth 0 date))
 373                          (format "%s %s %s %s %s"
 374                                  (nth 0 date) (nth 2 date) (nth 1 date)
 375                                  (nth 4 date) (nth 3 date)))
 376                         (t
 377                          ;; this really needs to be better but I don't feel
 378                          ;; like writing a date to day converter.
 379                          (format "Sun %s %s %s %s"
 380                                  (nth 1 date) (nth 0 date)
 381                                  (nth 3 date) (nth 2 date)))
 382                         ))
 383             (setq From_ (format "\nFrom %s  %s\n" from date))
 384             (while (string-match "," From_)
 385               (setq From_ (concat (substring From_ 0 (match-beginning 0))
 386                                   (substring From_ (match-end 0)))))
 387             (goto-char (point-min))
 388             (insert From_)
 389             (if (search-forward "\n\n" nil t)
 390                 nil
 391               (goto-char (point-max))
 392               (insert "\n"))
 393             (narrow-to-region (point) (point-max))
 394             (let ((size (- (point-max) (point-min))))
 395               (goto-char (point-min))
 396               (widen)
 397               (forward-line -1)
 398               (insert (format "Content-Length: %s\n" size)))
 399             )))))
 400
 401 ;; UIDL support
 402
 403 (defun pop3-get-message-numbers (process)
 404   "Get the list of message numbers and lengths to retrieve via PROCESS."
 405   ;; we use the LIST comand first anyway to get the message lengths.
 406   ;; then if we're leaving mail on the server, see if the UIDL command
 407   ;; is implemented. if so, we use it to get the message number list.
 408   (let* ((messages (pop3-list process))
 409          (total (or (pop messages) 0))
 410          (uidl (if pop3-leave-mail-on-server
 411                    (pop3-get-uidl process)))
 412          out)
 413     (while messages
 414       ;; only retrieve messages matching our regexp or in the uidl list
 415       (when (and
 416              ;; remove elements not in the uidl, this assumes the uidl is short
 417              (or (not (eq pop3-uidl-support t))
 418                  (memq (caar messages) uidl))
 419              (caar messages)
 420              ;; don't download messages that are too large
 421              (not (and pop3-maximum-message-size
 422                        (> (cdar messages) pop3-maximum-message-size)))
 423              (not (and pop3-except-header-regexp
 424                        (string-match pop3-except-header-regexp
 425                                      (pop3-top process (caar messages) 0)))))
 426         (push (car messages) out))
 427       (setq messages (cdr messages)))
 428     (cons total (reverse out))))
 429
 430 (defun pop3-get-uidl (process)
 431   "Use PROCESS to get a list of unread message numbers."
 432   (let ((messages (pop3-uidl process)) uidl)
 433     (if (or (null messages) (null pop3-uidl-support))
 434         (setq pop3-uidl-support nil)
 435       (setq pop3-uidl-support t)
 436       (save-excursion
 437         (with-temp-buffer
 438           (when (file-readable-p pop3-uidl-file-name)
 439             (insert-file-contents pop3-uidl-file-name))
 440           (goto-char (point-min))
 441           (while (looking-at "\\([^ \n\t]+\\)")
 442             (set (intern (match-string 1) pop3-uidl-obarray)
 443                  (cons nil t))
 444             (forward-line 1))
 445           ))
 446       (dolist (message (cdr messages))
 447         (if (setq uidl (intern-soft (cdr message) pop3-uidl-obarray))
 448             (setcar (symbol-value uidl) (car message))
 449           (set (intern (cdr message) pop3-uidl-obarray)
 450                (cons (car message) nil))))
 451       (pop3-get-unread-message-numbers))
 452     ))
 453
 454 (defun pop3-get-unread-message-numbers ()
 455   "Return a sorted list of unread msg numbers to retrieve."
 456   (let (nums)
 457     (mapatoms (lambda (atom)
 458                 (if (not (cdr (symbol-value atom)))
 459                     (push (car (symbol-value atom)) nums)))
 460               pop3-uidl-obarray)
 461     (sort nums '<)))
 462
 463 (defun pop3-save-uidls ()
 464   "Save the updated UIDLs to disk for use next time."
 465   (when (and pop3-leave-mail-on-server
 466              ;; UIDL hash table is non-empty
 467              (let ((len (length pop3-uidl-obarray)))
 468                (while (< 0 len)
 469                  (setq len (if (symbolp (aref pop3-uidl-obarray (1- len)))
 470                                -1 (1- len))))
 471                (minusp len)))
 472     (when (file-readable-p pop3-uidl-file-name)
 473       (copy-file pop3-uidl-file-name
 474                  (concat pop3-uidl-file-name ".old")
 475                  'overwrite 'keeptime))
 476     (save-excursion
 477       (with-temp-file pop3-uidl-file-name
 478         (mapatoms
 479          (lambda (atom)
 480            (when (car (symbol-value atom))
 481              (insert (format "%s\n" atom))))
 482          pop3-uidl-obarray)))
 483     (fillarray pop3-uidl-obarray 0)))
 484
 485
 486 ;; The Command Set
 487
 488 ;; AUTHORIZATION STATE
 489
 490 (defun pop3-user (process user)
 491   "Send USER information to POP3 server."
 492   (pop3-send-command process (format "USER %s" user))
 493   (let ((response (pop3-read-response process t)))
 494     (if (not (and response (string-match "+OK" response)))
 495         (error (format "USER %s not valid" user)))))
 496
 497 (defun pop3-pass (process)
 498   "Send authentication information to the server."
 499   (pop3-send-command process (format "PASS %s" pop3-password))
 500   (let ((response (pop3-read-response process t)))
 501     (if (not (and response (string-match "+OK" response)))
 502         (pop3-quit process))))
 503
 504 ;; When this file is being compiled in the Gnus (not T-gnus) source
 505 ;; tree, `md5' might have been defined in w3/md5.el, ./lpath.el or one
 506 ;; of some other libraries and `md5' will accept only 3 arguments.  We
 507 ;; will deceive the byte-compiler not to say warnings.
 508 (eval-and-compile
 509   (if (fboundp 'eval-when)
 510       ;; `eval-when' might not be provided when loading .el file.
 511       (eval-when 'compile
 512         (let ((def (assq 'md5 byte-compile-function-environment)))
 513           (if def
 514               (setcdr def '(lambda (object &optional start end
 515                                            coding-system noerror)))
 516             (setq byte-compile-function-environment
 517                   (cons '(md5 . (lambda (object &optional start end
 518                                                 coding-system noerror)))
 519                         byte-compile-function-environment)))))))
 520
 521 ;; Note that `pop3-md5' should never encode a given string to use for
 522 ;; the apop authentication.
 523 (eval-and-compile
 524   (if (fboundp 'md5)
 525       (if (condition-case nil
 526               (md5 "\
 527 Check whether the 4th argument CODING-SYSTEM is allowed"
 528                    nil nil 'binary)
 529             (error nil))
 530           ;; Emacs 21 or XEmacs 21
 531           ;; (md5 OBJECT &optional START END CODING-SYSTEM NOERROR)
 532           (defun pop3-md5 (string)
 533             (md5 string nil nil 'binary))
 534         ;; The reason why the program reaches here:
 535         ;; 1. XEmacs 20 is running and the built-in `md5' doesn't
 536         ;;    allow the 4th argument.
 537         ;; 2. `md5' has been defined by one of some lisp libraries.
 538         ;; 3. This file is being compiled in the Gnus source tree,
 539         ;;    and `md5' has been defined in lpath.el.
 540         (defalias 'pop3-md5 'md5))
 541     ;; The lisp function will be provided by FLIM or other libraries.
 542     (autoload 'md5 "md5")
 543     (defalias 'pop3-md5 'md5)))
 544
 545 (defun pop3-apop (process user)
 546   "Send alternate authentication information to the server."
 547   (let ((pass pop3-password))
 548     (if (and pop3-password-required (not pass))
 549         (setq pass
 550               (read-passwd (format "Password for %s: " pop3-maildrop))))
 551     (if pass
 552         (let ((hash (pop3-md5 (concat pop3-timestamp pass))))
 553           (pop3-send-command process (format "APOP %s %s" user hash))
 554           (let ((response (pop3-read-response process t)))
 555             (if (not (and response (string-match "+OK" response)))
 556                 (pop3-quit process)))))
 557     ))
 558
 559 (defun pop3-stls (process)
 560   "Query whether TLS extension is supported"
 561   (pop3-send-command process "STLS")
 562   (let ((response (pop3-read-response process t)))
 563     (if (not (and response (string-match "+OK" response)))
 564         (pop3-quit process))))
 565
 566 ;; TRANSACTION STATE
 567
 568 (defun pop3-stat (process)
 569   "Return the number of messages in the maildrop and the maildrop's size."
 570   (pop3-send-command process "STAT")
 571   (let ((response (pop3-read-response process t)))
 572     (list (string-to-int (nth 1 (split-string response " ")))
 573           (string-to-int (nth 2 (split-string response " "))))
 574     ))
 575
 576 (defun pop3-retr (process msg crashbuf)
 577   "Retrieve message-id MSG to buffer CRASHBUF."
 578   (pop3-send-command process (format "RETR %s" msg))
 579   (pop3-read-response process)
 580   (save-excursion
 581     (let ((region (pop3-get-extended-response process)))
 582       (pop3-munge-message-separator (car region) (cadr region))
 583       (append-to-buffer crashbuf (car region) (cadr region))
 584       (delete-region (car region) (cadr region))
 585       )))
 586
 587 (defun pop3-dele (process msg)
 588   "Mark message-id MSG as deleted."
 589   (pop3-send-command process (format "DELE %s" msg))
 590   (pop3-read-response process))
 591
 592 (defun pop3-noop (process msg)
 593   "No-operation."
 594   (pop3-send-command process "NOOP")
 595   (pop3-read-response process))
 596
 597 (defun pop3-last (process)
 598   "Return highest accessed message-id number for the session."
 599   (pop3-send-command process "LAST")
 600   (let ((response (pop3-read-response process t)))
 601     (string-to-int (nth 1 (split-string response " ")))
 602     ))
 603
 604 (defun pop3-rset (process)
 605   "Remove all delete marks from current maildrop."
 606   (pop3-send-command process "RSET")
 607   (pop3-read-response process))
 608
 609 ;; UPDATE
 610
 611 (defun pop3-quit (process)
 612   "Close connection to POP3 server.
 613 Tell server to remove all messages marked as deleted, unlock the maildrop,
 614 and close the connection."
 615   (pop3-send-command process "QUIT")
 616   (pop3-read-response process t)
 617   (when process
 618     (save-excursion
 619       (set-buffer (process-buffer process))
 620       (goto-char (point-max))
 621       (delete-process process))))
 622
 623 (defun pop3-uidl (process &optional msgno)
 624   "Return the results of a UIDL command in PROCESS for optional MSGNO.
 625 If UIDL is unsupported on this mail server or if msgno is invalid, return nil.
 626 Otherwise, return a list in the form
 627
 628    (N (1 UIDL-1) (2 UIDL-2) ... (N UIDL-N))
 629
 630 where
 631
 632    N is an integer for the number of UIDLs returned (could be 0)
 633    UIDL-n is a string."
 634
 635   (if msgno
 636       (pop3-send-command process (format "UIDL %d" msgno))
 637     (pop3-send-command process "UIDL"))
 638
 639   (if (null (pop3-read-response process t))
 640       nil ;; UIDL is not supported on this server
 641     (let (pairs uidl)
 642       (save-excursion
 643         (save-restriction
 644           (apply 'narrow-to-region (pop3-get-extended-response process))
 645           (goto-char (point-min))
 646           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 647             (setq msgno (string-to-int (match-string 1))
 648                   uidl (match-string 2))
 649             (push (cons msgno uidl) pairs)
 650             (beginning-of-line 2))
 651           (cons (length pairs) (nreverse pairs))
 652           )))))
 653
 654 (defun pop3-list (process &optional msgno)
 655   "Return the results of a LIST command for PROCESS and optional MSGNO.
 656 If (optional) msgno is invalid, return nil.  Otherwise, return a list
 657 in the form
 658
 659    (N (1 LEN-1) (2 LEN-2) ... (N LEN-N))
 660
 661 where
 662
 663    N is an integer for the number of msg/len pairs (could be 0)
 664    LEN-n is an integer."
 665   (if msgno
 666       (pop3-send-command process (format "LIST %d" msgno))
 667     (pop3-send-command process "LIST"))
 668
 669   (if (null (pop3-read-response process t))
 670       nil ;; MSGNO is not valid number
 671     (let (pairs len)
 672       (save-excursion
 673         (save-restriction
 674           (apply 'narrow-to-region (pop3-get-extended-response process))
 675           (goto-char (point-min))
 676           (while (looking-at "\\([^ \n\t]*\\) \\([^ \n\t]*\\)")
 677             (setq msgno (string-to-int (match-string 1))
 678                   len (string-to-int (match-string 2)))
 679             (push (cons msgno len) pairs)
 680             (beginning-of-line 2))
 681           (cons (length pairs) (nreverse pairs))
 682           )))))
 683
 684 (defun pop3-top (process msgno &optional lines)
 685   "Return the top LINES of messages for PROCESS and MSGNO.
 686 If msgno is invalid, return nil.  Otherwise, return a string."
 687   (pop3-send-command process (format "TOP %d %d" msgno (or lines 1)))
 688   (if (pop3-read-response process t)
 689       nil ;; MSGNO is not valid number
 690     (save-excursion
 691       (apply 'buffer-substring (pop3-get-extended-response process)))
 692     ))
 693
 694 ;;; Utility code
 695
 696 (defun pop3-get-extended-response (process)
 697   "Get the extended pop3 response in the PROCESS buffer."
 698   (let ((start pop3-read-point) end)
 699     (set-buffer (process-buffer process))
 700     (goto-char start)
 701     (while (not (re-search-forward "^\\.\r\n" nil t))
 702       (nnheader-accept-process-output process)
 703       (goto-char start))
 704     (setq pop3-read-point (point-marker))
 705     (goto-char (match-beginning 0))
 706     (setq end (point-marker))
 707     (pop3-clean-region start end)
 708     (list start end)))
 709
 710 \f
 711 ;; Summary of POP3 (Post Office Protocol version 3) commands and responses
 712
 713 ;;; AUTHORIZATION STATE
 714
 715 ;; Initial TCP connection
 716 ;; Arguments: none
 717 ;; Restrictions: none
 718 ;; Possible responses:
 719 ;;  +OK [POP3 server ready]
 720
 721 ;; USER name
 722 ;; Arguments: a server specific user-id (required)
 723 ;; Restrictions: authorization state [after unsuccessful USER or PASS
 724 ;; Possible responses:
 725 ;;  +OK [valid user-id]
 726 ;;  -ERR [invalid user-id]
 727
 728 ;; PASS string
 729 ;; Arguments: a server/user-id specific password (required)
 730 ;; Restrictions: authorization state, after successful USER
 731 ;; Possible responses:
 732 ;;  +OK [maildrop locked and ready]
 733 ;;  -ERR [invalid password]
 734 ;;  -ERR [unable to lock maildrop]
 735
 736 ;; STLS
 737 ;; Arguments: none
 738 ;; Restrictions: authorization state
 739 ;; Possible responses:
 740 ;;  +OK [negotiation is ready]
 741 ;;  -ERR [security layer is already active]
 742
 743 ;;; TRANSACTION STATE
 744
 745 ;; STAT
 746 ;; Arguments: none
 747 ;; Restrictions: transaction state
 748 ;; Possible responses:
 749 ;;  +OK nn mm [# of messages, size of maildrop]
 750
 751 ;; LIST [msg]
 752 ;; Arguments: a message-id (optional)
 753 ;; Restrictions: transaction state; msg must not be deleted
 754 ;; Possible responses:
 755 ;;  +OK [scan listing follows]
 756 ;;  -ERR [no such message]
 757
 758 ;; TOP msg [lines]
 759 ;; Arguments: a message-id (required), number of lines (optional)
 760 ;; Restrictions: transaction state; msg must not be deleted
 761 ;; Possible responses:
 762 ;;  +OK [partial message listing follows]
 763 ;;  -ERR [no such message]
 764
 765 ;; UIDL [msg]
 766 ;; Arguments: a message-id (optional)
 767 ;; Restrictions: transaction state; msg must not be deleted
 768 ;; Possible responses:
 769 ;;  +OK [uidl listing follows]
 770 ;;  -ERR [no such message]
 771
 772 ;; RETR msg
 773 ;; Arguments: a message-id (required)
 774 ;; Restrictions: transaction state; msg must not be deleted
 775 ;; Possible responses:
 776 ;;  +OK [message contents follow]
 777 ;;  -ERR [no such message]
 778
 779 ;; DELE msg
 780 ;; Arguments: a message-id (required)
 781 ;; Restrictions: transaction state; msg must not be deleted
 782 ;; Possible responses:
 783 ;;  +OK [message deleted]
 784 ;;  -ERR [no such message]
 785
 786 ;; NOOP
 787 ;; Arguments: none
 788 ;; Restrictions: transaction state
 789 ;; Possible responses:
 790 ;;  +OK
 791
 792 ;; LAST
 793 ;; Arguments: none
 794 ;; Restrictions: transaction state
 795 ;; Possible responses:
 796 ;;  +OK nn [highest numbered message accessed]
 797
 798 ;; RSET
 799 ;; Arguments: none
 800 ;; Restrictions: transaction state
 801 ;; Possible responses:
 802 ;;  +OK [all delete marks removed]
 803
 804 ;;; UPDATE STATE
 805
 806 ;; QUIT
 807 ;; Arguments: none
 808 ;; Restrictions: none
 809 ;; Possible responses:
 810 ;;  +OK [TCP connection closed]
 811
 812 (provide 'pop3)
 813
 814 ;;; pop3.el ends here