git.chise.org Git - elisp/gnus.git-/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- Functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998,99 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-and-compile
  28   (eval
  29    '(unless (fboundp 'base64-decode-string)
  30       (require 'base64))))
  31
  32 (require 'qp)
  33 (require 'mm-util)
  34 (require 'ietf-drums)
  35 (require 'mail-prsvr)
  36
  37 (defvar rfc2047-header-encoding-alist
  38   '(("Newsgroups" . nil)
  39     ("Message-ID" . nil)
  40     (t . mime))
  41   "*Header/encoding method alist.
  42 The list is traversed sequentially.  The keys can either be
  43 header regexps or `t'.
  44
  45 The values can be:
  46
  47 1) nil, in which case no encoding is done;
  48 2) `mime', in which case the header will be encoded according to RFC2047;
  49 3) a charset, in which case it will be encoded as that charse;
  50 4) `default', in which case the field will be encoded as the rest
  51    of the article.")
  52
  53 (defvar rfc2047-charset-encoding-alist
  54   '((us-ascii . nil)
  55     (iso-8859-1 . Q)
  56     (iso-8859-2 . Q)
  57     (iso-8859-3 . Q)
  58     (iso-8859-4 . Q)
  59     (iso-8859-5 . B)
  60     (koi8-r . B)
  61     (iso-8859-7 . Q)
  62     (iso-8859-8 . Q)
  63     (iso-8859-9 . Q)
  64     (iso-2022-jp . B)
  65     (iso-2022-kr . B)
  66     (gb2312 . B)
  67     (cn-gb . B)
  68     (cn-gb-2312 . B)
  69     (euc-kr . B)
  70     (iso-2022-jp-2 . B)
  71     (iso-2022-int-1 . B))
  72   "Alist of MIME charsets to RFC2047 encodings.
  73 Valid encodings are nil, `Q' and `B'.")
  74
  75 (defvar rfc2047-encoding-function-alist
  76   '((Q . rfc2047-q-encode-region)
  77     (B . rfc2047-b-encode-region)
  78     (nil . ignore))
  79   "Alist of RFC2047 encodings to encoding functions.")
  80
  81 (defvar rfc2047-q-encoding-alist
  82   '(("\\(From\\|Cc\\|To\\|Bcc\||Reply-To\\):" . "-A-Za-z0-9!*+/=_")
  83     ("." . "^\000-\007\013\015-\037\200-\377=_?"))
  84   "Alist of header regexps and valid Q characters.")
  85
  86 ;;;
  87 ;;; Functions for encoding RFC2047 messages
  88 ;;;
  89
  90 (defun rfc2047-narrow-to-field ()
  91   "Narrow the buffer to the header on the current line."
  92   (beginning-of-line)
  93   (narrow-to-region
  94    (point)
  95    (progn
  96      (forward-line 1)
  97      (if (re-search-forward "^[^ \n\t]" nil t)
  98          (progn
  99            (beginning-of-line)
 100            (point))
 101        (point-max))))
 102   (goto-char (point-min)))
 103
 104 (defun rfc2047-encode-message-header ()
 105   "Encode the message header according to `rfc2047-header-encoding-alist'.
 106 Should be called narrowed to the head of the message."
 107   (interactive "*")
 108   (when (featurep 'mule)
 109     (save-excursion
 110       (goto-char (point-min))
 111       (let ((alist rfc2047-header-encoding-alist)
 112             elem method)
 113         (while (not (eobp))
 114           (save-restriction
 115             (rfc2047-narrow-to-field)
 116             (when (rfc2047-encodable-p)
 117               ;; We found something that may perhaps be encoded.
 118               (while (setq elem (pop alist))
 119                 (when (or (and (stringp (car elem))
 120                                (looking-at (car elem)))
 121                           (eq (car elem) t))
 122                   (setq alist nil
 123                         method (cdr elem))))
 124               (when method
 125                 (cond
 126                  ((eq method 'mime)
 127                   (rfc2047-encode-region (point-min) (point-max))
 128                   (rfc2047-fold-region (point-min) (point-max)))
 129                  ;; Hm.
 130                  (t))))
 131             (goto-char (point-max)))))
 132       (when mail-parse-charset
 133         (encode-coding-region (point-min) (point-max)
 134                               mail-parse-charset)))))
 135
 136 (defun rfc2047-encodable-p ()
 137   "Say whether the current (narrowed) buffer contains characters that need encoding."
 138   (let ((charsets
 139          (mapcar
 140           'mm-mime-charset
 141           (mm-find-charset-region (point-min) (point-max))))
 142         (cs (list 'us-ascii mail-parse-charset))
 143         found)
 144     (while charsets
 145       (unless (memq (pop charsets) cs)
 146         (setq found t)))
 147     found))
 148
 149 (defun rfc2047-dissect-region (b e)
 150   "Dissect the region between B and E into words."
 151   (let (words)
 152     (save-restriction
 153       (narrow-to-region b e)
 154       (goto-char (point-min))
 155       (while (re-search-forward
 156               (concat "[^" ietf-drums-tspecials " \t\n]+") nil t)
 157         (push
 158          (list (match-beginning 0) (match-end 0)
 159                (car (delq 'ascii (mm-find-charset-region
 160                                   (match-beginning 0) (match-end 0)))))
 161          words))
 162       words)))
 163
 164 (defun rfc2047-encode-region (b e)
 165   "Encode all encodable words in REGION."
 166   (let ((words (rfc2047-dissect-region b e))
 167         beg end current word)
 168     (while (setq word (pop words))
 169       (if (equal (nth 2 word) current)
 170           (setq beg (nth 0 word))
 171         (when current
 172           (rfc2047-encode beg end current))
 173         (setq current (nth 2 word)
 174               beg (nth 0 word)
 175               end (nth 1 word))))
 176     (when current
 177       (rfc2047-encode beg end current))))
 178
 179 (defun rfc2047-encode-string (string)
 180   "Encode words in STRING."
 181   (with-temp-buffer
 182     (insert string)
 183     (rfc2047-encode-region (point-min) (point-max))
 184     (buffer-string)))
 185
 186 (defun rfc2047-encode (b e charset)
 187   "Encode the word in the region with CHARSET."
 188   (let* ((mime-charset (mm-mime-charset charset))
 189          (encoding (or (cdr (assq mime-charset
 190                                   rfc2047-charset-encoding-alist))
 191                        'B))
 192          (start (concat
 193                  "=?" (downcase (symbol-name mime-charset)) "?"
 194                  (downcase (symbol-name encoding)) "?"))
 195          (first t))
 196     (save-restriction
 197       (narrow-to-region b e)
 198       (when (eq encoding 'B)
 199         ;; break into lines before encoding
 200         (goto-char (point-min))
 201         (while (not (eobp))
 202           (goto-char (min (point-max) (+ 15 (point))))
 203           (unless (eobp)
 204             (insert "\n"))))
 205       (mm-encode-coding-region (point-min) (point-max) mime-charset)
 206       (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 207                (point-min) (point-max))
 208       (goto-char (point-min))
 209       (while (not (eobp))
 210         (unless first
 211           (insert " "))
 212         (setq first nil)
 213         (insert start)
 214         (end-of-line)
 215         (insert "?=")
 216         (forward-line 1)))))
 217
 218 (defun rfc2047-fold-region (b e)
 219   "Fold the long lines in the region."
 220   (save-restriction
 221     (narrow-to-region b e)
 222     (goto-char (point-min))
 223     (let ((break nil))
 224       (while (not (eobp))
 225         (cond
 226          ((memq (char-after) '(?  ?\t))
 227           (setq break (point)))
 228          ((and (not break)
 229                (looking-at "=\\?"))
 230           (setq break (point)))
 231          ((and (looking-at "\\?=")
 232                (> (- (point) (save-excursion (beginning-of-line) (point))) 76))
 233           (goto-char break)
 234           (insert "\n ")
 235           (forward-line 1)))
 236         (unless (eobp)
 237           (forward-char 1))))))
 238
 239 (defun rfc2047-b-encode-region (b e)
 240   "Encode the header contained in REGION with the B encoding."
 241   (save-restriction
 242     (narrow-to-region (goto-char b) e)
 243     (while (not (eobp))
 244       (base64-encode-region (point) (progn (end-of-line) (point)) t)
 245       (if (and (bolp) (eolp))
 246           (delete-backward-char 1))
 247       (forward-line))))
 248
 249 (defun rfc2047-q-encode-region (b e)
 250   "Encode the header contained in REGION with the Q encoding."
 251   (save-excursion
 252     (save-restriction
 253       (narrow-to-region (goto-char b) e)
 254       (let ((alist rfc2047-q-encoding-alist))
 255         (while alist
 256           (when (looking-at (caar alist))
 257             (quoted-printable-encode-region b e nil (cdar alist))
 258             (subst-char-in-region (point-min) (point-max) ?  ?_)
 259             (setq alist nil))
 260           (pop alist))
 261         (goto-char (point-min))
 262         (while (not (eobp))
 263           (goto-char (min (point-max) (+ 64 (point))))
 264           (search-backward "=" (- (point) 2) t)
 265           (unless (eobp)
 266             (insert "\n")))))))
 267
 268 ;;;
 269 ;;; Functions for decoding RFC2047 messages
 270 ;;;
 271
 272 (defvar rfc2047-encoded-word-regexp
 273   "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\\?\\([!->@-~ +]+\\)\\?=")
 274
 275 (defun rfc2047-decode-region (start end)
 276   "Decode MIME-encoded words in region between START and END."
 277   (interactive "r")
 278   (let ((case-fold-search t)
 279         b e)
 280     (save-excursion
 281       (save-restriction
 282         (narrow-to-region start end)
 283         (goto-char (point-min))
 284         ;; Remove whitespace between encoded words.
 285         (while (re-search-forward
 286                 (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 287                         "\\(\n?[ \t]\\)+"
 288                         "\\(" rfc2047-encoded-word-regexp "\\)")
 289                 nil t)
 290           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 291         ;; Decode the encoded words.
 292         (setq b (goto-char (point-min)))
 293         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 294           (setq e (match-beginning 0))
 295           (insert (rfc2047-parse-and-decode
 296                    (prog1
 297                        (match-string 0)
 298                      (delete-region (match-beginning 0) (match-end 0)))))
 299           (when (and (mm-multibyte-p)
 300                      mail-parse-charset)
 301             (mm-decode-coding-region b e mail-parse-charset))
 302           (setq b (point)))
 303         (when (and (mm-multibyte-p)
 304                    mail-parse-charset
 305                    (not (eq mail-parse-charset 'us-ascii)))
 306           (mm-decode-coding-region b (point-max) mail-parse-charset))))))
 307
 308 (defun rfc2047-decode-string (string)
 309   "Decode the quoted-printable-encoded STRING and return the results."
 310   (let ((m (mm-multibyte-p)))
 311     (with-temp-buffer
 312       (when m
 313         (mm-enable-multibyte))
 314       (insert string)
 315       (inline
 316         (rfc2047-decode-region (point-min) (point-max)))
 317       (buffer-string))))
 318
 319 (defun rfc2047-parse-and-decode (word)
 320   "Decode WORD and return it if it is an encoded word.
 321 Return WORD if not."
 322   (if (not (string-match rfc2047-encoded-word-regexp word))
 323       word
 324     (or
 325      (condition-case nil
 326          (rfc2047-decode
 327           (match-string 1 word)
 328           (upcase (match-string 2 word))
 329           (match-string 3 word))
 330        (error word))
 331      word)))
 332
 333 (defun rfc2047-decode (charset encoding string)
 334   "Decode STRING that uses CHARSET with ENCODING.
 335 Valid ENCODINGs are \"B\" and \"Q\".
 336 If your Emacs implementation can't decode CHARSET, it returns nil."
 337   (if (stringp charset)
 338     (setq charset (intern (downcase charset))))
 339   (if (or (not charset) (memq charset mail-parse-ignored-charsets))
 340       (setq charset mail-parse-charset))
 341   (let ((cs (mm-charset-to-coding-system charset)))
 342     (when cs
 343       (when (and (eq cs 'ascii)
 344                  mail-parse-charset)
 345         (setq cs mail-parse-charset))
 346       (mm-decode-coding-string
 347        (cond
 348         ((equal "B" encoding)
 349          (base64-decode-string string))
 350         ((equal "Q" encoding)
 351          (quoted-printable-decode-string
 352           (mm-replace-chars-in-string string ?_ ? )))
 353         (t (error "Invalid encoding: %s" encoding)))
 354        cs))))
 355
 356 (provide 'rfc2047)
 357
 358 ;;; rfc2047.el ends here