git.chise.org Git - elisp/gnus.git-/blob - lisp/rfc2047.el

   1 ;;; rfc2047.el --- Functions for encoding and decoding rfc2047 messages
   2 ;; Copyright (C) 1998 Free Software Foundation, Inc.
   3
   4 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   5 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-and-compile
  28   (eval
  29    '(if (not (fboundp 'base64-encode-string))
  30         (require 'base64))))
  31 (require 'qp)
  32 (require 'mm-util)
  33
  34 (defvar rfc2047-default-charset 'iso-8859-1
  35   "Default MIME charset -- does not need encoding.")
  36
  37 (defvar rfc2047-header-encoding-alist
  38   '(("Newsgroups" . nil)
  39     ("Message-ID" . nil)
  40     (t . mime))
  41   "*Header/encoding method alist.
  42 The list is traversed sequentially.  The keys can either be
  43 header regexps or `t'.
  44
  45 The values can be:
  46
  47 1) nil, in which case no encoding is done;
  48 2) `mime', in which case the header will be encoded according to RFC2047;
  49 3) a charset, in which case it will be encoded as that charse;
  50 4) `default', in which case the field will be encoded as the rest
  51    of the article.")
  52
  53 (defvar rfc2047-charset-encoding-alist
  54   '((us-ascii . nil)
  55     (iso-8859-1 . Q)
  56     (iso-8859-2 . Q)
  57     (iso-8859-3 . Q)
  58     (iso-8859-4 . Q)
  59     (iso-8859-5 . B)
  60     (koi8-r . Q)
  61     (iso-8859-7 . Q)
  62     (iso-8859-8 . Q)
  63     (iso-8859-9 . Q)
  64     (iso-2022-jp . B)
  65     (iso-2022-kr . B)
  66     (gb2312 . B)
  67     (cn-gb . B)
  68     (cn-gb-2312 . B)
  69     (euc-kr . B)
  70     (iso-2022-jp-2 . B)
  71     (iso-2022-int-1 . B))
  72   "Alist of MIME charsets to RFC2047 encodings.
  73 Valid encodings are nil, `Q' and `B'.")
  74
  75 (defvar rfc2047-encoding-function-alist
  76   '((Q . rfc2047-q-encode-region)
  77     (B . rfc2047-b-encode-region)
  78     (nil . ignore))
  79   "Alist of RFC2047 encodings to encoding functions.")
  80
  81 (defvar rfc2047-q-encoding-alist
  82   '(("\\(From\\|Cc\\|To\\|Bcc\||Reply-To\\):" . "-A-Za-z0-9!*+/=_")
  83     ("." . "^\000-\007\013\015-\037\200-\377=_?"))
  84   "Alist of header regexps and valid Q characters.")
  85
  86 ;;;
  87 ;;; Functions for encoding RFC2047 messages
  88 ;;;
  89
  90 (defun rfc2047-narrow-to-field ()
  91   "Narrow the buffer to the header on the current line."
  92   (beginning-of-line)
  93   (narrow-to-region
  94    (point)
  95    (progn
  96      (forward-line 1)
  97      (if (re-search-forward "^[^ \n\t]" nil t)
  98          (progn
  99            (beginning-of-line)
 100            (point))
 101        (point-max))))
 102   (goto-char (point-min)))
 103
 104 ;;;###autoload
 105 (defun rfc2047-encode-message-header ()
 106   "Encode the message header according to `rfc2047-header-encoding-alist'.
 107 Should be called narrowed to the head of the message."
 108   (interactive "*")
 109   (when (featurep 'mule)
 110     (save-excursion
 111       (let ((alist rfc2047-header-encoding-alist)
 112             elem method)
 113         (while (not (eobp))
 114           (save-restriction
 115             (rfc2047-narrow-to-field)
 116             (when (rfc2047-encodable-p)
 117               ;; We found something that may perhaps be encoded.
 118               (while (setq elem (pop alist))
 119                 (when (or (and (stringp (car elem))
 120                                (looking-at (car elem)))
 121                           (eq (car elem) t))
 122                   (setq alist nil
 123                         method (cdr elem))))
 124               (when method
 125                 (cond
 126                  ((eq method 'mime)
 127                   (rfc2047-encode-region (point-min) (point-max)))
 128                  ;; Hm.
 129                  (t))))
 130             (goto-char (point-max))))))))
 131
 132 (defun rfc2047-encodable-p ()
 133   "Say whether the current (narrowed) buffer contains characters that need encoding."
 134   (let ((charsets (mapcar
 135                    'mm-mule-charset-to-mime-charset
 136                    (find-charset-region (point-min) (point-max))))
 137         (cs (list 'us-ascii rfc2047-default-charset))
 138         found)
 139     (while charsets
 140       (unless (memq (pop charsets) cs)
 141         (setq found t)))
 142     found))
 143
 144 (defun rfc2047-dissect-region (b e)
 145   "Dissect the region between B and E."
 146   (let (words)
 147     (save-restriction
 148       (narrow-to-region b e)
 149       (goto-char (point-min))
 150       (while (re-search-forward "[^ \t\n]+" nil t)
 151         (push
 152          (list (match-beginning 0) (match-end 0)
 153                (car
 154                 (delq 'ascii
 155                       (find-charset-region (match-beginning 0)
 156                                            (match-end 0)))))
 157          words))
 158       words)))
 159
 160 (defun rfc2047-encode-region (b e)
 161   "Encode all encodable words in REGION."
 162   (let ((words (rfc2047-dissect-region b e))
 163         beg end current word)
 164     (while (setq word (pop words))
 165       (if (equal (nth 2 word) current)
 166           (setq beg (nth 0 word))
 167         (when current
 168           (rfc2047-encode beg end current))
 169         (setq current (nth 2 word)
 170               beg (nth 0 word)
 171               end (nth 1 word))))
 172     (when current
 173       (rfc2047-encode beg end current))))
 174
 175 (defun rfc2047-encode-string (string)
 176   "Encode words in STRING."
 177   (with-temp-buffer
 178     (insert string)
 179     (rfc2047-encode-region (point-min) (point-max))
 180     (buffer-string)))
 181
 182 (defun rfc2047-encode (b e charset)
 183   "Encode the word in the region with CHARSET."
 184   (let* ((mime-charset
 185           (mm-mime-charset charset b e))
 186          (encoding (or (cdr (assq mime-charset
 187                               rfc2047-charset-encoding-alist))
 188                        'B))
 189          (start (concat
 190                  "=?" (downcase (symbol-name mime-charset)) "?"
 191                  (downcase (symbol-name encoding)) "?")))
 192     (save-restriction
 193       (narrow-to-region b e)
 194       (mm-encode-coding-region b e mime-charset)
 195       (funcall (cdr (assq encoding rfc2047-encoding-function-alist))
 196                (point-min) (point-max))
 197       (goto-char (point-min))
 198       (insert start)
 199       (goto-char (point-max))
 200       (insert "?=")
 201       ;; Encoded words can't be more than 75 chars long, so we have to
 202       ;; split the long ones up.
 203       (end-of-line)
 204       (while (> (current-column) 74)
 205         (beginning-of-line)
 206         (forward-char 73)
 207         (insert "?=\n " start)
 208         (end-of-line)))))
 209
 210 (defun rfc2047-b-encode-region (b e)
 211   "Encode the header contained in REGION with the B encoding."
 212   (base64-encode-region b e t))
 213
 214 (defun rfc2047-q-encode-region (b e)
 215   "Encode the header contained in REGION with the Q encoding."
 216   (save-excursion
 217     (save-restriction
 218       (narrow-to-region (goto-char b) e)
 219       (let ((alist rfc2047-q-encoding-alist))
 220         (while alist
 221           (when (looking-at (caar alist))
 222             (quoted-printable-encode-region b e nil (cdar alist))
 223             (subst-char-in-region (point-min) (point-max) ?  ?_))
 224           (pop alist))))))
 225
 226 ;;;
 227 ;;; Functions for decoding RFC2047 messages
 228 ;;;
 229
 230 (defvar rfc2047-encoded-word-regexp
 231   "=\\?\\([^][\000-\040()<>@,\;:\\\"/?.=]+\\)\\?\\(B\\|Q\\)\\?\\([!->@-~ ]+\\)\\?=")
 232
 233 ;;;###autoload
 234 (defun rfc2047-decode-region (start end)
 235   "Decode MIME-encoded words in region between START and END."
 236   (interactive "r")
 237   (let ((case-fold-search t)
 238         b e)
 239     (save-excursion
 240       (save-restriction
 241         (narrow-to-region start end)
 242         (goto-char (point-min))
 243         ;; Remove whitespace between encoded words.
 244         (while (re-search-forward
 245                 (concat "\\(" rfc2047-encoded-word-regexp "\\)"
 246                         "\\(\n?[ \t]\\)+"
 247                         "\\(" rfc2047-encoded-word-regexp "\\)")
 248                 nil t)
 249           (delete-region (goto-char (match-end 1)) (match-beginning 6)))
 250         ;; Decode the encoded words.
 251         (setq b (goto-char (point-min)))
 252         (while (re-search-forward rfc2047-encoded-word-regexp nil t)
 253           (setq e (match-beginning 0))
 254           (insert (rfc2047-parse-and-decode
 255                    (prog1
 256                        (match-string 0)
 257                      (delete-region (match-beginning 0) (match-end 0)))))
 258           (when (mm-multibyte-p)
 259             (mm-decode-coding-region b e rfc2047-default-charset))
 260           (setq b (point)))
 261         (when (mm-multibyte-p)
 262           (mm-decode-coding-region b (point-max) rfc2047-default-charset))))))
 263
 264 ;;;###autoload
 265 (defun rfc2047-decode-string (string)
 266   "Decode the quoted-printable-encoded STRING and return the results."
 267   (let ((m (mm-multibyte-p)))
 268     (with-temp-buffer
 269       (when m
 270         (mm-enable-multibyte))
 271       (insert string)
 272       (inline
 273         (rfc2047-decode-region (point-min) (point-max)))
 274       (buffer-string))))
 275
 276 (defun rfc2047-parse-and-decode (word)
 277   "Decode WORD and return it if it is an encoded word.
 278 Return WORD if not."
 279   (if (not (string-match rfc2047-encoded-word-regexp word))
 280       word
 281     (or
 282      (condition-case nil
 283          (rfc2047-decode
 284           (match-string 1 word)
 285           (upcase (match-string 2 word))
 286           (match-string 3 word))
 287        (error word))
 288      word)))
 289
 290 (defun rfc2047-decode (charset encoding string)
 291   "Decode STRING that uses CHARSET with ENCODING.
 292 Valid ENCODINGs are \"B\" and \"Q\".
 293 If your Emacs implementation can't decode CHARSET, it returns nil."
 294   (let ((cs (mm-charset-to-coding-system charset)))
 295     (when cs
 296       (mm-decode-coding-string
 297        (cond
 298         ((equal "B" encoding)
 299          (if (fboundp 'base64-decode-string)
 300              (base64-decode-string string)
 301            (base64-decode string)))
 302         ((equal "Q" encoding)
 303          (quoted-printable-decode-string
 304           (mm-replace-chars-in-string string ?_ ? )))
 305         (t (error "Invalid encoding: %s" encoding)))
 306        cs))))
 307
 308 (provide 'rfc2047)
 309
 310 ;;; rfc2047.el ends here